arch/s390/kernel/mcount.S

   1 /*
   2  * Copyright IBM Corp. 2008, 2009
   3  *
   4  *   Author(s): Heiko Carstens <heiko.carstens@de.ibm.com>,
   5  *
   6  */
   7
   8 #include <linux/linkage.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/ftrace.h>
  11 #include <asm/ptrace.h>
  12
  13         .section .kprobes.text, "ax"
  14
  15 ENTRY(ftrace_stub)
  16         br      %r14
  17
  18 #define STACK_FRAME_SIZE  (STACK_FRAME_OVERHEAD + __PT_SIZE)
  19 #define STACK_PTREGS      (STACK_FRAME_OVERHEAD)
  20 #define STACK_PTREGS_GPRS (STACK_PTREGS + __PT_GPRS)
  21 #define STACK_PTREGS_PSW  (STACK_PTREGS + __PT_PSW)
  22
  23 ENTRY(_mcount)
  24         br      %r14
  25
  26 ENTRY(ftrace_caller)
  27         .globl  ftrace_regs_caller
  28         .set    ftrace_regs_caller,ftrace_caller
  29         lgr     %r1,%r15
  30 #ifndef CC_USING_HOTPATCH
  31         aghi    %r0,MCOUNT_RETURN_FIXUP
  32 #endif
  33         aghi    %r15,-STACK_FRAME_SIZE
  34         stg     %r1,__SF_BACKCHAIN(%r15)
  35         stg     %r1,(STACK_PTREGS_GPRS+15*8)(%r15)
  36         stg     %r0,(STACK_PTREGS_PSW+8)(%r15)
  37         stmg    %r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
  38 #ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
  39         aghik   %r2,%r0,-MCOUNT_INSN_SIZE
  40         lgrl    %r4,function_trace_op
  41         lgrl    %r1,ftrace_trace_function
  42 #else
  43         lgr     %r2,%r0
  44         aghi    %r2,-MCOUNT_INSN_SIZE
  45         larl    %r4,function_trace_op
  46         lg      %r4,0(%r4)
  47         larl    %r1,ftrace_trace_function
  48         lg      %r1,0(%r1)
  49 #endif
  50         lgr     %r3,%r14
  51         la      %r5,STACK_PTREGS(%r15)
  52         basr    %r14,%r1
  53 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  54 # The j instruction gets runtime patched to a nop instruction.
  55 # See ftrace_enable_ftrace_graph_caller.
  56 ENTRY(ftrace_graph_caller)
  57         j       ftrace_graph_caller_end
  58         lg      %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  59         lg      %r3,(STACK_PTREGS_PSW+8)(%r15)
  60         brasl   %r14,prepare_ftrace_return
  61         stg     %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  62 ftrace_graph_caller_end:
  63         .globl  ftrace_graph_caller_end
  64 #endif
  65         lg      %r1,(STACK_PTREGS_PSW+8)(%r15)
  66         lmg     %r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
  67         br      %r1
  68
  69 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  70
  71 ENTRY(return_to_handler)
  72         stmg    %r2,%r5,32(%r15)
  73         lgr     %r1,%r15
  74         aghi    %r15,-STACK_FRAME_OVERHEAD
  75         stg     %r1,__SF_BACKCHAIN(%r15)
  76         brasl   %r14,ftrace_return_to_handler
  77         aghi    %r15,STACK_FRAME_OVERHEAD
  78         lgr     %r14,%r2
  79         lmg     %r2,%r5,32(%r15)
  80         br      %r14
  81
  82 #endif