bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.5)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21 AC_ARG_ENABLE(shared,
  22 [  --enable-shared         build shared BFD library],
  23 [case "${enableval}" in
  24   yes) shared=true ;;
  25   no)  shared=false ;;
  26   *bfd*) shared=true ;;
  27   *) shared=false ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(commonbfdlib,
  30 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  31 [case "${enableval}" in
  32   yes) commonbfdlib=true ;;
  33   no)  commonbfdlib=false ;;
  34   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  35 esac])dnl
  36 AC_ARG_WITH(mmap,
  37 [  --with-mmap             try using mmap for BFD input files if available],
  38 [case "${withval}" in
  39   yes)  want_mmap=true ;;
  40   no)   want_mmap=false ;;
  41   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  42 esac],[want_mmap=false])dnl
  43
  44 AC_CONFIG_HEADER(config.h:config.in)
  45
  46 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  47 AC_CANONICAL_SYSTEM
  48 if test -z "$target" ; then
  49     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  50 fi
  51 AC_ARG_PROGRAM
  52
  53 host64=false
  54 target64=false
  55
  56 # host stuff:
  57
  58 ALLLIBS='$(TARGETLIB)'
  59 PICFLAG=
  60 SHLIB=unused-shlib
  61 SHLINK=unused-shlink
  62 if test "${shared}" = "true"; then
  63   PICFLAG=-fpic
  64   if test "${commonbfdlib}" = "true"; then
  65     ALLLIBS='$(TARGETLIB)'
  66   else
  67     ALLLIBS='$(TARGETLIB) $(SHLIB) $(SHLINK)'
  68 changequote(,)dnl
  69     SHLIB=libbfd.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/VERSION`
  70 changequote([,])dnl
  71     SHLINK=libbfd.so
  72   fi
  73 fi
  74
  75 AC_PROG_CC
  76
  77 AC_ISC_POSIX
  78
  79 # Permit host specific settings.
  80 . ${srcdir}/configure.host
  81
  82 AC_SUBST(HDEFINES)
  83 AC_CHECK_TOOL(AR, ar)
  84 AC_CHECK_TOOL(RANLIB, ranlib, :)
  85 AC_PROG_INSTALL
  86
  87 if test "${shared}" = "true"; then
  88   if test "${GCC}" != "yes" && test "${shared_non_gcc}" != "yes"; then
  89     AC_MSG_WARN([BFD --enable-shared only supported when using gcc])
  90     shared=false
  91     ALLLIBS='$(TARGETLIB)'
  92     PICFLAG=
  93     SHLIB=unused-shlib
  94   fi
  95 fi
  96
  97 AC_SUBST(ALLLIBS)
  98 AC_SUBST(PICFLAG)
  99 AC_SUBST(SHLIB)
 100 AC_SUBST(SHLIB_CC)
 101 AC_SUBST(SHLIB_CFLAGS)
 102 if test "${commonbfdlib}" = "true"; then
 103   COMMON_SHLIB=yes
 104   PICLIST=piclist
 105 else
 106   COMMON_SHLIB=
 107   PICLIST=
 108 fi
 109 AC_SUBST(COMMON_SHLIB)
 110 AC_SUBST(PICLIST)
 111 AC_SUBST(SHLINK)
 112 AC_SUBST(INSTALL_SHLIB)
 113
 114 VERSION=`cat ${srcdir}/VERSION`
 115 AC_SUBST(VERSION)
 116
 117 BFD_HOST_64BIT_LONG=0
 118 BFD_HOST_64_BIT_DEFINED=0
 119 BFD_HOST_64_BIT=
 120 BFD_HOST_U_64_BIT=
 121 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 122   BFD_HOST_64BIT_LONG=1
 123 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 124   BFD_HOST_64_BIT_DEFINED=1
 125   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 126   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 127 fi
 128 AC_SUBST(BFD_HOST_64BIT_LONG)
 129 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 130 AC_SUBST(BFD_HOST_64_BIT)
 131 AC_SUBST(BFD_HOST_U_64_BIT)
 132
 133 BFD_CC_FOR_BUILD
 134
 135 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 136 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 137 AC_HEADER_TIME
 138 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf)
 139
 140 BFD_BINARY_FOPEN
 141
 142 BFD_NEED_DECLARATION(malloc)
 143 BFD_NEED_DECLARATION(free)
 144
 145 # If we are configured native, pick a core file support file.
 146 COREFILE=
 147 COREFLAG=
 148 if test "${target}" = "${host}"; then
 149   case "${host}" in
 150   alpha*-*-linux*)
 151         COREFILE=trad-core.o
 152         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 153         ;;
 154   alpha*-*-*)           COREFILE=osf-core.o ;;
 155   arm-*-riscix)         COREFILE=trad-core.o ;;
 156   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
 157   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
 158   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
 159                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 160 changequote(,)dnl
 161   i[345]86-sequent-bsd*)
 162 changequote([,])dnl
 163         COREFILE=trad-core.o;
 164         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 165         ;;
 166 changequote(,)dnl
 167   i[345]86-sequent-sysv4*) ;;
 168   i[345]86-sequent-sysv*)
 169 changequote([,])dnl
 170         COREFILE=trad-core.o
 171         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 172         ;;
 173 changequote(,)dnl
 174   i[345]86-*-bsd* | i[345]86-*-freebsd*)
 175 changequote([,])dnl
 176         COREFILE=trad-core.o
 177         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 178         ;;
 179 changequote(,)dnl
 180   i[345]86-*-netbsd*)
 181 changequote([,])dnl
 182         COREFILE=netbsd-core.o
 183         ;;
 184 changequote(,)dnl
 185   i[345]86-esix-sysv3*)
 186 changequote([,])dnl
 187         COREFILE=trad-core.o
 188         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 189         ;;
 190 changequote(,)dnl
 191   i[345]86-*-sco* | i[345]86-*-isc*)
 192 changequote([,])dnl
 193         COREFILE=trad-core.o
 194         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 195         ;;
 196 changequote(,)dnl
 197   i[345]86-*-mach3*)
 198 changequote([,])dnl
 199         COREFILE=trad-core.o
 200         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 201         ;;
 202 changequote(,)dnl
 203   i[345]86-*-linux*)
 204 changequote([,])dnl
 205         COREFILE=trad-core.o
 206         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 207         ;;
 208 changequote(,)dnl
 209   i[345]86-*-isc*)      COREFILE=trad-core.o ;;
 210   i[345]86-*-aix*)      COREFILE=aix386-core.o ;;
 211 changequote([,])dnl
 212   i860-*-mach3* | i860-*-osf1*)
 213         COREFILE=trad-core.o
 214         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 215         ;;
 216   mips-dec-bsd*)
 217         COREFILE=trad-core.o
 218         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 219         ;;
 220   mips-dec-mach3*)
 221         COREFILE=trad-core.o
 222         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 223         ;;
 224   mips-*-netbsd*)
 225         COREFILE=netbsd-core.o
 226         ;;
 227   mips-dec-*)
 228         COREFILE=trad-core.o
 229         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 230         ;;
 231   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
 232   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
 233   mips-*-mach3*)
 234         COREFILE=trad-core.o
 235         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 236         ;;
 237   mips-*-sysv4*)        ;;
 238   mips-*-sysv* | mips-*-riscos*)
 239         COREFILE=trad-core.o
 240         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 241         ;;
 242   mips-sony-bsd*)
 243         COREFILE=trad-core.o
 244         AC_DEFINE(TRAD_HEADER,"hosts/news-mips.h")
 245         ;;
 246   m68*-bull*-sysv*)
 247         COREFILE=trad-core.o
 248         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 249         ;;
 250   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 251   m68*-hp-bsd*)
 252         COREFILE=trad-core.o
 253         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 254         ;;
 255   m68*-*-linux*)
 256         COREFILE=trad-core.o
 257         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 258         ;;
 259   m68*-motorola-sysv*)
 260         COREFILE=trad-core.o
 261         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 262         ;;
 263   m68*-sony-*)
 264         COREFILE=trad-core.o
 265         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 266         ;;
 267   m68*-*-netbsd*)
 268         COREFILE=netbsd-core.o
 269         ;;
 270   m68*-apple-aux*)
 271         COREFILE=trad-core.o
 272         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 273         ;;
 274   m88*-*-sysv4*)        ;;
 275   m88*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 276   m88*-*-mach3*)
 277         COREFILE=trad-core.o
 278         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 279         ;;
 280   ns32k-pc532-mach)
 281         COREFILE=trad-core.o
 282         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 283         ;;
 284   ns32k-*-netbsd*)
 285         COREFILE=netbsd-core.o
 286         ;;
 287   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 288   rs6000-*-aix4*)       COREFILE=rs6000-core.o ;;
 289   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 290   powerpc-*-aix4*)      COREFILE=rs6000-core.o ;;
 291   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 292   sparc-*-netbsd*)
 293         COREFILE=netbsd-core.o
 294         ;;
 295   tahoe-*-*)
 296         COREFILE=trad-core.o
 297         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 298         ;;
 299   vax-*-ultrix2*)
 300         COREFILE=trad-core.o
 301         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 302         ;;
 303   vax-*-ultrix*)
 304         COREFILE=trad-core.o
 305         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 306         ;;
 307   vax-*-*)
 308         COREFILE=trad-core.o
 309         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 310         ;;
 311   esac
 312
 313   case "$COREFILE" in
 314   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 315   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 316   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 317   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 318   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 319   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 320   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 321   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 322   trad-core.o)          COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 323   esac
 324
 325   # The ELF code uses the native <sys/procfs.h> to handle core files.
 326   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 327   # prstatus_t.
 328   AC_MSG_CHECKING([for sys/procfs.h])
 329   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 330   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 331   [prstatus_t t;],
 332   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 333   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 334   if test $bfd_cv_header_sys_procfs_h = yes; then
 335     AC_DEFINE(HAVE_SYS_PROCFS_H)
 336   fi
 337
 338 fi
 339 AC_SUBST(COREFILE)
 340 AC_SUBST(COREFLAG)
 341
 342 # target stuff:
 343
 344 # Canonicalize the secondary target names.
 345 if test -n "$enable_targets" ; then
 346     for targ in `echo $enable_targets | sed 's/,/ /g'`
 347     do
 348         result=`$ac_config_sub $targ 2>/dev/null`
 349         if test -n "$result" ; then
 350             canon_targets="$canon_targets $result"
 351         else
 352             # Allow targets that config.sub doesn't recognize, like "all".
 353             canon_targets="$canon_targets $targ"
 354         fi
 355     done
 356 fi
 357
 358 all_targets=false
 359 defvec=
 360 selvecs=
 361 selarchs=
 362 TDEFINES=
 363 for targ in $target $canon_targets
 364 do
 365     if test "x$targ" = "xall"; then
 366         all_targets=true
 367     else
 368         . $srcdir/config.bfd
 369         if test "x$targ" = "x$target"; then
 370             defvec=$targ_defvec
 371         fi
 372         selvecs="$selvecs $targ_defvec $targ_selvecs"
 373         selarchs="$selarchs $targ_archs"
 374         TDEFINES="$TDEFINES $targ_cflags"
 375     fi
 376 done
 377 AC_SUBST(TDEFINES)
 378
 379 # This processing still needs to be done if we're to decide properly whether
 380 # 64-bit support needs to be compiled in.  Currently, it will be included if
 381 # the default or any other explicitly requested target requires it; it
 382 # will not be included on a 32-bit host if no 64-bit target is requested, and
 383 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 384 # used.
 385
 386 # uniq the default and selected vectors in all the configured targets.
 387 f=""
 388 for i in $selvecs ; do
 389     case " $f " in
 390     *" $i "*) ;;
 391     *) f="$f $i" ;;
 392     esac
 393 done
 394 selvecs="$f"
 395
 396 # uniq the architectures in all the configured targets.
 397 f=""
 398 for i in $selarchs ; do
 399     case " $f " in
 400     *" $i "*) ;;
 401     *) f="$f $i" ;;
 402     esac
 403 done
 404 selarchs="$f"
 405
 406 # Target backend .o files.
 407 tb=
 408
 409 elf="elf.o elflink.o"
 410
 411 for vec in $selvecs
 412 do
 413     case "$vec" in
 414     # This list is alphabetized to make it easy to compare
 415     # with the two vector lists in targets.c.
 416     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 417     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o" ;;
 418     armcoff_little_vec)         tb="$tb coff-arm.o cofflink.o " ;;
 419     armcoff_big_vec)            tb="$tb coff-arm.o cofflink.o " ;;
 420     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 421     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 422     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 423     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 424     aout0_big_vec)              tb="$tb aout0.o aout32.o" ;;
 425     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o" ;;
 426     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o" ;;
 427     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o" ;;
 428     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o" ;;
 429     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 430     b_out_vec_big_host)         tb="$tb bout.o aout32.o" ;;
 431     b_out_vec_little_host)      tb="$tb bout.o aout32.o" ;;
 432     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.o elf64.o $elf"
 433                                 target64=true ;;
 434 # start-sanitize-arc
 435     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 436     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 437 # end-sanitize-arc
 438     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 439     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 440     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.o elf64.o elf32-mips.o elf32.o $elf ecofflink.o"
 441                                 target64=true ;;
 442 # start-sanitize-d10v
 443     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.o elf32.o $elf" ;;
 444 # end-sanitize-d10v
 445     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 446     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 447     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 448     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 449     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 450     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.o elf64.o elf32-mips.o elf32.o $elf ecofflink.o"
 451                                 target64=true ;;
 452     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 453     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 454     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 455     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 456     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 457     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 458                                 target64=true ;;
 459     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 460                                 target64=true ;;
 461     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 462                                 target64=true ;;
 463     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 464     demo_64_vec)                tb="$tb demo64.o aout64.o"
 465                                 target64=true ;;
 466     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 467     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 468     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 469                                 target64=true ;;
 470     evax_alpha_vec)             tb="$tb evax-alpha.o evax-emh.o evax-egsd.o evax-etir.o evax-misc.o"
 471                                 target64=true ;;
 472     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 473     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 474     host_aout_vec)              tb="$tb host-aout.o aout32.o" ;;
 475     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o" ;;
 476     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o" ;;
 477     i386aout_vec)               tb="$tb i386aout.o aout32.o" ;;
 478     i386bsd_vec)                tb="$tb i386bsd.o aout32.o" ;;
 479     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 480     i386dynix_vec)              tb="$tb i386dynix.o aout32.o" ;;
 481     i386freebsd_vec)            tb="$tb i386freebsd.o aout32.o" ;;
 482     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 483     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 484     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 485     i386linux_vec)              tb="$tb i386linux.o aout32.o" ;;
 486     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o" ;;
 487     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o" ;;
 488     i386mach3_vec)              tb="$tb i386mach3.o aout32.o" ;;
 489     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o" ;;
 490     i386os9k_vec)               tb="$tb i386os9k.o aout32.o" ;;
 491     i860coff_vec)               tb="$tb coff-i860.o cofflink.o" ;;
 492     icoff_big_vec)              tb="$tb coff-i960.o cofflink.o" ;;
 493     icoff_little_vec)           tb="$tb coff-i960.o cofflink.o" ;;
 494     ieee_vec)                   tb="$tb ieee.o" ;;
 495     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 496     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 497     m68klinux_vec)              tb="$tb m68klinux.o aout32.o" ;;
 498     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o" ;;
 499     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o" ;;
 500     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o" ;;
 501     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.o aout32.o" ;;
 502     m68kaux_coff_vec)           tb="$tb coff-aux.o coff-m68k.o cofflink.o" ;;
 503     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 504     newsos3_vec)                tb="$tb newsos3.o aout32.o" ;;
 505     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 506     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 507     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 508                                 target64=true ;;
 509     riscix_vec)                 tb="$tb aout32.o riscix.o" ;;
 510     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 511     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o" ;;
 512     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o" ;;
 513     pmac_xcoff_vec)             tb="$tb coff-pmac.o xcofflink.o" ;;
 514     rs6000coff_vec)             tb="$tb coff-rs6000.o xcofflink.o" ;;
 515     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.o cofflink.o" ;;
 516     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.o cofflink.o" ;;
 517     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.o cofflink.o" ;;
 518     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.o cofflink.o" ;;
 519     ppcboot_vec)                tb="$tb ppcboot.o" ;;
 520     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 521     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 522     som_vec)                    tb="$tb som.o" ;;
 523     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o" ;;
 524     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o" ;;
 525     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o" ;;
 526     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 527     srec_vec)                   tb="$tb srec.o" ;;
 528     sunos_big_vec)              tb="$tb sunos.o aout32.o" ;;
 529     symbolsrec_vec)             tb="$tb srec.o" ;;
 530     tekhex_vec)                 tb="$tb tekhex.o" ;;
 531     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 532     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 533     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 534     versados_vec)               tb="$tb versados.o" ;;
 535
 536     "")                 ;;
 537     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 538     esac
 539 done
 540
 541 # Target architecture .o files.
 542 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g`
 543
 544 # Weed out duplicate .o files.
 545 f=""
 546 for i in $tb ; do
 547     case " $f " in
 548     *" $i "*) ;;
 549     *) f="$f $i" ;;
 550     esac
 551 done
 552 tb="$f"
 553
 554 f=""
 555 for i in $ta ; do
 556     case " $f " in
 557     *" $i "*) ;;
 558     *) f="$f $i" ;;
 559     esac
 560 done
 561 ta="$f"
 562
 563 bfd_backends="$tb"
 564 bfd_machines="$ta"
 565
 566 if test x${all_targets} = xtrue ; then
 567   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 568   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 569   selvecs=
 570   selarchs=
 571 else    # all_targets is true
 572   # Only set these if they will be nonempty, for the clever echo.
 573   test -n "$selvecs" &&
 574     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 575   test -n "$selarchs" &&
 576     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 577 fi      # all_targets is true
 578
 579 case ${host64}-${target64}-${want64} in
 580   *true*)
 581     wordsize=64
 582     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 583     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 584       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 585       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 586     fi
 587     ;;
 588   false-false-false)
 589     wordsize=32
 590     all_backends='$(BFD32_BACKENDS)'
 591     ;;
 592 esac
 593
 594 AC_SUBST(wordsize)
 595 AC_SUBST(all_backends)
 596 AC_SUBST(bfd_backends)
 597 AC_SUBST(bfd_machines)
 598
 599 tdefaults=""
 600 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 601 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 602 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 603 AC_SUBST(tdefaults)
 604
 605 dnl AC_CHECK_HEADERS(sys/mman.h)
 606 AC_FUNC_MMAP
 607 AC_CHECK_FUNCS(madvise mprotect)
 608 case ${want_mmap}+${ac_cv_func_mmap} in
 609   true+yes )  AC_DEFINE(USE_MMAP) ;;
 610 esac
 611
 612 rm -f doc/config.status
 613 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h,
 614 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])