bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.3)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21
  22 AC_CONFIG_HEADER(config.h:config.in)
  23
  24 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  25 AC_CANONICAL_SYSTEM
  26 if test -z "$target" ; then
  27     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  28 fi
  29 AC_ARG_PROGRAM
  30
  31 host64=false
  32 target64=false
  33
  34 # host stuff:
  35
  36 # Permit host specific settings.
  37 . ${srcdir}/configure.host
  38
  39 AC_PROG_CC
  40 AC_SUBST(CFLAGS)
  41 AC_SUBST(HDEFINES)
  42 AR=${AR-ar}
  43 AC_SUBST(AR)
  44 AC_PROG_RANLIB
  45 AC_PROG_INSTALL
  46
  47 HOST_64BIT_LONG=0
  48 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
  49   HOST_64BIT_LONG=1
  50 fi
  51 AC_SUBST(HOST_64BIT_LONG)
  52
  53 BFD_CC_FOR_BUILD
  54
  55 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
  56 AC_CHECK_HEADERS(fcntl.h sys/file.h)
  57 AC_CHECK_FUNCS(fcntl getpagesize)
  58
  59 BFD_BINARY_FOPEN
  60
  61 AC_MSG_CHECKING([whether malloc must be declared])
  62 AC_CACHE_VAL(bfd_cv_decl_needed_malloc,
  63 [AC_TRY_COMPILE([
  64 #include <stdio.h>
  65 #ifdef HAVE_STDLIB_H
  66 #include <stdlib.h>
  67 #endif
  68 #ifdef HAVE_UNISTD_H
  69 #include <unistd.h>
  70 #endif],
  71 [char *(*pfn) = (char *(*)) malloc],
  72 bfd_cv_decl_needed_malloc=no, bfd_cv_decl_needed_malloc=yes)])
  73 AC_MSG_RESULT($bfd_cv_decl_needed_malloc)
  74 if test $bfd_cv_decl_needed_malloc = yes; then
  75   AC_DEFINE(NEED_DECLARATION_MALLOC)
  76 fi
  77
  78 AC_MSG_CHECKING([whether free must be declared])
  79 AC_CACHE_VAL(bfd_cv_decl_needed_free,
  80 [AC_TRY_COMPILE([
  81 #include <stdio.h>
  82 #ifdef HAVE_STDLIB_H
  83 #include <stdlib.h>
  84 #endif
  85 #ifdef HAVE_UNISTD_H
  86 #include <unistd.h>
  87 #endif],
  88 [int (*pfn) = (int (*)) free],
  89 bfd_cv_decl_needed_free=no, bfd_cv_decl_needed_free=yes)])
  90 AC_MSG_RESULT($bfd_cv_decl_needed_free)
  91 if test $bfd_cv_decl_needed_free = yes; then
  92   AC_DEFINE(NEED_DECLARATION_FREE)
  93 fi
  94
  95 # If we are configured native, pick a core file support file.
  96 COREFILE=
  97 COREFLAG=
  98 if test "${target}" = "${host}"; then
  99   case "${host}" in
 100   alpha*-*-linux*)
 101         COREFILE=trad-core.o
 102         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 103         ;;
 104   alpha*-*-*)           COREFILE=osf-core.o ;;
 105   arm-*-riscix)         COREFILE=trad-core.o ;;
 106   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
 107   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
 108   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
 109                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 110 changequote(,)dnl
 111   i[345]86-sequent-bsd*)
 112 changequote([,])dnl
 113         COREFILE=trad-core.o;
 114         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 115         ;;
 116 changequote(,)dnl
 117   i[345]86-sequent-sysv4*) ;;
 118   i[345]86-sequent-sysv*)
 119 changequote([,])dnl
 120         COREFILE=trad-core.o
 121         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 122         ;;
 123 changequote(,)dnl
 124   i[345]86-*-bsd* | i[345]86-*-freebsd*)
 125 changequote([,])dnl
 126         COREFILE=trad-core.o
 127         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 128         ;;
 129 changequote(,)dnl
 130   i[345]86-*-netbsd*)
 131 changequote([,])dnl
 132         COREFILE=trad-core.o
 133         AC_DEFINE(TRAD_HEADER,"hosts/i386nbsd.h")
 134         ;;
 135 changequote(,)dnl
 136   i[345]86-esix-sysv3*)
 137 changequote([,])dnl
 138         COREFILE=trad-core.o
 139         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 140         ;;
 141 changequote(,)dnl
 142   i[345]86-*-sco* | i[345]86-*-isc*)
 143 changequote([,])dnl
 144         COREFILE=trad-core.o
 145         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 146         ;;
 147 changequote(,)dnl
 148   i[345]86-*-mach3*)
 149 changequote([,])dnl
 150         COREFILE=trad-core.o
 151         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 152         ;;
 153 changequote(,)dnl
 154   i[345]86-*-linux*)
 155 changequote([,])dnl
 156         COREFILE=trad-core.o
 157         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 158         ;;
 159 changequote(,)dnl
 160   i[345]86-*-isc*)      COREFILE=trad-core.o ;;
 161   i[345]86-*-aix*)      COREFILE=aix386-core.o ;;
 162 changequote([,])dnl
 163   mips-dec-bsd*)
 164         COREFILE=trad-core.o
 165         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 166         ;;
 167   mips-dec-mach3*)
 168         COREFILE=trad-core.o
 169         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 170         ;;
 171   mips-*-netbsd*)
 172         COREFILE=trad-core.o
 173         AC_DEFINE(TRAD_HEADER,"hosts/mipsnbsd.h")
 174         ;;
 175   mips-dec-*)
 176         COREFILE=trad-core.o
 177         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 178         ;;
 179   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
 180   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
 181   mips-*-mach3*)
 182         COREFILE=trad-core.o
 183         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 184         ;;
 185   mips-*-sysv4*)        ;;
 186   mips-*-sysv* | mips-*-riscos*)
 187         COREFILE=trad-core.o
 188         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 189         ;;
 190   mips-sony-bsd*)
 191         COREFILE=trad-core.o
 192         AC_DEFINE(TRAD_HEADER,"hosts/news-mips".h)
 193         ;;
 194   m68*-bull*-sysv*)
 195         COREFILE=trad-core.o
 196         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 197         ;;
 198   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 199   m68*-hp-bsd*)
 200         COREFILE=trad-core.o
 201         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 202         ;;
 203   m68*-motorola-sysv*)
 204         COREFILE=trad-core.o
 205         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 206         ;;
 207   m68*-sony-*)
 208         COREFILE=trad-core.o
 209         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 210         ;;
 211   m68*-*-netbsd*)
 212         COREFILE=trad-core.o
 213         AC_DEFINE(TRAD_HEADER,"hosts/m68knbsd.h")
 214         ;;
 215   m88*-*-sysv4*)        ;;
 216   m88*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 217   m88*-*-mach3*)
 218         COREFILE=trad-core.o
 219         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 220         ;;
 221   ns32k-pc532-mach)
 222         COREFILE=trad-core.o
 223         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 224         ;;
 225   ns32k-*-netbsd*)
 226         COREFILE=trad-core.o
 227         AC_DEFINE(TRAD_HEADER,"hosts/ns32knbsd.h")
 228         ;;
 229   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 230   rs6000-*-aix4*)       COREFILE=rs6000-core.o ;;
 231   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 232   powerpc-*-aix4*)      COREFILE=rs6000-core.o ;;
 233   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 234   sparc-*-netbsd*)
 235         COREFILE=trad-core.o
 236         AC_DEFINE(TRAD_HEADER,"hosts/sparcnbsd.h")
 237         ;;
 238   tahoe-*-*)
 239         COREFILE=trad-core.o
 240         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 241         ;;
 242   vax-*-ultrix2*)
 243         COREFILE=trad-core.o
 244         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 245         ;;
 246   vax-*-ultrix*)
 247         COREFILE=trad-core.o
 248         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 249         ;;
 250   vax-*-*)
 251         COREFILE=trad-core.o
 252         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 253         ;;
 254   esac
 255
 256   case "$COREFILE" in
 257   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 258   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 259   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 260   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 261   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 262   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 263   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 264   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 265   trad-core.o)          COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 266   esac
 267
 268   # The ELF code uses the native <sys/procfs.h> to handle core files.
 269   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 270   # prstatus_t.
 271   AC_MSG_CHECKING([for sys/procfs.h])
 272   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 273   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 274   [prstatus_t t;],
 275   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 276   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 277   if test $bfd_cv_header_sys_procfs_h = yes; then
 278     AC_DEFINE(HAVE_SYS_PROCFS_H)
 279   fi
 280
 281 fi
 282 AC_SUBST(COREFILE)
 283 AC_SUBST(COREFLAG)
 284
 285 # target stuff:
 286
 287 # Canonicalize the secondary target names.
 288 if test -n "$enable_targets" ; then
 289     for targ in `echo $enable_targets | sed 's/,/ /g'`
 290     do
 291         result=`$ac_config_sub $targ 2>/dev/null`
 292         if test -n "$result" ; then
 293             canon_targets="$canon_targets $result"
 294         else
 295             # Allow targets that config.sub doesn't recognize, like "all".
 296             canon_targets="$canon_targets $targ"
 297         fi
 298     done
 299 fi
 300
 301 all_targets=false
 302 defvec=
 303 selvecs=
 304 selarchs=
 305 TDEFINES=
 306 for targ in $target $canon_targets
 307 do
 308     if test "x$targ" = "xall"; then
 309         all_targets=true
 310     else
 311         . $srcdir/config.bfd
 312         if test "x$targ" = "x$target"; then
 313             defvec=$targ_defvec
 314         fi
 315         selvecs="$selvecs $targ_defvec $targ_selvecs"
 316         selarchs="$selarchs $targ_archs"
 317         TDEFINES="$TDEFINES $targ_cflags"
 318     fi
 319 done
 320 AC_SUBST(TDEFINES)
 321
 322 # This processing still needs to be done if we're to decide properly whether
 323 # 64-bit support needs to be compiled in.  Currently, it will be included if
 324 # the default or any other explicitly requested target requires it; it
 325 # will not be included on a 32-bit host if no 64-bit target is requested, and
 326 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 327 # used.
 328
 329 # uniq the default and selected vectors in all the configured targets.
 330 f=""
 331 for i in $selvecs ; do
 332     case " $f " in
 333     *" $i "*) ;;
 334     *) f="$f $i" ;;
 335     esac
 336 done
 337 selvecs="$f"
 338
 339 # uniq the architectures in all the configured targets.
 340 f=""
 341 for i in $selarchs ; do
 342     case " $f " in
 343     *" $i "*) ;;
 344     *) f="$f $i" ;;
 345     esac
 346 done
 347 selarchs="$f"
 348
 349 # Target backend .o files.
 350 tb=
 351
 352 elf="elf.o elflink.o"
 353
 354 for vec in $selvecs
 355 do
 356     case "$vec" in
 357     # This list is alphabetized to make it easy to compare
 358     # with the two vector lists in targets.c.
 359     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 360     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o stab-syms.o" ;;
 361     armcoff_little_vec)         tb="$tb coff-arm.o cofflink.o " ;;
 362     armcoff_big_vec)            tb="$tb coff-arm.o cofflink.o " ;;
 363     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 364     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 365     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 366     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 367     aout0_big_vec)              tb="$tb aout0.o aout32.o stab-syms.o" ;;
 368     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 369     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 370     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 371     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 372     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 373     b_out_vec_big_host)         tb="$tb bout.o aout32.o stab-syms.o" ;;
 374     b_out_vec_little_host)      tb="$tb bout.o aout32.o stab-syms.o" ;;
 375 # start-sanitize-arc
 376     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 377     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 378 # end-sanitize-arc
 379     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 380     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 381     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 382     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 383     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 384     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 385     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 386     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 387     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 388     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 389     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 390     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 391     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 392                                 target64=true ;;
 393     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 394                                 target64=true ;;
 395     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 396                                 target64=true ;;
 397     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 398     demo_64_vec)                tb="$tb demo64.o aout64.o stab-syms.o"
 399                                 target64=true ;;
 400     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 401     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 402     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 403                                 target64=true ;;
 404     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 405     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 406     host_aout_vec)              tb="$tb host-aout.o aout32.o stab-syms.o" ;;
 407     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o stab-syms.o" ;;
 408     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o stab-syms.o" ;;
 409     i386aout_vec)               tb="$tb i386aout.o aout32.o stab-syms.o" ;;
 410     i386bsd_vec)                tb="$tb i386bsd.o aout32.o stab-syms.o" ;;
 411     i386dynix_vec)              tb="$tb i386dynix.o aout32.o stab-syms.o" ;;
 412     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 413     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 414     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 415     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 416     i386linux_vec)              tb="$tb i386linux.o aout32.o stab-syms.o" ;;
 417     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o stab-syms.o" ;;
 418     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o stab-syms.o" ;;
 419     i386mach3_vec)              tb="$tb i386mach3.o aout32.o stab-syms.o" ;;
 420     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o stab-syms.o" ;;
 421     i386os9k_vec)               tb="$tb i386os9k.o aout32.o stab-syms.o" ;;
 422     icoff_big_vec)              tb="$tb coff-i960.o cofflink.o" ;;
 423     icoff_little_vec)           tb="$tb coff-i960.o cofflink.o" ;;
 424     ieee_vec)                   tb="$tb ieee.o" ;;
 425     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 426     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 427     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o stab-syms.o" ;;
 428     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o stab-syms.o" ;;
 429     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o stab-syms.o" ;;
 430     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.o aout32.o stab-syms.o" ;;
 431     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 432     newsos3_vec)                tb="$tb newsos3.o aout32.o stab-syms.o" ;;
 433     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 434     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 435     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 436                                 target64=true ;;
 437     riscix_vec)                 tb="$tb aout32.o riscix.o stab-syms.o" ;;
 438     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 439     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o stab-syms.o" ;;
 440     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o stab-syms.o" ;;
 441     pmac_xcoff_vec)             tb="$tb coff-pmac.o xcofflink.o" ;;
 442     rs6000coff_vec)             tb="$tb coff-rs6000.o xcofflink.o" ;;
 443     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.o cofflink.o" ;;
 444     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.o cofflink.o" ;;
 445     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.o cofflink.o" ;;
 446     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.o cofflink.o" ;;
 447     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 448 # start-sanitize-rce
 449     rce_aout_vec)               tb="$tb aout-rce.o aout32.o stab-syms.o" ;;
 450 # end-sanitize-rce
 451     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 452     som_vec)                    tb="$tb som.o" ;;
 453     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o stab-syms.o" ;;
 454     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o stab-syms.o" ;;
 455     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o stab-syms.o" ;;
 456     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 457     srec_vec)                   tb="$tb srec.o" ;;
 458     sunos_big_vec)              tb="$tb sunos.o aout32.o stab-syms.o" ;;
 459     symbolsrec_vec)             tb="$tb srec.o" ;;
 460     tekhex_vec)                 tb="$tb tekhex.o" ;;
 461     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 462     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 463     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 464     versados_vec)               tb="$tb versados.o" ;;
 465
 466     "")                 ;;
 467     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 468     esac
 469 done
 470
 471 # Target architecture .o files.
 472 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g`
 473
 474 # Weed out duplicate .o files.
 475 f=""
 476 for i in $tb ; do
 477     case " $f " in
 478     *" $i "*) ;;
 479     *) f="$f $i" ;;
 480     esac
 481 done
 482 tb="$f"
 483
 484 f=""
 485 for i in $ta ; do
 486     case " $f " in
 487     *" $i "*) ;;
 488     *) f="$f $i" ;;
 489     esac
 490 done
 491 ta="$f"
 492
 493 bfd_backends="$tb"
 494 bfd_machines="$ta"
 495
 496 if test x${all_targets} = xtrue ; then
 497   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 498   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 499   selvecs=
 500   selarchs=
 501 else    # all_targets is true
 502   # Only set these if they will be nonempty, for the clever echo.
 503   test -n "$selvecs" &&
 504     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 505   test -n "$selarchs" &&
 506     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 507 fi      # all_targets is true
 508
 509 case ${host64}-${target64}-${want64} in
 510   *true*)
 511     wordsize=64
 512     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 513     ;;
 514   false-false-false)
 515     wordsize=32
 516     all_backends='$(BFD32_BACKENDS)'
 517     ;;
 518 esac
 519
 520 AC_SUBST(wordsize)
 521 AC_SUBST(all_backends)
 522 AC_SUBST(bfd_backends)
 523 AC_SUBST(bfd_machines)
 524
 525 tdefaults=""
 526 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 527 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 528 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 529 AC_SUBST(tdefaults)
 530
 531 dnl AC_CHECK_HEADERS(sys/mman.h)
 532 AC_FUNC_MMAP
 533 AC_CHECK_FUNCS(madvise mprotect)
 534
 535 rm -f doc/config.status
 536 AC_OUTPUT(Makefile doc/Makefile,
 537 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])