[deliverable/linux.git] / arch / arm64 / mm / proc.S

/*
 * Based on arch/arm/mm/proc.S
 *
 * Copyright (C) 2001 Deep Blue Solutions Ltd.
 * Copyright (C) 2012 ARM Ltd.
 * Author: Catalin Marinas <catalin.marinas@arm.com>
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */

#include <linux/init.h>
#include <linux/linkage.h>
#include <asm/assembler.h>
#include <asm/asm-offsets.h>
#include <asm/hwcap.h>
#include <asm/pgtable.h>
#include <asm/pgtable-hwdef.h>
#include <asm/cpufeature.h>
#include <asm/alternative.h>

#ifdef CONFIG_ARM64_64K_PAGES
#define TCR_TG_FLAGS	TCR_TG0_64K | TCR_TG1_64K
#elif defined(CONFIG_ARM64_16K_PAGES)
#define TCR_TG_FLAGS	TCR_TG0_16K | TCR_TG1_16K
#else /* CONFIG_ARM64_4K_PAGES */
#define TCR_TG_FLAGS	TCR_TG0_4K | TCR_TG1_4K
#endif

#define TCR_SMP_FLAGS	TCR_SHARED

/* PTWs cacheable, inner/outer WBWA */
#define TCR_CACHE_FLAGS	TCR_IRGN_WBWA | TCR_ORGN_WBWA

#define MAIR(attr, mt)	((attr) << ((mt) * 8))

/*
 *	cpu_do_idle()
 *
 *	Idle the processor (wait for interrupt).
 */
ENTRY(cpu_do_idle)
	dsb	sy				// WFI may enter a low-power mode
	wfi
	ret
ENDPROC(cpu_do_idle)

#ifdef CONFIG_CPU_PM
/**
 * cpu_do_suspend - save CPU registers context
 *
 * x0: virtual address of context pointer
 */
