bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.5)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.8.4)
  11
  12 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  13 dnl to call AC_CHECK_PROG.
  14 AC_CHECK_TOOL(AR, ar)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16
  17 dnl Default to a non shared library.  This may be overridden by the
  18 dnl configure option --enable-shared.
  19 libtool_enable_shared=no
  20
  21 AM_PROG_LIBTOOL
  22
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45 AC_ARG_WITH(mmap,
  46 [  --with-mmap             try using mmap for BFD input files if available],
  47 [case "${withval}" in
  48   yes)  want_mmap=true ;;
  49   no)   want_mmap=false ;;
  50   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  51 esac],[want_mmap=false])dnl
  52
  53 AM_CONFIG_HEADER(config.h:config.in)
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58 AC_ARG_PROGRAM
  59
  60 AM_MAINTAINER_MODE
  61 AM_CYGWIN32
  62 AM_EXEEXT
  63
  64 host64=false
  65 target64=false
  66
  67 # host stuff:
  68
  69 AC_PROG_CC
  70
  71 # Permit host specific settings.
  72 . ${srcdir}/configure.host
  73
  74 AC_SUBST(HDEFINES)
  75 AM_PROG_INSTALL
  76
  77 BFD_HOST_64BIT_LONG=0
  78 BFD_HOST_64_BIT_DEFINED=0
  79 BFD_HOST_64_BIT=
  80 BFD_HOST_U_64_BIT=
  81 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
  82   BFD_HOST_64BIT_LONG=1
  83 elif test "x${HOST_64BIT_TYPE}" != "x"; then
  84   BFD_HOST_64_BIT_DEFINED=1
  85   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
  86   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
  87 fi
  88 AC_SUBST(BFD_HOST_64BIT_LONG)
  89 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
  90 AC_SUBST(BFD_HOST_64_BIT)
  91 AC_SUBST(BFD_HOST_U_64_BIT)
  92
  93 BFD_CC_FOR_BUILD
  94
  95 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
  96 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
  97 AC_HEADER_TIME
  98 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen)
  99
 100 BFD_BINARY_FOPEN
 101
 102 BFD_NEED_DECLARATION(strstr)
 103 BFD_NEED_DECLARATION(malloc)
 104 BFD_NEED_DECLARATION(realloc)
 105 BFD_NEED_DECLARATION(free)
 106 BFD_NEED_DECLARATION(getenv)
 107
 108 # If we are configured native, pick a core file support file.
 109 COREFILE=
 110 COREFLAG=
 111 if test "${target}" = "${host}"; then
 112   case "${host}" in
 113   alpha*-*-linux-gnu*)
 114         COREFILE=trad-core.lo
 115         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 116         ;;
 117   alpha*-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 118   alpha*-*-*)           COREFILE=osf-core.lo ;;
 119   arm-*-riscix)         COREFILE=trad-core.lo ;;
 120   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 121   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 122   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 123                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 124 changequote(,)dnl
 125   i[3456]86-sequent-bsd*)
 126 changequote([,])dnl
 127         COREFILE=trad-core.lo;
 128         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 129         ;;
 130 changequote(,)dnl
 131   i[3456]86-sequent-sysv4*) ;;
 132   i[3456]86-sequent-sysv*)
 133 changequote([,])dnl
 134         COREFILE=trad-core.lo
 135         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 136         ;;
 137 changequote(,)dnl
 138   i[3456]86-*-bsd* | i[3456]86-*-freebsd*)
 139 changequote([,])dnl
 140         COREFILE=trad-core.lo
 141         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 142         ;;
 143 changequote(,)dnl
 144   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 145 changequote([,])dnl
 146         COREFILE=netbsd-core.lo
 147         ;;
 148 changequote(,)dnl
 149   i[3456]86-esix-sysv3*)
 150 changequote([,])dnl
 151         COREFILE=trad-core.lo
 152         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 153         ;;
 154 changequote(,)dnl
 155   i[3456]86-*-sco* | i[3456]86-*-isc*)
 156 changequote([,])dnl
 157         COREFILE=trad-core.lo
 158         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 159         ;;
 160 changequote(,)dnl
 161   i[3456]86-*-mach3*)
 162 changequote([,])dnl
 163         COREFILE=trad-core.lo
 164         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 165         ;;
 166 changequote(,)dnl
 167   i[3456]86-*-linux-gnu*)
 168 changequote([,])dnl
 169         COREFILE=trad-core.lo
 170         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 171         ;;
 172 changequote(,)dnl
 173   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 174   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 175 changequote([,])dnl
 176   i860-*-mach3* | i860-*-osf1*)
 177         COREFILE=trad-core.lo
 178         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 179         ;;
 180   mips-dec-bsd*)
 181         COREFILE=trad-core.lo
 182         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 183         ;;
 184   mips-dec-mach3*)
 185         COREFILE=trad-core.lo
 186         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 187         ;;
 188   mips-*-netbsd* | mips*-*-openbsd*)
 189         COREFILE=netbsd-core.lo
 190         ;;
 191   mips-dec-*)
 192         COREFILE=trad-core.lo
 193         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 194         ;;
 195   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 196   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 197   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 198   mips-*-mach3*)
 199         COREFILE=trad-core.lo
 200         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 201         ;;
 202   mips-*-sysv4*)        ;;
 203   mips-*-sysv* | mips-*-riscos*)
 204         COREFILE=trad-core.lo
 205         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 206         ;;
 207   mips-sony-bsd*)
 208         COREFILE=trad-core.lo
 209         AC_DEFINE(TRAD_HEADER,"hosts/news-mips.h")
 210         ;;
 211   m68*-bull*-sysv*)
 212         COREFILE=trad-core.lo
 213         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 214         ;;
 215   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 216   m68*-hp-bsd*)
 217         COREFILE=trad-core.lo
 218         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 219         ;;
 220   m68*-*-linux-gnu*)
 221         COREFILE=trad-core.lo
 222         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 223         ;;
 224   m68*-motorola-sysv*)
 225         COREFILE=trad-core.lo
 226         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 227         ;;
 228   m68*-sony-*)
 229         COREFILE=trad-core.lo
 230         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 231         ;;
 232   m68*-*-netbsd* | m68*-*-openbsd*)
 233         COREFILE=netbsd-core.lo
 234         ;;
 235   m68*-apple-aux*)
 236         COREFILE=trad-core.lo
 237         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 238         ;;
 239   m88*-*-sysv4*)        ;;
 240   m88*-motorola-sysv*)  COREFILE=ptrace-core.lo ;;
 241   m88*-*-mach3*)
 242         COREFILE=trad-core.lo
 243         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 244         ;;
 245   ns32k-pc532-mach)
 246         COREFILE=trad-core.lo
 247         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 248         ;;
 249   ns32k-*-netbsd* | ns32k-*-openbsd*)
 250         COREFILE=netbsd-core.lo
 251         ;;
 252   rs6000-*-lynx*)       COREFILE=lynx-core.lo ;;
 253   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 254   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 255   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 256   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 257   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 258   powerpc-*-beos*)      ;;
 259   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 260   sparc-*-netbsd* | sparc-*-openbsd*)
 261         COREFILE=netbsd-core.lo
 262         ;;
 263   tahoe-*-*)
 264         COREFILE=trad-core.lo
 265         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 266         ;;
 267   vax-*-ultrix2*)
 268         COREFILE=trad-core.lo
 269         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 270         ;;
 271   vax-*-ultrix*)
 272         COREFILE=trad-core.lo
 273         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 274         ;;
 275   vax-*-*)
 276         COREFILE=trad-core.lo
 277         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 278         ;;
 279   esac
 280
 281   case "$COREFILE" in
 282   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 283   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 284   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 285   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 286   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 287   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 288   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 289   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 290   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 291   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 292   esac
 293
 294   # The ELF code uses the native <sys/procfs.h> to handle core files.
 295   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 296   # prstatus_t.
 297   AC_MSG_CHECKING([for sys/procfs.h])
 298   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 299   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 300   [prstatus_t t;],
 301   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 302   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 303   if test $bfd_cv_header_sys_procfs_h = yes; then
 304     AC_DEFINE(HAVE_SYS_PROCFS_H)
 305   fi
 306
 307 fi
 308 AC_SUBST(COREFILE)
 309 AC_SUBST(COREFLAG)
 310
 311 # target stuff:
 312
 313 # Canonicalize the secondary target names.
 314 if test -n "$enable_targets" ; then
 315     for targ in `echo $enable_targets | sed 's/,/ /g'`
 316     do
 317         result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 318         if test -n "$result" ; then
 319             canon_targets="$canon_targets $result"
 320         else
 321             # Allow targets that config.sub doesn't recognize, like "all".
 322             canon_targets="$canon_targets $targ"
 323         fi
 324     done
 325 fi
 326
 327 all_targets=false
 328 defvec=
 329 selvecs=
 330 selarchs=
 331 TDEFINES=
 332 for targ in $target $canon_targets
 333 do
 334     if test "x$targ" = "xall"; then
 335         all_targets=true
 336     else
 337         . $srcdir/config.bfd
 338         if test "x$targ" = "x$target"; then
 339             defvec=$targ_defvec
 340         fi
 341         selvecs="$selvecs $targ_defvec $targ_selvecs"
 342         selarchs="$selarchs $targ_archs"
 343         TDEFINES="$TDEFINES $targ_cflags"
 344     fi
 345 done
 346 AC_SUBST(TDEFINES)
 347
 348 # This processing still needs to be done if we're to decide properly whether
 349 # 64-bit support needs to be compiled in.  Currently, it will be included if
 350 # the default or any other explicitly requested target requires it; it
 351 # will not be included on a 32-bit host if no 64-bit target is requested, and
 352 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 353 # used.
 354
 355 # uniq the default and selected vectors in all the configured targets.
 356 f=""
 357 for i in $selvecs ; do
 358     case " $f " in
 359     *" $i "*) ;;
 360     *) f="$f $i" ;;
 361     esac
 362 done
 363 selvecs="$f"
 364
 365 # start-sanitize-sky
 366 # dvp is really mips, but we need to distinguish it from mips for opcodes
 367 selarchs=`echo $selarchs | sed -e s/dvp/mips/g`
 368 # end-sanitize-sky
 369
 370 # uniq the architectures in all the configured targets.
 371 f=""
 372 for i in $selarchs ; do
 373     case " $f " in
 374     *" $i "*) ;;
 375     *) f="$f $i" ;;
 376     esac
 377 done
 378 selarchs="$f"
 379
 380 # Target backend .o files.
 381 tb=
 382
 383 elf="elflink.lo dwarf2.lo"
 384
 385 for vec in $selvecs
 386 do
 387     case "$vec" in
 388     # This list is alphabetized to make it easy to compare
 389     # with the two vector lists in targets.c.
 390     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 391     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 392     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 393     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 394     armpe_little_vec)           tb="$tb pe-arm.lo cofflink.lo " ;;
 395     armpe_big_vec)              tb="$tb pe-arm.lo cofflink.lo " ;;
 396     armpei_little_vec)          tb="$tb pei-arm.lo cofflink.lo " ;;
 397     armpei_big_vec)             tb="$tb pei-arm.lo cofflink.lo " ;;
 398     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 399     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 400     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 401     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 402     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 403     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 404     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 405     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 406     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"
 407                                 target64=true ;;
 408     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 409     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 410     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 411     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 412     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 413                                 target64=true ;;
 414     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 415 # start-sanitize-d30v
 416     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 417 # end-sanitize-d30v
 418     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 419     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 420     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 421     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 422     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 423     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 424                                 target64=true ;;
 425     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 426     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 427     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 428     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 429     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 430     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 431     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 432     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 433     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 434     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 435     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 436     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"
 437                                 target64=true ;;
 438     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"
 439                                 target64=true ;;
 440     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"
 441                                 target64=true ;;
 442     cisco_core_vec)             tb="$tb cisco-core.lo" ;;
 443     demo_64_vec)                tb="$tb demo64.lo aout64.lo"
 444                                 target64=true ;;
 445     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 446     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 447     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 448     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"
 449                                 target64=true ;;
 450     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 451     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 452     evax_alpha_vec)             tb="$tb evax-alpha.lo evax-emh.lo evax-egsd.lo evax-etir.lo evax-misc.lo"
 453                                 target64=true ;;
 454     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 455     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 456     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 457     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 458     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 459     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 460     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 461     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 462     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 463     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 464     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 465     i386pe_vec)                 tb="$tb pe-i386.lo cofflink.lo " ;;
 466     i386pei_vec)                tb="$tb pei-i386.lo cofflink.lo" ;;
 467     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 468     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 469     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 470     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 471     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 472     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 473     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 474     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 475     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 476     ieee_vec)                   tb="$tb ieee.lo" ;;
 477     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 478     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 479     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 480     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 481     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 482     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 483     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 484     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 485     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 486     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 487     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 488     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 489     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 490     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"
 491                                 target64=true ;;
 492     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 493     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 494     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 495     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 496     pmac_xcoff_vec)             tb="$tb coff-pmac.lo xcofflink.lo" ;;
 497     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 498     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo cofflink.lo" ;;
 499     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo cofflink.lo" ;;
 500     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo cofflink.lo" ;;
 501     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo cofflink.lo" ;;
 502     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 503     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 504     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 505     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 506     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 507     som_vec)                    tb="$tb som.lo" ;;
 508     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 509     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 510     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 511     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 512     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 513     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 514     srec_vec)                   tb="$tb srec.lo" ;;
 515     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 516     symbolsrec_vec)             tb="$tb srec.lo" ;;
 517     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 518     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 519     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 520 # start-sanitize-tic80
 521     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 522 # end-sanitize-tic80
 523     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 524     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 525     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 526     versados_vec)               tb="$tb versados.lo" ;;
 527
 528     "")                 ;;
 529     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 530     esac
 531 done
 532
 533 # Target architecture .o files.
 534 # A couple of CPUs use shorter file names to avoid problems on DOS
 535 # filesystems.
 536 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 537
 538 # Weed out duplicate .o files.
 539 f=""
 540 for i in $tb ; do
 541     case " $f " in
 542     *" $i "*) ;;
 543     *) f="$f $i" ;;
 544     esac
 545 done
 546 tb="$f"
 547
 548 f=""
 549 for i in $ta ; do
 550     case " $f " in
 551     *" $i "*) ;;
 552     *) f="$f $i" ;;
 553     esac
 554 done
 555 ta="$f"
 556
 557 bfd_backends="$tb"
 558 bfd_machines="$ta"
 559
 560 if test x${all_targets} = xtrue ; then
 561   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 562   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 563   selvecs=
 564   havevecs=
 565   selarchs=
 566 else    # all_targets is true
 567   # Only set these if they will be nonempty, for the clever echo.
 568   havevecs=
 569   test -n "$selvecs" &&
 570     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 571   test -n "$selvecs" &&
 572     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 573   test -n "$selarchs" &&
 574     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 575 fi      # all_targets is true
 576
 577 case ${host64}-${target64}-${want64} in
 578   *true*)
 579     wordsize=64
 580     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 581     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 582       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 583       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 584     fi
 585     ;;
 586   false-false-false)
 587     wordsize=32
 588     all_backends='$(BFD32_BACKENDS)'
 589     ;;
 590 esac
 591
 592 AC_SUBST(wordsize)
 593 AC_SUBST(all_backends)
 594 AC_SUBST(bfd_backends)
 595 AC_SUBST(bfd_machines)
 596
 597 tdefaults=""
 598 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 599 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 600 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 601 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 602 AC_SUBST(tdefaults)
 603
 604 dnl AC_CHECK_HEADERS(sys/mman.h)
 605 AC_FUNC_MMAP
 606 AC_CHECK_FUNCS(madvise mprotect)
 607 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 608   true+yes )  AC_DEFINE(USE_MMAP) ;;
 609 esac
 610
 611 rm -f doc/config.status
 612 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h)