[lttng-ust.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_INIT([lttng-ust],[2.1.0-rc2],[mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])

# Compute minor/major/patchlevel version numbers
AC_PROG_SED
major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
AC_SUBST([MAJOR_VERSION], [$major_version])
AC_SUBST([MINOR_VERSION], [$minor_version])
AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])

version_name="Basse Messe"
version_description="Light coloured German ale whose style was named after the city Cologne (Koln) where it was first brewed. It is a rather simple beer with lightly fruity aromas and a delicate hoppy fragrance. The beer has a pronounced malty taste with a subtle bitter aftertaste"
AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])

AC_PROG_GREP
# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE(libtool-linkdep-fixup,
	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
			[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	libtool_fixup=$enableval,
	libtool_fixup=yes)

AS_IF([test "x$libtool_fixup" = "xyes"],
	    [
	    libtool_m4="$srcdir/config/libtool.m4"
	    libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	    AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	    libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
	    AS_IF([test $libtool_flag_pattern_count -ne 0],
	    [
		  AC_MSG_RESULT([$libtool_flag_pattern_count])
		  AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		  sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
		  ],
		  [
		  AC_MSG_RESULT([none])
		  ])
	    ])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_MAKE_SET
LT_INIT

## Checks for libraries.
AC_CHECK_LIB([dl], [dlopen],
[
	have_libdl=yes
],
[
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen],
	[
		have_libc_dl=yes
	],
	[
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])

# Check for libuuid
AC_CHECK_LIB([uuid], [uuid_generate],
[
	AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
	have_libuuid=yes
],
[
	# libuuid not found, check for uuid_create in libc.
	AC_CHECK_LIB([c], [uuid_create],
	[
		AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
		have_libc_uuid=yes
	],
	[
		AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
	])
]
)
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])

# Checks for header files.
#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
#AC_TYPE_INT16_T
#AC_TYPE_INT32_T
#AC_TYPE_INT64_T
#AC_TYPE_INT8_T
#AC_TYPE_PID_T
#AC_TYPE_SIZE_T
#AC_TYPE_SSIZE_T
#AC_TYPE_UINT16_T
#AC_TYPE_UINT32_T
#AC_TYPE_UINT64_T
#AC_TYPE_UINT8_T
#AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
#include <urcu/compiler.h>
void fct(void)
{
	if (caa_likely(1)) {
	}
}
]])],[
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])

])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

AC_MSG_CHECKING([host system alignment requirements])
case $host_cpu in
changequote(,)dnl
	i[3456]86)
changequote([,])dnl
	  ;;
	x86_64) ;;
	amd64) ;;
	powerpc) ;;
	ppc64) ;;
	powerpc64) ;;
	s390) NO_UNALIGNED_ACCESS=1 ;;
	s390x) NO_UNALIGNED_ACCESS=1 ;;
        arm*) NO_UNALIGNED_ACCESS=1 ;;
	mips*) NO_UNALIGNED_ACCESS=1;;
	*) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
esac

if test x$NO_UNALIGNED_ACCESS = x ; then
AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
fi

# Set compile flags to java include files if given
AC_ARG_WITH([java-jdk],
	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	[JAVA_JDK=$withval],
	[JAVA_JDK=""]
)
AS_IF([test $JAVA_JDK],[
	AS_IF([test -d $JAVA_JDK],[
                AC_MSG_RESULT([using Java includes in $JAVA_SDK])
                SUBDIRS=`find $JAVA_JDK/include -type d`
		CPPFLAGS+=" "
                CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
		CPPFLAGS+=" "
        ],[
                AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
        ])
])

# Check for JNI header files if requested
AC_ARG_WITH([jni-interface],
	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	[jni_interface=$withval],
	[jni_interface=no]
)

AS_IF([test "x$jni_interface" = "xyes"],[
        AC_CHECK_HEADERS([jni.h],[],[
        AC_MSG_ERROR([missing jni.h
Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	])
])
AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])

# sdt.h integration
AC_ARG_WITH([sdt],
	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
	[with_sdt=$withval],
	[with_sdt="no"]
)