ENTRY(cpu_do_suspend)
	mrs	x2, tpidr_el0
	mrs	x3, tpidrro_el0
	mrs	x4, contextidr_el1
	mrs	x5, cpacr_el1
	mrs	x6, tcr_el1
	mrs	x7, vbar_el1
	mrs	x8, mdscr_el1
	mrs	x9, oslsr_el1
	mrs	x10, sctlr_el1
	stp	x2, x3, [x0]
	stp	x4, xzr, [x0, #16]
	stp	x5, x6, [x0, #32]
	stp	x7, x8, [x0, #48]
	stp	x9, x10, [x0, #64]
	ret
ENDPROC(cpu_do_suspend)

/**
 * cpu_do_resume - restore CPU register context
 *
 * x0: Address of context pointer
 */
	.pushsection ".idmap.text", "ax"
ENTRY(cpu_do_resume)
	ldp	x2, x3, [x0]
	ldp	x4, x5, [x0, #16]
	ldp	x6, x8, [x0, #32]
	ldp	x9, x10, [x0, #48]
	ldp	x11, x12, [x0, #64]
	msr	tpidr_el0, x2
	msr	tpidrro_el0, x3
	msr	contextidr_el1, x4
	msr	cpacr_el1, x6

	/* Don't change t0sz here, mask those bits when restoring */
	mrs	x5, tcr_el1
	bfi	x8, x5, TCR_T0SZ_OFFSET, TCR_TxSZ_WIDTH

	msr	tcr_el1, x8
	msr	vbar_el1, x9

	/*
	 * __cpu_setup() cleared MDSCR_EL1.MDE and friends, before unmasking
	 * debug exceptions. By restoring MDSCR_EL1 here, we may take a debug
	 * exception. Mask them until local_dbg_restore() in cpu_suspend()
	 * resets them.
	 */
	disable_dbg
	msr	mdscr_el1, x10

	msr	sctlr_el1, x12
	/*
	 * Restore oslsr_el1 by writing oslar_el1
	 */
	ubfx	x11, x11, #1, #1
	msr	oslar_el1, x11
	reset_pmuserenr_el0 x0			// Disable PMU access from EL0
	isb
	ret
ENDPROC(cpu_do_resume)
	.popsection
#endif

/*
 *	cpu_do_switch_mm(pgd_phys, tsk)
 *
 *	Set the translation table base pointer to be pgd_phys.
 *
 *	- pgd_phys - physical address of new TTB
 */
ENTRY(cpu_do_switch_mm)
	mmid	x1, x1				// get mm->context.id
	bfi	x0, x1, #48, #16		// set the ASID
	msr	ttbr0_el1, x0			// set TTBR0
	isb
alternative_if ARM64_WORKAROUND_CAVIUM_27456
	ic	iallu
	dsb	nsh
	isb
alternative_else_nop_endif
	ret
ENDPROC(cpu_do_switch_mm)

	.pushsection ".idmap.text", "ax"
/*
 * void idmap_cpu_replace_ttbr1(phys_addr_t new_pgd)
 *
 * This is the low-level counterpart to cpu_replace_ttbr1, and should not be
 * called by anything else. It can only be executed from a TTBR0 mapping.
 */
ENTRY(idmap_cpu_replace_ttbr1)
	mrs	x2, daif
	msr	daifset, #0xf

	adrp	x1, empty_zero_page
	msr	ttbr1_el1, x1
	isb

	tlbi	vmalle1
	dsb	nsh
	isb

	msr	ttbr1_el1, x0
	isb

	msr	daif, x2

	ret
ENDPROC(idmap_cpu_replace_ttbr1)
	.popsection

/*
 *	__cpu_setup
 *
 *	Initialise the processor for turning the MMU on.  Return in x0 the
 *	value of the SCTLR_EL1 register.
 */
	.pushsection ".idmap.text", "ax"
ENTRY(__cpu_setup)
	tlbi	vmalle1				// Invalidate local TLB
	dsb	nsh

	mov	x0, #3 << 20
	msr	cpacr_el1, x0			// Enable FP/ASIMD
	mov	x0, #1 << 12			// Reset mdscr_el1 and disable
	msr	mdscr_el1, x0			// access to the DCC from EL0
	isb					// Unmask debug exceptions now,
	enable_dbg				// since this is per-cpu
	reset_pmuserenr_el0 x0			// Disable PMU access from EL0
	/*
	 * Memory region attributes for LPAE:
	 *
	 *   n = AttrIndx[2:0]
	 *			n	MAIR
	 *   DEVICE_nGnRnE	000	00000000
	 *   DEVICE_nGnRE	001	00000100
	 *   DEVICE_GRE		010	00001100
	 *   NORMAL_NC		011	01000100
	 *   NORMAL		100	11111111
	 *   NORMAL_WT		101	10111011
	 */
	ldr	x5, =MAIR(0x00, MT_DEVICE_nGnRnE) | \
		     MAIR(0x04, MT_DEVICE_nGnRE) | \
		     MAIR(0x0c, MT_DEVICE_GRE) | \
		     MAIR(0x44, MT_NORMAL_NC) | \
		     MAIR(0xff, MT_NORMAL) | \
		     MAIR(0xbb, MT_NORMAL_WT)
	msr	mair_el1, x5
	/*
	 * Prepare SCTLR
	 */
	adr	x5, crval
	ldp	w5, w6, [x5]
	mrs	x0, sctlr_el1
	bic	x0, x0, x5			// clear bits
	orr	x0, x0, x6			// set bits
	/*
	 * Set/prepare TCR and TTBR. We use 512GB (39-bit) address range for
	 * both user and kernel.
	 */
	ldr	x10, =TCR_TxSZ(VA_BITS) | TCR_CACHE_FLAGS | TCR_SMP_FLAGS | \
			TCR_TG_FLAGS | TCR_ASID16 | TCR_TBI0
	tcr_set_idmap_t0sz	x10, x9

	/*
	 * Read the PARange bits from ID_AA64MMFR0_EL1 and set the IPS bits in
	 * TCR_EL1.
	 */
	mrs	x9, ID_AA64MMFR0_EL1
	bfi	x10, x9, #32, #3
#ifdef CONFIG_ARM64_HW_AFDBM
	/*
	 * Hardware update of the Access and Dirty bits.
	 */
	mrs	x9, ID_AA64MMFR1_EL1
	and	x9, x9, #0xf
	cbz	x9, 2f
	cmp	x9, #2
	b.lt	1f
	orr	x10, x10, #TCR_HD		// hardware Dirty flag update
1:	orr	x10, x10, #TCR_HA		// hardware Access flag update
2:
#endif	/* CONFIG_ARM64_HW_AFDBM */
	msr	tcr_el1, x10
	ret					// return to head.S
ENDPROC(__cpu_setup)

	/*
	 * We set the desired value explicitly, including those of the
	 * reserved bits. The values of bits EE & E0E were set early in
	 * el2_setup, which are left untouched below.
	 *
	 *                 n n            T
	 *       U E      WT T UD     US IHBS
	 *       CE0      XWHW CZ     ME TEEA S
	 * .... .IEE .... NEAI TE.I ..AD DEN0 ACAM
	 * 0011 0... 1101 ..0. ..0. 10.. .0.. .... < hardware reserved
	 * .... .1.. .... 01.1 11.1 ..01 0.01 1101 < software settings
	 */
	.type	crval, #object
crval:
	.word	0xfcffffff			// clear
	.word	0x34d5d91d			// set
	.popsection
Commit	Line	Data
9cce7a43 CM	1	/*
	2	* Based on arch/arm/mm/proc.S
	3	*
	4	* Copyright (C) 2001 Deep Blue Solutions Ltd.
	5	* Copyright (C) 2012 ARM Ltd.
	6	* Author: Catalin Marinas <catalin.marinas@arm.com>
	7	*
	8	* This program is free software; you can redistribute it and/or modify
	9	* it under the terms of the GNU General Public License version 2 as
	10	* published by the Free Software Foundation.
	11	*
	12	* This program is distributed in the hope that it will be useful,
	13	* but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	* GNU General Public License for more details.
	16	*
	17	* You should have received a copy of the GNU General Public License
	18	* along with this program. If not, see <http://www.gnu.org/licenses/>.
	19	*/
	20
	21	#include <linux/init.h>
	22	#include <linux/linkage.h>
	23	#include <asm/assembler.h>
	24	#include <asm/asm-offsets.h>
	25	#include <asm/hwcap.h>
9cce7a43	26	#include <asm/pgtable.h>
cabe1c81	27	#include <asm/pgtable-hwdef.h>
104a0c02 AP	28	#include <asm/cpufeature.h>
104a0c02 AP	29	#include <asm/alternative.h>
9cce7a43	30
35a86976 CM	31	#ifdef CONFIG_ARM64_64K_PAGES
35a86976 CM	32	#define TCR_TG_FLAGS TCR_TG0_64K \| TCR_TG1_64K
44eaacf1 SP	33	#elif defined(CONFIG_ARM64_16K_PAGES)
	34	#define TCR_TG_FLAGS TCR_TG0_16K \| TCR_TG1_16K
	35	#else /* CONFIG_ARM64_4K_PAGES */
35a86976 CM	36	#define TCR_TG_FLAGS TCR_TG0_4K \| TCR_TG1_4K
	37	#endif
	38
35a86976	39	#define TCR_SMP_FLAGS TCR_SHARED
9cce7a43	40
35a86976 CM	41	/* PTWs cacheable, inner/outer WBWA */
	42	#define TCR_CACHE_FLAGS TCR_IRGN_WBWA \| TCR_ORGN_WBWA
	43
9cce7a43 CM	44	#define MAIR(attr, mt) ((attr) << ((mt) * 8))
9cce7a43 CM	45
9cce7a43 CM	46	/*
	47	* cpu_do_idle()
	48	*
	49	* Idle the processor (wait for interrupt).
	50	*/
	51	ENTRY(cpu_do_idle)
	52	dsb sy // WFI may enter a low-power mode
	53	wfi
	54	ret
	55	ENDPROC(cpu_do_idle)
	56
af3cfdbf	57	#ifdef CONFIG_CPU_PM
6732bc65 LP	58	/**
	59	* cpu_do_suspend - save CPU registers context
	60	*
	61	* x0: virtual address of context pointer
	62	*/
	63	ENTRY(cpu_do_suspend)
	64	mrs x2, tpidr_el0
	65	mrs x3, tpidrro_el0
	66	mrs x4, contextidr_el1
cabe1c81 JM	67	mrs x5, cpacr_el1
	68	mrs x6, tcr_el1
	69	mrs x7, vbar_el1
	70	mrs x8, mdscr_el1
	71	mrs x9, oslsr_el1
	72	mrs x10, sctlr_el1
6732bc65	73	stp x2, x3, [x0]
cabe1c81 JM	74	stp x4, xzr, [x0, #16]
	75	stp x5, x6, [x0, #32]
	76	stp x7, x8, [x0, #48]
	77	stp x9, x10, [x0, #64]
6732bc65 LP	78	ret
	79	ENDPROC(cpu_do_suspend)
	80
	81	/**
	82	* cpu_do_resume - restore CPU register context
	83	*
cabe1c81	84	* x0: Address of context pointer
6732bc65	85	*/
b6113038	86	.pushsection ".idmap.text", "ax"
6732bc65	87	ENTRY(cpu_do_resume)
6732bc65 LP	88	ldp x2, x3, [x0]
6732bc65 LP	89	ldp x4, x5, [x0, #16]
cabe1c81 JM	90	ldp x6, x8, [x0, #32]
	91	ldp x9, x10, [x0, #48]
	92	ldp x11, x12, [x0, #64]
6732bc65 LP	93	msr tpidr_el0, x2
	94	msr tpidrro_el0, x3
	95	msr contextidr_el1, x4
6732bc65	96	msr cpacr_el1, x6
cabe1c81 JM	97
	98	/* Don't change t0sz here, mask those bits when restoring */
	99	mrs x5, tcr_el1
	100	bfi x8, x5, TCR_T0SZ_OFFSET, TCR_TxSZ_WIDTH
	101
6732bc65 LP	102	msr tcr_el1, x8
6732bc65 LP	103	msr vbar_el1, x9
744c6c37 JM	104
	105	/*
	106	* __cpu_setup() cleared MDSCR_EL1.MDE and friends, before unmasking
	107	* debug exceptions. By restoring MDSCR_EL1 here, we may take a debug
	108	* exception. Mask them until local_dbg_restore() in cpu_suspend()
	109	* resets them.
	110	*/
	111	disable_dbg
6732bc65	112	msr mdscr_el1, x10
744c6c37	113
cabe1c81	114	msr sctlr_el1, x12
6732bc65 LP	115	/*
	116	* Restore oslsr_el1 by writing oslar_el1
	117	*/
	118	ubfx x11, x11, #1, #1
	119	msr oslar_el1, x11
f436b2ac	120	reset_pmuserenr_el0 x0 // Disable PMU access from EL0
6732bc65 LP	121	isb
	122	ret
	123	ENDPROC(cpu_do_resume)
b6113038	124	.popsection
6732bc65 LP	125	#endif
6732bc65 LP	126
9cce7a43	127	/*
812944e9	128	* cpu_do_switch_mm(pgd_phys, tsk)
9cce7a43 CM	129	*
	130	* Set the translation table base pointer to be pgd_phys.
	131	*
	132	* - pgd_phys - physical address of new TTB
	133	*/
	134	ENTRY(cpu_do_switch_mm)
5aec715d	135	mmid x1, x1 // get mm->context.id
9cce7a43 CM	136	bfi x0, x1, #48, #16 // set the ASID
	137	msr ttbr0_el1, x0 // set TTBR0
	138	isb
6ba3b554	139	alternative_if ARM64_WORKAROUND_CAVIUM_27456
104a0c02 AP	140	ic iallu
	141	dsb nsh
	142	isb
6ba3b554	143	alternative_else_nop_endif
104a0c02	144	ret
9cce7a43 CM	145	ENDPROC(cpu_do_switch_mm)
9cce7a43 CM	146
50e1881d MR	147	.pushsection ".idmap.text", "ax"
	148	/*
	149	* void idmap_cpu_replace_ttbr1(phys_addr_t new_pgd)
	150	*
	151	* This is the low-level counterpart to cpu_replace_ttbr1, and should not be
	152	* called by anything else. It can only be executed from a TTBR0 mapping.
	153	*/
	154	ENTRY(idmap_cpu_replace_ttbr1)
	155	mrs x2, daif
	156	msr daifset, #0xf
	157
	158	adrp x1, empty_zero_page
	159	msr ttbr1_el1, x1
	160	isb
	161
	162	tlbi vmalle1
	163	dsb nsh
	164	isb
	165
	166	msr ttbr1_el1, x0
	167	isb
	168
	169	msr daif, x2
	170
	171	ret
	172	ENDPROC(idmap_cpu_replace_ttbr1)
	173	.popsection
	174
9cce7a43 CM	175	/*
	176	* __cpu_setup
	177	*
	178	* Initialise the processor for turning the MMU on. Return in x0 the
	179	* value of the SCTLR_EL1 register.
	180	*/
b6113038	181	.pushsection ".idmap.text", "ax"
9cce7a43	182	ENTRY(__cpu_setup)
fa7aae8a WD	183	tlbi vmalle1 // Invalidate local TLB
fa7aae8a WD	184	dsb nsh
9cce7a43 CM	185
	186	mov x0, #3 << 20
	187	msr cpacr_el1, x0 // Enable FP/ASIMD
d8d23fa0 WD	188	mov x0, #1 << 12 // Reset mdscr_el1 and disable
d8d23fa0 WD	189	msr mdscr_el1, x0 // access to the DCC from EL0
2ce39ad1 WD	190	isb // Unmask debug exceptions now,
2ce39ad1 WD	191	enable_dbg // since this is per-cpu
f436b2ac	192	reset_pmuserenr_el0 x0 // Disable PMU access from EL0
9cce7a43 CM	193	/*
	194	* Memory region attributes for LPAE:
	195	*
	196	* n = AttrIndx[2:0]
	197	* n MAIR
	198	* DEVICE_nGnRnE 000 00000000
	199	* DEVICE_nGnRE 001 00000100
	200	* DEVICE_GRE 010 00001100
	201	* NORMAL_NC 011 01000100
	202	* NORMAL 100 11111111
8d446c86	203	* NORMAL_WT 101 10111011
9cce7a43 CM	204	*/
	205	ldr x5, =MAIR(0x00, MT_DEVICE_nGnRnE) \| \
	206	MAIR(0x04, MT_DEVICE_nGnRE) \| \
	207	MAIR(0x0c, MT_DEVICE_GRE) \| \
	208	MAIR(0x44, MT_NORMAL_NC) \| \
8d446c86 JZZ	209	MAIR(0xff, MT_NORMAL) \| \
8d446c86 JZZ	210	MAIR(0xbb, MT_NORMAL_WT)
9cce7a43 CM	211	msr mair_el1, x5
	212	/*
	213	* Prepare SCTLR
	214	*/
	215	adr x5, crval
	216	ldp w5, w6, [x5]
	217	mrs x0, sctlr_el1
	218	bic x0, x0, x5 // clear bits
	219	orr x0, x0, x6 // set bits
	220	/*
	221	* Set/prepare TCR and TTBR. We use 512GB (39-bit) address range for
	222	* both user and kernel.
	223	*/
35a86976 CM	224	ldr x10, =TCR_TxSZ(VA_BITS) \| TCR_CACHE_FLAGS \| TCR_SMP_FLAGS \| \
35a86976 CM	225	TCR_TG_FLAGS \| TCR_ASID16 \| TCR_TBI0
dd006da2 AB	226	tcr_set_idmap_t0sz x10, x9
dd006da2 AB	227
87366d8c RMC	228	/*
	229	* Read the PARange bits from ID_AA64MMFR0_EL1 and set the IPS bits in
	230	* TCR_EL1.
	231	*/
	232	mrs x9, ID_AA64MMFR0_EL1
	233	bfi x10, x9, #32, #3
2f4b829c CM	234	#ifdef CONFIG_ARM64_HW_AFDBM
	235	/*
	236	* Hardware update of the Access and Dirty bits.
	237	*/
	238	mrs x9, ID_AA64MMFR1_EL1
	239	and x9, x9, #0xf
	240	cbz x9, 2f
	241	cmp x9, #2
	242	b.lt 1f
	243	orr x10, x10, #TCR_HD // hardware Dirty flag update
	244	1: orr x10, x10, #TCR_HA // hardware Access flag update
	245	2:
	246	#endif /* CONFIG_ARM64_HW_AFDBM */
9cce7a43 CM	247	msr tcr_el1, x10
	248	ret // return to head.S
	249	ENDPROC(__cpu_setup)
	250
	251	/*
9f71ac96 SP	252	* We set the desired value explicitly, including those of the
	253	* reserved bits. The values of bits EE & E0E were set early in
	254	* el2_setup, which are left untouched below.
	255	*
9cce7a43 CM	256	* n n T
	257	* U E WT T UD US IHBS
	258	* CE0 XWHW CZ ME TEEA S
	259	* .... .IEE .... NEAI TE.I ..AD DEN0 ACAM
9f71ac96 SP	260	* 0011 0... 1101 ..0. ..0. 10.. .0.. .... < hardware reserved
9f71ac96 SP	261	* .... .1.. .... 01.1 11.1 ..01 0.01 1101 < software settings
9cce7a43 CM	262	*/
	263	.type crval, #object
	264	crval:
9f71ac96 SP	265	.word 0xfcffffff // clear
9f71ac96 SP	266	.word 0x34d5d91d // set
b6113038	267	.popsection