bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.5)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.8.4)
  11
  12 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  13 dnl to call AC_CHECK_PROG.
  14 AC_CHECK_TOOL(AR, ar)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16
  17 dnl Default to a non shared library.  This may be overridden by the
  18 dnl configure option --enable-shared.
  19 libtool_enable_shared=no
  20
  21 AM_PROG_LIBTOOL
  22
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45 AC_ARG_WITH(mmap,
  46 [  --with-mmap             try using mmap for BFD input files if available],
  47 [case "${withval}" in
  48   yes)  want_mmap=true ;;
  49   no)   want_mmap=false ;;
  50   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  51 esac],[want_mmap=false])dnl
  52
  53 AM_CONFIG_HEADER(config.h:config.in)
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58 AC_ARG_PROGRAM
  59
  60 AM_MAINTAINER_MODE
  61 AM_CYGWIN32
  62 AM_EXEEXT
  63
  64 host64=false
  65 target64=false
  66
  67 # host stuff:
  68
  69 AC_PROG_CC
  70
  71 # Permit host specific settings.
  72 . ${srcdir}/configure.host
  73
  74 AC_SUBST(HDEFINES)
  75 AM_PROG_INSTALL
  76
  77 BFD_HOST_64BIT_LONG=0
  78 BFD_HOST_64_BIT_DEFINED=0
  79 BFD_HOST_64_BIT=
  80 BFD_HOST_U_64_BIT=
  81 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
  82   BFD_HOST_64BIT_LONG=1
  83 elif test "x${HOST_64BIT_TYPE}" != "x"; then
  84   BFD_HOST_64_BIT_DEFINED=1
  85   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
  86   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
  87 fi
  88 AC_SUBST(BFD_HOST_64BIT_LONG)
  89 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
  90 AC_SUBST(BFD_HOST_64_BIT)
  91 AC_SUBST(BFD_HOST_U_64_BIT)
  92
  93 BFD_CC_FOR_BUILD
  94
  95 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
  96 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
  97 AC_HEADER_TIME
  98 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen)
  99
 100 BFD_BINARY_FOPEN
 101
 102 BFD_NEED_DECLARATION(strstr)
 103 BFD_NEED_DECLARATION(malloc)
 104 BFD_NEED_DECLARATION(realloc)
 105 BFD_NEED_DECLARATION(free)
 106 BFD_NEED_DECLARATION(getenv)
 107
 108 # If we are configured native, pick a core file support file.
 109 COREFILE=
 110 COREFLAG=
 111 if test "${target}" = "${host}"; then
 112   case "${host}" in
 113   alpha*-*-linux*)
 114         COREFILE=trad-core.lo
 115         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 116         ;;
 117   alpha*-*-*)           COREFILE=osf-core.lo ;;
 118   arm-*-riscix)         COREFILE=trad-core.lo ;;
 119   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 120   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 121   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 122                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 123 changequote(,)dnl
 124   i[3456]86-sequent-bsd*)
 125 changequote([,])dnl
 126         COREFILE=trad-core.lo;
 127         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 128         ;;
 129 changequote(,)dnl
 130   i[3456]86-sequent-sysv4*) ;;
 131   i[3456]86-sequent-sysv*)
 132 changequote([,])dnl
 133         COREFILE=trad-core.lo
 134         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 135         ;;
 136 changequote(,)dnl
 137   i[3456]86-*-bsd* | i[3456]86-*-freebsd*)
 138 changequote([,])dnl
 139         COREFILE=trad-core.lo
 140         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 141         ;;
 142 changequote(,)dnl
 143   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 144 changequote([,])dnl
 145         COREFILE=netbsd-core.lo
 146         ;;
 147 changequote(,)dnl
 148   i[3456]86-esix-sysv3*)
 149 changequote([,])dnl
 150         COREFILE=trad-core.lo
 151         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 152         ;;
 153 changequote(,)dnl
 154   i[3456]86-*-sco* | i[3456]86-*-isc*)
 155 changequote([,])dnl
 156         COREFILE=trad-core.lo
 157         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 158         ;;
 159 changequote(,)dnl
 160   i[3456]86-*-mach3*)
 161 changequote([,])dnl
 162         COREFILE=trad-core.lo
 163         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 164         ;;
 165 changequote(,)dnl
 166   i[3456]86-*-linux*)
 167 changequote([,])dnl
 168         COREFILE=trad-core.lo
 169         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 170         ;;
 171 changequote(,)dnl
 172   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 173   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 174 changequote([,])dnl
 175   i860-*-mach3* | i860-*-osf1*)
 176         COREFILE=trad-core.lo
 177         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 178         ;;
 179   mips-dec-bsd*)
 180         COREFILE=trad-core.lo
 181         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 182         ;;
 183   mips-dec-mach3*)
 184         COREFILE=trad-core.lo
 185         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 186         ;;
 187   mips-*-netbsd* | mips*-*-openbsd*)
 188         COREFILE=netbsd-core.lo
 189         ;;
 190   mips-dec-*)
 191         COREFILE=trad-core.lo
 192         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 193         ;;
 194   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 195   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 196   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 197   mips-*-mach3*)
 198         COREFILE=trad-core.lo
 199         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 200         ;;
 201   mips-*-sysv4*)        ;;
 202   mips-*-sysv* | mips-*-riscos*)
 203         COREFILE=trad-core.lo
 204         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 205         ;;
 206   mips-sony-bsd*)
 207         COREFILE=trad-core.lo
 208         AC_DEFINE(TRAD_HEADER,"hosts/news-mips.h")
 209         ;;
 210   m68*-bull*-sysv*)
 211         COREFILE=trad-core.lo
 212         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 213         ;;
 214   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 215   m68*-hp-bsd*)
 216         COREFILE=trad-core.lo
 217         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 218         ;;
 219   m68*-*-linux*)
 220         COREFILE=trad-core.lo
 221         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 222         ;;
 223   m68*-motorola-sysv*)
 224         COREFILE=trad-core.lo
 225         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 226         ;;
 227   m68*-sony-*)
 228         COREFILE=trad-core.lo
 229         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 230         ;;
 231   m68*-*-netbsd* | m68*-*-openbsd*)
 232         COREFILE=netbsd-core.lo
 233         ;;
 234   m68*-apple-aux*)
 235         COREFILE=trad-core.lo
 236         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 237         ;;
 238   m88*-*-sysv4*)        ;;
 239   m88*-motorola-sysv*)  COREFILE=ptrace-core.lo ;;
 240   m88*-*-mach3*)
 241         COREFILE=trad-core.lo
 242         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 243         ;;
 244   ns32k-pc532-mach)
 245         COREFILE=trad-core.lo
 246         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 247         ;;
 248   ns32k-*-netbsd* | ns32k-*-openbsd*)
 249         COREFILE=netbsd-core.lo
 250         ;;
 251   rs6000-*-lynx*)       COREFILE=lynx-core.lo ;;
 252   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 253   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 254   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 255   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 256   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 257   powerpc-*-beos*)      ;;
 258   sparc-*-netbsd* | sparc-*-openbsd*)
 259         COREFILE=netbsd-core.lo
 260         ;;
 261   sparc*-*-linux*)
 262         COREFILE=trad-core.lo
 263         AC_DEFINE(TRAD_HEADER,"hosts/sparclinux.h")
 264         ;;
 265   tahoe-*-*)
 266         COREFILE=trad-core.lo
 267         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 268         ;;
 269   vax-*-ultrix2*)
 270         COREFILE=trad-core.lo
 271         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 272         ;;
 273   vax-*-ultrix*)
 274         COREFILE=trad-core.lo
 275         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 276         ;;
 277   vax-*-*)
 278         COREFILE=trad-core.lo
 279         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 280         ;;
 281   esac
 282
 283   case "$COREFILE" in
 284   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 285   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 286   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 287   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 288   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 289   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 290   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 291   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 292   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 293   esac
 294
 295   # The ELF code uses the native <sys/procfs.h> to handle core files.
 296   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 297   # prstatus_t.
 298   AC_MSG_CHECKING([for sys/procfs.h])
 299   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 300   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 301   [prstatus_t t;],
 302   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 303   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 304   if test $bfd_cv_header_sys_procfs_h = yes; then
 305     AC_DEFINE(HAVE_SYS_PROCFS_H)
 306   fi
 307
 308 fi
 309 AC_SUBST(COREFILE)
 310 AC_SUBST(COREFLAG)
 311
 312 # target stuff:
 313
 314 # Canonicalize the secondary target names.
 315 if test -n "$enable_targets" ; then
 316     for targ in `echo $enable_targets | sed 's/,/ /g'`
 317     do
 318         result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 319         if test -n "$result" ; then
 320             canon_targets="$canon_targets $result"
 321         else
 322             # Allow targets that config.sub doesn't recognize, like "all".
 323             canon_targets="$canon_targets $targ"
 324         fi
 325     done
 326 fi
 327
 328 all_targets=false
 329 defvec=
 330 selvecs=
 331 selarchs=
 332 TDEFINES=
 333 for targ in $target $canon_targets
 334 do
 335     if test "x$targ" = "xall"; then
 336         all_targets=true
 337     else
 338         . $srcdir/config.bfd
 339         if test "x$targ" = "x$target"; then
 340             defvec=$targ_defvec
 341         fi
 342         selvecs="$selvecs $targ_defvec $targ_selvecs"
 343         selarchs="$selarchs $targ_archs"
 344         TDEFINES="$TDEFINES $targ_cflags"
 345     fi
 346 done
 347 AC_SUBST(TDEFINES)
 348
 349 # This processing still needs to be done if we're to decide properly whether
 350 # 64-bit support needs to be compiled in.  Currently, it will be included if
 351 # the default or any other explicitly requested target requires it; it
 352 # will not be included on a 32-bit host if no 64-bit target is requested, and
 353 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 354 # used.
 355
 356 # uniq the default and selected vectors in all the configured targets.
 357 f=""
 358 for i in $selvecs ; do
 359     case " $f " in
 360     *" $i "*) ;;
 361     *) f="$f $i" ;;
 362     esac
 363 done
 364 selvecs="$f"
 365
 366 # start-sanitize-sky
 367 # dvp is really mips, but we need to distinguish it from mips for opcodes
 368 selarchs=`echo $selarchs | sed -e s/dvp/mips/g`
 369 # end-sanitize-sky
 370
 371 # uniq the architectures in all the configured targets.
 372 f=""
 373 for i in $selarchs ; do
 374     case " $f " in
 375     *" $i "*) ;;
 376     *) f="$f $i" ;;
 377     esac
 378 done
 379 selarchs="$f"
 380
 381 # Target backend .o files.
 382 tb=
 383
 384 elf="elflink.lo dwarf2.lo"
 385
 386 for vec in $selvecs
 387 do
 388     case "$vec" in
 389     # This list is alphabetized to make it easy to compare
 390     # with the two vector lists in targets.c.
 391     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 392     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 393     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 394     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 395     armpe_little_vec)           tb="$tb pe-arm.lo cofflink.lo " ;;
 396     armpe_big_vec)              tb="$tb pe-arm.lo cofflink.lo " ;;
 397     armpei_little_vec)          tb="$tb pei-arm.lo cofflink.lo " ;;
 398     armpei_big_vec)             tb="$tb pei-arm.lo cofflink.lo " ;;
 399     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 400     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 401     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 402     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 403     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 404     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 405     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 406     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 407     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"
 408                                 target64=true ;;
 409     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 410     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 411     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 412     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 413     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 414                                 target64=true ;;
 415     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 416 # start-sanitize-d30v
 417     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 418 # end-sanitize-d30v
 419     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 420     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 421     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 422     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 423     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 424     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 425                                 target64=true ;;
 426     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 427     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 428     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 429     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 430     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 431     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 432     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 433     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 434     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 435     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 436     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 437     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"
 438                                 target64=true ;;
 439     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"
 440                                 target64=true ;;
 441     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"
 442                                 target64=true ;;
 443     cisco_core_vec)             tb="$tb cisco-core.lo" ;;
 444     demo_64_vec)                tb="$tb demo64.lo aout64.lo"
 445                                 target64=true ;;
 446     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 447     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 448     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 449     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"
 450                                 target64=true ;;
 451     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 452     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 453     evax_alpha_vec)             tb="$tb evax-alpha.lo evax-emh.lo evax-egsd.lo evax-etir.lo evax-misc.lo"
 454                                 target64=true ;;
 455     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 456     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 457     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 458     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 459     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 460     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 461     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 462     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 463     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 464     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 465     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 466     i386pe_vec)                 tb="$tb pe-i386.lo cofflink.lo " ;;
 467     i386pei_vec)                tb="$tb pei-i386.lo cofflink.lo" ;;
 468     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 469     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 470     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 471     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 472     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 473     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 474     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 475     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 476     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 477     ieee_vec)                   tb="$tb ieee.lo" ;;
 478     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 479     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 480     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 481     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 482     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 483     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 484     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 485     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 486     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 487     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 488     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 489     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 490     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 491     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"
 492                                 target64=true ;;
 493     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 494     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 495     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 496     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 497     pmac_xcoff_vec)             tb="$tb coff-pmac.lo xcofflink.lo" ;;
 498     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 499     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo cofflink.lo" ;;
 500     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo cofflink.lo" ;;
 501     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo cofflink.lo" ;;
 502     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo cofflink.lo" ;;
 503     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 504     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 505     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 506     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 507     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 508     som_vec)                    tb="$tb som.lo" ;;
 509     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 510     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo stab-syms.lo" ;;
 511     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 512     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 513     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 514     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 515     srec_vec)                   tb="$tb srec.lo" ;;
 516     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 517     symbolsrec_vec)             tb="$tb srec.lo" ;;
 518     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 519     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 520     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 521 # start-sanitize-tic80
 522     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 523 # end-sanitize-tic80
 524     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 525     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 526     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 527     versados_vec)               tb="$tb versados.lo" ;;
 528
 529     "")                 ;;
 530     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 531     esac
 532 done
 533
 534 # Target architecture .o files.
 535 # A couple of CPUs use shorter file names to avoid problems on DOS
 536 # filesystems.
 537 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 538
 539 # Weed out duplicate .o files.
 540 f=""
 541 for i in $tb ; do
 542     case " $f " in
 543     *" $i "*) ;;
 544     *) f="$f $i" ;;
 545     esac
 546 done
 547 tb="$f"
 548
 549 f=""
 550 for i in $ta ; do
 551     case " $f " in
 552     *" $i "*) ;;
 553     *) f="$f $i" ;;
 554     esac
 555 done
 556 ta="$f"
 557
 558 bfd_backends="$tb"
 559 bfd_machines="$ta"
 560
 561 if test x${all_targets} = xtrue ; then
 562   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 563   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 564   selvecs=
 565   havevecs=
 566   selarchs=
 567 else    # all_targets is true
 568   # Only set these if they will be nonempty, for the clever echo.
 569   havevecs=
 570   test -n "$selvecs" &&
 571     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 572   test -n "$selvecs" &&
 573     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 574   test -n "$selarchs" &&
 575     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 576 fi      # all_targets is true
 577
 578 case ${host64}-${target64}-${want64} in
 579   *true*)
 580     wordsize=64
 581     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 582     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 583       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 584       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 585     fi
 586     ;;
 587   false-false-false)
 588     wordsize=32
 589     all_backends='$(BFD32_BACKENDS)'
 590     ;;
 591 esac
 592
 593 AC_SUBST(wordsize)
 594 AC_SUBST(all_backends)
 595 AC_SUBST(bfd_backends)
 596 AC_SUBST(bfd_machines)
 597
 598 tdefaults=""
 599 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 600 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 601 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 602 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 603 AC_SUBST(tdefaults)
 604
 605 dnl AC_CHECK_HEADERS(sys/mman.h)
 606 AC_FUNC_MMAP
 607 AC_CHECK_FUNCS(madvise mprotect)
 608 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 609   true+yes )  AC_DEFINE(USE_MMAP) ;;
 610 esac
 611
 612 rm -f doc/config.status
 613 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h)