AS_IF([test "x$with_sdt" = "xyes"],[
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#define SDT_USE_VARIADIC
	#include <sys/sdt.h>
	void fct(void)
	{
		STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	}
	]])],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	],[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

#currently disabled.
	#tests/hello2/Makefile
	#tests/basic/Makefile
	#tests/simple_include/Makefile
	#tests/snprintf/Makefile
	#tests/test-nevents/Makefile
	#tests/test-libustinstr-malloc/Makefile
	#tests/dlopen/Makefile
	#tests/same_line_marker/Makefile
	#tests/trace_event/Makefile
	#tests/tracepoint/Makefile
	#tests/tracepoint/benchmark/Makefile
	#tests/register_test/Makefile
	#tests/libustctl_function_#tests/Makefile
	#tests/exit-fast/Makefile
	#tests/basic_long/Makefile

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-libc-wrapper/Makefile
	tools/Makefile
	tests/Makefile
	tests/hello/Makefile
	tests/hello-static-lib/Makefile
	tests/hello.cxx/Makefile
	tests/daemon/Makefile
	tests/demo/Makefile
	tests/fork/Makefile
	tests/ust-basic-tracing/Makefile
	tests/ust-multi-test/Makefile
	lttng-ust.pc
])

AC_OUTPUT

AS_ECHO()
AS_ECHO("Version name: $version_name")
AS_ECHO("$version_description")

# Report on the configuration options
AS_ECHO()
AS_ECHO("LTTng-UST will be built with the following options:")
AS_ECHO("Library format: $LIBFORMAT")

