arch/ia64/lib/idiv64.S

   1 /*
   2  * Copyright (C) 1999-2000 Hewlett-Packard Co
   3  * Copyright (C) 1999-2000 David Mosberger-Tang <davidm@hpl.hp.com>
   4  *
   5  * 64-bit integer division.
   6  *
   7  * This code is based on the application note entitled "Divide, Square Root
   8  * and Remainder Algorithms for the IA-64 Architecture".  This document
   9  * is available as Intel document number 248725-002 or via the web at
  10  * http://developer.intel.com/software/opensource/numerics/
  11  *
  12  * For more details on the theory behind these algorithms, see "IA-64
  13  * and Elementary Functions" by Peter Markstein; HP Professional Books
  14  * (http://www.goodreads.com/book/show/2019887.Ia_64_and_Elementary_Functions)
  15  */
  16
  17 #include <asm/asmmacro.h>
  18 #include <asm/export.h>
  19
  20 #ifdef MODULO
  21 # define OP     mod
  22 #else
  23 # define OP     div
  24 #endif
  25
  26 #ifdef UNSIGNED
  27 # define SGN    u
  28 # define INT_TO_FP(a,b) fcvt.xuf.s1 a=b
  29 # define FP_TO_INT(a,b) fcvt.fxu.trunc.s1 a=b
  30 #else
  31 # define SGN
  32 # define INT_TO_FP(a,b) fcvt.xf a=b
  33 # define FP_TO_INT(a,b) fcvt.fx.trunc.s1 a=b
  34 #endif
  35
  36 #define PASTE1(a,b)     a##b
  37 #define PASTE(a,b)      PASTE1(a,b)
  38 #define NAME            PASTE(PASTE(__,SGN),PASTE(OP,di3))
  39
  40 GLOBAL_ENTRY(NAME)
  41         .regstk 2,0,0,0
  42         // Transfer inputs to FP registers.
  43         setf.sig f8 = in0
  44         setf.sig f9 = in1
  45         ;;
  46         // Convert the inputs to FP, to avoid FP software-assist faults.
  47         INT_TO_FP(f8, f8)
  48         INT_TO_FP(f9, f9)
  49         ;;
  50         frcpa.s1 f11, p6 = f8, f9       // y0 = frcpa(b)
  51         ;;
  52 (p6)    fmpy.s1 f7 = f8, f11            // q0 = a*y0
  53 (p6)    fnma.s1 f6 = f9, f11, f1        // e0 = -b*y0 + 1
  54         ;;
  55 (p6)    fma.s1 f10 = f7, f6, f7         // q1 = q0*e0 + q0
  56 (p6)    fmpy.s1 f7 = f6, f6             // e1 = e0*e0
  57         ;;
  58 #ifdef MODULO
  59         sub in1 = r0, in1               // in1 = -b
  60 #endif
  61 (p6)    fma.s1 f10 = f10, f7, f10       // q2 = q1*e1 + q1
  62 (p6)    fma.s1 f6 = f11, f6, f11        // y1 = y0*e0 + y0
  63         ;;
  64 (p6)    fma.s1 f6 = f6, f7, f6          // y2 = y1*e1 + y1
  65 (p6)    fnma.s1 f7 = f9, f10, f8        // r = -b*q2 + a
  66         ;;
  67 #ifdef MODULO
  68         setf.sig f8 = in0               // f8 = a
  69         setf.sig f9 = in1               // f9 = -b
  70 #endif
  71 (p6)    fma.s1 f11 = f7, f6, f10        // q3 = r*y2 + q2
  72         ;;
  73         FP_TO_INT(f11, f11)             // q = trunc(q3)
  74         ;;
  75 #ifdef MODULO
  76         xma.l f11 = f11, f9, f8         // r = q*(-b) + a
  77         ;;
  78 #endif
  79         getf.sig r8 = f11               // transfer result to result register
  80         br.ret.sptk.many rp
  81 END(NAME)
  82 EXPORT_SYMBOL(NAME)