bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.3)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21 AC_ARG_ENABLE(shared,
  22 [  --enable-shared         build shared BFD library],
  23 [case "${enableval}" in
  24   yes) shared=true ;;
  25   no)  shared=false ;;
  26   *)   AC_MSG_ERROR([bad value ${enableval} for BFD shared option]) ;;
  27 esac])dnl
  28 AC_ARG_ENABLE(commonbfdlib,
  29 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  30 [case "${enableval}" in
  31   yes) commonbfdlib=true ;;
  32   no)  commonbfdlib=false ;;
  33   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  34 esac])dnl
  35 AC_ARG_WITH(mmap,
  36 [  --with-mmap             try using mmap for BFD input files if available],
  37 [case "${withval}" in
  38   yes)  want_mmap=true ;;
  39   no)   want_mmap=false ;;
  40   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  41 esac],[want_mmap=false])dnl
  42
  43 AC_CONFIG_HEADER(config.h:config.in)
  44
  45 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  46 AC_CANONICAL_SYSTEM
  47 if test -z "$target" ; then
  48     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  49 fi
  50 AC_ARG_PROGRAM
  51
  52 host64=false
  53 target64=false
  54
  55 # host stuff:
  56
  57 ALLLIBS='$(TARGETLIB)'
  58 PICFLAG=
  59 SHLIB=
  60 SHLINK=
  61 if test "${shared}" = "true"; then
  62   PICFLAG=-fpic
  63   if test "${commonbfdlib}" = "true"; then
  64     ALLLIBS='$(TARGETLIB)'
  65   else
  66     ALLLIBS='$(TARGETLIB) $(SHLIB) $(SHLINK)'
  67 changequote(,)dnl
  68     SHLIB=libbfd.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/VERSION`
  69 changequote([,])dnl
  70     SHLINK=libbfd.so
  71   fi
  72 fi
  73
  74 # Permit host specific settings.
  75 . ${srcdir}/configure.host
  76
  77 AC_PROG_CC
  78 AC_SUBST(CFLAGS)
  79 AC_SUBST(HDEFINES)
  80 AC_CHECK_PROG(AR, ar, ar, :)
  81 AC_PROG_RANLIB
  82 AC_PROG_INSTALL
  83
  84 if test "${shared}" = "true"; then
  85   if test "${GCC}" != "yes" && test "${shared_non_gcc}" != "yes"; then
  86     AC_MSG_WARN([BFD --enable-shared only supported when using gcc])
  87     shared=false
  88     PICFLAG=
  89     SHLIB=
  90   fi
  91 fi
  92
  93 AC_SUBST(ALLLIBS)
  94 AC_SUBST(PICFLAG)
  95 AC_SUBST(SHLIB)
  96 AC_SUBST(SHLIB_CC)
  97 AC_SUBST(SHLIB_CFLAGS)
  98 if test "${commonbfdlib}" = "true"; then
  99   COMMON_SHLIB=yes
 100   PICLIST=piclist
 101 else
 102   COMMON_SHLIB=
 103   PICLIST=
 104 fi
 105 AC_SUBST(COMMON_SHLIB)
 106 AC_SUBST(PICLIST)
 107 AC_SUBST(SHLINK)
 108
 109 HOST_64BIT_LONG=0
 110 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 111   HOST_64BIT_LONG=1
 112 fi
 113 AC_SUBST(HOST_64BIT_LONG)
 114
 115 BFD_CC_FOR_BUILD
 116
 117 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 118 AC_CHECK_HEADERS(fcntl.h sys/file.h)
 119 AC_CHECK_FUNCS(fcntl getpagesize)
 120
 121 BFD_BINARY_FOPEN
 122
 123 BFD_NEED_DECLARATION(malloc)
 124 BFD_NEED_DECLARATION(free)
 125
 126 # If we are configured native, pick a core file support file.
 127 COREFILE=
 128 COREFLAG=
 129 if test "${target}" = "${host}"; then
 130   case "${host}" in
 131   alpha*-*-linux*)
 132         COREFILE=trad-core.o
 133         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 134         ;;
 135   alpha*-*-*)           COREFILE=osf-core.o ;;
 136   arm-*-riscix)         COREFILE=trad-core.o ;;
 137   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
 138   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
 139   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
 140                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 141 changequote(,)dnl
 142   i[345]86-sequent-bsd*)
 143 changequote([,])dnl
 144         COREFILE=trad-core.o;
 145         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 146         ;;
 147 changequote(,)dnl
 148   i[345]86-sequent-sysv4*) ;;
 149   i[345]86-sequent-sysv*)
 150 changequote([,])dnl
 151         COREFILE=trad-core.o
 152         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 153         ;;
 154 changequote(,)dnl
 155   i[345]86-*-bsd* | i[345]86-*-freebsd*)
 156 changequote([,])dnl
 157         COREFILE=trad-core.o
 158         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 159         ;;
 160 changequote(,)dnl
 161   i[345]86-*-netbsd*)
 162 changequote([,])dnl
 163         COREFILE=trad-core.o
 164         AC_DEFINE(TRAD_HEADER,"hosts/i386nbsd.h")
 165         ;;
 166 changequote(,)dnl
 167   i[345]86-esix-sysv3*)
 168 changequote([,])dnl
 169         COREFILE=trad-core.o
 170         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 171         ;;
 172 changequote(,)dnl
 173   i[345]86-*-sco* | i[345]86-*-isc*)
 174 changequote([,])dnl
 175         COREFILE=trad-core.o
 176         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 177         ;;
 178 changequote(,)dnl
 179   i[345]86-*-mach3*)
 180 changequote([,])dnl
 181         COREFILE=trad-core.o
 182         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 183         ;;
 184 changequote(,)dnl
 185   i[345]86-*-linux*)
 186 changequote([,])dnl
 187         COREFILE=trad-core.o
 188         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 189         ;;
 190 changequote(,)dnl
 191   i[345]86-*-isc*)      COREFILE=trad-core.o ;;
 192   i[345]86-*-aix*)      COREFILE=aix386-core.o ;;
 193 changequote([,])dnl
 194   i860-*-mach3* | i860-*-osf1*)
 195         COREFILE=trad-core.o
 196         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 197         ;;
 198   mips-dec-bsd*)
 199         COREFILE=trad-core.o
 200         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 201         ;;
 202   mips-dec-mach3*)
 203         COREFILE=trad-core.o
 204         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 205         ;;
 206   mips-*-netbsd*)
 207         COREFILE=trad-core.o
 208         AC_DEFINE(TRAD_HEADER,"hosts/mipsnbsd.h")
 209         ;;
 210   mips-dec-*)
 211         COREFILE=trad-core.o
 212         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 213         ;;
 214   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
 215   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
 216   mips-*-mach3*)
 217         COREFILE=trad-core.o
 218         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 219         ;;
 220   mips-*-sysv4*)        ;;
 221   mips-*-sysv* | mips-*-riscos*)
 222         COREFILE=trad-core.o
 223         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 224         ;;
 225   mips-sony-bsd*)
 226         COREFILE=trad-core.o
 227         AC_DEFINE(TRAD_HEADER,"hosts/news-mips".h)
 228         ;;
 229   m68*-bull*-sysv*)
 230         COREFILE=trad-core.o
 231         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 232         ;;
 233   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 234   m68*-hp-bsd*)
 235         COREFILE=trad-core.o
 236         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 237         ;;
 238   m68*-motorola-sysv*)
 239         COREFILE=trad-core.o
 240         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 241         ;;
 242   m68*-sony-*)
 243         COREFILE=trad-core.o
 244         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 245         ;;
 246   m68*-*-netbsd*)
 247         COREFILE=trad-core.o
 248         AC_DEFINE(TRAD_HEADER,"hosts/m68knbsd.h")
 249         ;;
 250   m68*-apple-aux*)
 251         COREFILE=trad-core.o
 252         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 253         ;;
 254   m88*-*-sysv4*)        ;;
 255   m88*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 256   m88*-*-mach3*)
 257         COREFILE=trad-core.o
 258         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 259         ;;
 260   ns32k-pc532-mach)
 261         COREFILE=trad-core.o
 262         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 263         ;;
 264   ns32k-*-netbsd*)
 265         COREFILE=trad-core.o
 266         AC_DEFINE(TRAD_HEADER,"hosts/ns32knbsd.h")
 267         ;;
 268   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 269   rs6000-*-aix4*)       COREFILE=rs6000-core.o ;;
 270   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 271   powerpc-*-aix4*)      COREFILE=rs6000-core.o ;;
 272   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 273   sparc-*-netbsd*)
 274         COREFILE=trad-core.o
 275         AC_DEFINE(TRAD_HEADER,"hosts/sparcnbsd.h")
 276         ;;
 277   tahoe-*-*)
 278         COREFILE=trad-core.o
 279         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 280         ;;
 281   vax-*-ultrix2*)
 282         COREFILE=trad-core.o
 283         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 284         ;;
 285   vax-*-ultrix*)
 286         COREFILE=trad-core.o
 287         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 288         ;;
 289   vax-*-*)
 290         COREFILE=trad-core.o
 291         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 292         ;;
 293   esac
 294
 295   case "$COREFILE" in
 296   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 297   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 298   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 299   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 300   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 301   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 302   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 303   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 304   trad-core.o)          COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 305   esac
 306
 307   # The ELF code uses the native <sys/procfs.h> to handle core files.
 308   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 309   # prstatus_t.
 310   AC_MSG_CHECKING([for sys/procfs.h])
 311   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 312   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 313   [prstatus_t t;],
 314   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 315   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 316   if test $bfd_cv_header_sys_procfs_h = yes; then
 317     AC_DEFINE(HAVE_SYS_PROCFS_H)
 318   fi
 319
 320 fi
 321 AC_SUBST(COREFILE)
 322 AC_SUBST(COREFLAG)
 323
 324 # target stuff:
 325
 326 # Canonicalize the secondary target names.
 327 if test -n "$enable_targets" ; then
 328     for targ in `echo $enable_targets | sed 's/,/ /g'`
 329     do
 330         result=`$ac_config_sub $targ 2>/dev/null`
 331         if test -n "$result" ; then
 332             canon_targets="$canon_targets $result"
 333         else
 334             # Allow targets that config.sub doesn't recognize, like "all".
 335             canon_targets="$canon_targets $targ"
 336         fi
 337     done
 338 fi
 339
 340 all_targets=false
 341 defvec=
 342 selvecs=
 343 selarchs=
 344 TDEFINES=
 345 for targ in $target $canon_targets
 346 do
 347     if test "x$targ" = "xall"; then
 348         all_targets=true
 349     else
 350         . $srcdir/config.bfd
 351         if test "x$targ" = "x$target"; then
 352             defvec=$targ_defvec
 353         fi
 354         selvecs="$selvecs $targ_defvec $targ_selvecs"
 355         selarchs="$selarchs $targ_archs"
 356         TDEFINES="$TDEFINES $targ_cflags"
 357     fi
 358 done
 359 AC_SUBST(TDEFINES)
 360
 361 # This processing still needs to be done if we're to decide properly whether
 362 # 64-bit support needs to be compiled in.  Currently, it will be included if
 363 # the default or any other explicitly requested target requires it; it
 364 # will not be included on a 32-bit host if no 64-bit target is requested, and
 365 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 366 # used.
 367
 368 # uniq the default and selected vectors in all the configured targets.
 369 f=""
 370 for i in $selvecs ; do
 371     case " $f " in
 372     *" $i "*) ;;
 373     *) f="$f $i" ;;
 374     esac
 375 done
 376 selvecs="$f"
 377
 378 # uniq the architectures in all the configured targets.
 379 f=""
 380 for i in $selarchs ; do
 381     case " $f " in
 382     *" $i "*) ;;
 383     *) f="$f $i" ;;
 384     esac
 385 done
 386 selarchs="$f"
 387
 388 # Target backend .o files.
 389 tb=
 390
 391 elf="elf.o elflink.o"
 392
 393 for vec in $selvecs
 394 do
 395     case "$vec" in
 396     # This list is alphabetized to make it easy to compare
 397     # with the two vector lists in targets.c.
 398     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 399     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o stab-syms.o" ;;
 400     armcoff_little_vec)         tb="$tb coff-arm.o cofflink.o " ;;
 401     armcoff_big_vec)            tb="$tb coff-arm.o cofflink.o " ;;
 402     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 403     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 404     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 405     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 406     aout0_big_vec)              tb="$tb aout0.o aout32.o stab-syms.o" ;;
 407     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 408     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 409     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 410     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 411     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 412     b_out_vec_big_host)         tb="$tb bout.o aout32.o stab-syms.o" ;;
 413     b_out_vec_little_host)      tb="$tb bout.o aout32.o stab-syms.o" ;;
 414 # start-sanitize-arc
 415     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 416     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 417 # end-sanitize-arc
 418     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 419     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 420     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 421     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 422     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 423     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 424     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 425     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 426     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 427     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 428     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 429     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 430     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 431                                 target64=true ;;
 432     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 433                                 target64=true ;;
 434     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 435                                 target64=true ;;
 436     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 437     demo_64_vec)                tb="$tb demo64.o aout64.o stab-syms.o"
 438                                 target64=true ;;
 439     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 440     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 441     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 442                                 target64=true ;;
 443     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 444     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 445     host_aout_vec)              tb="$tb host-aout.o aout32.o stab-syms.o" ;;
 446     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o stab-syms.o" ;;
 447     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o stab-syms.o" ;;
 448     i386aout_vec)               tb="$tb i386aout.o aout32.o stab-syms.o" ;;
 449     i386bsd_vec)                tb="$tb i386bsd.o aout32.o stab-syms.o" ;;
 450     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 451     i386dynix_vec)              tb="$tb i386dynix.o aout32.o stab-syms.o" ;;
 452     i386freebsd_vec)            tb="$tb i386freebsd.o aout32.o stab-syms.o" ;;
 453     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 454     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 455     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 456     i386linux_vec)              tb="$tb i386linux.o aout32.o stab-syms.o" ;;
 457     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o stab-syms.o" ;;
 458     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o stab-syms.o" ;;
 459     i386mach3_vec)              tb="$tb i386mach3.o aout32.o stab-syms.o" ;;
 460     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o stab-syms.o" ;;
 461     i386os9k_vec)               tb="$tb i386os9k.o aout32.o stab-syms.o" ;;
 462     i860coff_vec)               tb="$tb coff-i860.o cofflink.o" ;;
 463     icoff_big_vec)              tb="$tb coff-i960.o cofflink.o" ;;
 464     icoff_little_vec)           tb="$tb coff-i960.o cofflink.o" ;;
 465     ieee_vec)                   tb="$tb ieee.o" ;;
 466     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 467     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 468     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o stab-syms.o" ;;
 469     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o stab-syms.o" ;;
 470     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o stab-syms.o" ;;
 471     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.o aout32.o stab-syms.o" ;;
 472     m68kaux_coff_vec)           tb="$tb coff-aux.o coff-m68k.o cofflink.o" ;;
 473     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 474     newsos3_vec)                tb="$tb newsos3.o aout32.o stab-syms.o" ;;
 475     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 476     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 477     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 478                                 target64=true ;;
 479     riscix_vec)                 tb="$tb aout32.o riscix.o stab-syms.o" ;;
 480     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 481     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o stab-syms.o" ;;
 482     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o stab-syms.o" ;;
 483     pmac_xcoff_vec)             tb="$tb coff-pmac.o xcofflink.o" ;;
 484     rs6000coff_vec)             tb="$tb coff-rs6000.o xcofflink.o" ;;
 485     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.o cofflink.o" ;;
 486     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.o cofflink.o" ;;
 487     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.o cofflink.o" ;;
 488     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.o cofflink.o" ;;
 489     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 490 # start-sanitize-rce
 491     rce_aout_vec)               tb="$tb aout-rce.o aout32.o stab-syms.o" ;;
 492 # end-sanitize-rce
 493     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 494     som_vec)                    tb="$tb som.o" ;;
 495     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o stab-syms.o" ;;
 496     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o stab-syms.o" ;;
 497     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o stab-syms.o" ;;
 498     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 499     srec_vec)                   tb="$tb srec.o" ;;
 500     sunos_big_vec)              tb="$tb sunos.o aout32.o stab-syms.o" ;;
 501     symbolsrec_vec)             tb="$tb srec.o" ;;
 502     tekhex_vec)                 tb="$tb tekhex.o" ;;
 503     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 504     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 505     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 506     versados_vec)               tb="$tb versados.o" ;;
 507
 508     "")                 ;;
 509     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 510     esac
 511 done
 512
 513 # Target architecture .o files.
 514 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g`
 515
 516 # Weed out duplicate .o files.
 517 f=""
 518 for i in $tb ; do
 519     case " $f " in
 520     *" $i "*) ;;
 521     *) f="$f $i" ;;
 522     esac
 523 done
 524 tb="$f"
 525
 526 f=""
 527 for i in $ta ; do
 528     case " $f " in
 529     *" $i "*) ;;
 530     *) f="$f $i" ;;
 531     esac
 532 done
 533 ta="$f"
 534
 535 bfd_backends="$tb"
 536 bfd_machines="$ta"
 537
 538 if test x${all_targets} = xtrue ; then
 539   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 540   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 541   selvecs=
 542   selarchs=
 543 else    # all_targets is true
 544   # Only set these if they will be nonempty, for the clever echo.
 545   test -n "$selvecs" &&
 546     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 547   test -n "$selarchs" &&
 548     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 549 fi      # all_targets is true
 550
 551 case ${host64}-${target64}-${want64} in
 552   *true*)
 553     wordsize=64
 554     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 555     ;;
 556   false-false-false)
 557     wordsize=32
 558     all_backends='$(BFD32_BACKENDS)'
 559     ;;
 560 esac
 561
 562 AC_SUBST(wordsize)
 563 AC_SUBST(all_backends)
 564 AC_SUBST(bfd_backends)
 565 AC_SUBST(bfd_machines)
 566
 567 tdefaults=""
 568 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 569 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 570 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 571 AC_SUBST(tdefaults)
 572
 573 dnl AC_CHECK_HEADERS(sys/mman.h)
 574 AC_FUNC_MMAP
 575 AC_CHECK_FUNCS(madvise mprotect)
 576 case ${want_mmap}+${ac_cv_func_mmap} in
 577   true+yes )  AC_DEFINE(USE_MMAP) ;;
 578 esac
 579
 580 rm -f doc/config.status
 581 AC_OUTPUT(Makefile doc/Makefile,
 582 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])