[lttng-ust.git] / configure.ac

dnl -*- Autoconf -*-
dnl Process this file with autoconf to produce a configure script.

dnl Version infos
m4_define([V_MAJOR], [2])
m4_define([V_MINOR], [8])
m4_define([V_PATCH], [0])
m4_define([V_EXTRA], [rc1])
m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
m4_define([V_NAME], [[Isseki Nicho]])
m4_define([V_DESC], [[The result of a collaboration between "Dieu du Ciel!" and Nagano-based "Shiga Kogen", Isseki Nicho is a strong Imperial Dark Saison offering a rich roasted malt flavor combined with a complex fruity finish typical of Saison yeasts.]])

AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
# This is the library version of liblttng-ust.
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

# This is the library version of liblttng-ust-ctl, used internally by
# liblttng-ust, lttng-sessiond, and lttng-consumerd.
AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])

dnl Substitute minor/major/patchlevel version numbers
AC_SUBST([MAJOR_VERSION], [V_MAJOR])
AC_SUBST([MINOR_VERSION], [V_MINOR])
AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])

AC_PROG_SED
AC_PROG_GREP
AC_PROG_LN_S

# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE([libtool-linkdep-fixup], [
	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
], [
	libtool_fixup=$enableval
], [
	libtool_fixup=yes
])

AS_IF([test "x$libtool_fixup" = "xyes"], [
	libtool_m4="$srcdir/config/libtool.m4"
	libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)

	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	AC_MSG_RESULT([$libtool_flag_pattern_count])
	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
	], [
		AC_MSG_RESULT([none])
	])
])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_MAKE_SET
LT_INIT

# rw_PROG_CXX_WORKS
# Check whether the C++ compiler works.
AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	AC_LANG_PUSH([C++])

	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
		check_cxx_designated_initializers=yes
	], [
		rw_cv_prog_cxx_works=no
	])

	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
			struct foo { int a; int b; };
			void fct(void)
			{
				struct foo f = { .a = 0, .b = 1 };
			}
		]])], [
			rw_cv_prog_cxx_works=yes
		], [
			rw_cv_prog_cxx_works=no
		])
	])

	AC_LANG_POP([C++])
])

AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])

# Check if the compiler support weak symbols
AX_SYS_WEAK_ALIAS

AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
])

# Checks for libraries.
AC_CHECK_LIB([dl], [dlopen], [
	have_libdl=yes
], [
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen], [
		have_libc_dl=yes
	], [
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])

AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])

# Check for dlfcn.h
AC_CHECK_HEADER([dlfcn.h])
AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
		#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
		#include <dlfcn.h>
	])
], [
	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
])

AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])

# Checks for header files.
dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
dnl AC_TYPE_INT16_T
dnl AC_TYPE_INT32_T
dnl AC_TYPE_INT64_T
dnl AC_TYPE_INT8_T
dnl AC_TYPE_PID_T
dnl AC_TYPE_SIZE_T
dnl AC_TYPE_SSIZE_T
dnl AC_TYPE_UINT16_T
dnl AC_TYPE_UINT32_T
dnl AC_TYPE_UINT64_T
dnl AC_TYPE_UINT8_T
dnl AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#include <urcu/compiler.h>
	void fct(void)
	{
		if (caa_likely(1)) {
		}
	}
]])], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

# optional linux/perf_event.h
AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])

# Perf event counters are only supported on x86 so far.
AC_MSG_CHECKING([UST support for architecture perf event counters])
AS_CASE([$host_cpu],
	[i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])

AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])

AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
])

AC_MSG_CHECKING([host system alignment requirements])
AS_CASE([$host_cpu],
	[i[[3456]]86], [],
	[x86_64], [],
	[amd64], [],
	[powerpc], [],
	[ppc64], [],
	[ppc64le], [],
	[powerpc64], [],
	[powerpc64le], [],
	[s390], [NO_UNALIGNED_ACCESS=1],
	[s390x], [NO_UNALIGNED_ACCESS=1],
	[arm*], [NO_UNALIGNED_ACCESS=1],
	[aarch64], [NO_UNALIGNED_ACCESS=1],
	[mips*], [NO_UNALIGNED_ACCESS=1],
	[tile*], [NO_UNALIGNED_ACCESS=1],
	[
		UNSUPPORTED_ARCH=1
		NO_UNALIGNED_ACCESS=1
	])
