arch/x86/entry/thunk_64.S

   1 /*
   2  * Save registers before calling assembly functions. This avoids
   3  * disturbance of register allocation in some inline assembly constructs.
   4  * Copyright 2001,2002 by Andi Kleen, SuSE Labs.
   5  * Added trace_hardirqs callers - Copyright 2007 Steven Rostedt, Red Hat, Inc.
   6  * Subject to the GNU public license, v.2. No warranty of any kind.
   7  */
   8 #include <linux/linkage.h>
   9 #include "calling.h"
  10 #include <asm/asm.h>
  11
  12         /* rdi: arg1 ... normal C conventions. rax is saved/restored. */
  13         .macro THUNK name, func, put_ret_addr_in_rdi=0
  14         .globl \name
  15         .type \name, @function
  16 \name:
  17         pushq %rbp
  18         movq %rsp, %rbp
  19
  20         pushq %rdi
  21         pushq %rsi
  22         pushq %rdx
  23         pushq %rcx
  24         pushq %rax
  25         pushq %r8
  26         pushq %r9
  27         pushq %r10
  28         pushq %r11
  29
  30         .if \put_ret_addr_in_rdi
  31         /* 8(%rbp) is return addr on stack */
  32         movq 8(%rbp), %rdi
  33         .endif
  34
  35         call \func
  36         jmp  .L_restore
  37         _ASM_NOKPROBE(\name)
  38         .endm
  39
  40 #ifdef CONFIG_TRACE_IRQFLAGS
  41         THUNK trace_hardirqs_on_thunk,trace_hardirqs_on_caller,1
  42         THUNK trace_hardirqs_off_thunk,trace_hardirqs_off_caller,1
  43 #endif
  44
  45 #ifdef CONFIG_DEBUG_LOCK_ALLOC
  46         THUNK lockdep_sys_exit_thunk,lockdep_sys_exit
  47 #endif
  48
  49 #ifdef CONFIG_PREEMPT
  50         THUNK ___preempt_schedule, preempt_schedule
  51         THUNK ___preempt_schedule_notrace, preempt_schedule_notrace
  52 #endif
  53
  54 #if defined(CONFIG_TRACE_IRQFLAGS) \
  55  || defined(CONFIG_DEBUG_LOCK_ALLOC) \
  56  || defined(CONFIG_PREEMPT)
  57 .L_restore:
  58         popq %r11
  59         popq %r10
  60         popq %r9
  61         popq %r8
  62         popq %rax
  63         popq %rcx
  64         popq %rdx
  65         popq %rsi
  66         popq %rdi
  67         popq %rbp
  68         ret
  69         _ASM_NOKPROBE(.L_restore)
  70 #endif