bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.5)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.9.4)
  11
  12 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  13 dnl to call AC_CHECK_PROG.
  14 AC_CHECK_TOOL(AR, ar)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16
  17 dnl Default to a non shared library.  This may be overridden by the
  18 dnl configure option --enable-shared.
  19 AM_DISABLE_SHARED
  20
  21 AM_PROG_LIBTOOL
  22
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45 AC_ARG_WITH(mmap,
  46 [  --with-mmap             try using mmap for BFD input files if available],
  47 [case "${withval}" in
  48   yes)  want_mmap=true ;;
  49   no)   want_mmap=false ;;
  50   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  51 esac],[want_mmap=false])dnl
  52
  53 AM_CONFIG_HEADER(config.h:config.in)
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58 AC_ARG_PROGRAM
  59
  60 AM_MAINTAINER_MODE
  61 AM_CYGWIN32
  62 AM_EXEEXT
  63
  64 host64=false
  65 target64=false
  66
  67 # host stuff:
  68
  69 AC_PROG_CC
  70
  71 ALL_LINGUAS=
  72 CY_GNU_GETTEXT
  73
  74 # Permit host specific settings.
  75 . ${srcdir}/configure.host
  76
  77 AC_SUBST(HDEFINES)
  78 AM_PROG_INSTALL
  79
  80 BFD_HOST_64BIT_LONG=0
  81 BFD_HOST_64_BIT_DEFINED=0
  82 BFD_HOST_64_BIT=
  83 BFD_HOST_U_64_BIT=
  84 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
  85   BFD_HOST_64BIT_LONG=1
  86 elif test "x${HOST_64BIT_TYPE}" != "x"; then
  87   BFD_HOST_64_BIT_DEFINED=1
  88   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
  89   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
  90 fi
  91 AC_SUBST(BFD_HOST_64BIT_LONG)
  92 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
  93 AC_SUBST(BFD_HOST_64_BIT)
  94 AC_SUBST(BFD_HOST_U_64_BIT)
  95
  96 BFD_CC_FOR_BUILD
  97
  98 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
  99 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 100 AC_HEADER_TIME
 101 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen)
 102
 103 BFD_BINARY_FOPEN
 104
 105 BFD_NEED_DECLARATION(strstr)
 106 BFD_NEED_DECLARATION(malloc)
 107 BFD_NEED_DECLARATION(realloc)
 108 BFD_NEED_DECLARATION(free)
 109 BFD_NEED_DECLARATION(getenv)
 110
 111 # If we are configured native, pick a core file support file.
 112 COREFILE=
 113 COREFLAG=
 114 if test "${target}" = "${host}"; then
 115   case "${host}" in
 116   alpha*-*-linux-gnu*)
 117         COREFILE=trad-core.lo
 118         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 119         ;;
 120   alpha*-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 121   alpha*-*-*)           COREFILE=osf-core.lo ;;
 122   arm-*-riscix)         COREFILE=trad-core.lo ;;
 123   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 124   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 125   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 126                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 127 changequote(,)dnl
 128   i[3456]86-sequent-bsd*)
 129 changequote([,])dnl
 130         COREFILE=trad-core.lo;
 131         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 132         ;;
 133 changequote(,)dnl
 134   i[3456]86-sequent-sysv4*) ;;
 135   i[3456]86-sequent-sysv*)
 136 changequote([,])dnl
 137         COREFILE=trad-core.lo
 138         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 139         ;;
 140 changequote(,)dnl
 141   i[3456]86-*-bsd* | i[3456]86-*-freebsd*)
 142 changequote([,])dnl
 143         COREFILE=trad-core.lo
 144         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 145         ;;
 146 changequote(,)dnl
 147   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 148 changequote([,])dnl
 149         COREFILE=netbsd-core.lo
 150         ;;
 151 changequote(,)dnl
 152   i[3456]86-esix-sysv3*)
 153 changequote([,])dnl
 154         COREFILE=trad-core.lo
 155         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 156         ;;
 157 changequote(,)dnl
 158   i[3456]86-*-sco* | i[3456]86-*-isc*)
 159 changequote([,])dnl
 160         COREFILE=trad-core.lo
 161         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 162         ;;
 163 changequote(,)dnl
 164   i[3456]86-*-mach3*)
 165 changequote([,])dnl
 166         COREFILE=trad-core.lo
 167         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 168         ;;
 169 changequote(,)dnl
 170   i[3456]86-*-linux-gnu*)
 171 changequote([,])dnl
 172         COREFILE=trad-core.lo
 173         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 174         ;;
 175 changequote(,)dnl
 176   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 177   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 178 changequote([,])dnl
 179   i860-*-mach3* | i860-*-osf1*)
 180         COREFILE=trad-core.lo
 181         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 182         ;;
 183   mips-dec-bsd*)
 184         COREFILE=trad-core.lo
 185         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 186         ;;
 187   mips-dec-mach3*)
 188         COREFILE=trad-core.lo
 189         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 190         ;;
 191   mips-*-netbsd* | mips*-*-openbsd*)
 192         COREFILE=netbsd-core.lo
 193         ;;
 194   mips-dec-*)
 195         COREFILE=trad-core.lo
 196         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 197         ;;
 198   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 199   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 200   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 201   mips-*-mach3*)
 202         COREFILE=trad-core.lo
 203         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 204         ;;
 205   mips-*-sysv4*)        ;;
 206   mips-*-sysv* | mips-*-riscos*)
 207         COREFILE=trad-core.lo
 208         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 209         ;;
 210   mips-sony-bsd*)
 211         COREFILE=trad-core.lo
 212         AC_DEFINE(TRAD_HEADER,"hosts/news-mips.h")
 213         ;;
 214   m68*-bull*-sysv*)
 215         COREFILE=trad-core.lo
 216         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 217         ;;
 218   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 219   m68*-hp-bsd*)
 220         COREFILE=trad-core.lo
 221         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 222         ;;
 223   m68*-*-linux-gnu*)
 224         COREFILE=trad-core.lo
 225         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 226         ;;
 227   m68*-motorola-sysv*)
 228         COREFILE=trad-core.lo
 229         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 230         ;;
 231   m68*-sony-*)
 232         COREFILE=trad-core.lo
 233         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 234         ;;
 235   m68*-*-netbsd* | m68*-*-openbsd*)
 236         COREFILE=netbsd-core.lo
 237         ;;
 238   m68*-apple-aux*)
 239         COREFILE=trad-core.lo
 240         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 241         ;;
 242   m88*-*-sysv4*)        ;;
 243   m88*-motorola-sysv*)  COREFILE=ptrace-core.lo ;;
 244   m88*-*-mach3*)
 245         COREFILE=trad-core.lo
 246         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 247         ;;
 248   ns32k-pc532-mach)
 249         COREFILE=trad-core.lo
 250         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 251         ;;
 252   ns32k-*-netbsd* | ns32k-*-openbsd*)
 253         COREFILE=netbsd-core.lo
 254         ;;
 255   rs6000-*-lynx*)       COREFILE=lynx-core.lo ;;
 256   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 257   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 258   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 259   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 260   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 261   powerpc-*-beos*)      ;;
 262   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 263   sparc-*-netbsd* | sparc-*-openbsd*)
 264         COREFILE=netbsd-core.lo
 265         ;;
 266   tahoe-*-*)
 267         COREFILE=trad-core.lo
 268         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 269         ;;
 270   vax-*-ultrix2*)
 271         COREFILE=trad-core.lo
 272         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 273         ;;
 274   vax-*-ultrix*)
 275         COREFILE=trad-core.lo
 276         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 277         ;;
 278   vax-*-*)
 279         COREFILE=trad-core.lo
 280         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 281         ;;
 282   esac
 283
 284   case "$COREFILE" in
 285   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 286   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 287   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 288   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 289   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 290   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 291   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 292   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 293   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 294   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 295   esac
 296
 297   # ELF corefile support has several flavors, but all of
 298   # them use something called <sys/procfs.h>
 299   AC_CHECK_HEADERS(sys/procfs.h)
 300   if test "$ac_cv_header_sys_procfs_h" = yes; then
 301     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 302     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 303     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 304     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 305     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 306     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 307     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 308     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 309   fi
 310 fi
 311 AC_SUBST(COREFILE)
 312 AC_SUBST(COREFLAG)
 313
 314 # Horrible hacks to build DLLs on Windows.
 315 WIN32LDFLAGS=
 316 WIN32LIBADD=
 317 case "${host}" in
 318 *-*-cygwin*)
 319   if test "$enable_shared" = "yes"; then
 320     WIN32LDFLAGS="-no-undefined"
 321     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 322   fi
 323   ;;
 324 esac
 325 AC_SUBST(WIN32LDFLAGS)
 326 AC_SUBST(WIN32LIBADD)
 327
 328 # target stuff:
 329
 330 # Canonicalize the secondary target names.
 331 if test -n "$enable_targets" ; then
 332     for targ in `echo $enable_targets | sed 's/,/ /g'`
 333     do
 334         result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 335         if test -n "$result" ; then
 336             canon_targets="$canon_targets $result"
 337         else
 338             # Allow targets that config.sub doesn't recognize, like "all".
 339             canon_targets="$canon_targets $targ"
 340         fi
 341     done
 342 fi
 343
 344 all_targets=false
 345 defvec=
 346 selvecs=
 347 selarchs=
 348 TDEFINES=
 349 for targ in $target $canon_targets
 350 do
 351     if test "x$targ" = "xall"; then
 352         all_targets=true
 353     else
 354         . $srcdir/config.bfd
 355         if test "x$targ" = "x$target"; then
 356             defvec=$targ_defvec
 357         fi
 358         selvecs="$selvecs $targ_defvec $targ_selvecs"
 359         selarchs="$selarchs $targ_archs"
 360         TDEFINES="$TDEFINES $targ_cflags"
 361     fi
 362 done
 363 AC_SUBST(TDEFINES)
 364
 365 # This processing still needs to be done if we're to decide properly whether
 366 # 64-bit support needs to be compiled in.  Currently, it will be included if
 367 # the default or any other explicitly requested target requires it; it
 368 # will not be included on a 32-bit host if no 64-bit target is requested, and
 369 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 370 # used.
 371
 372 # uniq the default and selected vectors in all the configured targets.
 373 f=""
 374 for i in $selvecs ; do
 375     case " $f " in
 376     *" $i "*) ;;
 377     *) f="$f $i" ;;
 378     esac
 379 done
 380 selvecs="$f"
 381
 382 # start-sanitize-sky
 383 # dvp is really mips, but we need to distinguish it from mips for opcodes
 384 selarchs=`echo $selarchs | sed -e s/dvp/mips/g`
 385 # end-sanitize-sky
 386
 387 # uniq the architectures in all the configured targets.
 388 f=""
 389 for i in $selarchs ; do
 390     case " $f " in
 391     *" $i "*) ;;
 392     *) f="$f $i" ;;
 393     esac
 394 done
 395 selarchs="$f"
 396
 397 # Target backend .o files.
 398 tb=
 399
 400 elf="elf.lo elflink.lo dwarf2.lo dwarf1.lo"
 401
 402 for vec in $selvecs
 403 do
 404     case "$vec" in
 405     # This list is alphabetized to make it easy to compare
 406     # with the two vector lists in targets.c.
 407     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 408     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 409     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 410     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 411     armpe_little_vec)           tb="$tb pe-arm.lo coff-arm.lo cofflink.lo " ;;
 412     armpe_big_vec)              tb="$tb pe-arm.lo coff-arm.lo cofflink.lo " ;;
 413     armpei_little_vec)          tb="$tb pei-arm.lo cofflink.lo " ;;
 414     armpei_big_vec)             tb="$tb pei-arm.lo cofflink.lo " ;;
 415     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 416     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 417     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 418     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 419     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 420     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 421     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 422     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 423     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"
 424                                 target64=true ;;
 425     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 426     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 427     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 428     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 429     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 430     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 431     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 432                                 target64=true ;;
 433     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 434     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 435     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 436     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 437     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 438     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 439     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 440     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 441     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 442                                 target64=true ;;
 443     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 444     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 445     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 446     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 447     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 448     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 449     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 450     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 451     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 452     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 453     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 454     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"
 455                                 target64=true ;;
 456     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"
 457                                 target64=true ;;
 458     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"
 459                                 target64=true ;;
 460     cisco_core_vec)             tb="$tb cisco-core.lo" ;;
 461     demo_64_vec)                tb="$tb demo64.lo aout64.lo"
 462                                 target64=true ;;
 463     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 464     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 465     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 466     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"
 467                                 target64=true ;;
 468     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 469     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 470     evax_alpha_vec)             tb="$tb evax-alpha.lo evax-emh.lo evax-egsd.lo evax-etir.lo evax-misc.lo"
 471                                 target64=true ;;
 472     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 473     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 474     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 475     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 476     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 477     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 478     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 479     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 480     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 481     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 482     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 483     i386pe_vec)                 tb="$tb pe-i386.lo cofflink.lo " ;;
 484     i386pei_vec)                tb="$tb pei-i386.lo cofflink.lo" ;;
 485     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 486     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 487     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 488     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 489     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 490     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 491     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 492     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 493     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 494     ieee_vec)                   tb="$tb ieee.lo" ;;
 495     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 496     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 497     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 498     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 499     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 500     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 501     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 502     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 503     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 504     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 505     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 506     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 507     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 508     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"
 509                                 target64=true ;;
 510     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 511     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 512     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 513     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 514     pmac_xcoff_vec)             tb="$tb coff-pmac.lo xcofflink.lo" ;;
 515     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 516     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo cofflink.lo" ;;
 517     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo cofflink.lo" ;;
 518     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo cofflink.lo" ;;
 519     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo cofflink.lo" ;;
 520     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 521     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 522     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 523     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 524     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 525     som_vec)                    tb="$tb som.lo" ;;
 526     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 527     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 528     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 529     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 530     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 531     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 532     srec_vec)                   tb="$tb srec.lo" ;;
 533     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 534     symbolsrec_vec)             tb="$tb srec.lo" ;;
 535     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 536     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 537     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 538 # start-sanitize-tic80
 539     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 540 # end-sanitize-tic80
 541     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 542     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 543     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 544     versados_vec)               tb="$tb versados.lo" ;;
 545
 546     "")                 ;;
 547     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 548     esac
 549 done
 550
 551 # Target architecture .o files.
 552 # A couple of CPUs use shorter file names to avoid problems on DOS
 553 # filesystems.
 554 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 555
 556 # Weed out duplicate .o files.
 557 f=""
 558 for i in $tb ; do
 559     case " $f " in
 560     *" $i "*) ;;
 561     *) f="$f $i" ;;
 562     esac
 563 done
 564 tb="$f"
 565
 566 f=""
 567 for i in $ta ; do
 568     case " $f " in
 569     *" $i "*) ;;
 570     *) f="$f $i" ;;
 571     esac
 572 done
 573 ta="$f"
 574
 575 bfd_backends="$tb"
 576 bfd_machines="$ta"
 577
 578 if test x${all_targets} = xtrue ; then
 579   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 580   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 581   selvecs=
 582   havevecs=
 583   selarchs=
 584 else    # all_targets is true
 585   # Only set these if they will be nonempty, for the clever echo.
 586   havevecs=
 587   test -n "$selvecs" &&
 588     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 589   test -n "$selvecs" &&
 590     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 591   test -n "$selarchs" &&
 592     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 593 fi      # all_targets is true
 594
 595 case ${host64}-${target64}-${want64} in
 596   *true*)
 597     wordsize=64
 598     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 599     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 600       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 601       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 602     fi
 603     ;;
 604   false-false-false)
 605     wordsize=32
 606     all_backends='$(BFD32_BACKENDS)'
 607     ;;
 608 esac
 609
 610 AC_SUBST(wordsize)
 611 AC_SUBST(all_backends)
 612 AC_SUBST(bfd_backends)
 613 AC_SUBST(bfd_machines)
 614
 615 tdefaults=""
 616 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 617 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 618 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 619 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 620 AC_SUBST(tdefaults)
 621
 622 dnl AC_CHECK_HEADERS(sys/mman.h)
 623 AC_FUNC_MMAP
 624 AC_CHECK_FUNCS(madvise mprotect)
 625 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 626   true+yes )  AC_DEFINE(USE_MMAP) ;;
 627 esac
 628
 629 rm -f doc/config.status
 630 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 631 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])