AC_MSG_RESULT([$host_cpu])

AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
])

# Check for JNI header files if requested
AC_ARG_ENABLE([jni-interface], [
	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
], [
	jni_interface=$enableval
], [
	jni_interface=no
])

AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])


AC_ARG_ENABLE([java-agent-jul], [
	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
], [
	java_agent_jul=$enableval
], [
	java_agent_jul=no
])

AC_ARG_ENABLE([java-agent-log4j], [
	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
], [
	java_agent_log4j=$enableval
], [
	java_agent_log4j=no
])

AC_ARG_ENABLE([java-agent-all], [
	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
], [
	java_agent_jul=$enableval
	java_agent_log4j=$enableval
], [:])

AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])

AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
	AX_JAVA_OPTIONS
	AX_PROG_JAVAC
	AX_PROG_JAVA
	AX_PROG_JAR

	AX_JNI_INCLUDE_DIR
	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	do
		CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	done

	AX_PROG_JAVAH
])

AS_IF([test "x$java_agent_log4j" = "xyes"], [
	AX_CHECK_CLASSPATH
	AX_CHECK_CLASS([org.apache.log4j.Logger])
	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
		AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	])
])

# Option to build the python agent
AC_ARG_ENABLE([python-agent], [
	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
], [
	python_agent=$enableval
], [:])
AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
AS_IF([test "x$python_agent" = "xyes"], [
	AM_PATH_PYTHON([2.7])
])

# sdt.h integration
AC_ARG_WITH([sdt], [
	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
], [
	with_sdt=$withval
], [
	with_sdt="no"
])

AS_IF([test "x$with_sdt" = "xyes"], [
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define SDT_USE_VARIADIC
		#include <sys/sdt.h>
		void fct(void)
		{
			STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
		}
	]])], [
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	], [
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
])

AC_ARG_WITH([lttng-system-rundir], [
	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
], [
	lttng_system_rundir="$withval"
], [
	lttng_system_rundir="/var/run/lttng"
])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
		[LTTng system runtime directory])

AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])

# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
# is not distributed in tarballs.
AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])

# Enable building man pages (user's intention).
AC_ARG_ENABLE(
	man-pages,
	AS_HELP_STRING(
		[--disable-man-pages],
		[Do not build and install man pages (already built in a distributed tarball)]
	),
	[man_pages_opt=$enableval],
	[man_pages_opt=yes]
)

# Check for asciidoc and xmlto if we enabled building the man pages.
have_asciidoc_xmlto=no

AS_IF([test "x$man_pages_opt" = "xyes"], [
	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	AC_PATH_PROG([XMLTO], [xmlto], [no])

	AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
		AS_IF([test "x$in_git_repo" = "xyes"], [
			# This is an error because we're in the Git repo, which
			# means the man pages are not already generated for us,
			# thus asciidoc/xmlto are required because we were asked
			# to build the man pages.
			AC_MSG_ERROR([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
--disable-man-pages to disable building the man pages, in which case
they will not be installed.
			])
		], [
			# Only warn here: since we're in the tarball, the man
			# pages should already be generated at this point, thus
			# asciidoc/xmlto are not strictly required.
			AC_MSG_WARN([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
Note that the man pages are already built in this distribution tarball,
so asciidoc and xmlto are only needed if you intend to modify their
sources. Use --disable-man-pages to completely disable building
and installing the man pages.
			])
		])
	], [
		have_asciidoc_xmlto=yes
	])
])

# Export man page build condition: build the man pages if the user
# asked for it, and if the tools are available.
AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	doc/man/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-java-agent/Makefile
	liblttng-ust-java-agent/java/Makefile
	liblttng-ust-java-agent/java/liblttng-ust-agent/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	liblttng-ust-java-agent/jni/Makefile
	liblttng-ust-java-agent/jni/common/Makefile
	liblttng-ust-java-agent/jni/jul/Makefile
	liblttng-ust-java-agent/jni/log4j/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	liblttng-ust-python-agent/Makefile
	python-lttngust/Makefile
	python-lttngust/setup.py
	python-lttngust/lttngust/__init__.py
	tools/Makefile
	tests/Makefile
	tests/ctf-types/Makefile
	tests/hello/Makefile
	tests/hello.cxx/Makefile
	tests/same_line_tracepoint/Makefile
	tests/snprintf/Makefile
	tests/ust-elf/Makefile
	tests/benchmark/Makefile
	tests/utils/Makefile
	tests/test-app-ctx/Makefile
	lttng-ust.pc
])

