bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.3)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21 AC_ARG_ENABLE(shared,
  22 [  --enable-shared         build shared BFD library],
  23 [case "${enableval}" in
  24   yes) shared=true ;;
  25   no)  shared=false ;;
  26   *)   AC_MSG_ERROR([bad value ${enableval} for BFD shared option]) ;;
  27 esac])dnl
  28 AC_ARG_ENABLE(commonbfdlib,
  29 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  30 [case "${enableval}" in
  31   yes) commonbfdlib=true ;;
  32   no)  commonbfdlib=false ;;
  33   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  34 esac])dnl
  35 AC_ARG_WITH(mmap,
  36 [  --with-mmap             try using mmap for BFD input files if available],
  37 [case "${withval}" in
  38   yes)  want_mmap=true ;;
  39   no)   want_mmap=false ;;
  40   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  41 esac],[want_mmap=false])dnl
  42
  43 AC_CONFIG_HEADER(config.h:config.in)
  44
  45 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  46 AC_CANONICAL_SYSTEM
  47 if test -z "$target" ; then
  48     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  49 fi
  50 AC_ARG_PROGRAM
  51
  52 host64=false
  53 target64=false
  54
  55 # host stuff:
  56
  57 ALLLIBS='$(TARGETLIB)'
  58 PICFLAG=
  59 SHLIB=unused-shlib
  60 SHLINK=unused-shlink
  61 if test "${shared}" = "true"; then
  62   PICFLAG=-fpic
  63   if test "${commonbfdlib}" = "true"; then
  64     ALLLIBS='$(TARGETLIB)'
  65   else
  66     ALLLIBS='$(TARGETLIB) $(SHLIB) $(SHLINK)'
  67 changequote(,)dnl
  68     SHLIB=libbfd.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/VERSION`
  69 changequote([,])dnl
  70     SHLINK=libbfd.so
  71   fi
  72 fi
  73
  74 AC_PROG_CC
  75
  76 # Permit host specific settings.
  77 . ${srcdir}/configure.host
  78
  79 AC_SUBST(HDEFINES)
  80 AC_CHECK_TOOL(AR, ar)
  81 AC_CHECK_TOOL(RANLIB, ranlib, :)
  82 AC_PROG_INSTALL
  83
  84 if test "${shared}" = "true"; then
  85   if test "${GCC}" != "yes" && test "${shared_non_gcc}" != "yes"; then
  86     AC_MSG_WARN([BFD --enable-shared only supported when using gcc])
  87     shared=false
  88     ALLLIBS='$(TARGETLIB)'
  89     PICFLAG=
  90     SHLIB=unused-shlib
  91   fi
  92 fi
  93
  94 AC_SUBST(ALLLIBS)
  95 AC_SUBST(PICFLAG)
  96 AC_SUBST(SHLIB)
  97 AC_SUBST(SHLIB_CC)
  98 AC_SUBST(SHLIB_CFLAGS)
  99 if test "${commonbfdlib}" = "true"; then
 100   COMMON_SHLIB=yes
 101   PICLIST=piclist
 102 else
 103   COMMON_SHLIB=
 104   PICLIST=
 105 fi
 106 AC_SUBST(COMMON_SHLIB)
 107 AC_SUBST(PICLIST)
 108 AC_SUBST(SHLINK)
 109
 110 HOST_64BIT_LONG=0
 111 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 112   HOST_64BIT_LONG=1
 113 fi
 114 AC_SUBST(HOST_64BIT_LONG)
 115
 116 BFD_CC_FOR_BUILD
 117
 118 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 119 AC_CHECK_HEADERS(fcntl.h sys/file.h)
 120 AC_CHECK_FUNCS(fcntl getpagesize)
 121
 122 BFD_BINARY_FOPEN
 123
 124 BFD_NEED_DECLARATION(malloc)
 125 BFD_NEED_DECLARATION(free)
 126
 127 # If we are configured native, pick a core file support file.
 128 COREFILE=
 129 COREFLAG=
 130 if test "${target}" = "${host}"; then
 131   case "${host}" in
 132   alpha*-*-linux*)
 133         COREFILE=trad-core.o
 134         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 135         ;;
 136   alpha*-*-*)           COREFILE=osf-core.o ;;
 137   arm-*-riscix)         COREFILE=trad-core.o ;;
 138   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
 139   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
 140   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
 141                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 142 changequote(,)dnl
 143   i[345]86-sequent-bsd*)
 144 changequote([,])dnl
 145         COREFILE=trad-core.o;
 146         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 147         ;;
 148 changequote(,)dnl
 149   i[345]86-sequent-sysv4*) ;;
 150   i[345]86-sequent-sysv*)
 151 changequote([,])dnl
 152         COREFILE=trad-core.o
 153         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 154         ;;
 155 changequote(,)dnl
 156   i[345]86-*-bsd* | i[345]86-*-freebsd*)
 157 changequote([,])dnl
 158         COREFILE=trad-core.o
 159         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 160         ;;
 161 changequote(,)dnl
 162   i[345]86-*-netbsd*)
 163 changequote([,])dnl
 164         COREFILE=netbsd-core.o
 165         ;;
 166 changequote(,)dnl
 167   i[345]86-esix-sysv3*)
 168 changequote([,])dnl
 169         COREFILE=trad-core.o
 170         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 171         ;;
 172 changequote(,)dnl
 173   i[345]86-*-sco* | i[345]86-*-isc*)
 174 changequote([,])dnl
 175         COREFILE=trad-core.o
 176         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 177         ;;
 178 changequote(,)dnl
 179   i[345]86-*-mach3*)
 180 changequote([,])dnl
 181         COREFILE=trad-core.o
 182         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 183         ;;
 184 changequote(,)dnl
 185   i[345]86-*-linux*)
 186 changequote([,])dnl
 187         COREFILE=trad-core.o
 188         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 189         ;;
 190 changequote(,)dnl
 191   i[345]86-*-isc*)      COREFILE=trad-core.o ;;
 192   i[345]86-*-aix*)      COREFILE=aix386-core.o ;;
 193 changequote([,])dnl
 194   i860-*-mach3* | i860-*-osf1*)
 195         COREFILE=trad-core.o
 196         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 197         ;;
 198   mips-dec-bsd*)
 199         COREFILE=trad-core.o
 200         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 201         ;;
 202   mips-dec-mach3*)
 203         COREFILE=trad-core.o
 204         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 205         ;;
 206   mips-*-netbsd*)
 207         COREFILE=netbsd-core.o
 208         ;;
 209   mips-dec-*)
 210         COREFILE=trad-core.o
 211         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 212         ;;
 213   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
 214   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
 215   mips-*-mach3*)
 216         COREFILE=trad-core.o
 217         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 218         ;;
 219   mips-*-sysv4*)        ;;
 220   mips-*-sysv* | mips-*-riscos*)
 221         COREFILE=trad-core.o
 222         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 223         ;;
 224   mips-sony-bsd*)
 225         COREFILE=trad-core.o
 226         AC_DEFINE(TRAD_HEADER,"hosts/news-mips".h)
 227         ;;
 228   m68*-bull*-sysv*)
 229         COREFILE=trad-core.o
 230         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 231         ;;
 232   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 233   m68*-hp-bsd*)
 234         COREFILE=trad-core.o
 235         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 236         ;;
 237   m68*-*-linux*)
 238         COREFILE=trad-core.o
 239         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 240         ;;
 241   m68*-motorola-sysv*)
 242         COREFILE=trad-core.o
 243         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 244         ;;
 245   m68*-sony-*)
 246         COREFILE=trad-core.o
 247         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 248         ;;
 249   m68*-*-netbsd*)
 250         COREFILE=netbsd-core.o
 251         ;;
 252   m68*-apple-aux*)
 253         COREFILE=trad-core.o
 254         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 255         ;;
 256   m88*-*-sysv4*)        ;;
 257   m88*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 258   m88*-*-mach3*)
 259         COREFILE=trad-core.o
 260         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 261         ;;
 262   ns32k-pc532-mach)
 263         COREFILE=trad-core.o
 264         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 265         ;;
 266   ns32k-*-netbsd*)
 267         COREFILE=netbsd-core.o
 268         ;;
 269   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 270   rs6000-*-aix4*)       COREFILE=rs6000-core.o ;;
 271   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 272   powerpc-*-aix4*)      COREFILE=rs6000-core.o ;;
 273   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 274   sparc-*-netbsd*)
 275         COREFILE=netbsd-core.o
 276         ;;
 277   tahoe-*-*)
 278         COREFILE=trad-core.o
 279         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 280         ;;
 281   vax-*-ultrix2*)
 282         COREFILE=trad-core.o
 283         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 284         ;;
 285   vax-*-ultrix*)
 286         COREFILE=trad-core.o
 287         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 288         ;;
 289   vax-*-*)
 290         COREFILE=trad-core.o
 291         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 292         ;;
 293   esac
 294
 295   case "$COREFILE" in
 296   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 297   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 298   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 299   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 300   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 301   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 302   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 303   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 304   trad-core.o)          COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 305   esac
 306
 307   # The ELF code uses the native <sys/procfs.h> to handle core files.
 308   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 309   # prstatus_t.
 310   AC_MSG_CHECKING([for sys/procfs.h])
 311   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 312   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 313   [prstatus_t t;],
 314   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 315   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 316   if test $bfd_cv_header_sys_procfs_h = yes; then
 317     AC_DEFINE(HAVE_SYS_PROCFS_H)
 318   fi
 319
 320 fi
 321 AC_SUBST(COREFILE)
 322 AC_SUBST(COREFLAG)
 323
 324 # target stuff:
 325
 326 # Canonicalize the secondary target names.
 327 if test -n "$enable_targets" ; then
 328     for targ in `echo $enable_targets | sed 's/,/ /g'`
 329     do
 330         result=`$ac_config_sub $targ 2>/dev/null`
 331         if test -n "$result" ; then
 332             canon_targets="$canon_targets $result"
 333         else
 334             # Allow targets that config.sub doesn't recognize, like "all".
 335             canon_targets="$canon_targets $targ"
 336         fi
 337     done
 338 fi
 339
 340 all_targets=false
 341 defvec=
 342 selvecs=
 343 selarchs=
 344 TDEFINES=
 345 for targ in $target $canon_targets
 346 do
 347     if test "x$targ" = "xall"; then
 348         all_targets=true
 349     else
 350         . $srcdir/config.bfd
 351         if test "x$targ" = "x$target"; then
 352             defvec=$targ_defvec
 353         fi
 354         selvecs="$selvecs $targ_defvec $targ_selvecs"
 355         selarchs="$selarchs $targ_archs"
 356         TDEFINES="$TDEFINES $targ_cflags"
 357     fi
 358 done
 359 AC_SUBST(TDEFINES)
 360
 361 # This processing still needs to be done if we're to decide properly whether
 362 # 64-bit support needs to be compiled in.  Currently, it will be included if
 363 # the default or any other explicitly requested target requires it; it
 364 # will not be included on a 32-bit host if no 64-bit target is requested, and
 365 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 366 # used.
 367
 368 # uniq the default and selected vectors in all the configured targets.
 369 f=""
 370 for i in $selvecs ; do
 371     case " $f " in
 372     *" $i "*) ;;
 373     *) f="$f $i" ;;
 374     esac
 375 done
 376 selvecs="$f"
 377
 378 # uniq the architectures in all the configured targets.
 379 f=""
 380 for i in $selarchs ; do
 381     case " $f " in
 382     *" $i "*) ;;
 383     *) f="$f $i" ;;
 384     esac
 385 done
 386 selarchs="$f"
 387
 388 # Target backend .o files.
 389 tb=
 390
 391 elf="elf.o elflink.o"
 392
 393 for vec in $selvecs
 394 do
 395     case "$vec" in
 396     # This list is alphabetized to make it easy to compare
 397     # with the two vector lists in targets.c.
 398     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 399     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o" ;;
 400     armcoff_little_vec)         tb="$tb coff-arm.o cofflink.o " ;;
 401     armcoff_big_vec)            tb="$tb coff-arm.o cofflink.o " ;;
 402     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 403     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 404     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 405     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 406     aout0_big_vec)              tb="$tb aout0.o aout32.o" ;;
 407     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o" ;;
 408     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o" ;;
 409     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o" ;;
 410     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o" ;;
 411     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 412     b_out_vec_big_host)         tb="$tb bout.o aout32.o" ;;
 413     b_out_vec_little_host)      tb="$tb bout.o aout32.o" ;;
 414 # start-sanitize-arc
 415     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 416     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 417 # end-sanitize-arc
 418     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 419     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 420     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 421     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 422     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 423     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 424     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 425     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 426     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 427     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 428     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 429     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 430     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 431                                 target64=true ;;
 432     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 433                                 target64=true ;;
 434     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 435                                 target64=true ;;
 436     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 437     demo_64_vec)                tb="$tb demo64.o aout64.o"
 438                                 target64=true ;;
 439     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 440     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 441     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 442                                 target64=true ;;
 443     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 444     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 445     host_aout_vec)              tb="$tb host-aout.o aout32.o" ;;
 446     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o" ;;
 447     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o" ;;
 448     i386aout_vec)               tb="$tb i386aout.o aout32.o" ;;
 449     i386bsd_vec)                tb="$tb i386bsd.o aout32.o" ;;
 450     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 451     i386dynix_vec)              tb="$tb i386dynix.o aout32.o" ;;
 452     i386freebsd_vec)            tb="$tb i386freebsd.o aout32.o" ;;
 453     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 454     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 455     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 456     i386linux_vec)              tb="$tb i386linux.o aout32.o" ;;
 457     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o" ;;
 458     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o" ;;
 459     i386mach3_vec)              tb="$tb i386mach3.o aout32.o" ;;
 460     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o" ;;
 461     i386os9k_vec)               tb="$tb i386os9k.o aout32.o" ;;
 462     i860coff_vec)               tb="$tb coff-i860.o cofflink.o" ;;
 463     icoff_big_vec)              tb="$tb coff-i960.o cofflink.o" ;;
 464     icoff_little_vec)           tb="$tb coff-i960.o cofflink.o" ;;
 465     ieee_vec)                   tb="$tb ieee.o" ;;
 466     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 467     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 468     m68klinux_vec)              tb="$tb m68klinux.o aout32.o" ;;
 469     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o" ;;
 470     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o" ;;
 471     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o" ;;
 472     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.o aout32.o" ;;
 473     m68kaux_coff_vec)           tb="$tb coff-aux.o coff-m68k.o cofflink.o" ;;
 474     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 475     newsos3_vec)                tb="$tb newsos3.o aout32.o" ;;
 476     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 477     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 478     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 479                                 target64=true ;;
 480     riscix_vec)                 tb="$tb aout32.o riscix.o" ;;
 481     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 482     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o" ;;
 483     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o" ;;
 484     pmac_xcoff_vec)             tb="$tb coff-pmac.o xcofflink.o" ;;
 485     rs6000coff_vec)             tb="$tb coff-rs6000.o xcofflink.o" ;;
 486     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.o cofflink.o" ;;
 487     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.o cofflink.o" ;;
 488     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.o cofflink.o" ;;
 489     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.o cofflink.o" ;;
 490     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 491 # start-sanitize-rce
 492     rce_aout_vec)               tb="$tb aout-rce.o aout32.o" ;;
 493 # end-sanitize-rce
 494     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 495     som_vec)                    tb="$tb som.o" ;;
 496     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o" ;;
 497     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o" ;;
 498     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o" ;;
 499     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 500     srec_vec)                   tb="$tb srec.o" ;;
 501     sunos_big_vec)              tb="$tb sunos.o aout32.o" ;;
 502     symbolsrec_vec)             tb="$tb srec.o" ;;
 503     tekhex_vec)                 tb="$tb tekhex.o" ;;
 504     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 505     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 506     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 507     versados_vec)               tb="$tb versados.o" ;;
 508
 509     "")                 ;;
 510     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 511     esac
 512 done
 513
 514 # Target architecture .o files.
 515 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g`
 516
 517 # Weed out duplicate .o files.
 518 f=""
 519 for i in $tb ; do
 520     case " $f " in
 521     *" $i "*) ;;
 522     *) f="$f $i" ;;
 523     esac
 524 done
 525 tb="$f"
 526
 527 f=""
 528 for i in $ta ; do
 529     case " $f " in
 530     *" $i "*) ;;
 531     *) f="$f $i" ;;
 532     esac
 533 done
 534 ta="$f"
 535
 536 bfd_backends="$tb"
 537 bfd_machines="$ta"
 538
 539 if test x${all_targets} = xtrue ; then
 540   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 541   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 542   selvecs=
 543   selarchs=
 544 else    # all_targets is true
 545   # Only set these if they will be nonempty, for the clever echo.
 546   test -n "$selvecs" &&
 547     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 548   test -n "$selarchs" &&
 549     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 550 fi      # all_targets is true
 551
 552 case ${host64}-${target64}-${want64} in
 553   *true*)
 554     wordsize=64
 555     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 556     ;;
 557   false-false-false)
 558     wordsize=32
 559     all_backends='$(BFD32_BACKENDS)'
 560     ;;
 561 esac
 562
 563 AC_SUBST(wordsize)
 564 AC_SUBST(all_backends)
 565 AC_SUBST(bfd_backends)
 566 AC_SUBST(bfd_machines)
 567
 568 tdefaults=""
 569 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 570 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 571 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 572 AC_SUBST(tdefaults)
 573
 574 dnl AC_CHECK_HEADERS(sys/mman.h)
 575 AC_FUNC_MMAP
 576 AC_CHECK_FUNCS(madvise mprotect)
 577 case ${want_mmap}+${ac_cv_func_mmap} in
 578   true+yes )  AC_DEFINE(USE_MMAP) ;;
 579 esac
 580
 581 rm -f doc/config.status
 582 AC_OUTPUT(Makefile doc/Makefile,
 583 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])