[lttng-ust.git] / configure.ac

dnl -*- Autoconf -*-
dnl Process this file with autoconf to produce a configure script.

dnl Version infos
m4_define([V_MAJOR], [2])
m4_define([V_MINOR], [9])
m4_define([V_PATCH], [0])
m4_define([V_EXTRA], [pre])
m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
m4_define([V_NAME], [[J-TBD]])
m4_define([V_DESC], [[]])

AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
# This is the library version of liblttng-ust.
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

# This is the library version of liblttng-ust-ctl, used internally by
# liblttng-ust, lttng-sessiond, and lttng-consumerd.
AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

AC_REQUIRE_AUX_FILE([tap-driver.sh])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])

dnl Substitute minor/major/patchlevel version numbers
AC_SUBST([MAJOR_VERSION], [V_MAJOR])
AC_SUBST([MINOR_VERSION], [V_MINOR])
AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])

AC_PROG_SED
AC_PROG_GREP
AC_PROG_LN_S

# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE([libtool-linkdep-fixup], [
	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
], [
	libtool_fixup=$enableval
], [
	libtool_fixup=yes
])

AS_IF([test "x$libtool_fixup" = "xyes"], [
	libtool_m4="$srcdir/config/libtool.m4"
	libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)

	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	AC_MSG_RESULT([$libtool_flag_pattern_count])
	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
	], [
		AC_MSG_RESULT([none])
	])
])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_MAKE_SET
LT_INIT

# rw_PROG_CXX_WORKS
# Check whether the C++ compiler works.
AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	AC_LANG_PUSH([C++])

	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
		check_cxx_designated_initializers=yes
	], [
		rw_cv_prog_cxx_works=no
	])

	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
			struct foo { int a; int b; };
			void fct(void)
			{
				struct foo f = { .a = 0, .b = 1 };
			}
		]])], [
			rw_cv_prog_cxx_works=yes
		], [
			rw_cv_prog_cxx_works=no
		])
	])

	AC_LANG_POP([C++])
])

AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])

# Check if the compiler support weak symbols
AX_SYS_WEAK_ALIAS

AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
])

# Checks for libraries.
AC_CHECK_LIB([dl], [dlopen], [
	have_libdl=yes
], [
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen], [
		have_libc_dl=yes
	], [
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])

AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])

# Check for dlfcn.h
AC_CHECK_HEADER([dlfcn.h])
AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
		#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
		#include <dlfcn.h>
	])
], [
	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
])

AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])

# Checks for header files.
dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
dnl AC_TYPE_INT16_T
dnl AC_TYPE_INT32_T
dnl AC_TYPE_INT64_T
dnl AC_TYPE_INT8_T
dnl AC_TYPE_PID_T
dnl AC_TYPE_SIZE_T
dnl AC_TYPE_SSIZE_T
dnl AC_TYPE_UINT16_T
dnl AC_TYPE_UINT32_T
dnl AC_TYPE_UINT64_T
dnl AC_TYPE_UINT8_T
dnl AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#include <urcu/compiler.h>
	void fct(void)
	{
		if (caa_likely(1)) {
		}
	}
]])], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

# optional linux/perf_event.h
AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])

# Perf event counters are only supported on x86 so far.
AC_MSG_CHECKING([UST support for architecture perf event counters])
AS_CASE([$host_cpu],
	[i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])

AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])

AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
])

AC_MSG_CHECKING([host system alignment requirements])
AS_CASE([$host_cpu],
	[i[[3456]]86], [],
	[x86_64], [],
	[amd64], [],
	[powerpc], [],
	[ppc64], [],
	[ppc64le], [],
	[powerpc64], [],
	[powerpc64le], [],
	[s390], [NO_UNALIGNED_ACCESS=1],
	[s390x], [NO_UNALIGNED_ACCESS=1],
	[arm*], [NO_UNALIGNED_ACCESS=1],
	[aarch64*], [NO_UNALIGNED_ACCESS=1],
	[mips*], [NO_UNALIGNED_ACCESS=1],
	[tile*], [NO_UNALIGNED_ACCESS=1],
	[
		UNSUPPORTED_ARCH=1
		NO_UNALIGNED_ACCESS=1
	])
AC_MSG_RESULT([$host_cpu])

AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
])

# Check for JNI header files if requested
AC_ARG_ENABLE([jni-interface], [
	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
], [
	jni_interface=$enableval
], [
	jni_interface=no
])

AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])


AC_ARG_ENABLE([java-agent-jul], [
	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
], [
	java_agent_jul=$enableval
], [
	java_agent_jul=no
])

AC_ARG_ENABLE([java-agent-log4j], [
	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
], [
	java_agent_log4j=$enableval
], [
	java_agent_log4j=no
])

AC_ARG_ENABLE([java-agent-all], [
	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
], [
	java_agent_jul=$enableval
	java_agent_log4j=$enableval
], [:])

AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])

AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
	AX_JAVA_OPTIONS
	AX_PROG_JAVAC
	AX_PROG_JAVA
	AX_PROG_JAR

	AX_JNI_INCLUDE_DIR
	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	do
		CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	done

	AX_PROG_JAVAH
])

AS_IF([test "x$java_agent_log4j" = "xyes"], [
	AX_CHECK_CLASSPATH
	AX_CHECK_CLASS([org.apache.log4j.Logger])
	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
		AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	])
])

# Option to build the python agent
AC_ARG_ENABLE([python-agent], [
	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
], [
	python_agent=$enableval
], [:])
AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
AS_IF([test "x$python_agent" = "xyes"], [
	AM_PATH_PYTHON([2.7])
])

# sdt.h integration
AC_ARG_WITH([sdt], [
	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
], [
	with_sdt=$withval
], [
	with_sdt="no"
])

AS_IF([test "x$with_sdt" = "xyes"], [
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define SDT_USE_VARIADIC
		#include <sys/sdt.h>
		void fct(void)
		{
			STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
		}
	]])], [
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	], [
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
])

AC_ARG_WITH([lttng-system-rundir], [
	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
], [
	lttng_system_rundir="$withval"
], [
	lttng_system_rundir="/var/run/lttng"
])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
		[LTTng system runtime directory])

AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])

# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
# is not distributed in tarballs.
AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])

# Enable building man pages (user's intention).
AC_ARG_ENABLE(
	man-pages,
	AS_HELP_STRING(
		[--disable-man-pages],
		[Do not build and install man pages (already built in a distributed tarball)]
	),
	[man_pages_opt=$enableval],
	[man_pages_opt=yes]
)

# Check for asciidoc and xmlto if we enabled building the man pages.
have_asciidoc_xmlto=no

AS_IF([test "x$man_pages_opt" = "xyes"], [
	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	AC_PATH_PROG([XMLTO], [xmlto], [no])

	AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
		AS_IF([test "x$in_git_repo" = "xyes"], [
			# This is an error because we're in the Git repo, which
			# means the man pages are not already generated for us,
			# thus asciidoc/xmlto are required because we were asked
			# to build the man pages.
			AC_MSG_ERROR([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
--disable-man-pages to disable building the man pages, in which case
they will not be installed.
			])
		], [
			# Only warn here: since we're in the tarball, the man
			# pages should already be generated at this point, thus
			# asciidoc/xmlto are not strictly required.
			AC_MSG_WARN([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
Note that the man pages are already built in this distribution tarball,
so asciidoc and xmlto are only needed if you intend to modify their
sources. Use --disable-man-pages to completely disable building
and installing the man pages.
			])
		])
	], [
		have_asciidoc_xmlto=yes
	])
])

# Export man page build condition: build the man pages if the user
# asked for it, and if the tools are available.
AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])

# Default values
AC_DEFUN([_AC_DEFINE_AND_SUBST], [
	AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
	$1="$2"
	AC_SUBST([$1])
])

_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	doc/man/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-java-agent/Makefile
	liblttng-ust-java-agent/java/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	liblttng-ust-java-agent/jni/Makefile
	liblttng-ust-java-agent/jni/common/Makefile
	liblttng-ust-java-agent/jni/jul/Makefile
	liblttng-ust-java-agent/jni/log4j/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	liblttng-ust-python-agent/Makefile
	python-lttngust/Makefile
	python-lttngust/setup.py
	python-lttngust/lttngust/__init__.py
	tools/Makefile
	tests/Makefile
	tests/ctf-types/Makefile
	tests/hello/Makefile
	tests/hello.cxx/Makefile
	tests/same_line_tracepoint/Makefile
	tests/snprintf/Makefile
	tests/ust-elf/Makefile
	tests/benchmark/Makefile
	tests/utils/Makefile
	tests/test-app-ctx/Makefile
	tests/gcc-weak-hidden/Makefile
	lttng-ust.pc
])