# Create link for python agent for the VPATH guru.
AC_CONFIG_LINKS([
	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
])

AC_OUTPUT

AS_ECHO
AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
AS_ECHO
AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])

# Report on the configuration options
AS_ECHO
AS_ECHO(["LTTng-UST will be built with the following options:"])

AS_ECHO

AS_ECHO_N(["Java agent (JUL support): "])
AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["Java agent (Log4j support): "])
AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["JNI interface (JNI): "])
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["Python ($PYTHON) agent: "])
AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["sdt.h integration: "])
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO(["Architecture: $host_cpu"])
AS_ECHO_N(["Efficient unaligned memory access: "])
AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
AS_ECHO

AS_ECHO(["Type 'make' to compile."])
Commit	Line	Data
	1	dnl -- Autoconf --
	2	dnl Process this file with autoconf to produce a configure script.
	3
	4	dnl Version infos
	5	m4_define([V_MAJOR], [2])
	6	m4_define([V_MINOR], [8])
	7	m4_define([V_PATCH], [0])
	8	m4_define([V_EXTRA], [rc1])
	9	m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
	10	m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
	11	m4_define([V_NAME], [[Isseki Nicho]])
	12	m4_define([V_DESC], [[The result of a collaboration between "Dieu du Ciel!" and Nagano-based "Shiga Kogen", Isseki Nicho is a strong Imperial Dark Saison offering a rich roasted malt flavor combined with a complex fruity finish typical of Saison yeasts.]])
	13
	14	AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])
	15
	16	# Following the numbering scheme proposed by libtool for the library version
	17	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	18	# This is the library version of liblttng-ust.
	19	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	20	# note: remember to update tracepoint.h dlopen() to match this version
	21	# number. TODO: eventually automate by exporting the major number.
	22
	23	# This is the library version of liblttng-ust-ctl, used internally by
	24	# liblttng-ust, lttng-sessiond, and lttng-consumerd.
	25	AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
	26
	27	AC_CONFIG_AUX_DIR([config])
	28	AC_CANONICAL_TARGET
	29	AC_CANONICAL_HOST
	30	AC_CONFIG_MACRO_DIR([config])
	31	AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
	32	AM_MAINTAINER_MODE([enable])
	33	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	34	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
	35
	36	# Configuration options, which will be installed in the config.h
	37	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
	38	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
	39	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
	40	AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
	41
	42	dnl Substitute minor/major/patchlevel version numbers
	43	AC_SUBST([MAJOR_VERSION], [V_MAJOR])
	44	AC_SUBST([MINOR_VERSION], [V_MINOR])
	45	AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
	46
	47	AC_PROG_SED
	48	AC_PROG_GREP
	49	AC_PROG_LN_S
	50
	51	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	52	AC_ARG_ENABLE([libtool-linkdep-fixup], [
	53	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
	54	], [
	55	libtool_fixup=$enableval
	56	], [
	57	libtool_fixup=yes
	58	])
	59
	60	AS_IF([test "x$libtool_fixup" = "xyes"], [
	61	libtool_m4="$srcdir/config/libtool.m4"
	62	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	63	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	64	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	65
	66	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	67	AC_MSG_RESULT([$libtool_flag_pattern_count])
	68	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	69	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	70	], [
	71	AC_MSG_RESULT([none])
	72	])
	73	])
	74
	75	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	76
	77	# Checks for programs.
	78	AC_PROG_CC
	79	AC_PROG_CXX
	80	AC_PROG_MAKE_SET
	81	LT_INIT
	82
	83	# rw_PROG_CXX_WORKS
	84	# Check whether the C++ compiler works.
	85	AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	86	AC_LANG_PUSH([C++])
	87
	88	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
	89	check_cxx_designated_initializers=yes
	90	], [
	91	rw_cv_prog_cxx_works=no
	92	])
	93
	94	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
	95	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	96	struct foo { int a; int b; };
	97	void fct(void)
	98	{
	99	struct foo f = { .a = 0, .b = 1 };
	100	}
	101	]])], [
	102	rw_cv_prog_cxx_works=yes
	103	], [
	104	rw_cv_prog_cxx_works=no
	105	])
	106	])
	107
	108	AC_LANG_POP([C++])
	109	])
	110
	111	AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
	112
	113	# Check if the compiler support weak symbols
	114	AX_SYS_WEAK_ALIAS
	115
	116	AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	117	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
	118	])
	119
	120	# Checks for libraries.
	121	AC_CHECK_LIB([dl], [dlopen], [
	122	have_libdl=yes
	123	], [
	124	#libdl not found, check for dlopen in libc.
	125	AC_CHECK_LIB([c], [dlopen], [
	126	have_libc_dl=yes
	127	], [
	128	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	129	])
	130	])
	131
	132	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	133	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	134
	135	AC_CHECK_LIB([pthread], [pthread_create])
	136
	137	# Check for dlfcn.h
	138	AC_CHECK_HEADER([dlfcn.h])
	139	AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	140	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
	141	#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
	142	#include <dlfcn.h>
	143	])
	144	], [
	145	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
	146	])
	147
	148	AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
	149
	150	# Checks for header files.
	151	dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	152
	153	# Checks for typedefs, structures, and compiler characteristics.
	154	AC_C_INLINE
	155	dnl AC_TYPE_INT16_T
	156	dnl AC_TYPE_INT32_T
	157	dnl AC_TYPE_INT64_T
	158	dnl AC_TYPE_INT8_T
	159	dnl AC_TYPE_PID_T
	160	dnl AC_TYPE_SIZE_T
	161	dnl AC_TYPE_SSIZE_T
	162	dnl AC_TYPE_UINT16_T
	163	dnl AC_TYPE_UINT32_T
	164	dnl AC_TYPE_UINT64_T
	165	dnl AC_TYPE_UINT8_T
	166	dnl AC_CHECK_TYPES([ptrdiff_t])
	167
	168	# Checks for library functions.
	169	AC_FUNC_MALLOC
	170	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
	171
	172	CFLAGS="-Wall $CFLAGS"
	173
	174	# URCU
	175
	176	# urcu - check if we just find the headers it out of the box.
	177	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
	178	This error can also occur when the liburcu package's configure script has not been run.])])
	179
	180	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	181	# Part of Userspace RCU library 0.7.2 or better.
	182	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	183	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
	184
	185	AC_MSG_CHECKING([caa_likely()])
	186	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	187	#include <urcu/compiler.h>
	188	void fct(void)
	189	{
	190	if (caa_likely(1)) {
	191	}
	192	}
	193	]])], [
	194	AC_MSG_RESULT([yes])
	195	], [
	196	AC_MSG_RESULT([no])
	197	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
	198	])
	199
	200	# urcu - check that URCU lib is available to compilation
	201	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
	202
	203	# urcu - check that URCU lib is at least version 0.6
	204	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
	205
	206	# optional linux/perf_event.h
	207	AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
	208
	209	# Perf event counters are only supported on x86 so far.
	210	AC_MSG_CHECKING([UST support for architecture perf event counters])
	211	AS_CASE([$host_cpu],
	212	[i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	213	[x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	214	[amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	215	[UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
	216	AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
	217
	218	AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
	219
	220	AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
	221	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
	222	])
	223
	224	AC_MSG_CHECKING([host system alignment requirements])
	225	AS_CASE([$host_cpu],
	226	[i[[3456]]86], [],
	227	[x86_64], [],
	228	[amd64], [],
	229	[powerpc], [],
	230	[ppc64], [],
	231	[ppc64le], [],
	232	[powerpc64], [],
	233	[powerpc64le], [],
	234	[s390], [NO_UNALIGNED_ACCESS=1],
	235	[s390x], [NO_UNALIGNED_ACCESS=1],
	236	[arm*], [NO_UNALIGNED_ACCESS=1],
	237	[aarch64], [NO_UNALIGNED_ACCESS=1],
	238	[mips*], [NO_UNALIGNED_ACCESS=1],
	239	[tile*], [NO_UNALIGNED_ACCESS=1],
	240	[
	241	UNSUPPORTED_ARCH=1
	242	NO_UNALIGNED_ACCESS=1
	243	])
	244	AC_MSG_RESULT([$host_cpu])
	245
	246	AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	247	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
	248	])
	249
	250	# Check for JNI header files if requested
	251	AC_ARG_ENABLE([jni-interface], [
	252	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
	253	], [
	254	jni_interface=$enableval
	255	], [
	256	jni_interface=no
	257	])
	258
	259	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
	260
	261
	262	AC_ARG_ENABLE([java-agent-jul], [
	263	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
	264	], [
	265	java_agent_jul=$enableval
	266	], [
	267	java_agent_jul=no
	268	])
	269
	270	AC_ARG_ENABLE([java-agent-log4j], [
	271	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
	272	], [
	273	java_agent_log4j=$enableval
	274	], [
	275	java_agent_log4j=no
	276	])
	277
	278	AC_ARG_ENABLE([java-agent-all], [
	279	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
	280	], [
	281	java_agent_jul=$enableval
	282	java_agent_log4j=$enableval
	283	], [:])
	284
	285	AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"])
	286	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
	287	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
	288
	289	AS_IF([test "x$jni_interface" = "xyes" \|\| test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"], [
	290	AX_JAVA_OPTIONS
	291	AX_PROG_JAVAC
	292	AX_PROG_JAVA
	293	AX_PROG_JAR
	294
	295	AX_JNI_INCLUDE_DIR
	296	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	297	do
	298	CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	299	done
	300
	301	AX_PROG_JAVAH
	302	])
	303
	304	AS_IF([test "x$java_agent_log4j" = "xyes"], [
	305	AX_CHECK_CLASSPATH
	306	AX_CHECK_CLASS([org.apache.log4j.Logger])
	307	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
	308	AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	309	])
	310	])
	311
	312	# Option to build the python agent
	313	AC_ARG_ENABLE([python-agent], [
	314	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
	315	], [
	316	python_agent=$enableval
	317	], [:])
	318	AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
	319	AS_IF([test "x$python_agent" = "xyes"], [
	320	AM_PATH_PYTHON([2.7])
	321	])
	322
	323	# sdt.h integration
	324	AC_ARG_WITH([sdt], [
	325	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
	326	], [
	327	with_sdt=$withval
	328	], [
	329	with_sdt="no"
	330	])
	331
	332	AS_IF([test "x$with_sdt" = "xyes"], [
	333	AC_MSG_CHECKING([STAP_PROBEV()])
	334	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	335	#define SDT_USE_VARIADIC
	336	#include <sys/sdt.h>
	337	void fct(void)
	338	{
	339	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	340	}
	341	]])], [
	342	AC_MSG_RESULT([yes])
	343	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	344	], [
	345	AC_MSG_RESULT([no])
	346	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	347	])
	348	])
	349
	350	AC_MSG_CHECKING([whether shared libraries are enabled])
	351	AS_IF([test "x$enable_shared" = "xyes"], [
	352	AC_MSG_RESULT([yes])
	353	], [
	354	AC_MSG_RESULT([no])
	355	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	356	])
	357
	358	AC_ARG_WITH([lttng-system-rundir], [
	359	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	360	], [
	361	lttng_system_rundir="$withval"
	362	], [
	363	lttng_system_rundir="/var/run/lttng"
	364	])
	365	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	366	[LTTng system runtime directory])
	367
	368	AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
	369	AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
	370
	371	# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
	372	# is not distributed in tarballs.
	373	AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
	374	AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
	375
	376	# Enable building man pages (user's intention).
	377	AC_ARG_ENABLE(
	378	man-pages,
	379	AS_HELP_STRING(
	380	[--disable-man-pages],
	381	[Do not build and install man pages (already built in a distributed tarball)]
	382	),
	383	[man_pages_opt=$enableval],
	384	[man_pages_opt=yes]
	385	)
	386
	387	# Check for asciidoc and xmlto if we enabled building the man pages.
	388	have_asciidoc_xmlto=no
	389
	390	AS_IF([test "x$man_pages_opt" = "xyes"], [
	391	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	392	AC_PATH_PROG([XMLTO], [xmlto], [no])
	393
	394	AS_IF([test "x$ASCIIDOC" = "xno" \|\| test "x$XMLTO" = "xno"], [
	395	AS_IF([test "x$in_git_repo" = "xyes"], [
	396	# This is an error because we're in the Git repo, which
	397	# means the man pages are not already generated for us,
	398	# thus asciidoc/xmlto are required because we were asked
	399	# to build the man pages.
	400	AC_MSG_ERROR([
	401	Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
	402	--disable-man-pages to disable building the man pages, in which case
	403	they will not be installed.
	404	])
	405	], [
	406	# Only warn here: since we're in the tarball, the man
	407	# pages should already be generated at this point, thus
	408	# asciidoc/xmlto are not strictly required.
	409	AC_MSG_WARN([
	410	Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
	411	Note that the man pages are already built in this distribution tarball,
	412	so asciidoc and xmlto are only needed if you intend to modify their
	413	sources. Use --disable-man-pages to completely disable building
	414	and installing the man pages.
	415	])
	416	])
	417	], [
	418	have_asciidoc_xmlto=yes
	419	])
	420	])
	421
	422	# Export man page build condition: build the man pages if the user
	423	# asked for it, and if the tools are available.
	424	AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
	425	AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
	426
	427	AC_CONFIG_FILES([
	428	Makefile
	429	doc/Makefile
	430	doc/examples/Makefile
	431	doc/man/Makefile
	432	include/Makefile
	433	include/lttng/ust-version.h
	434	snprintf/Makefile
	435	libringbuffer/Makefile
	436	liblttng-ust-comm/Makefile
	437	liblttng-ust/Makefile
	438	liblttng-ust-ctl/Makefile
	439	liblttng-ust-fork/Makefile
	440	liblttng-ust-dl/Makefile
	441	liblttng-ust-java/Makefile
	442	liblttng-ust-java-agent/Makefile
	443	liblttng-ust-java-agent/java/Makefile
	444	liblttng-ust-java-agent/java/liblttng-ust-agent/Makefile
	445	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	446	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	447	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	448	liblttng-ust-java-agent/jni/Makefile
	449	liblttng-ust-java-agent/jni/common/Makefile
	450	liblttng-ust-java-agent/jni/jul/Makefile
	451	liblttng-ust-java-agent/jni/log4j/Makefile
	452	liblttng-ust-libc-wrapper/Makefile
	453	liblttng-ust-cyg-profile/Makefile
	454	liblttng-ust-python-agent/Makefile
	455	python-lttngust/Makefile
	456	python-lttngust/setup.py
	457	python-lttngust/lttngust/__init__.py
	458	tools/Makefile
	459	tests/Makefile
	460	tests/ctf-types/Makefile
	461	tests/hello/Makefile
	462	tests/hello.cxx/Makefile
	463	tests/same_line_tracepoint/Makefile
	464	tests/snprintf/Makefile
	465	tests/ust-elf/Makefile
	466	tests/benchmark/Makefile
	467	tests/utils/Makefile
	468	tests/test-app-ctx/Makefile
	469	lttng-ust.pc
	470	])
	471
	472	# Create link for python agent for the VPATH guru.
	473	AC_CONFIG_LINKS([
	474	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	475	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	476	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	477	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
	478	])
	479
	480	AC_OUTPUT
	481
	482	AS_ECHO
	483	AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
	484	AS_ECHO
	485	AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
	486
	487	# Report on the configuration options
	488	AS_ECHO
	489	AS_ECHO(["LTTng-UST will be built with the following options:"])
	490
	491	AS_ECHO
	492
	493	AS_ECHO_N(["Java agent (JUL support): "])
	494	AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	495
	496	AS_ECHO_N(["Java agent (Log4j support): "])
	497	AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	498
	499	AS_ECHO_N(["JNI interface (JNI): "])
	500	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	501
	502	AS_ECHO_N(["Python ($PYTHON) agent: "])
	503	AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	504
	505	AS_ECHO_N(["sdt.h integration: "])
	506	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	507
	508	AS_ECHO(["Architecture: $host_cpu"])
	509	AS_ECHO_N(["Efficient unaligned memory access: "])
	510	AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
	511	AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
	512	AS_ECHO
	513
	514	AS_ECHO(["Type 'make' to compile."])
	515