binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.5)
   4 AC_INIT(ar.c)
   5
   6 AC_CANONICAL_SYSTEM
   7
   8 AM_INIT_AUTOMAKE(binutils, 2.8.2)
   9
  10 AM_PROG_LIBTOOL
  11
  12 AC_ARG_ENABLE(targets,
  13 [  --enable-targets        alternative target configurations],
  14 [case "${enableval}" in
  15   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  16             ;;
  17   no)       enable_targets= ;;
  18   *)        enable_targets=$enableval ;;
  19 esac])dnl
  20 AC_ARG_ENABLE(commonbfdlib,
  21 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  22 [case "${enableval}" in
  23   yes) commonbfdlib=true ;;
  24   no)  commonbfdlib=false ;;
  25   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  26 esac])dnl
  27
  28 AM_CONFIG_HEADER(config.h:config.in)
  29
  30 if test -z "$target" ; then
  31     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  32 fi
  33 if test -z "$host" ; then
  34     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  35 fi
  36
  37 AC_PROG_CC
  38
  39 AC_PROG_YACC
  40 AC_PROG_LEX
  41 AC_DECL_YYTEXT
  42
  43 AM_MAINTAINER_MODE
  44 AM_CYGWIN32
  45 AM_EXEEXT
  46
  47 # host-specific stuff:
  48
  49 HDEFINES=
  50
  51 . ${srcdir}/../bfd/configure.host
  52
  53 AC_SUBST(HDEFINES)
  54 AR=${AR-ar}
  55 AC_SUBST(AR)
  56 AC_PROG_RANLIB
  57 AM_PROG_INSTALL
  58
  59 BFD_CC_FOR_BUILD
  60
  61 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h)
  62 AC_HEADER_SYS_WAIT
  63 AC_FUNC_ALLOCA
  64 AC_CHECK_FUNCS(sbrk utimes)
  65 dnl Temporary workaround for bug in autoconf 2.12.  When the bug is
  66 dnl fixed, we can just call AC_FUNC_VFORK in all cases.
  67 if test "x$cross_compiling" = "xno"; then
  68   AC_FUNC_VFORK
  69 else
  70   AC_CHECK_FUNC(vfork, , AC_DEFINE(vfork, fork))
  71 fi
  72
  73 AC_MSG_CHECKING(for time_t in time.h)
  74 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
  75 [AC_TRY_COMPILE([#include <time.h>], [time_t i;],
  76 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
  77 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
  78 if test $bu_cv_decl_time_t_time_h = yes; then
  79   AC_DEFINE([HAVE_TIME_T_IN_TIME_H])
  80 fi
  81
  82 AC_MSG_CHECKING(for time_t in sys/types.h)
  83 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
  84 [AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
  85 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
  86 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
  87 if test $bu_cv_decl_time_t_types_h = yes; then
  88   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H])
  89 fi
  90
  91 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
  92 # by default.
  93 AC_MSG_CHECKING([for utime.h])
  94 AC_CACHE_VAL(bu_cv_header_utime_h,
  95 [AC_TRY_COMPILE([#include <sys/types.h>
  96 #ifdef HAVE_TIME_H
  97 #include <time.h>
  98 #endif
  99 #include <utime.h>],
 100 [struct utimbuf s;],
 101 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 102 AC_MSG_RESULT($bu_cv_header_utime_h)
 103 if test $bu_cv_header_utime_h = yes; then
 104   AC_DEFINE(HAVE_GOOD_UTIME_H)
 105 fi
 106
 107 BFD_NEED_DECLARATION(fprintf)
 108 BFD_NEED_DECLARATION(strstr)
 109 BFD_NEED_DECLARATION(sbrk)
 110 BFD_NEED_DECLARATION(getenv)
 111
 112 BFD_BINARY_FOPEN
 113
 114 # target-specific stuff:
 115
 116 # Canonicalize the secondary target names.
 117 if test -n "$enable_targets"; then
 118     for targ in `echo $enable_targets | sed 's/,/ /g'`
 119     do
 120         result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 121         if test -n "$result"; then
 122             canon_targets="$canon_targets $result"
 123         else
 124             # Allow targets that config.sub doesn't recognize, like "all".
 125             canon_targets="$canon_targets $targ"
 126         fi
 127     done
 128 fi
 129
 130 all_targets=false
 131 BUILD_NLMCONV=
 132 NLMCONV_DEFS=
 133 BUILD_SRCONV=
 134 BUILD_DLLTOOL=
 135 DLLTOOL_DEFS=
 136 BUILD_WINDRES=
 137
 138 for targ in $target $canon_targets
 139 do
 140     if test "x$targ" = "xall"; then
 141         all_targets=true
 142         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 143         BUILD_SRCONV='$(SRCONV_PROG)$(EXEEXT)'
 144         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 145     else
 146         case $targ in
 147 changequote(,)dnl
 148         i[3456]86*-*-netware*)
 149 changequote([,])dnl
 150           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 151           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 152           ;;
 153         alpha*-*-netware*)
 154           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 155           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 156           ;;
 157         powerpc*-*-netware*)
 158           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 159           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 160           ;;
 161         sparc*-*-netware*)
 162           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 163           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 164           ;;
 165         esac
 166         case $targ in
 167         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)$(EXEEXT)' ;;
 168         esac
 169         case $targ in
 170         arm-*pe*)
 171           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 172           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 173           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 174          ;;
 175 changequote(,)dnl
 176         i[3-6]86-*pe* | i[3-6]86-*-cygwin32)
 177 changequote([,])dnl
 178           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 179           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 180           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 181          ;;
 182         powerpc*-*-*pe* | powerpc*-*-cygwin32)
 183           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 184           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 185           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 186          ;;
 187         esac
 188     fi
 189 done
 190
 191 AC_SUBST(NLMCONV_DEFS)
 192 AC_SUBST(BUILD_NLMCONV)
 193 AC_SUBST(BUILD_SRCONV)
 194 AC_SUBST(BUILD_DLLTOOL)
 195 AC_SUBST(DLLTOOL_DEFS)
 196 AC_SUBST(BUILD_WINDRES)
 197
 198 targ=$target
 199 . $srcdir/../bfd/config.bfd
 200 if test "x$targ_underscore" = "xyes"; then
 201     UNDERSCORE=1
 202 else
 203     UNDERSCORE=0
 204 fi
 205 AC_SUBST(UNDERSCORE)
 206
 207 AC_OUTPUT(Makefile)