AS_ECHO()
AS_ECHO_N("Java support (JNI): ")
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO_N("sdt.h integration:  ")
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO()
AS_ECHO("Type 'make' to compile.")
Commit	Line	Data
	1	# -- Autoconf --
	2	# Process this file with autoconf to produce a configure script.
	3
	4	AC_INIT([lttng-ust],[2.1.0-rc2],[mathieu dot desnoyers at efficios dot com])
	5
	6	# Following the numbering scheme proposed by libtool for the library version
	7	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	8	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	9	# note: remember to update tracepoint.h dlopen() to match this version
	10	# number. TODO: eventually automate by exporting the major number.
	11
	12	AC_CONFIG_AUX_DIR([config])
	13	AC_CANONICAL_TARGET
	14	AC_CANONICAL_HOST
	15	AC_CONFIG_MACRO_DIR([config])
	16	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
	17	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	18	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
	19
	20	# Configuration options, which will be installed in the config.h
	21	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
	22	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
	23	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
	24
	25	# Compute minor/major/patchlevel version numbers
	26	AC_PROG_SED
	27	major_version=$(echo AC_PACKAGE_VERSION \| sed 's/^\([[0-9]]\)\.[[0-9]]\.[[0-9]].$/\1/')
	28	minor_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.\([[0-9]]\)\.[[0-9]].$/\1/')
	29	patchlevel_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.[[0-9]]\.\([[0-9]]\).$/\1/')
	30	AC_SUBST([MAJOR_VERSION], [$major_version])
	31	AC_SUBST([MINOR_VERSION], [$minor_version])
	32	AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
	33	AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
	34	AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
	35	AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
	36
	37	version_name="Basse Messe"
	38	version_description="Light coloured German ale whose style was named after the city Cologne (Koln) where it was first brewed. It is a rather simple beer with lightly fruity aromas and a delicate hoppy fragrance. The beer has a pronounced malty taste with a subtle bitter aftertaste"
	39	AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
	40	AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
	41
	42	AC_PROG_GREP
	43	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	44	AC_ARG_ENABLE(libtool-linkdep-fixup,
	45	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
	46	[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	47	libtool_fixup=$enableval,
	48	libtool_fixup=yes)
	49
	50	AS_IF([test "x$libtool_fixup" = "xyes"],
	51	[
	52	libtool_m4="$srcdir/config/libtool.m4"
	53	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	54	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	55	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	56	AS_IF([test $libtool_flag_pattern_count -ne 0],
	57	[
	58	AC_MSG_RESULT([$libtool_flag_pattern_count])
	59	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	60	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	61	],
	62	[
	63	AC_MSG_RESULT([none])
	64	])
	65	])
	66
	67	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	68
	69	# Checks for programs.
	70	AC_PROG_CC
	71	AC_PROG_CXX
	72	AC_PROG_MAKE_SET
	73	LT_INIT
	74
	75	## Checks for libraries.
	76	AC_CHECK_LIB([dl], [dlopen],
	77	[
	78	have_libdl=yes
	79	],
	80	[
	81	#libdl not found, check for dlopen in libc.
	82	AC_CHECK_LIB([c], [dlopen],
	83	[
	84	have_libc_dl=yes
	85	],
	86	[
	87	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	88	])
	89	])
	90	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	91	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	92
	93	AC_CHECK_LIB([pthread], [pthread_create])
	94
	95	# Check for libuuid
	96	AC_CHECK_LIB([uuid], [uuid_generate],
	97	[
	98	AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
	99	have_libuuid=yes
	100	],
	101	[
	102	# libuuid not found, check for uuid_create in libc.
	103	AC_CHECK_LIB([c], [uuid_create],
	104	[
	105	AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
	106	have_libc_uuid=yes
	107	],
	108	[
	109	AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
	110	])
	111	]
	112	)
	113	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
	114	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
	115
	116	# Checks for header files.
	117	#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	118
	119	# Checks for typedefs, structures, and compiler characteristics.
	120	AC_C_INLINE
	121	#AC_TYPE_INT16_T
	122	#AC_TYPE_INT32_T
	123	#AC_TYPE_INT64_T
	124	#AC_TYPE_INT8_T
	125	#AC_TYPE_PID_T
	126	#AC_TYPE_SIZE_T
	127	#AC_TYPE_SSIZE_T
	128	#AC_TYPE_UINT16_T
	129	#AC_TYPE_UINT32_T
	130	#AC_TYPE_UINT64_T
	131	#AC_TYPE_UINT8_T
	132	#AC_CHECK_TYPES([ptrdiff_t])
	133
	134	# Checks for library functions.
	135	AC_FUNC_MALLOC
	136	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
	137
	138	CFLAGS="-Wall $CFLAGS"
	139
	140	# URCU
	141
	142	# urcu - check if we just find the headers it out of the box.
	143	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
	144	This error can also occur when the liburcu package's configure script has not been run.])])
	145
	146	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	147	# Part of Userspace RCU library 0.7.2 or better.
	148	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	149	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
	150
	151	AC_MSG_CHECKING([caa_likely()])
	152	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	153	#include <urcu/compiler.h>
	154	void fct(void)
	155	{
	156	if (caa_likely(1)) {
	157	}
	158	}
	159	]])],[
	160	AC_MSG_RESULT([yes])
	161	],[
	162	AC_MSG_RESULT([no])
	163	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
	164
	165	])
	166
	167	# urcu - check that URCU lib is available to compilation
	168	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
	169
	170	# urcu - check that URCU lib is at least version 0.6
	171	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
	172
	173	AC_MSG_CHECKING([host system alignment requirements])
	174	case $host_cpu in
	175	changequote(,)dnl
	176	i[3456]86)
	177	changequote([,])dnl
	178	;;
	179	x86_64) ;;
	180	amd64) ;;
	181	powerpc) ;;
	182	ppc64) ;;
	183	powerpc64) ;;
	184	s390) NO_UNALIGNED_ACCESS=1 ;;
	185	s390x) NO_UNALIGNED_ACCESS=1 ;;
	186	arm*) NO_UNALIGNED_ACCESS=1 ;;
	187	mips*) NO_UNALIGNED_ACCESS=1;;
	188	*) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
	189	esac
	190
	191	if test x$NO_UNALIGNED_ACCESS = x ; then
	192	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
	193	fi
	194
	195	# Set compile flags to java include files if given
	196	AC_ARG_WITH([java-jdk],
	197	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	198	[JAVA_JDK=$withval],
	199	[JAVA_JDK=""]
	200	)
	201	AS_IF([test $JAVA_JDK],[
	202	AS_IF([test -d $JAVA_JDK],[
	203	AC_MSG_RESULT([using Java includes in $JAVA_SDK])
	204	SUBDIRS=`find $JAVA_JDK/include -type d`
	205	CPPFLAGS+=" "
	206	CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
	207	CPPFLAGS+=" "
	208	],[
	209	AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
	210	])
	211	])
	212
	213	# Check for JNI header files if requested
	214	AC_ARG_WITH([jni-interface],
	215	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	216	[jni_interface=$withval],
	217	[jni_interface=no]
	218	)
	219
	220	AS_IF([test "x$jni_interface" = "xyes"],[
	221	AC_CHECK_HEADERS([jni.h],[],[
	222	AC_MSG_ERROR([missing jni.h
	223	Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
	224	Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	225	])
	226	])
	227	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
	228
	229	# sdt.h integration
	230	AC_ARG_WITH([sdt],
	231	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
	232	[with_sdt=$withval],
	233	[with_sdt="no"]
	234	)
	235
	236	AS_IF([test "x$with_sdt" = "xyes"],[
	237	AC_MSG_CHECKING([STAP_PROBEV()])
	238	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	239	#define SDT_USE_VARIADIC
	240	#include <sys/sdt.h>
	241	void fct(void)
	242	{
	243	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	244	}
	245	]])],[
	246	AC_MSG_RESULT([yes])
	247	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	248	],[
	249	AC_MSG_RESULT([no])
	250	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	251	])
	252	])
	253
	254	#currently disabled.
	255	#tests/hello2/Makefile
	256	#tests/basic/Makefile
	257	#tests/simple_include/Makefile
	258	#tests/snprintf/Makefile
	259	#tests/test-nevents/Makefile
	260	#tests/test-libustinstr-malloc/Makefile
	261	#tests/dlopen/Makefile
	262	#tests/same_line_marker/Makefile
	263	#tests/trace_event/Makefile
	264	#tests/tracepoint/Makefile
	265	#tests/tracepoint/benchmark/Makefile
	266	#tests/register_test/Makefile
	267	#tests/libustctl_function_#tests/Makefile
	268	#tests/exit-fast/Makefile
	269	#tests/basic_long/Makefile
	270
	271	AC_CONFIG_FILES([
	272	Makefile
	273	doc/Makefile
	274	doc/examples/Makefile
	275	include/Makefile
	276	include/lttng/ust-version.h
	277	snprintf/Makefile
	278	libringbuffer/Makefile
	279	liblttng-ust-comm/Makefile
	280	liblttng-ust/Makefile
	281	liblttng-ust-ctl/Makefile
	282	liblttng-ust-fork/Makefile
	283	liblttng-ust-java/Makefile
	284	liblttng-ust-libc-wrapper/Makefile
	285	tools/Makefile
	286	tests/Makefile
	287	tests/hello/Makefile
	288	tests/hello-static-lib/Makefile
	289	tests/hello.cxx/Makefile
	290	tests/daemon/Makefile
	291	tests/demo/Makefile
	292	tests/fork/Makefile
	293	tests/ust-basic-tracing/Makefile
	294	tests/ust-multi-test/Makefile
	295	lttng-ust.pc
	296	])
	297
	298	AC_OUTPUT
	299
	300	AS_ECHO()
	301	AS_ECHO("Version name: $version_name")
	302	AS_ECHO("$version_description")
	303
	304	# Report on the configuration options
	305	AS_ECHO()
	306	AS_ECHO("LTTng-UST will be built with the following options:")
	307	AS_ECHO("Library format: $LIBFORMAT")
	308
	309	AS_ECHO()
	310	AS_ECHO_N("Java support (JNI): ")
	311	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	312
	313	AS_ECHO_N("sdt.h integration: ")
	314	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	315
	316	AS_ECHO()
	317	AS_ECHO("Type 'make' to compile.")
	318