binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 m4_include([../config/debuginfod.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 LT_INIT
  35 ACX_LARGEFILE
  36
  37 AC_ARG_ENABLE(targets,
  38 [  --enable-targets        alternative target configurations],
  39 [case "${enableval}" in
  40   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  41             ;;
  42   no)       enable_targets= ;;
  43   *)        enable_targets=$enableval ;;
  44 esac])dnl
  45
  46 AC_ARG_ENABLE(deterministic-archives,
  47 [AS_HELP_STRING([--enable-deterministic-archives],
  48                 [ar and ranlib default to -D behavior])], [
  49 if test "${enableval}" = no; then
  50   default_ar_deterministic=0
  51 else
  52   default_ar_deterministic=1
  53 fi], [default_ar_deterministic=0])
  54
  55 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  56                    [Should ar and ranlib use -D behavior by default?])
  57
  58 AC_ARG_ENABLE(default-strings-all,
  59 [AS_HELP_STRING([--disable-default-strings-all],
  60                 [strings defaults to --data behavior])], [
  61 if test "${enableval}" = no; then
  62   default_strings_all=0
  63 else
  64   default_strings_all=1
  65 fi], [default_strings_all=1])
  66
  67 AC_DEBUGINFOD
  68
  69 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  70                    [Should strings use -a behavior by default?])
  71
  72 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
  73 if test "${enable_libctf}" = yes; then
  74     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
  75 fi
  76 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
  77
  78 AM_BINUTILS_WARNINGS
  79
  80 AC_CONFIG_HEADERS(config.h:config.in)
  81
  82 AH_VERBATIM([00_CONFIG_H_CHECK],
  83 [/* Check that config.h is #included before system headers
  84    (this works only for glibc, but that should be enough).  */
  85 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  86 #  error config.h must be #included before system headers
  87 #endif
  88 #define __CONFIG_H__ 1])
  89
  90 if test -z "$target" ; then
  91     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  92 fi
  93 if test -z "$host" ; then
  94     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  95 fi
  96
  97 AC_PROG_YACC
  98 AM_PROG_LEX
  99
 100 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
 101 ZW_GNU_GETTEXT_SISTER_DIR
 102 AM_PO_SUBDIRS
 103
 104 AM_MAINTAINER_MODE
 105 AM_CONDITIONAL(GENINSRC_NEVER, false)
 106 AC_EXEEXT
 107 if test -n "$EXEEXT"; then
 108   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 109             [Does the platform use an executable suffix?])
 110 fi
 111 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 112                    [Suffix used for executables, if any.])
 113
 114 # host-specific stuff:
 115
 116 HDEFINES=
 117
 118 . ${srcdir}/../bfd/configure.host
 119
 120 AC_SUBST(HDEFINES)
 121 AR=${AR-ar}
 122 AC_SUBST(AR)
 123 AC_PROG_RANLIB
 124 AC_PROG_INSTALL
 125
 126 BFD_CC_FOR_BUILD
 127
 128 DEMANGLER_NAME=c++filt
 129 case "${host}" in
 130   *-*-go32* | *-*-msdos*)
 131     DEMANGLER_NAME=cxxfilt
 132 esac
 133 AC_SUBST(DEMANGLER_NAME)
 134
 135 AC_CHECK_SIZEOF([long])
 136 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 137
 138 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h locale.h sys/param.h wchar.h)
 139 AC_HEADER_SYS_WAIT
 140 ACX_HEADER_STRING
 141 AC_FUNC_ALLOCA
 142 AC_FUNC_MMAP
 143 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
 144 AC_CHECK_FUNC([mkstemp],
 145               AC_DEFINE([HAVE_MKSTEMP], 1,
 146               [Define to 1 if you have the `mkstemp' function.]))
 147 AC_CHECK_FUNC([mkdtemp],
 148               AC_DEFINE([HAVE_MKDTEMP], 1,
 149               [Define to 1 if you have the `mkdtemp' function.]))
 150   AC_MSG_CHECKING([for mbstate_t])
 151   AC_TRY_COMPILE([#include <wchar.h>],
 152   [mbstate_t teststate;],
 153   have_mbstate_t=yes, have_mbstate_t=no)
 154   AC_MSG_RESULT($have_mbstate_t)
 155   if test x"$have_mbstate_t" = xyes; then
 156     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 157   fi
 158
 159 # Some systems have frexp only in -lm, not in -lc.
 160 AC_SEARCH_LIBS(frexp, m)
 161
 162 AM_LC_MESSAGES
 163
 164 AC_MSG_CHECKING(for time_t in time.h)
 165 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 166 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 167 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 168 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 169 if test $bu_cv_decl_time_t_time_h = yes; then
 170   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 171             [Is the type time_t defined in <time.h>?])
 172 fi
 173
 174 AC_MSG_CHECKING(for time_t in sys/types.h)
 175 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 176 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 177 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 178 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 179 if test $bu_cv_decl_time_t_types_h = yes; then
 180   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 181             [Is the type time_t defined in <sys/types.h>?])
 182 fi
 183
 184 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 185 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 186 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 187 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 188 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 189 if test $bu_cv_decl_getopt_unistd_h = yes; then
 190   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 191             [Is the prototype for getopt in <unistd.h> in the expected format?])
 192 fi
 193
 194 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 195 # by default.
 196 AC_MSG_CHECKING([for utime.h])
 197 AC_CACHE_VAL(bu_cv_header_utime_h,
 198 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 199 #ifdef HAVE_TIME_H
 200 #include <time.h>
 201 #endif
 202 #include <utime.h>],
 203 [struct utimbuf s;])],
 204 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 205 AC_MSG_RESULT($bu_cv_header_utime_h)
 206 if test $bu_cv_header_utime_h = yes; then
 207   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 208 fi
 209
 210 AC_CHECK_DECLS([asprintf, environ, fprintf, getc_unlocked, getenv,
 211                 sbrk, snprintf, stpcpy, strnlen, strstr, vsnprintf])
 212
 213 # Link in zlib if we can.  This allows us to read compressed debug
 214 # sections.  This is used only by readelf.c (objdump uses bfd for
 215 # reading compressed sections).
 216 AM_ZLIB
 217
 218 BFD_BINARY_FOPEN
 219
 220 # target-specific stuff:
 221
 222 # Canonicalize the secondary target names.
 223 if test -n "$enable_targets"; then
 224     for targ in `echo $enable_targets | sed 's/,/ /g'`
 225     do
 226         result=`$ac_config_sub $targ 2>/dev/null`
 227         if test -n "$result"; then
 228             canon_targets="$canon_targets $result"
 229         else
 230             # Allow targets that config.sub doesn't recognize, like "all".
 231             canon_targets="$canon_targets $targ"
 232         fi
 233     done
 234 fi
 235
 236 AC_CHECK_HEADER(iconv.h)
 237 AM_ICONV
 238
 239 all_targets=false
 240 BUILD_SRCONV=
 241 BUILD_DLLTOOL=
 242 DLLTOOL_DEFS=
 243 DLLTOOL_DEFAULT=
 244 BUILD_WINDRES=
 245 BUILD_WINDMC=
 246 BUILD_DLLWRAP=
 247 BUILD_MISC=
 248 BUILD_INSTALL_MISC=
 249 OBJDUMP_DEFS=
 250 OBJDUMP_PRIVATE_VECTORS=
 251 OBJDUMP_PRIVATE_OFILES=
 252 od_vectors=
 253
 254 for targ in $target $canon_targets
 255 do
 256     if test "x$targ" = "xall"; then
 257         all_targets=true
 258         BUILD_SRCONV='$(SRCONV_PROG)'
 259         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 260         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 261         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 262         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 263         if test -z "$DLLTOOL_DEFAULT"; then
 264           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 265         fi
 266         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 267         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 268         od_vectors="$od_vectors objdump_private_desc_xcoff"
 269     else
 270         case $targ in
 271         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 272         esac
 273
 274         case $targ in
 275         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 276           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 277           if test -z "$DLLTOOL_DEFAULT"; then
 278             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 279           fi
 280           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 281           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 282           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 283           ;;
 284         arm-*-pe*)
 285           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 286           if test -z "$DLLTOOL_DEFAULT"; then
 287             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 288           fi
 289           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 290           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 291           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 292           ;;
 293         x86_64-*-mingw* | x86_64-*-cygwin*)
 294           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 295           if test -z "$DLLTOOL_DEFAULT"; then
 296             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 297           fi
 298           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 299           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 300           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 301           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 302           ;;
 303 changequote(,)dnl
 304         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 305 changequote([,])dnl
 306           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 307           if test -z "$DLLTOOL_DEFAULT"; then
 308             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 309           fi
 310           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 311           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 312           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 313           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 314           ;;
 315 changequote(,)dnl
 316         i[3-7]86-*-interix)
 317 changequote([,])dnl
 318           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 319           if test -z "$DLLTOOL_DEFAULT"; then
 320             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 321           fi
 322           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 323           ;;
 324 changequote(,)dnl
 325         powerpc*-aix5.[01])
 326 changequote([,])dnl
 327           ;;
 328 changequote(,)dnl
 329         powerpc*-aix[5-9].*)
 330 changequote([,])dnl
 331           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 332           ;;
 333         powerpc*-*-pe* | powerpc*-*-cygwin*)
 334           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 335           if test -z "$DLLTOOL_DEFAULT"; then
 336             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 337           fi
 338           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 339           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 340           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 341           ;;
 342         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 343           case "$BUILD_INSTALL_MISC" in
 344             *embedspu*) ;;
 345             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 346           esac
 347           ;;
 348         sh*-*-pe)
 349           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 350           if test -z "$DLLTOOL_DEFAULT"; then
 351             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 352           fi
 353           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 354           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 355           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 356           ;;
 357         spu-*-*)
 358           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 359           ;;
 360         mips*-*-pe)
 361           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 362           if test -z "$DLLTOOL_DEFAULT"; then
 363             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 364           fi
 365           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 366           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 367           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 368           ;;
 369         mcore-*-pe)
 370           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 371           if test -z "$DLLTOOL_DEFAULT"; then
 372             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 373           fi
 374           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 375           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 376           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 377           ;;
 378         mcore-*-elf)
 379           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 380           if test -z "$DLLTOOL_DEFAULT"; then
 381             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 382           fi
 383           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 384           ;;
 385         mep-*)
 386           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 387           ;;
 388         esac
 389
 390         # Add objdump private vectors.
 391         case $targ in
 392         avr-*-*)
 393           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 394           ;;
 395         powerpc*-*-aix* | rs6000-*-aix*)
 396           od_vectors="$od_vectors objdump_private_desc_xcoff"
 397           ;;
 398         *-*-darwin*)
 399           od_vectors="$od_vectors objdump_private_desc_mach_o"
 400           ;;
 401         esac
 402     fi
 403 done
 404
 405 # Uniq objdump private vector, build objdump target ofiles.
 406 od_files=
 407 f=""
 408 for i in $od_vectors ; do
 409     case " $f " in
 410     *" $i "*) ;;
 411     *)
 412         f="$f $i"
 413         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 414         case $i in
 415         objdump_private_desc_elf32_avr)
 416             od_files="$od_files od-elf32_avr" ;;
 417         objdump_private_desc_xcoff)
 418             od_files="$od_files od-xcoff" ;;
 419         objdump_private_desc_mach_o)
 420             od_files="$od_files od-macho" ;;
 421         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 422         esac
 423         ;;
 424     esac
 425 done
 426
 427 # Uniq objdump target ofiles
 428 f=""
 429 for i in $od_files ; do
 430     case " $f " in
 431     *" $i "*) ;;
 432     *)
 433         f="$f $i"
 434         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 435         ;;
 436     esac
 437 done
 438
 439 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 440
 441 if test "${with_windres+set}" = set; then
 442           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 443 fi
 444
 445 if test "${with_windmc+set}" = set; then
 446           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 447 fi
 448
 449 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 450
 451 AC_SUBST(BUILD_SRCONV)
 452 AC_SUBST(BUILD_DLLTOOL)
 453 AC_SUBST(DLLTOOL_DEFS)
 454 AC_SUBST(BUILD_WINDRES)
 455 AC_SUBST(BUILD_WINDMC)
 456 AC_SUBST(BUILD_DLLWRAP)
 457 AC_SUBST(BUILD_MISC)
 458 AC_SUBST(BUILD_INSTALL_MISC)
 459 AC_SUBST(OBJDUMP_DEFS)
 460 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 461
 462 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 463
 464 targ=$target
 465 . $srcdir/../bfd/config.bfd
 466 if test "x$targ_underscore" = "xyes"; then
 467     UNDERSCORE=1
 468 else
 469     UNDERSCORE=0
 470 fi
 471 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 472  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 473
 474 # Emulation
 475 targ=$target
 476 . ${srcdir}/configure.tgt
 477 EMULATION=$targ_emul
 478 EMULATION_VECTOR=$targ_emul_vector
 479
 480 AC_SUBST(EMULATION)
 481 AC_SUBST(EMULATION_VECTOR)
 482
 483 # Required for html and install-html
 484 AC_SUBST(datarootdir)
 485 AC_SUBST(docdir)
 486 AC_SUBST(htmldir)
 487 AC_SUBST(pdfdir)
 488
 489 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 490 AC_OUTPUT