bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.5)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21 AC_ARG_ENABLE(shared,
  22 [  --enable-shared         build shared BFD library],
  23 [case "${enableval}" in
  24   yes) shared=true ;;
  25   no)  shared=false ;;
  26   *bfd*) shared=true ;;
  27   *) shared=false ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(commonbfdlib,
  30 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  31 [case "${enableval}" in
  32   yes) commonbfdlib=true ;;
  33   no)  commonbfdlib=false ;;
  34   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  35 esac])dnl
  36 AC_ARG_WITH(mmap,
  37 [  --with-mmap             try using mmap for BFD input files if available],
  38 [case "${withval}" in
  39   yes)  want_mmap=true ;;
  40   no)   want_mmap=false ;;
  41   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  42 esac],[want_mmap=false])dnl
  43
  44 AC_CONFIG_HEADER(config.h:config.in)
  45
  46 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  47 AC_CANONICAL_SYSTEM
  48 if test -z "$target" ; then
  49     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  50 fi
  51 AC_ARG_PROGRAM
  52
  53 host64=false
  54 target64=false
  55
  56 # host stuff:
  57
  58 ALLLIBS='$(TARGETLIB)'
  59 PICFLAG=
  60 SHLIB=unused-shlib
  61 SHLINK=unused-shlink
  62 if test "${shared}" = "true"; then
  63   PICFLAG=-fpic
  64   if test "${commonbfdlib}" = "true"; then
  65     ALLLIBS='$(TARGETLIB)'
  66   else
  67     ALLLIBS='$(TARGETLIB) $(SHLIB) $(SHLINK)'
  68 changequote(,)dnl
  69     SHLIB=libbfd.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/VERSION`
  70 changequote([,])dnl
  71     SHLINK=libbfd.so
  72   fi
  73 fi
  74
  75 AC_PROG_CC
  76
  77 AC_ISC_POSIX
  78
  79 # Permit host specific settings.
  80 . ${srcdir}/configure.host
  81
  82 AC_SUBST(HDEFINES)
  83 AC_CHECK_TOOL(AR, ar)
  84 AC_CHECK_TOOL(RANLIB, ranlib, :)
  85 AC_PROG_INSTALL
  86
  87 if test "${shared}" = "true"; then
  88   if test "${GCC}" != "yes" && test "${shared_non_gcc}" != "yes"; then
  89     AC_MSG_WARN([BFD --enable-shared only supported when using gcc])
  90     shared=false
  91     ALLLIBS='$(TARGETLIB)'
  92     PICFLAG=
  93     SHLIB=unused-shlib
  94   fi
  95 fi
  96
  97 AC_SUBST(ALLLIBS)
  98 AC_SUBST(PICFLAG)
  99 AC_SUBST(SHLIB)
 100 AC_SUBST(SHLIB_CC)
 101 AC_SUBST(SHLIB_CFLAGS)
 102 AC_SUBST(SHLIB_LIBS)
 103 if test "${commonbfdlib}" = "true"; then
 104   COMMON_SHLIB=yes
 105   PICLIST=piclist
 106 else
 107   COMMON_SHLIB=
 108   PICLIST=
 109 fi
 110 AC_SUBST(COMMON_SHLIB)
 111 AC_SUBST(PICLIST)
 112 AC_SUBST(SHLINK)
 113 AC_SUBST(INSTALL_SHLIB)
 114
 115 VERSION=`cat ${srcdir}/VERSION`
 116 AC_SUBST(VERSION)
 117
 118 BFD_HOST_64BIT_LONG=0
 119 BFD_HOST_64_BIT_DEFINED=0
 120 BFD_HOST_64_BIT=
 121 BFD_HOST_U_64_BIT=
 122 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 123   BFD_HOST_64BIT_LONG=1
 124 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 125   BFD_HOST_64_BIT_DEFINED=1
 126   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 127   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 128 fi
 129 AC_SUBST(BFD_HOST_64BIT_LONG)
 130 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 131 AC_SUBST(BFD_HOST_64_BIT)
 132 AC_SUBST(BFD_HOST_U_64_BIT)
 133
 134 BFD_CC_FOR_BUILD
 135
 136 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 137 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 138 AC_HEADER_TIME
 139 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf)
 140
 141 BFD_BINARY_FOPEN
 142
 143 BFD_NEED_DECLARATION(strstr)
 144 BFD_NEED_DECLARATION(malloc)
 145 BFD_NEED_DECLARATION(realloc)
 146 BFD_NEED_DECLARATION(free)
 147 BFD_NEED_DECLARATION(getenv)
 148
 149 # If we are configured native, pick a core file support file.
 150 COREFILE=
 151 COREFLAG=
 152 if test "${target}" = "${host}"; then
 153   case "${host}" in
 154   alpha*-*-linux*)
 155         COREFILE=trad-core.o
 156         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 157         ;;
 158   alpha*-*-*)           COREFILE=osf-core.o ;;
 159   arm-*-riscix)         COREFILE=trad-core.o ;;
 160   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
 161   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
 162   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
 163                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 164 changequote(,)dnl
 165   i[3456]86-sequent-bsd*)
 166 changequote([,])dnl
 167         COREFILE=trad-core.o;
 168         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 169         ;;
 170 changequote(,)dnl
 171   i[3456]86-sequent-sysv4*) ;;
 172   i[3456]86-sequent-sysv*)
 173 changequote([,])dnl
 174         COREFILE=trad-core.o
 175         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 176         ;;
 177 changequote(,)dnl
 178   i[3456]86-*-bsd* | i[3456]86-*-freebsd*)
 179 changequote([,])dnl
 180         COREFILE=trad-core.o
 181         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 182         ;;
 183 changequote(,)dnl
 184   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 185 changequote([,])dnl
 186         COREFILE=netbsd-core.o
 187         ;;
 188 changequote(,)dnl
 189   i[3456]86-esix-sysv3*)
 190 changequote([,])dnl
 191         COREFILE=trad-core.o
 192         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 193         ;;
 194 changequote(,)dnl
 195   i[3456]86-*-sco* | i[3456]86-*-isc*)
 196 changequote([,])dnl
 197         COREFILE=trad-core.o
 198         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 199         ;;
 200 changequote(,)dnl
 201   i[3456]86-*-mach3*)
 202 changequote([,])dnl
 203         COREFILE=trad-core.o
 204         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 205         ;;
 206 changequote(,)dnl
 207   i[3456]86-*-linux*)
 208 changequote([,])dnl
 209         COREFILE=trad-core.o
 210         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 211         ;;
 212 changequote(,)dnl
 213   i[3456]86-*-isc*)     COREFILE=trad-core.o ;;
 214   i[3456]86-*-aix*)     COREFILE=aix386-core.o ;;
 215 changequote([,])dnl
 216   i860-*-mach3* | i860-*-osf1*)
 217         COREFILE=trad-core.o
 218         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 219         ;;
 220   mips-dec-bsd*)
 221         COREFILE=trad-core.o
 222         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 223         ;;
 224   mips-dec-mach3*)
 225         COREFILE=trad-core.o
 226         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 227         ;;
 228   mips-*-netbsd* | mips*-*-openbsd*)
 229         COREFILE=netbsd-core.o
 230         ;;
 231   mips-dec-*)
 232         COREFILE=trad-core.o
 233         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 234         ;;
 235   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
 236   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
 237   mips-sgi-irix6*)      COREFILE=irix-core.o ;;
 238   mips-*-mach3*)
 239         COREFILE=trad-core.o
 240         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 241         ;;
 242   mips-*-sysv4*)        ;;
 243   mips-*-sysv* | mips-*-riscos*)
 244         COREFILE=trad-core.o
 245         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 246         ;;
 247   mips-sony-bsd*)
 248         COREFILE=trad-core.o
 249         AC_DEFINE(TRAD_HEADER,"hosts/news-mips.h")
 250         ;;
 251   m68*-bull*-sysv*)
 252         COREFILE=trad-core.o
 253         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 254         ;;
 255   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 256   m68*-hp-bsd*)
 257         COREFILE=trad-core.o
 258         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 259         ;;
 260   m68*-*-linux*)
 261         COREFILE=trad-core.o
 262         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 263         ;;
 264   m68*-motorola-sysv*)
 265         COREFILE=trad-core.o
 266         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 267         ;;
 268   m68*-sony-*)
 269         COREFILE=trad-core.o
 270         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 271         ;;
 272   m68*-*-netbsd* | m68*-*-openbsd*)
 273         COREFILE=netbsd-core.o
 274         ;;
 275   m68*-apple-aux*)
 276         COREFILE=trad-core.o
 277         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 278         ;;
 279   m88*-*-sysv4*)        ;;
 280   m88*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 281   m88*-*-mach3*)
 282         COREFILE=trad-core.o
 283         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 284         ;;
 285   ns32k-pc532-mach)
 286         COREFILE=trad-core.o
 287         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 288         ;;
 289   ns32k-*-netbsd* | ns32k-*-openbsd*)
 290         COREFILE=netbsd-core.o
 291         ;;
 292   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 293   rs6000-*-aix4*)       COREFILE=rs6000-core.o ;;
 294   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 295   powerpc-*-*bsd*)      COREFILE=netbsd-core.o ;;
 296   powerpc-*-aix4*)      COREFILE=rs6000-core.o ;;
 297   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 298   powerpc-*-beos*)      ;;
 299   sparc-*-netbsd* | sparc-*-openbsd*)
 300         COREFILE=netbsd-core.o
 301         ;;
 302   tahoe-*-*)
 303         COREFILE=trad-core.o
 304         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 305         ;;
 306   vax-*-ultrix2*)
 307         COREFILE=trad-core.o
 308         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 309         ;;
 310   vax-*-ultrix*)
 311         COREFILE=trad-core.o
 312         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 313         ;;
 314   vax-*-*)
 315         COREFILE=trad-core.o
 316         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 317         ;;
 318   esac
 319
 320   case "$COREFILE" in
 321   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 322   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 323   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 324   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 325   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 326   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 327   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 328   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 329   trad-core.o)          COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 330   esac
 331
 332   # The ELF code uses the native <sys/procfs.h> to handle core files.
 333   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 334   # prstatus_t.
 335   AC_MSG_CHECKING([for sys/procfs.h])
 336   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 337   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 338   [prstatus_t t;],
 339   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 340   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 341   if test $bfd_cv_header_sys_procfs_h = yes; then
 342     AC_DEFINE(HAVE_SYS_PROCFS_H)
 343   fi
 344
 345 fi
 346 AC_SUBST(COREFILE)
 347 AC_SUBST(COREFLAG)
 348
 349 # target stuff:
 350
 351 # Canonicalize the secondary target names.
 352 if test -n "$enable_targets" ; then
 353     for targ in `echo $enable_targets | sed 's/,/ /g'`
 354     do
 355         result=`$ac_config_sub $targ 2>/dev/null`
 356         if test -n "$result" ; then
 357             canon_targets="$canon_targets $result"
 358         else
 359             # Allow targets that config.sub doesn't recognize, like "all".
 360             canon_targets="$canon_targets $targ"
 361         fi
 362     done
 363 fi
 364
 365 all_targets=false
 366 defvec=
 367 selvecs=
 368 selarchs=
 369 TDEFINES=
 370 for targ in $target $canon_targets
 371 do
 372     if test "x$targ" = "xall"; then
 373         all_targets=true
 374     else
 375         . $srcdir/config.bfd
 376         if test "x$targ" = "x$target"; then
 377             defvec=$targ_defvec
 378         fi
 379         selvecs="$selvecs $targ_defvec $targ_selvecs"
 380         selarchs="$selarchs $targ_archs"
 381         TDEFINES="$TDEFINES $targ_cflags"
 382     fi
 383 done
 384 AC_SUBST(TDEFINES)
 385
 386 # This processing still needs to be done if we're to decide properly whether
 387 # 64-bit support needs to be compiled in.  Currently, it will be included if
 388 # the default or any other explicitly requested target requires it; it
 389 # will not be included on a 32-bit host if no 64-bit target is requested, and
 390 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 391 # used.
 392
 393 # uniq the default and selected vectors in all the configured targets.
 394 f=""
 395 for i in $selvecs ; do
 396     case " $f " in
 397     *" $i "*) ;;
 398     *) f="$f $i" ;;
 399     esac
 400 done
 401 selvecs="$f"
 402
 403 # uniq the architectures in all the configured targets.
 404 f=""
 405 for i in $selarchs ; do
 406     case " $f " in
 407     *" $i "*) ;;
 408     *) f="$f $i" ;;
 409     esac
 410 done
 411 selarchs="$f"
 412
 413 # Target backend .o files.
 414 tb=
 415
 416 elf="elf.o elflink.o"
 417
 418 for vec in $selvecs
 419 do
 420     case "$vec" in
 421     # This list is alphabetized to make it easy to compare
 422     # with the two vector lists in targets.c.
 423     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 424     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o" ;;
 425     armcoff_little_vec)         tb="$tb coff-arm.o cofflink.o " ;;
 426     armcoff_big_vec)            tb="$tb coff-arm.o cofflink.o " ;;
 427     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 428     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 429     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 430     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 431     aout0_big_vec)              tb="$tb aout0.o aout32.o" ;;
 432     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o" ;;
 433     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o" ;;
 434     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o" ;;
 435     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o" ;;
 436     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 437     b_out_vec_big_host)         tb="$tb bout.o aout32.o" ;;
 438     b_out_vec_little_host)      tb="$tb bout.o aout32.o" ;;
 439     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.o elf64.o $elf"
 440                                 target64=true ;;
 441 # start-sanitize-arc
 442     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 443     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 444 # end-sanitize-arc
 445     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 446     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 447     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.o elf64.o elf32-mips.o elf32.o $elf ecofflink.o"
 448                                 target64=true ;;
 449     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.o elf32.o $elf" ;;
 450 # start-sanitize-d30v
 451     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.o elf32.o $elf" ;;
 452 # end-sanitize-d30v
 453     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 454     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 455     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 456     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 457     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 458     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.o elf64.o elf32-mips.o elf32.o $elf ecofflink.o"
 459                                 target64=true ;;
 460     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.o elf32.o $elf" ;;
 461     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 462     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 463     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.o elf32.o $elf" ;;
 464     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.o elf32.o $elf" ;;
 465     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 466     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 467     bfd_elf32_sh_vec)           tb="$tb elf32-sh.o elf32.o $elf coff-sh.o" ;;
 468     bfd_elf32_shl_vec)          tb="$tb elf32-sh.o elf32.o $elf coff-sh.o" ;;
 469     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 470 # start-sanitize-v850
 471     bfd_elf32_v850_vec)         tb="$tb elf32-v850.o elf32.o $elf" ;;
 472 # end-sanitize-v850
 473     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 474                                 target64=true ;;
 475     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 476                                 target64=true ;;
 477     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 478                                 target64=true ;;
 479     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 480     demo_64_vec)                tb="$tb demo64.o aout64.o"
 481                                 target64=true ;;
 482     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 483     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 484     ecoff_biglittle_vec)        tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 485     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 486                                 target64=true ;;
 487     evax_alpha_vec)             tb="$tb evax-alpha.o evax-emh.o evax-egsd.o evax-etir.o evax-misc.o"
 488                                 target64=true ;;
 489     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 490     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 491     host_aout_vec)              tb="$tb host-aout.o aout32.o" ;;
 492     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o" ;;
 493     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o" ;;
 494     i386aout_vec)               tb="$tb i386aout.o aout32.o" ;;
 495     i386bsd_vec)                tb="$tb i386bsd.o aout32.o" ;;
 496     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 497     i386dynix_vec)              tb="$tb i386dynix.o aout32.o" ;;
 498     i386freebsd_vec)            tb="$tb i386freebsd.o aout32.o" ;;
 499     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 500     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 501     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 502     i386linux_vec)              tb="$tb i386linux.o aout32.o" ;;
 503     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o" ;;
 504     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o" ;;
 505     i386mach3_vec)              tb="$tb i386mach3.o aout32.o" ;;
 506     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o" ;;
 507     i386os9k_vec)               tb="$tb i386os9k.o aout32.o" ;;
 508     i860coff_vec)               tb="$tb coff-i860.o cofflink.o" ;;
 509     icoff_big_vec)              tb="$tb coff-i960.o cofflink.o" ;;
 510     icoff_little_vec)           tb="$tb coff-i960.o cofflink.o" ;;
 511     ieee_vec)                   tb="$tb ieee.o" ;;
 512     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 513     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 514     m68klinux_vec)              tb="$tb m68klinux.o aout32.o" ;;
 515     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o" ;;
 516     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o" ;;
 517     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o" ;;
 518     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.o aout32.o" ;;
 519     m68kaux_coff_vec)           tb="$tb coff-aux.o coff-m68k.o cofflink.o" ;;
 520     m68ksysvcoff_vec)           tb="$tb coff-svm68k.o cofflink.o" ;;
 521     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 522     newsos3_vec)                tb="$tb newsos3.o aout32.o" ;;
 523     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 524     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 525     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 526                                 target64=true ;;
 527     riscix_vec)                 tb="$tb aout32.o riscix.o" ;;
 528     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 529     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o" ;;
 530     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o" ;;
 531     pmac_xcoff_vec)             tb="$tb coff-pmac.o xcofflink.o" ;;
 532     rs6000coff_vec)             tb="$tb coff-rs6000.o xcofflink.o" ;;
 533     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.o cofflink.o" ;;
 534     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.o cofflink.o" ;;
 535     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.o cofflink.o" ;;
 536     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.o cofflink.o" ;;
 537     ppcboot_vec)                tb="$tb ppcboot.o" ;;
 538     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 539     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 540     som_vec)                    tb="$tb som.o" ;;
 541     sparcle_aout_vec)           tb="$tb aout-sparcle.o aout32.o" ;;
 542     sparclinux_vec)             tb="$tb sparclinux.o aout32.o stab-syms.o" ;;
 543     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o" ;;
 544     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o" ;;
 545     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o" ;;
 546     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 547     srec_vec)                   tb="$tb srec.o" ;;
 548     sunos_big_vec)              tb="$tb sunos.o aout32.o" ;;
 549     symbolsrec_vec)             tb="$tb srec.o" ;;
 550     tekhex_vec)                 tb="$tb tekhex.o" ;;
 551 # start-sanitize-tic80
 552     tic80coff_vec)              tb="$tb coff-tic80.o cofflink.o" ;;
 553 # end-sanitize-tic80
 554     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 555     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 556     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 557     versados_vec)               tb="$tb versados.o" ;;
 558
 559     "")                 ;;
 560     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 561     esac
 562 done
 563
 564 # Target architecture .o files.
 565 # A couple of CPUs use shorter file names to avoid problems on DOS
 566 # filesystems.
 567 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 568
 569 # Weed out duplicate .o files.
 570 f=""
 571 for i in $tb ; do
 572     case " $f " in
 573     *" $i "*) ;;
 574     *) f="$f $i" ;;
 575     esac
 576 done
 577 tb="$f"
 578
 579 f=""
 580 for i in $ta ; do
 581     case " $f " in
 582     *" $i "*) ;;
 583     *) f="$f $i" ;;
 584     esac
 585 done
 586 ta="$f"
 587
 588 bfd_backends="$tb"
 589 bfd_machines="$ta"
 590
 591 if test x${all_targets} = xtrue ; then
 592   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 593   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 594   selvecs=
 595   havevecs=
 596   selarchs=
 597 else    # all_targets is true
 598   # Only set these if they will be nonempty, for the clever echo.
 599   havevecs=
 600   test -n "$selvecs" &&
 601     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 602   test -n "$selvecs" &&
 603     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 604   test -n "$selarchs" &&
 605     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 606 fi      # all_targets is true
 607
 608 case ${host64}-${target64}-${want64} in
 609   *true*)
 610     wordsize=64
 611     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 612     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 613       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 614       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 615     fi
 616     ;;
 617   false-false-false)
 618     wordsize=32
 619     all_backends='$(BFD32_BACKENDS)'
 620     ;;
 621 esac
 622
 623 AC_SUBST(wordsize)
 624 AC_SUBST(all_backends)
 625 AC_SUBST(bfd_backends)
 626 AC_SUBST(bfd_machines)
 627
 628 tdefaults=""
 629 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 630 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 631 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 632 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 633 AC_SUBST(tdefaults)
 634
 635 dnl AC_CHECK_HEADERS(sys/mman.h)
 636 AC_FUNC_MMAP
 637 AC_CHECK_FUNCS(madvise mprotect)
 638 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 639   true+yes )  AC_DEFINE(USE_MMAP) ;;
 640 esac
 641
 642 rm -f doc/config.status
 643 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h,
 644 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])