# Create link for python agent for the VPATH guru.
AC_CONFIG_LINKS([
	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
])

AC_OUTPUT

AS_ECHO
AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
AS_ECHO
AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])

# Report on the configuration options
AS_ECHO
AS_ECHO(["LTTng-UST will be built with the following options:"])

AS_ECHO

AS_ECHO_N(["Java agent (JUL support): "])
AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["Java agent (Log4j support): "])
AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["JNI interface (JNI): "])
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["Python ($PYTHON) agent: "])
AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["sdt.h integration: "])
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO(["Architecture: $host_cpu"])
AS_ECHO_N(["Efficient unaligned memory access: "])
AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
AS_ECHO

AS_ECHO(["Type 'make' to compile."])
Commit	Line	Data
	1	dnl -- Autoconf --
	2	dnl Process this file with autoconf to produce a configure script.
	3
	4	dnl Version infos
	5	m4_define([V_MAJOR], [2])
	6	m4_define([V_MINOR], [9])
	7	m4_define([V_PATCH], [0])
	8	m4_define([V_EXTRA], [pre])
	9	m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
	10	m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
	11	m4_define([V_NAME], [[J-TBD]])
	12	m4_define([V_DESC], [[]])
	13
	14	AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])
	15
	16	# Following the numbering scheme proposed by libtool for the library version
	17	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	18	# This is the library version of liblttng-ust.
	19	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	20	# note: remember to update tracepoint.h dlopen() to match this version
	21	# number. TODO: eventually automate by exporting the major number.
	22
	23	# This is the library version of liblttng-ust-ctl, used internally by
	24	# liblttng-ust, lttng-sessiond, and lttng-consumerd.
	25	AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
	26
	27	AC_CONFIG_AUX_DIR([config])
	28	AC_CANONICAL_TARGET
	29	AC_CANONICAL_HOST
	30	AC_CONFIG_MACRO_DIR([config])
	31	AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
	32	AM_MAINTAINER_MODE([enable])
	33	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	34	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
	35
	36	AC_REQUIRE_AUX_FILE([tap-driver.sh])
	37
	38	# Configuration options, which will be installed in the config.h
	39	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
	40	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
	41	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
	42	AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
	43
	44	dnl Substitute minor/major/patchlevel version numbers
	45	AC_SUBST([MAJOR_VERSION], [V_MAJOR])
	46	AC_SUBST([MINOR_VERSION], [V_MINOR])
	47	AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
	48
	49	AC_PROG_SED
	50	AC_PROG_GREP
	51	AC_PROG_LN_S
	52
	53	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	54	AC_ARG_ENABLE([libtool-linkdep-fixup], [
	55	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
	56	], [
	57	libtool_fixup=$enableval
	58	], [
	59	libtool_fixup=yes
	60	])
	61
	62	AS_IF([test "x$libtool_fixup" = "xyes"], [
	63	libtool_m4="$srcdir/config/libtool.m4"
	64	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	65	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	66	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	67
	68	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	69	AC_MSG_RESULT([$libtool_flag_pattern_count])
	70	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	71	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	72	], [
	73	AC_MSG_RESULT([none])
	74	])
	75	])
	76
	77	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	78
	79	# Checks for programs.
	80	AC_PROG_CC
	81	AC_PROG_CXX
	82	AC_PROG_MAKE_SET
	83	LT_INIT
	84
	85	# rw_PROG_CXX_WORKS
	86	# Check whether the C++ compiler works.
	87	AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	88	AC_LANG_PUSH([C++])
	89
	90	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
	91	check_cxx_designated_initializers=yes
	92	], [
	93	rw_cv_prog_cxx_works=no
	94	])
	95
	96	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
	97	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	98	struct foo { int a; int b; };
	99	void fct(void)
	100	{
	101	struct foo f = { .a = 0, .b = 1 };
	102	}
	103	]])], [
	104	rw_cv_prog_cxx_works=yes
	105	], [
	106	rw_cv_prog_cxx_works=no
	107	])
	108	])
	109
	110	AC_LANG_POP([C++])
	111	])
	112
	113	AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
	114
	115	# Check if the compiler support weak symbols
	116	AX_SYS_WEAK_ALIAS
	117
	118	AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	119	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
	120	])
	121
	122	# Checks for libraries.
	123	AC_CHECK_LIB([dl], [dlopen], [
	124	have_libdl=yes
	125	], [
	126	#libdl not found, check for dlopen in libc.
	127	AC_CHECK_LIB([c], [dlopen], [
	128	have_libc_dl=yes
	129	], [
	130	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	131	])
	132	])
	133
	134	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	135	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	136
	137	AC_CHECK_LIB([pthread], [pthread_create])
	138
	139	# Check for dlfcn.h
	140	AC_CHECK_HEADER([dlfcn.h])
	141	AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	142	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
	143	#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
	144	#include <dlfcn.h>
	145	])
	146	], [
	147	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
	148	])
	149
	150	AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
	151
	152	# Checks for header files.
	153	dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	154
	155	# Checks for typedefs, structures, and compiler characteristics.
	156	AC_C_INLINE
	157	dnl AC_TYPE_INT16_T
	158	dnl AC_TYPE_INT32_T
	159	dnl AC_TYPE_INT64_T
	160	dnl AC_TYPE_INT8_T
	161	dnl AC_TYPE_PID_T
	162	dnl AC_TYPE_SIZE_T
	163	dnl AC_TYPE_SSIZE_T
	164	dnl AC_TYPE_UINT16_T
	165	dnl AC_TYPE_UINT32_T
	166	dnl AC_TYPE_UINT64_T
	167	dnl AC_TYPE_UINT8_T
	168	dnl AC_CHECK_TYPES([ptrdiff_t])
	169
	170	# Checks for library functions.
	171	AC_FUNC_MALLOC
	172	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
	173
	174	CFLAGS="-Wall $CFLAGS"
	175
	176	# URCU
	177
	178	# urcu - check if we just find the headers it out of the box.
	179	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
	180	This error can also occur when the liburcu package's configure script has not been run.])])
	181
	182	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	183	# Part of Userspace RCU library 0.7.2 or better.
	184	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	185	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
	186
	187	AC_MSG_CHECKING([caa_likely()])
	188	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	189	#include <urcu/compiler.h>
	190	void fct(void)
	191	{
	192	if (caa_likely(1)) {
	193	}
	194	}
	195	]])], [
	196	AC_MSG_RESULT([yes])
	197	], [
	198	AC_MSG_RESULT([no])
	199	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
	200	])
	201
	202	# urcu - check that URCU lib is available to compilation
	203	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
	204
	205	# urcu - check that URCU lib is at least version 0.6
	206	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
	207
	208	# optional linux/perf_event.h
	209	AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
	210
	211	# Perf event counters are only supported on x86 so far.
	212	AC_MSG_CHECKING([UST support for architecture perf event counters])
	213	AS_CASE([$host_cpu],
	214	[i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	215	[x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	216	[amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	217	[UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
	218	AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
	219
	220	AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
	221
	222	AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
	223	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
	224	])
	225
	226	AC_MSG_CHECKING([host system alignment requirements])
	227	AS_CASE([$host_cpu],
	228	[i[[3456]]86], [],
	229	[x86_64], [],
	230	[amd64], [],
	231	[powerpc], [],
	232	[ppc64], [],
	233	[ppc64le], [],
	234	[powerpc64], [],
	235	[powerpc64le], [],
	236	[s390], [NO_UNALIGNED_ACCESS=1],
	237	[s390x], [NO_UNALIGNED_ACCESS=1],
	238	[arm*], [NO_UNALIGNED_ACCESS=1],
	239	[aarch64*], [NO_UNALIGNED_ACCESS=1],
	240	[mips*], [NO_UNALIGNED_ACCESS=1],
	241	[tile*], [NO_UNALIGNED_ACCESS=1],
	242	[
	243	UNSUPPORTED_ARCH=1
	244	NO_UNALIGNED_ACCESS=1
	245	])
	246	AC_MSG_RESULT([$host_cpu])
	247
	248	AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	249	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
	250	])
	251
	252	# Check for JNI header files if requested
	253	AC_ARG_ENABLE([jni-interface], [
	254	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
	255	], [
	256	jni_interface=$enableval
	257	], [
	258	jni_interface=no
	259	])
	260
	261	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
	262
	263
	264	AC_ARG_ENABLE([java-agent-jul], [
	265	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
	266	], [
	267	java_agent_jul=$enableval
	268	], [
	269	java_agent_jul=no
	270	])
	271
	272	AC_ARG_ENABLE([java-agent-log4j], [
	273	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
	274	], [
	275	java_agent_log4j=$enableval
	276	], [
	277	java_agent_log4j=no
	278	])
	279
	280	AC_ARG_ENABLE([java-agent-all], [
	281	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
	282	], [
	283	java_agent_jul=$enableval
	284	java_agent_log4j=$enableval
	285	], [:])
	286
	287	AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"])
	288	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
	289	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
	290
	291	AS_IF([test "x$jni_interface" = "xyes" \|\| test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"], [
	292	AX_JAVA_OPTIONS
	293	AX_PROG_JAVAC
	294	AX_PROG_JAVA
	295	AX_PROG_JAR
	296
	297	AX_JNI_INCLUDE_DIR
	298	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	299	do
	300	CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	301	done
	302
	303	AX_PROG_JAVAH
	304	])
	305
	306	AS_IF([test "x$java_agent_log4j" = "xyes"], [
	307	AX_CHECK_CLASSPATH
	308	AX_CHECK_CLASS([org.apache.log4j.Logger])
	309	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
	310	AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	311	])
	312	])
	313
	314	# Option to build the python agent
	315	AC_ARG_ENABLE([python-agent], [
	316	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
	317	], [
	318	python_agent=$enableval
	319	], [:])
	320	AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
	321	AS_IF([test "x$python_agent" = "xyes"], [
	322	AM_PATH_PYTHON([2.7])
	323	])
	324
	325	# sdt.h integration
	326	AC_ARG_WITH([sdt], [
	327	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
	328	], [
	329	with_sdt=$withval
	330	], [
	331	with_sdt="no"
	332	])
	333
	334	AS_IF([test "x$with_sdt" = "xyes"], [
	335	AC_MSG_CHECKING([STAP_PROBEV()])
	336	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	337	#define SDT_USE_VARIADIC
	338	#include <sys/sdt.h>
	339	void fct(void)
	340	{
	341	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	342	}
	343	]])], [
	344	AC_MSG_RESULT([yes])
	345	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	346	], [
	347	AC_MSG_RESULT([no])
	348	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	349	])
	350	])
	351
	352	AC_MSG_CHECKING([whether shared libraries are enabled])
	353	AS_IF([test "x$enable_shared" = "xyes"], [
	354	AC_MSG_RESULT([yes])
	355	], [
	356	AC_MSG_RESULT([no])
	357	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	358	])
	359
	360	AC_ARG_WITH([lttng-system-rundir], [
	361	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	362	], [
	363	lttng_system_rundir="$withval"
	364	], [
	365	lttng_system_rundir="/var/run/lttng"
	366	])
	367	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	368	[LTTng system runtime directory])
	369
	370	AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
	371	AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
	372
	373	# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
	374	# is not distributed in tarballs.
	375	AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
	376	AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
	377
	378	# Enable building man pages (user's intention).
	379	AC_ARG_ENABLE(
	380	man-pages,
	381	AS_HELP_STRING(
	382	[--disable-man-pages],
	383	[Do not build and install man pages (already built in a distributed tarball)]
	384	),
	385	[man_pages_opt=$enableval],
	386	[man_pages_opt=yes]
	387	)
	388
	389	# Check for asciidoc and xmlto if we enabled building the man pages.
	390	have_asciidoc_xmlto=no
	391
	392	AS_IF([test "x$man_pages_opt" = "xyes"], [
	393	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	394	AC_PATH_PROG([XMLTO], [xmlto], [no])
	395
	396	AS_IF([test "x$ASCIIDOC" = "xno" \|\| test "x$XMLTO" = "xno"], [
	397	AS_IF([test "x$in_git_repo" = "xyes"], [
	398	# This is an error because we're in the Git repo, which
	399	# means the man pages are not already generated for us,
	400	# thus asciidoc/xmlto are required because we were asked
	401	# to build the man pages.
	402	AC_MSG_ERROR([
	403	Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
	404	--disable-man-pages to disable building the man pages, in which case
	405	they will not be installed.
	406	])
	407	], [
	408	# Only warn here: since we're in the tarball, the man
	409	# pages should already be generated at this point, thus
	410	# asciidoc/xmlto are not strictly required.
	411	AC_MSG_WARN([
	412	Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
	413	Note that the man pages are already built in this distribution tarball,
	414	so asciidoc and xmlto are only needed if you intend to modify their
	415	sources. Use --disable-man-pages to completely disable building
	416	and installing the man pages.
	417	])
	418	])
	419	], [
	420	have_asciidoc_xmlto=yes
	421	])
	422	])
	423
	424	# Export man page build condition: build the man pages if the user
	425	# asked for it, and if the tools are available.
	426	AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
	427	AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
	428
	429	# Default values
	430	AC_DEFUN([_AC_DEFINE_AND_SUBST], [
	431	AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
	432	$1="$2"
	433	AC_SUBST([$1])
	434	])
	435
	436	_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
	437
	438	AC_CONFIG_FILES([
	439	Makefile
	440	doc/Makefile
	441	doc/examples/Makefile
	442	doc/man/Makefile
	443	include/Makefile
	444	include/lttng/ust-version.h
	445	snprintf/Makefile
	446	libringbuffer/Makefile
	447	liblttng-ust-comm/Makefile
	448	liblttng-ust/Makefile
	449	liblttng-ust-ctl/Makefile
	450	liblttng-ust-fork/Makefile
	451	liblttng-ust-dl/Makefile
	452	liblttng-ust-java/Makefile
	453	liblttng-ust-java-agent/Makefile
	454	liblttng-ust-java-agent/java/Makefile
	455	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	456	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	457	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	458	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	459	liblttng-ust-java-agent/jni/Makefile
	460	liblttng-ust-java-agent/jni/common/Makefile
	461	liblttng-ust-java-agent/jni/jul/Makefile
	462	liblttng-ust-java-agent/jni/log4j/Makefile
	463	liblttng-ust-libc-wrapper/Makefile
	464	liblttng-ust-cyg-profile/Makefile
	465	liblttng-ust-python-agent/Makefile
	466	python-lttngust/Makefile
	467	python-lttngust/setup.py
	468	python-lttngust/lttngust/__init__.py
	469	tools/Makefile
	470	tests/Makefile
	471	tests/ctf-types/Makefile
	472	tests/hello/Makefile
	473	tests/hello.cxx/Makefile
	474	tests/same_line_tracepoint/Makefile
	475	tests/snprintf/Makefile
	476	tests/ust-elf/Makefile
	477	tests/benchmark/Makefile
	478	tests/utils/Makefile
	479	tests/test-app-ctx/Makefile
	480	tests/gcc-weak-hidden/Makefile
	481	lttng-ust.pc
	482	])
	483
	484	# Create link for python agent for the VPATH guru.
	485	AC_CONFIG_LINKS([
	486	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	487	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	488	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	489	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
	490	])
	491
	492	AC_OUTPUT
	493
	494	AS_ECHO
	495	AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
	496	AS_ECHO
	497	AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
	498
	499	# Report on the configuration options
	500	AS_ECHO
	501	AS_ECHO(["LTTng-UST will be built with the following options:"])
	502
	503	AS_ECHO
	504
	505	AS_ECHO_N(["Java agent (JUL support): "])
	506	AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	507
	508	AS_ECHO_N(["Java agent (Log4j support): "])
	509	AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	510
	511	AS_ECHO_N(["JNI interface (JNI): "])
	512	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	513
	514	AS_ECHO_N(["Python ($PYTHON) agent: "])
	515	AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	516
	517	AS_ECHO_N(["sdt.h integration: "])
	518	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	519
	520	AS_ECHO(["Architecture: $host_cpu"])
	521	AS_ECHO_N(["Efficient unaligned memory access: "])
	522	AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
	523	AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
	524	AS_ECHO
	525
	526	AS_ECHO(["Type 'make' to compile."])
	527