Commit | Line | Data |
---|---|---|
1da177e4 LT |
1 | /* |
2 | * linux/boot/head.S | |
3 | * | |
4 | * Copyright (C) 1991, 1992, 1993 Linus Torvalds | |
1da177e4 LT |
5 | */ |
6 | ||
7 | /* | |
8 | * head.S contains the 32-bit startup code. | |
9 | * | |
10 | * NOTE!!! Startup happens at absolute address 0x00001000, which is also where | |
11 | * the page directory will exist. The startup code will be overwritten by | |
12 | * the page directory. [According to comments etc elsewhere on a compressed | |
13 | * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC] | |
14 | * | |
15 | * Page 0 is deliberately kept safe, since System Management Mode code in | |
16 | * laptops may need to access the BIOS data stored there. This is also | |
17 | * useful for future device drivers that either access the BIOS via VM86 | |
18 | * mode. | |
19 | */ | |
20 | ||
21 | /* | |
f4549448 | 22 | * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996 |
1da177e4 | 23 | */ |
b40d68d5 PA |
24 | .code32 |
25 | .text | |
1da177e4 | 26 | |
1dc818c1 | 27 | #include <linux/init.h> |
1da177e4 LT |
28 | #include <linux/linkage.h> |
29 | #include <asm/segment.h> | |
7c539764 | 30 | #include <asm/boot.h> |
1ab60e0f | 31 | #include <asm/msr.h> |
e83e31f4 | 32 | #include <asm/processor-flags.h> |
bd53147d | 33 | #include <asm/asm-offsets.h> |
fb148d83 | 34 | #include <asm/bootparam.h> |
1da177e4 | 35 | |
6d92bc9d L |
36 | /* |
37 | * Locally defined symbols should be marked hidden: | |
38 | */ | |
39 | .hidden _bss | |
40 | .hidden _ebss | |
41 | .hidden _got | |
42 | .hidden _egot | |
43 | ||
1dc818c1 | 44 | __HEAD |
1da177e4 | 45 | .code32 |
2d4eeecb | 46 | ENTRY(startup_32) |
8ee2f2df YL |
47 | /* |
48 | * 32bit entry is 0 and it is ABI so immutable! | |
49 | * If we come here directly from a bootloader, | |
50 | * kernel(text+data+bss+brk) ramdisk, zero_page, command line | |
51 | * all need to be under the 4G limit. | |
52 | */ | |
1da177e4 | 53 | cld |
b40d68d5 PA |
54 | /* |
55 | * Test KEEP_SEGMENTS flag to see if the bootloader is asking | |
56 | * us to not reload segments | |
57 | */ | |
fb148d83 | 58 | testb $KEEP_SEGMENTS, BP_loadflags(%esi) |
bd53147d EB |
59 | jnz 1f |
60 | ||
1da177e4 | 61 | cli |
2dead15f | 62 | movl $(__BOOT_DS), %eax |
1ab60e0f VG |
63 | movl %eax, %ds |
64 | movl %eax, %es | |
65 | movl %eax, %ss | |
bd53147d | 66 | 1: |
1ab60e0f | 67 | |
b40d68d5 PA |
68 | /* |
69 | * Calculate the delta between where we were compiled to run | |
1ab60e0f VG |
70 | * at and where we were actually loaded at. This can only be done |
71 | * with a short local call on x86. Nothing else will tell us what | |
72 | * address we are running at. The reserved chunk of the real-mode | |
85414b69 PA |
73 | * data at 0x1e4 (defined as a scratch field) are used as the stack |
74 | * for this calculation. Only 4 bytes are needed. | |
1ab60e0f | 75 | */ |
bd2a3698 | 76 | leal (BP_scratch+4)(%esi), %esp |
1ab60e0f VG |
77 | call 1f |
78 | 1: popl %ebp | |
79 | subl $1b, %ebp | |
80 | ||
a4831e08 | 81 | /* setup a stack and make sure cpu supports long mode. */ |
7c539764 | 82 | movl $boot_stack_end, %eax |
a4831e08 VG |
83 | addl %ebp, %eax |
84 | movl %eax, %esp | |
85 | ||
86 | call verify_cpu | |
87 | testl %eax, %eax | |
88 | jnz no_longmode | |
89 | ||
b40d68d5 PA |
90 | /* |
91 | * Compute the delta between where we were compiled to run at | |
1ab60e0f | 92 | * and where the code will actually run at. |
b40d68d5 PA |
93 | * |
94 | * %ebp contains the address we are loaded at by the boot loader and %ebx | |
1ab60e0f VG |
95 | * contains the address where we should move the kernel image temporarily |
96 | * for safe in-place decompression. | |
97 | */ | |
98 | ||
99 | #ifdef CONFIG_RELOCATABLE | |
100 | movl %ebp, %ebx | |
37ba7ab5 PA |
101 | movl BP_kernel_alignment(%esi), %eax |
102 | decl %eax | |
103 | addl %eax, %ebx | |
104 | notl %eax | |
105 | andl %eax, %ebx | |
8ab3820f KC |
106 | cmpl $LOAD_PHYSICAL_ADDR, %ebx |
107 | jge 1f | |
1ab60e0f | 108 | #endif |
8ab3820f KC |
109 | movl $LOAD_PHYSICAL_ADDR, %ebx |
110 | 1: | |
1ab60e0f | 111 | |
02a884c0 PA |
112 | /* Target address to relocate to for decompression */ |
113 | addl $z_extract_offset, %ebx | |
1da177e4 LT |
114 | |
115 | /* | |
1ab60e0f | 116 | * Prepare for entering 64 bit mode |
1da177e4 | 117 | */ |
1ab60e0f VG |
118 | |
119 | /* Load new GDT with the 64bit segments using 32bit descriptor */ | |
120 | leal gdt(%ebp), %eax | |
121 | movl %eax, gdt+2(%ebp) | |
122 | lgdt gdt(%ebp) | |
123 | ||
124 | /* Enable PAE mode */ | |
108d3f44 MF |
125 | movl %cr4, %eax |
126 | orl $X86_CR4_PAE, %eax | |
1ab60e0f VG |
127 | movl %eax, %cr4 |
128 | ||
129 | /* | |
130 | * Build early 4G boot pagetable | |
131 | */ | |
b40d68d5 | 132 | /* Initialize Page tables to 0 */ |
1ab60e0f VG |
133 | leal pgtable(%ebx), %edi |
134 | xorl %eax, %eax | |
135 | movl $((4096*6)/4), %ecx | |
136 | rep stosl | |
137 | ||
138 | /* Build Level 4 */ | |
139 | leal pgtable + 0(%ebx), %edi | |
140 | leal 0x1007 (%edi), %eax | |
141 | movl %eax, 0(%edi) | |
142 | ||
143 | /* Build Level 3 */ | |
144 | leal pgtable + 0x1000(%ebx), %edi | |
145 | leal 0x1007(%edi), %eax | |
146 | movl $4, %ecx | |
147 | 1: movl %eax, 0x00(%edi) | |
148 | addl $0x00001000, %eax | |
149 | addl $8, %edi | |
150 | decl %ecx | |
151 | jnz 1b | |
152 | ||
153 | /* Build Level 2 */ | |
154 | leal pgtable + 0x2000(%ebx), %edi | |
155 | movl $0x00000183, %eax | |
156 | movl $2048, %ecx | |
157 | 1: movl %eax, 0(%edi) | |
158 | addl $0x00200000, %eax | |
159 | addl $8, %edi | |
160 | decl %ecx | |
161 | jnz 1b | |
162 | ||
163 | /* Enable the boot page tables */ | |
164 | leal pgtable(%ebx), %eax | |
165 | movl %eax, %cr3 | |
166 | ||
167 | /* Enable Long mode in EFER (Extended Feature Enable Register) */ | |
168 | movl $MSR_EFER, %ecx | |
169 | rdmsr | |
170 | btsl $_EFER_LME, %eax | |
171 | wrmsr | |
172 | ||
d3c433bf YL |
173 | /* After gdt is loaded */ |
174 | xorl %eax, %eax | |
175 | lldt %ax | |
40e4f2d1 | 176 | movl $__BOOT_TSS, %eax |
d3c433bf YL |
177 | ltr %ax |
178 | ||
b40d68d5 PA |
179 | /* |
180 | * Setup for the jump to 64bit mode | |
1ab60e0f VG |
181 | * |
182 | * When the jump is performend we will be in long mode but | |
183 | * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1 | |
184 | * (and in turn EFER.LMA = 1). To jump into 64bit mode we use | |
185 | * the new gdt/idt that has __KERNEL_CS with CS.L = 1. | |
186 | * We place all of the values on our mini stack so lret can | |
187 | * used to perform that far jump. | |
188 | */ | |
189 | pushl $__KERNEL_CS | |
190 | leal startup_64(%ebp), %eax | |
b8ff87a6 MF |
191 | #ifdef CONFIG_EFI_MIXED |
192 | movl efi32_config(%ebp), %ebx | |
193 | cmp $0, %ebx | |
194 | jz 1f | |
195 | leal handover_entry(%ebp), %eax | |
196 | 1: | |
197 | #endif | |
1ab60e0f VG |
198 | pushl %eax |
199 | ||
200 | /* Enter paged protected Mode, activating Long Mode */ | |
e83e31f4 | 201 | movl $(X86_CR0_PG | X86_CR0_PE), %eax /* Enable Paging and Protected mode */ |
1ab60e0f VG |
202 | movl %eax, %cr0 |
203 | ||
204 | /* Jump from 32bit compatibility mode into 64bit mode. */ | |
205 | lret | |
2d4eeecb | 206 | ENDPROC(startup_32) |
1ab60e0f | 207 | |
b8ff87a6 MF |
208 | #ifdef CONFIG_EFI_MIXED |
209 | .org 0x190 | |
210 | ENTRY(efi32_stub_entry) | |
211 | add $0x4, %esp /* Discard return address */ | |
212 | popl %ecx | |
213 | popl %edx | |
214 | popl %esi | |
215 | ||
216 | leal (BP_scratch+4)(%esi), %esp | |
217 | call 1f | |
218 | 1: pop %ebp | |
219 | subl $1b, %ebp | |
220 | ||
221 | movl %ecx, efi32_config(%ebp) | |
222 | movl %edx, efi32_config+8(%ebp) | |
223 | sgdtl efi32_boot_gdt(%ebp) | |
224 | ||
225 | leal efi32_config(%ebp), %eax | |
226 | movl %eax, efi_config(%ebp) | |
227 | ||
228 | jmp startup_32 | |
229 | ENDPROC(efi32_stub_entry) | |
230 | #endif | |
231 | ||
1ab60e0f | 232 | .code64 |
a4831e08 | 233 | .org 0x200 |
1ab60e0f | 234 | ENTRY(startup_64) |
b40d68d5 | 235 | /* |
8ee2f2df | 236 | * 64bit entry is 0x200 and it is ABI so immutable! |
b40d68d5 | 237 | * We come here either from startup_32 or directly from a |
8ee2f2df YL |
238 | * 64bit bootloader. |
239 | * If we come here from a bootloader, kernel(text+data+bss+brk), | |
240 | * ramdisk, zero_page, command line could be above 4G. | |
241 | * We depend on an identity mapped page table being provided | |
242 | * that maps our entire kernel(text+data+bss+brk), zero page | |
243 | * and command line. | |
1ab60e0f | 244 | */ |
291f3632 | 245 | #ifdef CONFIG_EFI_STUB |
b1994304 | 246 | /* |
99f857db DW |
247 | * The entry point for the PE/COFF executable is efi_pe_entry, so |
248 | * only legacy boot loaders will execute this jmp. | |
b1994304 MF |
249 | */ |
250 | jmp preferred_addr | |
251 | ||
99f857db | 252 | ENTRY(efi_pe_entry) |
54b52d87 MF |
253 | movq %rcx, efi64_config(%rip) /* Handle */ |
254 | movq %rdx, efi64_config+8(%rip) /* EFI System table pointer */ | |
255 | ||
256 | leaq efi64_config(%rip), %rax | |
257 | movq %rax, efi_config(%rip) | |
258 | ||
259 | call 1f | |
260 | 1: popq %rbp | |
261 | subq $1b, %rbp | |
262 | ||
263 | /* | |
f3670394 | 264 | * Relocate efi_config->call(). |
54b52d87 MF |
265 | */ |
266 | addq %rbp, efi64_config+88(%rip) | |
267 | ||
268 | movq %rax, %rdi | |
9ca8f72a MF |
269 | call make_boot_params |
270 | cmpq $0,%rax | |
54b52d87 MF |
271 | je fail |
272 | mov %rax, %rsi | |
7e8213c1 MF |
273 | leaq startup_32(%rip), %rax |
274 | movl %eax, BP_code32_start(%rsi) | |
54b52d87 | 275 | jmp 2f /* Skip the relocation */ |
9ca8f72a | 276 | |
b8ff87a6 | 277 | handover_entry: |
54b52d87 MF |
278 | call 1f |
279 | 1: popq %rbp | |
280 | subq $1b, %rbp | |
281 | ||
282 | /* | |
f3670394 | 283 | * Relocate efi_config->call(). |
54b52d87 MF |
284 | */ |
285 | movq efi_config(%rip), %rax | |
286 | addq %rbp, 88(%rax) | |
54b52d87 MF |
287 | 2: |
288 | movq efi_config(%rip), %rdi | |
291f3632 | 289 | call efi_main |
291f3632 | 290 | movq %rax,%rsi |
b1994304 MF |
291 | cmpq $0,%rax |
292 | jne 2f | |
54b52d87 | 293 | fail: |
b1994304 MF |
294 | /* EFI init failed, so hang. */ |
295 | hlt | |
54b52d87 | 296 | jmp fail |
b1994304 | 297 | 2: |
7e8213c1 | 298 | movl BP_code32_start(%esi), %eax |
291f3632 MF |
299 | leaq preferred_addr(%rax), %rax |
300 | jmp *%rax | |
301 | ||
302 | preferred_addr: | |
303 | #endif | |
1ab60e0f VG |
304 | |
305 | /* Setup data segments. */ | |
306 | xorl %eax, %eax | |
307 | movl %eax, %ds | |
308 | movl %eax, %es | |
309 | movl %eax, %ss | |
08da5a2c ZA |
310 | movl %eax, %fs |
311 | movl %eax, %gs | |
1ab60e0f | 312 | |
b40d68d5 PA |
313 | /* |
314 | * Compute the decompressed kernel start address. It is where | |
1ab60e0f VG |
315 | * we were loaded at aligned to a 2M boundary. %rbp contains the |
316 | * decompressed kernel start address. | |
317 | * | |
318 | * If it is a relocatable kernel then decompress and run the kernel | |
319 | * from load address aligned to 2MB addr, otherwise decompress and | |
40b387a8 | 320 | * run the kernel from LOAD_PHYSICAL_ADDR |
02a884c0 PA |
321 | * |
322 | * We cannot rely on the calculation done in 32-bit mode, since we | |
323 | * may have been invoked via the 64-bit entry point. | |
1ab60e0f VG |
324 | */ |
325 | ||
326 | /* Start with the delta to where the kernel will run at. */ | |
327 | #ifdef CONFIG_RELOCATABLE | |
328 | leaq startup_32(%rip) /* - $startup_32 */, %rbp | |
37ba7ab5 PA |
329 | movl BP_kernel_alignment(%rsi), %eax |
330 | decl %eax | |
331 | addq %rax, %rbp | |
332 | notq %rax | |
333 | andq %rax, %rbp | |
8ab3820f KC |
334 | cmpq $LOAD_PHYSICAL_ADDR, %rbp |
335 | jge 1f | |
1ab60e0f | 336 | #endif |
8ab3820f KC |
337 | movq $LOAD_PHYSICAL_ADDR, %rbp |
338 | 1: | |
1ab60e0f | 339 | |
02a884c0 PA |
340 | /* Target address to relocate to for decompression */ |
341 | leaq z_extract_offset(%rbp), %rbx | |
1ab60e0f | 342 | |
0a137736 PA |
343 | /* Set up the stack */ |
344 | leaq boot_stack_end(%rbx), %rsp | |
345 | ||
346 | /* Zero EFLAGS */ | |
347 | pushq $0 | |
348 | popfq | |
349 | ||
b40d68d5 PA |
350 | /* |
351 | * Copy the compressed kernel to the end of our buffer | |
1ab60e0f VG |
352 | * where decompression in place becomes safe. |
353 | */ | |
36d3793c PA |
354 | pushq %rsi |
355 | leaq (_bss-8)(%rip), %rsi | |
356 | leaq (_bss-8)(%rbx), %rdi | |
5b11f1ce | 357 | movq $_bss /* - $startup_32 */, %rcx |
36d3793c PA |
358 | shrq $3, %rcx |
359 | std | |
360 | rep movsq | |
361 | cld | |
362 | popq %rsi | |
1ab60e0f VG |
363 | |
364 | /* | |
365 | * Jump to the relocated address. | |
366 | */ | |
367 | leaq relocated(%rbx), %rax | |
368 | jmp *%rax | |
369 | ||
b8ff87a6 MF |
370 | #ifdef CONFIG_EFI_STUB |
371 | .org 0x390 | |
372 | ENTRY(efi64_stub_entry) | |
373 | movq %rdi, efi64_config(%rip) /* Handle */ | |
374 | movq %rsi, efi64_config+8(%rip) /* EFI System table pointer */ | |
375 | ||
376 | leaq efi64_config(%rip), %rax | |
377 | movq %rax, efi_config(%rip) | |
378 | ||
379 | movq %rdx, %rsi | |
380 | jmp handover_entry | |
381 | ENDPROC(efi64_stub_entry) | |
382 | #endif | |
383 | ||
b40d68d5 | 384 | .text |
1ab60e0f VG |
385 | relocated: |
386 | ||
1da177e4 | 387 | /* |
0a137736 | 388 | * Clear BSS (stack is currently empty) |
1da177e4 | 389 | */ |
36d3793c PA |
390 | xorl %eax, %eax |
391 | leaq _bss(%rip), %rdi | |
392 | leaq _ebss(%rip), %rcx | |
1ab60e0f | 393 | subq %rdi, %rcx |
36d3793c PA |
394 | shrq $3, %rcx |
395 | rep stosq | |
1ab60e0f | 396 | |
f3670394 LT |
397 | /* |
398 | * Adjust our own GOT | |
399 | */ | |
400 | leaq _got(%rip), %rdx | |
401 | leaq _egot(%rip), %rcx | |
402 | 1: | |
403 | cmpq %rcx, %rdx | |
404 | jae 2f | |
405 | addq %rbx, (%rdx) | |
406 | addq $8, %rdx | |
407 | jmp 1b | |
408 | 2: | |
409 | ||
1da177e4 LT |
410 | /* |
411 | * Do the decompression, and jump to the new kernel.. | |
412 | */ | |
02a884c0 | 413 | pushq %rsi /* Save the real mode argument */ |
e6023367 JM |
414 | movq $z_run_size, %r9 /* size of kernel with .bss and .brk */ |
415 | pushq %r9 | |
02a884c0 PA |
416 | movq %rsi, %rdi /* real mode address */ |
417 | leaq boot_heap(%rip), %rsi /* malloc area for uncompression */ | |
418 | leaq input_data(%rip), %rdx /* input_data */ | |
419 | movl $z_input_len, %ecx /* input_len */ | |
420 | movq %rbp, %r8 /* output target address */ | |
e6023367 | 421 | movq $z_output_len, %r9 /* decompressed length, end of relocs */ |
8ab3820f | 422 | call decompress_kernel /* returns kernel location in %rax */ |
e6023367 | 423 | popq %r9 |
1ab60e0f | 424 | popq %rsi |
1da177e4 | 425 | |
1da177e4 | 426 | /* |
1ab60e0f | 427 | * Jump to the decompressed kernel. |
1da177e4 | 428 | */ |
8ab3820f | 429 | jmp *%rax |
1da177e4 | 430 | |
187a8a73 YL |
431 | .code32 |
432 | no_longmode: | |
433 | /* This isn't an x86-64 CPU so hang */ | |
434 | 1: | |
435 | hlt | |
436 | jmp 1b | |
437 | ||
438 | #include "../../kernel/verify_cpu.S" | |
439 | ||
1ab60e0f VG |
440 | .data |
441 | gdt: | |
442 | .word gdt_end - gdt | |
443 | .long gdt | |
444 | .word 0 | |
445 | .quad 0x0000000000000000 /* NULL descriptor */ | |
446 | .quad 0x00af9a000000ffff /* __KERNEL_CS */ | |
447 | .quad 0x00cf92000000ffff /* __KERNEL_DS */ | |
08da5a2c ZA |
448 | .quad 0x0080890000000000 /* TS descriptor */ |
449 | .quad 0x0000000000000000 /* TS continued */ | |
1ab60e0f | 450 | gdt_end: |
7c539764 | 451 | |
3db4cafd | 452 | #ifdef CONFIG_EFI_STUB |
54b52d87 MF |
453 | efi_config: |
454 | .quad 0 | |
455 | ||
b8ff87a6 MF |
456 | #ifdef CONFIG_EFI_MIXED |
457 | .global efi32_config | |
458 | efi32_config: | |
459 | .fill 11,8,0 | |
460 | .quad efi64_thunk | |
461 | .byte 0 | |
462 | #endif | |
463 | ||
54b52d87 MF |
464 | .global efi64_config |
465 | efi64_config: | |
466 | .fill 11,8,0 | |
62fa6e69 | 467 | .quad efi_call |
54b52d87 | 468 | .byte 1 |
3db4cafd MF |
469 | #endif /* CONFIG_EFI_STUB */ |
470 | ||
b40d68d5 PA |
471 | /* |
472 | * Stack and heap for uncompression | |
473 | */ | |
474 | .bss | |
475 | .balign 4 | |
7c539764 AH |
476 | boot_heap: |
477 | .fill BOOT_HEAP_SIZE, 1, 0 | |
478 | boot_stack: | |
479 | .fill BOOT_STACK_SIZE, 1, 0 | |
480 | boot_stack_end: | |
5b11f1ce PA |
481 | |
482 | /* | |
483 | * Space for page tables (not in .bss so not zeroed) | |
484 | */ | |
485 | .section ".pgtable","a",@nobits | |
486 | .balign 4096 | |
487 | pgtable: | |
488 | .fill 6*4096, 1, 0 |