bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.3)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21
  22 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  23 AC_CANONICAL_SYSTEM
  24 if test -z "$target" ; then
  25     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  26 fi
  27 AC_ARG_PROGRAM
  28
  29 host64=false
  30 target64=false
  31
  32 # host stuff:
  33
  34 HDEFINES=
  35
  36 # Permit host specific settings.
  37 . ${srcdir}/configure.host
  38
  39 AC_PROG_CC
  40 AC_SUBST(CFLAGS)
  41 AC_SUBST(HDEFINES)
  42 AR=${AR-ar}
  43 AC_SUBST(AR)
  44 AC_PROG_RANLIB
  45 AC_PROG_INSTALL
  46
  47 # Put a plausible default for CC_FOR_BUILD in Makefile.
  48 AC_C_CROSS
  49 if test "x$cross_compiling" = "xno"; then
  50   CC_FOR_BUILD='$(CC)'
  51 else
  52   CC_FOR_BUILD=gcc
  53 fi
  54 AC_SUBST(CC_FOR_BUILD)
  55
  56 # Set up to make a link between the host's include file and "sysdep.h".
  57 files=hosts/${my_host}.h
  58
  59 if test ! -f ${srcdir}/${files} ; then
  60         files=../bfd/hosts/std-host.h
  61         AC_MSG_WARN(BFD has no specific support for host ${host} -- using std-host)
  62 fi
  63
  64 AC_LINK_FILES($files, sysdep.h)
  65
  66 # If we are configured native, pick a core file support file.
  67 COREFILE=
  68 COREFLAG=
  69 if test "${target}" = "${host}"; then
  70   case "${host}" in
  71   alpha-*-*)            COREFILE=osf-core.o ;;
  72   arm-*-riscix)         COREFILE=trad-core.o ;;
  73   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
  74   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
  75   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
  76                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
  77 changequote(,)dnl
  78   i[345]86-sequent-bsd*) COREFILE=trad-core.o ;;
  79   i[345]86-sequent-sysv4*) ;;
  80   i[345]86-sequent-sysv*) COREFILE=trad-core.o ;;
  81   i[345]86-*-bsd*)      COREFILE=trad-core.o ;;
  82   i[345]86-*-freebsd*)  COREFILE=trad-core.o ;;
  83   i[345]86-*-netbsd*)   COREFILE=trad-core.o ;;
  84   i[345]86-esix-sysv3*) COREFILE=trad-core.o ;;
  85   i[345]86-*-sco*)      COREFILE=trad-core.o ;;
  86   i[345]86-*-mach3*)    COREFILE=trad-core.o ;;
  87   i[345]86-*-linux*)    COREFILE=trad-core.o ;;
  88   i[345]86-*-isc*)      COREFILE=trad-core.o ;;
  89   i[345]86-*-aix*)      COREFILE=aix386-core.o ;;
  90 changequote([,])dnl
  91   mips-dec-bsd*)        COREFILE=trad-core.o ;;
  92   mips-dec-mach3*)      COREFILE=trad-core.o ;;
  93   mips-dec-*)           COREFILE=trad-core.o ;;
  94   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
  95   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
  96   mips-*-mach3*)        COREFILE=trad-core.o ;;
  97   mips-*-sysv4*)        ;;
  98   mips-*-sysv*)         COREFILE=trad-core.o ;;
  99   mips-*-riscos*)       COREFILE=trad-core.o ;;
 100   mips-sony-bsd*)       COREFILE=trad-core.o ;;
 101   m68*-bull*-sysv*)     COREFILE=trad-core.o ;;
 102   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 103   m68*-hp-bsd*)         COREFILE=trad-core.o ;;
 104   m68*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 105   m68*-sony-*)          COREFILE=trad-core.o ;;
 106   m88*-*-sysv4*)        ;;
 107   m88*-motorola-sysv*)  COREFILE=trad-core.o ;;
 108   m88*-*-mach3*)        COREFILE=trad-core.o ;;
 109   ns32k-pc532-mach)     COREFILE=trad-core.o ;;
 110   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 111   rs6000-*-aix4*)       COREFILE=rs6000-core.o
 112                         COREFLAG=-DALTERNATE_AIX_CORE_FORMAT ;;
 113   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 114   powerpc-*-aix4*)      COREFILE=rs6000-core.o
 115                         COREFLAG=-DALTERNATE_AIX_CORE_FORMAT ;;
 116   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 117   tahoe-*-*)            COREFILE=trad-core.o ;;
 118   vax-*-ultrix2*)       COREFILE=trad-core.o ;;
 119   vax-*-ultrix*)        COREFILE=trad-core.o ;;
 120   vax-*-*)              COREFILE=trad-core.o ;;
 121   esac
 122
 123   case "$COREFILE" in
 124   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 125   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 126   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 127   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 128   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 129   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 130   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 131   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 132   trad-core.o)          COREFLAG=-DTRAD_CORE ;;
 133   esac
 134 fi
 135 AC_SUBST(COREFILE)
 136 AC_SUBST(COREFLAG)
 137
 138 # target stuff:
 139
 140 # Canonicalize the secondary target names.
 141 if test -n "$enable_targets" ; then
 142     for targ in `echo $enable_targets | sed 's/,/ /g'`
 143     do
 144         result=`$ac_config_sub $targ 2>/dev/null`
 145         if test -n "$result" ; then
 146             canon_targets="$canon_targets $result"
 147         else
 148             # Allow targets that config.sub doesn't recognize, like "all".
 149             canon_targets="$canon_targets $targ"
 150         fi
 151     done
 152 fi
 153
 154 all_targets=false
 155 defvec=
 156 selvecs=
 157 selarchs=
 158 TDEFINES=
 159 for targ in $target $canon_targets
 160 do
 161     if test "x$targ" = "xall"; then
 162         all_targets=true
 163     else
 164         . $srcdir/config.bfd
 165         if test "x$targ" = "x$target"; then
 166             defvec=$targ_defvec
 167         fi
 168         selvecs="$selvecs $targ_defvec $targ_selvecs"
 169         selarchs="$selarchs $targ_archs"
 170         TDEFINES="$TDEFINES $targ_cflags"
 171     fi
 172 done
 173 AC_SUBST(TDEFINES)
 174
 175 # This processing still needs to be done if we're to decide properly whether
 176 # 64-bit support needs to be compiled in.  Currently, it will be included if
 177 # the default or any other explicitly requested target requires it; it
 178 # will not be included on a 32-bit host if no 64-bit target is requested, and
 179 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 180 # used.
 181
 182 # uniq the default and selected vectors in all the configured targets.
 183 f=""
 184 for i in $selvecs ; do
 185     case " $f " in
 186     *" $i "*) ;;
 187     *) f="$f $i" ;;
 188     esac
 189 done
 190 selvecs="$f"
 191
 192 # uniq the architectures in all the configured targets.
 193 f=""
 194 for i in $selarchs ; do
 195     case " $f " in
 196     *" $i "*) ;;
 197     *) f="$f $i" ;;
 198     esac
 199 done
 200 selarchs="$f"
 201
 202 # Target backend .o files.
 203 tb=
 204
 205 elf="elf.o elflink.o"
 206
 207 for vec in $selvecs
 208 do
 209     case "$vec" in
 210     # This list is alphabetized to make it easy to compare
 211     # with the two vector lists in targets.c.
 212     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 213     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o stab-syms.o" ;;
 214     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 215     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 216     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 217     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 218     aout0_big_vec)              tb="$tb aout0.o aout32.o stab-syms.o" ;;
 219     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 220     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o stab-syms.o" ;;
 221     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 222     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o stab-syms.o" ;;
 223     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 224     b_out_vec_big_host)         tb="$tb bout.o aout32.o stab-syms.o" ;;
 225     b_out_vec_little_host)      tb="$tb bout.o aout32.o stab-syms.o" ;;
 226 # start-sanitize-arc
 227     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 228     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 229 # end-sanitize-arc
 230     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 231     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 232     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 233     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 234     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 235     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 236     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 237     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 238     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 239     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 240     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 241     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 242     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 243                                 target64=true ;;
 244     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 245                                 target64=true ;;
 246     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 247                                 target64=true ;;
 248     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 249     demo_64_vec)                tb="$tb demo64.o aout64.o stab-syms.o"
 250                                 target64=true ;;
 251     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 252     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 253     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 254                                 target64=true ;;
 255     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 256     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 257     host_aout_vec)              tb="$tb host-aout.o aout32.o stab-syms.o" ;;
 258     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o stab-syms.o" ;;
 259     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o stab-syms.o" ;;
 260     i386aout_vec)               tb="$tb i386aout.o aout32.o stab-syms.o" ;;
 261     i386bsd_vec)                tb="$tb i386bsd.o aout32.o stab-syms.o" ;;
 262     i386dynix_vec)              tb="$tb i386dynix.o aout32.o stab-syms.o" ;;
 263     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 264     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 265     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 266     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 267     i386linux_vec)              tb="$tb i386linux.o aout32.o stab-syms.o" ;;
 268     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o stab-syms.o" ;;
 269     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o stab-syms.o" ;;
 270     i386mach3_vec)              tb="$tb i386mach3.o aout32.o stab-syms.o" ;;
 271     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o stab-syms.o" ;;
 272     i386os9k_vec)               tb="$tb i386os9k.o aout32.o stab-syms.o" ;;
 273     icoff_big_vec)              tb="$tb coff-i960.o" ;;
 274     icoff_little_vec)           tb="$tb coff-i960.o" ;;
 275     ieee_vec)                   tb="$tb ieee.o" ;;
 276     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 277     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 278     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o stab-syms.o" ;;
 279     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o stab-syms.o" ;;
 280     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o stab-syms.o" ;;
 281     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 282     newsos3_vec)                tb="$tb newsos3.o aout32.o stab-syms.o" ;;
 283     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 284     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 285     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 286                                 target64=true ;;
 287     riscix_vec)                 tb="$tb aout32.o riscix.o stab-syms.o" ;;
 288     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 289     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o stab-syms.o" ;;
 290     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o stab-syms.o" ;;
 291     rs6000coff_vec)             tb="$tb coff-rs6000.o" ;;
 292     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 293 # start-sanitize-rce
 294     rce_aout_vec)               tb="$tb aout-rce.o aout32.o stab-syms.o" ;;
 295 # end-sanitize-rce
 296     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 297     som_vec)                    tb="$tb som.o" ;;
 298     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o stab-syms.o" ;;
 299     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o stab-syms.o" ;;
 300     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o stab-syms.o" ;;
 301     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 302     srec_vec)                   tb="$tb srec.o" ;;
 303     sunos_big_vec)              tb="$tb sunos.o aout32.o stab-syms.o" ;;
 304     symbolsrec_vec)             tb="$tb srec.o" ;;
 305     tekhex_vec)                 tb="$tb tekhex.o" ;;
 306     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 307     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 308     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 309     versados_vec)               tb="$tb versados.o" ;;
 310
 311     "")                 ;;
 312     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 313     esac
 314 done
 315
 316 # Target architecture .o files.
 317 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g`
 318
 319 # Weed out duplicate .o files.
 320 f=""
 321 for i in $tb ; do
 322     case " $f " in
 323     *" $i "*) ;;
 324     *) f="$f $i" ;;
 325     esac
 326 done
 327 tb="$f"
 328
 329 f=""
 330 for i in $ta ; do
 331     case " $f " in
 332     *" $i "*) ;;
 333     *) f="$f $i" ;;
 334     esac
 335 done
 336 ta="$f"
 337
 338 bfd_backends="$tb"
 339 bfd_machines="$ta"
 340
 341 if test x${all_targets} = xtrue ; then
 342   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 343   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 344   selvecs=
 345   selarchs=
 346 else    # all_targets is true
 347   # Only set these if they will be nonempty, for the clever echo.
 348   test -n "$selvecs" &&
 349     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 350   test -n "$selarchs" &&
 351     selarchs=`echo $selarchs | sed -e 's/ \(.\)/,\1/g'`
 352 fi      # all_targets is true
 353
 354 case ${host64}-${target64}-${want64} in
 355   *true*)
 356     wordsize=64
 357     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 358     ;;
 359   false-false-false)
 360     wordsize=32
 361     all_backends='$(BFD32_BACKENDS)'
 362     ;;
 363 esac
 364
 365 AC_SUBST(wordsize)
 366 AC_SUBST(all_backends)
 367 AC_SUBST(bfd_backends)
 368 AC_SUBST(bfd_machines)
 369
 370 tdefaults=""
 371 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 372 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 373 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 374 AC_SUBST(tdefaults)
 375
 376 rm -f doc/config.status
 377 AC_OUTPUT(Makefile doc/Makefile)