arch/arm/lib/putuser.S

   1 /*
   2  *  linux/arch/arm/lib/putuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make
  13  * them more efficient, especially as they return an error
  14  * value in addition to the "real" return value.
  15  *
  16  * __put_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  *              r1 contains the address limit, which must be preserved
  20  *              r2, r3 contains the value
  21  * Outputs:     r0 is the error code
  22  *              lr corrupted
  23  *
  24  * No other registers must be altered.  (see <asm/uaccess.h>
  25  * for specific ASM register usage).
  26  *
  27  * Note that ADDR_LIMIT is either 0 or 0xc0000000
  28  * Note also that it is intended that __put_user_bad is not global.
  29  */
  30 #include <linux/linkage.h>
  31 #include <asm/assembler.h>
  32 #include <asm/errno.h>
  33 #include <asm/domain.h>
  34 #include <asm/export.h>
  35
  36 ENTRY(__put_user_1)
  37         check_uaccess r0, 1, r1, ip, __put_user_bad
  38 1: TUSER(strb)  r2, [r0]
  39         mov     r0, #0
  40         ret     lr
  41 ENDPROC(__put_user_1)
  42 EXPORT_SYMBOL(__put_user_1)
  43
  44 ENTRY(__put_user_2)
  45         check_uaccess r0, 2, r1, ip, __put_user_bad
  46         mov     ip, r2, lsr #8
  47 #ifdef CONFIG_THUMB2_KERNEL
  48 #ifndef __ARMEB__
  49 2: TUSER(strb)  r2, [r0]
  50 3: TUSER(strb)  ip, [r0, #1]
  51 #else
  52 2: TUSER(strb)  ip, [r0]
  53 3: TUSER(strb)  r2, [r0, #1]
  54 #endif
  55 #else   /* !CONFIG_THUMB2_KERNEL */
  56 #ifndef __ARMEB__
  57 2: TUSER(strb)  r2, [r0], #1
  58 3: TUSER(strb)  ip, [r0]
  59 #else
  60 2: TUSER(strb)  ip, [r0], #1
  61 3: TUSER(strb)  r2, [r0]
  62 #endif
  63 #endif  /* CONFIG_THUMB2_KERNEL */
  64         mov     r0, #0
  65         ret     lr
  66 ENDPROC(__put_user_2)
  67 EXPORT_SYMBOL(__put_user_2)
  68
  69 ENTRY(__put_user_4)
  70         check_uaccess r0, 4, r1, ip, __put_user_bad
  71 4: TUSER(str)   r2, [r0]
  72         mov     r0, #0
  73         ret     lr
  74 ENDPROC(__put_user_4)
  75 EXPORT_SYMBOL(__put_user_4)
  76
  77 ENTRY(__put_user_8)
  78         check_uaccess r0, 8, r1, ip, __put_user_bad
  79 #ifdef CONFIG_THUMB2_KERNEL
  80 5: TUSER(str)   r2, [r0]
  81 6: TUSER(str)   r3, [r0, #4]
  82 #else
  83 5: TUSER(str)   r2, [r0], #4
  84 6: TUSER(str)   r3, [r0]
  85 #endif
  86         mov     r0, #0
  87         ret     lr
  88 ENDPROC(__put_user_8)
  89 EXPORT_SYMBOL(__put_user_8)
  90
  91 __put_user_bad:
  92         mov     r0, #-EFAULT
  93         ret     lr
  94 ENDPROC(__put_user_bad)
  95
  96 .pushsection __ex_table, "a"
  97         .long   1b, __put_user_bad
  98         .long   2b, __put_user_bad
  99         .long   3b, __put_user_bad
 100         .long   4b, __put_user_bad
 101         .long   5b, __put_user_bad
 102         .long   6b, __put_user_bad
 103 .popsection