compiler2/ttcn3/compiler.l

   1 /******************************************************************************
   2  * Copyright (c) 2000-2016 Ericsson Telecom AB
   3  * All rights reserved. This program and the accompanying materials
   4  * are made available under the terms of the Eclipse Public License v1.0
   5  * which accompanies this distribution, and is available at
   6  * http://www.eclipse.org/legal/epl-v10.html
   7  *
   8  * Contributors:
   9  *   Baji, Laszlo
  10  *   Balasko, Jeno
  11  *   Baranyi, Botond
  12  *   Cserveni, Akos
  13  *   Delic, Adam
  14  *   Feher, Csaba
  15  *   Forstner, Matyas
  16  *   Kovacs, Ferenc
  17  *   Kremer, Peter
  18  *   Raduly, Csaba
  19  *   Szabados, Kristof
  20  *   Szabo, Bence Janos
  21  *   Szabo, Janos Zoltan – initial implementation
  22  *   Zalanyi, Balazs Andor
  23  *
  24  ******************************************************************************/
  25 %option noyywrap
  26 %option never-interactive
  27 %option nounput
  28 %{
  29
  30 /* Tokenizer for TTCN-3 Core Language */
  31
  32 #include "../../common/dbgnew.hh"
  33 #include "compiler.h"
  34 #include "../string.hh"
  35 #include "../CompilerError.hh"
  36 #include "../Real.hh"
  37 #include "../Value.hh"
  38 #include "AST_ttcn3.hh"
  39 #include "Ttcnstuff.hh" // at least for PortTypeBody::PortOperationMode_t
  40 #include "Statement.hh" // for Statement::statementtype_t
  41 #include "Attributes.hh"
  42
  43 #include <string.h>
  44 #include <ctype.h>
  45 #include <openssl/md5.h>
  46
  47 namespace Common {
  48   class IndexedValue;
  49   class Location;
  50 }
  51
  52 namespace Ttcn {
  53   class ParamRedirect;
  54   class Statement;
  55   class AltGuard;
  56   class IfClause;
  57   class IfClauses;
  58   class NamedTemplate;
  59   class NamedTemplates;
  60   class IndexedTemplate;
  61   class IndexedTemplates;
  62   class Templates;
  63   class CompTypeRefList;
  64 }
  65
  66 using namespace Common;
  67 using namespace Ttcn;
  68
  69 #include "compiler.tab.hh"
  70
  71 #define yylval ttcn3_lval
  72 #define yylloc ttcn3_lloc
  73
  74 /* global variable indicating the location of the returned token to bison */
  75 extern YYLTYPE yylloc;
  76
  77 extern bool is_erroneous_parsed;
  78
  79 /* always points to the first character of the regexp to be recognized */
  80 static int current_line, current_column;
  81
  82 /* when reporting an error in linemarker or preprocessor
  83  * directive the real file name and line number is needed */
  84 static const char* real_infile;
  85 /* real_lineno = current_line + real_lineno_offset */
  86 static int real_lineno_offset;
  87
  88 static bool dot_flag = false;
  89 /* type of the backup token (that was found after a dot) */
  90 static int backup_token;
  91 /* semantic value of the backup token */
  92 static YYSTYPE backup_lval;
  93 /* location of the backup token */
  94 static YYLTYPE backup_lloc;
  95
  96 static MD5_CTX md5_ctx;
  97
  98 static void fill_location()
  99 {
 100   yylloc.first_line = current_line;
 101   yylloc.first_column = current_column;
 102   current_column += yyleng;
 103   yylloc.last_line = current_line;
 104   yylloc.last_column = current_column;
 105 }
 106
 107 static void update_md5()
 108 {
 109   MD5_Update(&md5_ctx, yytext, yyleng);
 110   MD5_Update(&md5_ctx, " ", 1);
 111 }
 112
 113 #define RETURN_SAVED_DOT \
 114   do { \
 115     yytext[0] = '\0'; \
 116     yylloc.first_line = dot_line; \
 117     yylloc.first_column = dot_column; \
 118     yylloc.last_line = dot_line; \
 119     yylloc.last_column = dot_column + 1; \
 120     return '.'; \
 121   } while (0)
 122
 123 /* return macro for simple tokens without semantic value */
 124 #define RETURN(ret_val) \
 125   do { \
 126     update_md5(); \
 127     fill_location(); \
 128     if (dot_flag) { \
 129       backup_token = ret_val; \
 130       backup_lloc = yylloc; \
 131       RETURN_SAVED_DOT; \
 132     } else return ret_val; \
 133   } while (0)
 134
 135 /* same as RETURN(ret_val) macro but without location update,
 136  * usually a return after an error */
 137 #define RETURN_NOLOCUPD(ret_val) \
 138   do { \
 139     update_md5(); \
 140     if (dot_flag) { \
 141       backup_token = ret_val; \
 142       backup_lloc = yylloc; \
 143       RETURN_SAVED_DOT; \
 144     } else return ret_val; \
 145   } while (0)
 146
 147 /* return macro for simple tokens with semantic value */
 148 #define RETURN_LVAL(ret_val) \
 149   do { \
 150     update_md5(); \
 151     fill_location(); \
 152     if (dot_flag) { \
 153       backup_token = ret_val; \
 154       backup_lval = yylval; \
 155       backup_lloc = yylloc; \
 156       RETURN_SAVED_DOT; \
 157     } else return ret_val; \
 158   } while (0)
 159
 160 /* return macro for special tokens that are glued together with previous dot */
 161 #define RETURN_DOT(ret_val) \
 162   do { \
 163     update_md5(); \
 164     if (dot_flag) { \
 165       dot_flag = false; \
 166       yylloc.first_line = dot_line; \
 167       yylloc.first_column = dot_column; \
 168       current_column += yyleng; \
 169       yylloc.last_line = current_line; \
 170       yylloc.last_column = current_column; \
 171       return Dot##ret_val; \
 172     } else { \
 173       fill_location(); \
 174       return ret_val; \
 175     } \
 176   } while (0)
 177
 178 extern string *parse_charstring_value(const char *str, const Location& loc);
 179
 180 %}
 181
 182 NUMBER 0|([1-9][0-9]*)
 183
 184 FLOAT ({NUMBER}\.[0-9]+)|({NUMBER}(\.[0-9]+)?[Ee][+-]?{NUMBER})
 185
 186 IDENTIFIER [A-Za-z][A-Za-z0-9_]*
 187
 188 LINECOMMENT "//"[^\r\n]*
 189
 190 WHITESPACE [ \t\v\f]
 191
 192 NEWLINE \r|\n|\r\n
 193
 194 LINEMARKER {NUMBER}{WHITESPACE}+\"([^\\\"\r\n]|\\[^\r\n])*\"
 195
 196 UID [uU][+]?[0-9A-Fa-f]{1,8}
 197
 198 TITAN "$#&&&(#TITANERRONEOUS$#&&^#% "
 199
 200 %x SC_blockcomment SC_cstring
 201 %x SC_binstring SC_binstring_bad
 202 %s SC_charkeyword
 203
 204 %%
 205   /* local variables of yylex() */
 206   int start_line = 0, start_column = 0; /**< used by block comments and
 207                                              string literals */
 208   int dot_line = 0, dot_column = 0; /**< location of the previous '.' token */
 209   /* variables used when processing binary strings */
 210   expstring_t binstr = NULL; /**< the string itself */
 211   bool valid_bit = false, /**< binstr is valid bitstring */
 212     valid_oct = false, /**< binstr is valid octetstring */
 213     half_oct = false, /**< binstr is not a valid octetstr but a valid hexstr */
 214     contains_match = false, /**< binstr contains matching symbol */
 215     contains_ws = false; /**< binstr contains whitespace characters */
 216
 217   if (dot_flag) {
 218     if (backup_token == '.') {
 219       /* Two dots were found in the previous call: the first one was returned,
 220        * the second one is now in the backup. Let's assume that we have just
 221        * found the second one. */
 222       dot_line = backup_lloc.first_line;
 223       dot_column = backup_lloc.first_column;
 224     } else {
 225       /* Return the token and its semantic value that was backed up after the
 226        * last token (which was a dot). */
 227       dot_flag = false;
 228       yylval = backup_lval;
 229       yylloc = backup_lloc;
 230       return backup_token;
 231     }
 232   }
 233
 234
 235 {TITAN} {
 236   // hack: to avoid the erroneous parsing reporting a syntax error where it
 237   //       also lists TTCN3ModuleKeyword as a possible nonterminal to use
 238   if (is_erroneous_parsed) {
 239     RETURN(TitanErroneousHackKeyword);
 240   } else {
 241     Location loc(infile, current_line, current_column, current_line,
 242                  current_column + yyleng);
 243     loc.error("Unexpected `%s'.", yytext);
 244   }
 245 }
 246
 247         /* Eat up comments and whitespaces */
 248
 249 "/*" {
 250   start_line = current_line;
 251   start_column = current_column;
 252   current_column += 2;
 253   BEGIN(SC_blockcomment);
 254 }
 255
 256 <SC_blockcomment> /* -------- SC_blockcomment scope -------------- */
 257 {
 258
 259   "*/" {
 260     current_column += 2;
 261     BEGIN(INITIAL);
 262   }
 263
 264   {NEWLINE} {
 265     current_line++;
 266     current_column = 0;
 267   }
 268
 269   . current_column++;
 270
 271 } /* SC_blockcomment */
 272
 273 {LINECOMMENT}?{NEWLINE} {
 274   current_line++;
 275   current_column = 0;
 276 }
 277
 278 {LINECOMMENT} {
 279   current_column += yyleng;
 280 }
 281
 282 {WHITESPACE}+ current_column += yyleng;
 283
 284         /* C preprocessor line markers */
 285
 286 ^{WHITESPACE}*"#"({WHITESPACE}*"line")?{WHITESPACE}+{LINEMARKER}[^\r\n]*{NEWLINE} {
 287   bool error_flag = false;
 288   int real_lineno = current_line + real_lineno_offset;
 289   /* skipping the leading whitespaces */
 290   int marker_begin = 0;
 291   while (yytext[marker_begin] != '#') marker_begin++;
 292   /* skipping the trailing whitespaces and newline */
 293   int marker_end = yyleng - 1;
 294   while (yytext[marker_end] == '\r' || yytext[marker_end] == '\n' ||
 295          yytext[marker_end] == ' ' || yytext[marker_end] == '\t') marker_end--;
 296   marker_end++;
 297   Location loc(real_infile, real_lineno, current_column + marker_begin,
 298     real_lineno, current_column + marker_end);
 299   Error_Context cntxt(&loc, "In preprocessor line marker");
 300   /* parsing out the line number */
 301   int lineno_begin = marker_begin + 1;
 302   while (!isdigit((unsigned char)yytext[lineno_begin])) lineno_begin++;
 303   int lineno_end = lineno_begin + 1;
 304   while (isdigit((int)yytext[lineno_end])) lineno_end++;
 305   errno = 0;
 306   int new_lineno = strtol(yytext + lineno_begin, NULL, 10);
 307   if (errno != 0) {
 308     Location lineno_loc(real_infile, real_lineno, current_column + lineno_begin,
 309       real_lineno, current_column + lineno_end);
 310     string lineno_str(lineno_end - lineno_begin, yytext + lineno_begin);
 311     lineno_loc.error("Line number `%s' is too large for being represented in "
 312       "memory: %s", lineno_str.c_str(), strerror(errno));
 313     error_flag = true;
 314   }
 315   /* parsing out the file name */
 316   int filename_begin = lineno_end + 1;
 317   while (yytext[filename_begin] != '"') filename_begin++;
 318   filename_begin++;
 319   int filename_end = filename_begin;
 320   while (yytext[filename_end] != '"') {
 321     if (yytext[filename_end] == '\\') filename_end += 2;
 322     else filename_end++;
 323   }
 324   Location filename_loc(real_infile, real_lineno, current_column +
 325     filename_begin - 1, real_lineno, current_column + filename_end + 1);
 326   string filename_str(filename_end - filename_begin, yytext + filename_begin);
 327   string *parsed_filename = parse_charstring_value(filename_str.c_str(),
 328     filename_loc);
 329   if (!parsed_filename) error_flag = true;
 330   /* updating the line/column counters */
 331   if (error_flag) {
 332     /* the line marker is erroneous, use the real line numbers */
 333     infile = real_infile;
 334     current_line = real_lineno + 1;
 335     real_lineno_offset = 0;
 336   } else {
 337     /* set the given line number */
 338     infile = Location::add_source_file_name(*parsed_filename);
 339     current_line = new_lineno;
 340     real_lineno_offset = real_lineno + 1 - new_lineno;
 341   }
 342   current_column = 0;
 343   delete parsed_filename;
 344 }
 345
 346 ^{WHITESPACE}*"#"[^\r\n]* {
 347   int real_lineno = current_line + real_lineno_offset;
 348   /* skip the leading and trailing whitespaces */
 349   int marker_begin = 0;
 350   while (yytext[marker_begin] != '#') marker_begin++;
 351   int marker_end = yyleng - 1;
 352   while (yytext[marker_end] == ' ' || yytext[marker_end] == '\t') marker_end--;
 353   marker_end++;
 354   Location loc(real_infile, real_lineno, current_column + marker_begin,
 355     real_lineno, current_column + marker_end);
 356   loc.error("Invalid/unsupported preprocessor directive or line marker: `%s'",
 357     string(marker_end - marker_begin, yytext + marker_begin).c_str());
 358   current_column += yyleng;
 359 }
 360
 361         /* Keywords */
 362
 363 action          RETURN(ActionKeyword);
 364 activate        RETURN(ActivateKeyword);
 365 address         RETURN(AddressKeyword);
 366 alive           RETURN_DOT(AliveKeyword);
 367 all             RETURN(AllKeyword);
 368 alt             RETURN(AltKeyword);
 369 altstep         RETURN(AltstepKeyword);
 370 and             RETURN(AndKeyword);
 371 and4b           RETURN(And4bKeyword);
 372 any             RETURN(AnyKeyword);
 373 anytype         RETURN(AnyTypeKeyword);
 374 apply           RETURN_DOT(ApplyKeyword);
 375 bitstring       RETURN(BitStringKeyword);
 376 boolean         RETURN(BooleanKeyword);
 377 break           RETURN(BreakKeyword);
 378 call            RETURN_DOT(CallOpKeyword);
 379 case            RETURN(CaseKeyword);
 380 catch           RETURN_DOT(CatchOpKeyword);
 381 char            { BEGIN(SC_charkeyword); RETURN(CharKeyword); }
 382 charstring      RETURN(CharStringKeyword);
 383 checkstate      RETURN_DOT(CheckStateKeyword);
 384 check           RETURN_DOT(CheckOpKeyword);
 385 clear           RETURN_DOT(ClearOpKeyword);
 386 complement      RETURN(ComplementKeyword);
 387 component       RETURN(ComponentKeyword);
 388 connect         RETURN(ConnectKeyword);
 389 const           RETURN(ConstKeyword);
 390 continue        RETURN(ContinueKeyword);
 391 control         RETURN(ControlKeyword);
 392 create          RETURN_DOT(CreateKeyword);
 393 deactivate      RETURN(DeactivateKeyword);
 394 default         RETURN(DefaultKeyword);
 395 derefers        RETURN(DerefersKeyword);
 396 disconnect      RETURN(DisconnectKeyword);
 397 display         RETURN(DisplayKeyword);
 398 do              RETURN(DoKeyword);
 399 done            RETURN_DOT(DoneKeyword);
 400 else            RETURN(ElseKeyword);
 401 encode          RETURN(EncodeKeyword);
 402 enumerated      RETURN(EnumKeyword);
 403 error           RETURN(ErrorKeyword);
 404 except          RETURN(ExceptKeyword);
 405 exception       RETURN(ExceptionKeyword);
 406 execute         RETURN(ExecuteKeyword);
 407 extends         RETURN(ExtendsKeyword);
 408 extension       RETURN(ExtensionKeyword);
 409 external        RETURN(ExtKeyword);
 410 fail            RETURN(FailKeyword);
 411 false           RETURN(FalseKeyword);
 412 float           RETURN(FloatKeyword);
 413 for             RETURN(ForKeyword);
 414 friend          RETURN(FriendKeyword);
 415 from            RETURN(FromKeyword);
 416 function        RETURN(FunctionKeyword);
 417 getcall         RETURN_DOT(GetCallOpKeyword);
 418 getreply        RETURN_DOT(GetReplyOpKeyword);
 419 getverdict      RETURN(GetVerdictKeyword);
 420 goto            RETURN(GotoKeyword);
 421 group           RETURN(GroupKeyword);
 422 halt            RETURN_DOT(HaltKeyword);
 423 hexstring       RETURN(HexStringKeyword);
 424 if              RETURN(IfKeyword);
 425 ifpresent       RETURN(IfPresentKeyword);
 426 import          RETURN(ImportKeyword);
 427 in              RETURN(InParKeyword);
 428 inconc          RETURN(InconcKeyword);
 429 infinity        RETURN(InfinityKeyword);
 430 inout           RETURN(InOutParKeyword);
 431 integer         RETURN(IntegerKeyword);
 432 interleave      RETURN(InterleavedKeyword);
 433 kill            RETURN_DOT(KillKeyword);
 434 killed          RETURN_DOT(KilledKeyword);
 435 label           RETURN(LabelKeyword);
 436 language        RETURN(LanguageKeyword);
 437 length          RETURN(LengthKeyword);
 438 log             RETURN(LogKeyword);
 439 map             RETURN(MapKeyword);
 440 match           RETURN(MatchKeyword);
 441 message         RETURN(MessageKeyword);
 442 mixed           RETURN(MixedKeyword);
 443 mod             RETURN(ModKeyword);
 444 modifies        RETURN(ModifiesKeyword);
 445 module          RETURN(TTCN3ModuleKeyword);
 446 modulepar       RETURN(ModuleParKeyword);
 447 mtc             RETURN(MTCKeyword);
 448 noblock         RETURN(NoBlockKeyword);
 449 none            RETURN(NoneKeyword);
 450 not             RETURN(NotKeyword);
 451 not_a_number  RETURN(NaNKeyword);
 452 not4b           RETURN(Not4bKeyword);
 453 nowait          RETURN(NowaitKeyword);
 454 null            RETURN(NullKeyword);
 455 objid           RETURN(ObjectIdentifierKeyword);
 456 octetstring     RETURN(OctetStringKeyword);
 457 of              RETURN(OfKeyword);
 458 omit            RETURN(OmitKeyword);
 459 on              RETURN(OnKeyword);
 460 optional        RETURN(OptionalKeyword);
 461 or              RETURN(OrKeyword);
 462 or4b            RETURN(Or4bKeyword);
 463 out             RETURN(OutParKeyword);
 464 override        RETURN(OverrideKeyword);
 465 param           RETURN(ParamKeyword);
 466 pass            RETURN(PassKeyword);
 467 pattern         RETURN(PatternKeyword);
 468 permutation     RETURN(PermutationKeyword);
 469 port            RETURN(PortKeyword);
 470 present         RETURN(PresentKeyword);
 471 private         RETURN(PrivateKeyword);
 472 procedure       RETURN(ProcedureKeyword);
 473 public          RETURN(PublicKeyword);
 474 raise           RETURN_DOT(RaiseKeyword);
 475 read            RETURN_DOT(ReadKeyword);
 476 receive         RETURN_DOT(ReceiveOpKeyword);
 477 record          RETURN(RecordKeyword);
 478 recursive       RETURN(RecursiveKeyword);
 479 refers          RETURN(RefersKeyword);
 480 rem             RETURN(RemKeyword);
 481 repeat          RETURN(RepeatKeyword);
 482 reply           RETURN_DOT(ReplyKeyword);
 483 return          RETURN(ReturnKeyword);
 484 running         RETURN_DOT(RunningKeyword);
 485 runs            RETURN(RunsKeyword);
 486 select          RETURN(SelectKeyword);
 487 self            RETURN(SelfKeyword);
 488 send            RETURN_DOT(SendOpKeyword);
 489 sender          RETURN(SenderKeyword);
 490 set             RETURN(SetKeyword);
 491 setverdict      RETURN(SetVerdictKeyword);
 492 signature       RETURN(SignatureKeyword);
 493 start           RETURN_DOT(StartKeyword);
 494 stop            RETURN_DOT(StopKeyword);
 495 subset          RETURN(SubsetKeyword);
 496 superset        RETURN(SupersetKeyword);
 497 system          RETURN(SystemKeyword);
 498 template        RETURN(TemplateKeyword);
 499 testcase        RETURN(TestcaseKeyword);
 500 timeout         RETURN_DOT(TimeoutKeyword);
 501 timer           RETURN(TimerKeyword);
 502 to              RETURN(ToKeyword);
 503 trigger         RETURN_DOT(TriggerOpKeyword);
 504 true            RETURN(TrueKeyword);
 505 type            RETURN(TypeDefKeyword);
 506 union           RETURN(UnionKeyword);
 507 universal       RETURN(UniversalKeyword);
 508 unmap           RETURN(UnmapKeyword);
 509 value           RETURN(ValueKeyword);
 510 valueof         RETURN(ValueofKeyword);
 511 var             RETURN(VarKeyword);
 512 variant         RETURN(VariantKeyword);
 513 verdicttype     RETURN(VerdictTypeKeyword);
 514 while           RETURN(WhileKeyword);
 515 with            RETURN(WithKeyword);
 516 xor             RETURN(XorKeyword);
 517 xor4b           RETURN(Xor4bKeyword);
 518
 519   /* modifier keywords */
 520
 521 "@nocase" RETURN(NocaseKeyword);
 522 "@lazy"   RETURN(LazyKeyword);
 523
 524   /* special TITAN specific keywords */
 525
 526 "@try"    RETURN(TitanSpecificTryKeyword);
 527 "@catch"  RETURN(TitanSpecificCatchKeyword);
 528 "@profiler" RETURN(TitanSpecificProfilerKeyword);
 529
 530
 531         /* Predefined function identifiers */
 532
 533 bit2hex         RETURN(bit2hexKeyword);
 534 bit2int         RETURN(bit2intKeyword);
 535 bit2oct         RETURN(bit2octKeyword);
 536 bit2str         RETURN(bit2strKeyword);
 537 char2int        RETURN(char2intKeyword);
 538 char2oct        RETURN(char2octKeyword);
 539 decomp          RETURN(decompKeyword);
 540 float2int       RETURN(float2intKeyword);
 541 float2str       RETURN(float2strKeyword);
 542 hex2bit         RETURN(hex2bitKeyword);
 543 hex2int         RETURN(hex2intKeyword);
 544 hex2oct         RETURN(hex2octKeyword);
 545 hex2str         RETURN(hex2strKeyword);
 546 int2bit         RETURN(int2bitKeyword);
 547 int2char        RETURN(int2charKeyword);
 548 int2enum  RETURN(int2enumKeyword);
 549 int2float       RETURN(int2floatKeyword);
 550 int2hex         RETURN(int2hexKeyword);
 551 int2oct         RETURN(int2octKeyword);
 552 int2str         RETURN(int2strKeyword);
 553 int2unichar     RETURN(int2unicharKeyword);
 554 isvalue         RETURN(isvalueKeyword);
 555 isbound         RETURN(isboundKeyword);
 556 ischosen        RETURN(ischosenKeyword);
 557 ispresent       RETURN(ispresentKeyword);
 558 lengthof        RETURN(lengthofKeyword);
 559 oct2bit         RETURN(oct2bitKeyword);
 560 oct2char        RETURN(oct2charKeyword);
 561 oct2hex         RETURN(oct2hexKeyword);
 562 oct2int         RETURN(oct2intKeyword);
 563 oct2str         RETURN(oct2strKeyword);
 564 regexp          RETURN(regexpKeyword);
 565 replace         RETURN(replaceKeyword);
 566 rnd                     RETURN(rndKeyword);
 567 sizeof          RETURN(sizeofKeyword);
 568 str2bit         RETURN(str2bitKeyword);
 569 str2float       RETURN(str2floatKeyword);
 570 str2hex         RETURN(str2hexKeyword);
 571 str2int         RETURN(str2intKeyword);
 572 str2oct         RETURN(str2octKeyword);
 573 substr          RETURN(substrKeyword);
 574 unichar2int     RETURN(unichar2intKeyword);
 575 unichar2char    RETURN(unichar2charKeyword);
 576 log2str         RETURN(log2strKeyword);
 577 enum2int        RETURN(enum2intKeyword);
 578 encvalue        RETURN(encvalueKeyword);
 579 decvalue        RETURN(decvalueKeyword);
 580 testcasename    RETURN(testcasenameKeyword);
 581 ttcn2string RETURN(ttcn2stringKeyword);
 582 string2ttcn RETURN(string2ttcnKeyword);
 583 unichar2oct     RETURN(unichar2octKeyword);
 584 oct2unichar     RETURN(oct2unicharKeyword);
 585 remove_bom      RETURN(remove_bomKeyWord);
 586 get_stringencoding      RETURN(get_stringencodingKeyWord);
 587 encode_base64   RETURN(encode_base64KeyWord);
 588 decode_base64   RETURN(decode_base64KeyWord);
 589 encvalue_unichar RETURN(encvalue_unicharKeyWord);
 590 decvalue_unichar RETURN(decvalue_unicharKeyWord);
 591 any2unistr      RETURN(any2unistrKeyWord);
 592
 593         /* Values */
 594
 595 {NUMBER} {
 596   Location loc(infile, current_line, current_column, current_line,
 597     current_column + yyleng);
 598   yylval.int_val = new int_val_t(yytext, loc);
 599   RETURN_LVAL(Number);
 600 }
 601
 602 {FLOAT} {
 603   Location loc(infile, current_line, current_column, current_line,
 604     current_column + yyleng);
 605   yylval.float_val = string2Real(yytext, loc);
 606   RETURN_LVAL(FloatValue);
 607 }
 608
 609 NULL RETURN(NullValue);
 610
 611 "'" {
 612   binstr=memptystr();
 613   valid_bit=true;
 614   valid_oct=true;
 615   half_oct=false;
 616   contains_match=false;
 617   contains_ws=false;
 618   start_line = current_line;
 619   start_column = current_column;
 620   current_column++;
 621   MD5_Update(&md5_ctx, yytext, yyleng);
 622   BEGIN(SC_binstring);
 623 }
 624
 625 \" {
 626   yylval.str = memptystr();
 627   start_line = current_line;
 628   start_column = current_column;
 629   current_column++;
 630   MD5_Update(&md5_ctx, yytext, yyleng);
 631   BEGIN(SC_cstring);
 632 }
 633
 634 <SC_charkeyword>
 635 {
 636   {UID} {
 637     yylval.str = mcopystrn(yytext, yyleng);
 638     RETURN_LVAL(Cstring);
 639   }
 640
 641   [,] { RETURN(*yytext); }
 642
 643   [)] { BEGIN(INITIAL); RETURN(*yytext); }
 644 }
 645
 646 <SC_binstring> /* -------- SC_binstring scope -------------- */
 647 {
 648
 649   {WHITESPACE}+ {
 650     contains_ws = true;
 651     current_column += yyleng;
 652   }
 653
 654   {WHITESPACE}*{NEWLINE} {
 655     contains_ws = true;
 656     current_line++;
 657     current_column = 0;
 658   }
 659
 660   [01] {
 661     binstr = mputc(binstr, yytext[0]);
 662     half_oct = !half_oct;
 663     current_column++;
 664   }
 665
 666   [2-9A-F] {
 667     binstr = mputc(binstr, yytext[0]);
 668     valid_bit = false;
 669     half_oct = !half_oct;
 670     current_column++;
 671   }
 672
 673   [a-f] {
 674     binstr = mputc(binstr, yytext[0] - 'a' + 'A');
 675     valid_bit = false;
 676     half_oct = !half_oct;
 677     current_column++;
 678   }
 679
 680   "?"|"*" {
 681     binstr = mputc(binstr, yytext[0]);
 682     contains_match = true;
 683     if (half_oct) valid_oct = false;
 684     current_column++;
 685   }
 686
 687   "'"[bBhHoO] {
 688     yylloc.first_line = start_line;
 689     yylloc.first_column = start_column;
 690     yylloc.last_line = current_line;
 691     yylloc.last_column = current_column + 2;
 692     Location loc(infile, yylloc);
 693     int ret_val = TOK_errval;
 694     switch (yytext[1]) {
 695     case 'b': {
 696       Location loc2(infile, current_line, current_column + 1, current_line,
 697         current_column + 2);
 698       loc2.warning("The last character of a bitstring literal should be "
 699         "`B' instead of `b'");
 700       /* no break */ }
 701     case 'B':
 702       if (valid_bit) {
 703         if (contains_ws) loc.warning("Bitstring %s contains whitespace and/or "
 704           "newline character(s)", contains_match ? "match" : "value");
 705         ret_val = contains_match ? BitStringMatch : Bstring;
 706         yylval.string_val = new string(binstr);
 707       } else loc.error("Bitstring value contains invalid character");
 708       break;
 709     case 'h': {
 710       Location loc2(infile, current_line, current_column + 1, current_line,
 711         current_column + 2);
 712       loc2.warning("The last character of a hexstring literal should be "
 713         "`H' instead of `h'");
 714       /* no break */ }
 715     case 'H':
 716       if (contains_ws) loc.warning("Hexstring %s contains whitespace and/or "
 717         "newline character(s)", contains_match ? "match" : "value");
 718       ret_val = contains_match ? HexStringMatch : Hstring;
 719       yylval.string_val = new string(binstr);
 720       break;
 721     case 'o': {
 722       Location loc2(infile, current_line, current_column + 1, current_line,
 723         current_column + 2);
 724       loc2.warning("The last character of an octetstring literal should be "
 725         "`O' instead of `o'");
 726       /* no break */ }
 727     case 'O':
 728       if (valid_oct && !half_oct) {
 729         if (contains_ws) loc.warning("Octetstring %s contains whitespace "
 730           "and/or newline character(s)", contains_match ? "match" : "value");
 731         ret_val = contains_match ? OctetStringMatch : Ostring;
 732         yylval.string_val = new string(binstr);
 733       } else if (contains_match) {
 734         loc.error("Octetstring match contains half octet(s)");
 735       } else {
 736         loc.error("Octetstring value contains odd number of hexadecimal "
 737           "digits");
 738       }
 739     }
 740     MD5_Update(&md5_ctx, binstr, strlen(binstr));
 741     Free(binstr);
 742     update_md5();
 743     BEGIN(INITIAL);
 744     current_column += 2;
 745     if (dot_flag) {
 746       backup_token = ret_val;
 747       backup_lval = yylval;
 748       backup_lloc = yylloc;
 749       RETURN_SAVED_DOT;
 750     } else return ret_val;
 751   }
 752
 753   "'" {
 754     yylloc.first_line = start_line;
 755     yylloc.first_column = start_column;
 756     current_column++;
 757     yylloc.last_line = current_line;
 758     yylloc.last_column = current_column;
 759     Location loc(infile, yylloc);
 760     loc.error("Invalid binary string literal. Expecting `B', `H' or `O' after "
 761       "the closing `''");
 762     MD5_Update(&md5_ctx, binstr, strlen(binstr));
 763     Free(binstr);
 764     BEGIN(INITIAL);
 765     RETURN_NOLOCUPD(TOK_errval);
 766   }
 767
 768   . {
 769     Location loc(infile, current_line, current_column, current_line,
 770       current_column + 1);
 771     int c = (unsigned char)yytext[0];
 772     loc.error("Invalid character `%c' (0x%02X) in binary string",
 773       isprint(c) ? c : '?', c);
 774     MD5_Update(&md5_ctx, binstr, strlen(binstr));
 775     Free(binstr);
 776     MD5_Update(&md5_ctx, yytext, 1);
 777     current_column++;
 778     BEGIN(SC_binstring_bad);
 779   }
 780
 781 } /* SC_binstring scope */
 782
 783 <SC_binstring_bad> /* -------- SC_binstring_bad scope -------------- */
 784 {
 785
 786   {WHITESPACE}+ current_column += yyleng;
 787
 788   {WHITESPACE}*{NEWLINE} {
 789     current_line++;
 790     current_column = 0;
 791   }
 792
 793   "'"[bBhHoO]? {
 794     current_column += yyleng;
 795     yylloc.first_line = start_line;
 796     yylloc.first_column = start_column;
 797     yylloc.last_line = current_line;
 798     yylloc.last_column = current_column;
 799     BEGIN(INITIAL);
 800     RETURN_NOLOCUPD(TOK_errval);
 801   }
 802
 803   . {
 804     MD5_Update(&md5_ctx, yytext, yyleng);
 805     current_column++;
 806   }
 807
 808 } /* SC_binstring_bad scope */
 809
 810 <SC_cstring> /* -------- SC_cstring scope -------------- */
 811 {
 812
 813   \\?{NEWLINE} { /* newline possibly preceded by backslash */
 814     yylval.str = mputstr(yylval.str, yytext);
 815     current_line++;
 816     current_column = 0;
 817   }
 818
 819   \"\"|\\. { /* two doublequotes or any backslash-escaped char */
 820     yylval.str = mputstr(yylval.str, yytext);
 821     current_column += 2;
 822     /* Note that both get added ("external representation").
 823      * parse_charstring_value() in charstring_la.l is responsible
 824      * for transforming the string to "internal representation" */
 825   }
 826
 827   \" {
 828     current_column++;
 829     yylloc.first_line = start_line;
 830     yylloc.first_column = start_column;
 831     yylloc.last_line = current_line;
 832     yylloc.last_column = current_column;
 833     MD5_Update(&md5_ctx, yylval.str, strlen(yylval.str));
 834     update_md5();
 835     BEGIN(INITIAL);
 836     if (dot_flag) {
 837       backup_token = Cstring;
 838       backup_lval = yylval;
 839       backup_lloc = yylloc;
 840       RETURN_SAVED_DOT;
 841     } else return Cstring;
 842   }
 843
 844   . {
 845     yylval.str = mputc(yylval.str, yytext[0]);
 846     current_column++;
 847   }
 848
 849 } /* SC_cstring scope */
 850
 851         /* Macros */
 852
 853 "%moduleId" {
 854   yylval.macrotype = Value::MACRO_MODULEID;
 855   RETURN_LVAL(MacroValue);
 856 }
 857 "%fileName" {
 858   yylval.macrotype = Value::MACRO_FILENAME;
 859   RETURN_LVAL(MacroValue);
 860 }
 861 "%lineNumber" {
 862   yylval.macrotype = Value::MACRO_LINENUMBER;
 863   RETURN_LVAL(MacroValue);
 864 }
 865 "%definitionId" {
 866   yylval.macrotype = Value::MACRO_DEFINITIONID;
 867   RETURN_LVAL(MacroValue);
 868 }
 869 "%testcaseId" {
 870   yylval.macrotype = Value::MACRO_TESTCASEID;
 871   RETURN_LVAL(MacroValue);
 872 }
 873 "%"{IDENTIFIER} {
 874   fill_location();
 875   Location loc(infile, yylloc);
 876   loc.error("Invalid macro notation: `%s'", yytext);
 877   RETURN_NOLOCUPD(TOK_errval);
 878 }
 879
 880 "__MODULE__" {
 881   yylval.macrotype = Value::MACRO_MODULEID;
 882   RETURN_LVAL(MacroValue);
 883 }
 884 "__FILE__" {
 885   yylval.macrotype = Value::MACRO_FILEPATH;
 886   RETURN_LVAL(MacroValue);
 887 }
 888 "__BFILE__" {
 889   yylval.macrotype = Value::MACRO_BFILENAME;
 890   RETURN_LVAL(MacroValue);
 891 }
 892 "__LINE__" {
 893   yylval.macrotype = Value::MACRO_LINENUMBER_C;
 894   RETURN_LVAL(MacroValue);
 895 }
 896 "__SCOPE__" {
 897   yylval.macrotype = Value::MACRO_SCOPE;
 898   RETURN_LVAL(MacroValue);
 899 }
 900 "__TESTCASE__" {
 901   yylval.macrotype = Value::MACRO_TESTCASEID;
 902   RETURN_LVAL(MacroValue);
 903 }
 904 "__"{IDENTIFIER}"__" {
 905   fill_location();
 906   Location loc(infile, yylloc);
 907   loc.error("Invalid macro notation: `%s'", yytext);
 908   RETURN_NOLOCUPD(TOK_errval);
 909 }
 910
 911         /* Multi-character operators */
 912
 913 ":="            RETURN(AssignmentChar);
 914 "\.\."          RETURN(DotDot);
 915 "->"            RETURN(PortRedirectSymbol);
 916 "=="            RETURN(EQ);
 917 "!="            RETURN(NE);
 918 ">="            RETURN(GE);
 919 "<="            RETURN(LE);
 920 "<<"            RETURN(SL);
 921 ">>"            RETURN(SR);
 922 "<@"            RETURN(RL);
 923 "@>"            RETURN(_RR);
 924
 925 "++" |
 926 "--" {
 927   fill_location();
 928   Location loc(infile, yylloc);
 929   loc.error("Operator `%s' is reserved for future use", yytext);
 930 }
 931
 932         /* Invalid operators */
 933
 934 "::=" {
 935   fill_location();
 936   Location loc(infile, yylloc);
 937   loc.error("`::=' is not a valid assignment operator in TTCN-3. Did you mean "
 938     "`:='?");
 939   RETURN_NOLOCUPD(AssignmentChar);
 940 }
 941
 942 "=" {
 943   fill_location();
 944   Location loc(infile, yylloc);
 945   loc.error("A single `=' character cannot be used in TTCN-3. Did you mean "
 946     "the assignment sign `:=' or the equality operator `=='?");
 947   /* the former is more probable than the latter */
 948   RETURN_NOLOCUPD(AssignmentChar);
 949 }
 950
 951 "<>" {
 952   fill_location();
 953   Location loc(infile, yylloc);
 954   loc.error("`<>' is not a valid comparison operator in TTCN-3. Did you mean "
 955     "`!='?");
 956   RETURN_NOLOCUPD(NE);
 957 }
 958
 959         /* Identifiers */
 960
 961 {IDENTIFIER} {
 962   yylval.id = new Identifier(Identifier::ID_TTCN, string(yyleng, yytext));
 963   RETURN_LVAL(IDentifier);
 964 }
 965
 966         /* Single character tokens (brackets, operators, etc.) */
 967
 968 \. {
 969   update_md5();
 970   if (dot_flag) {
 971     /* store this dot in the backup */
 972     backup_token = '.';
 973     backup_lloc.first_line = current_line;
 974     backup_lloc.first_column = current_column;
 975     current_column++;
 976     backup_lloc.last_line = current_line;
 977     backup_lloc.last_column = current_column;
 978     /* return the dot that was found previously */
 979     RETURN_SAVED_DOT;
 980   } else {
 981     dot_flag = true;
 982     dot_line = current_line;
 983     dot_column = current_column;
 984     current_column++;
 985   }
 986 }
 987
 988 [()\[\]{}+\-\*/&:;,<>\?!]  RETURN(*yytext);
 989
 990         /* Invalid characters */
 991
 992 . {
 993   fill_location();
 994   Location loc(infile, yylloc);
 995   int c = (unsigned char)yytext[0];
 996   loc.error("Character `%c' (0x%02X) is not used in TTCN-3",
 997     isprint(c) ? c : '?', c);
 998 }
 999
1000         /* EOF rule */
1001
1002 <*><<EOF>> {
1003   if (YY_START != INITIAL) {
1004     Location loc(infile, start_line, start_column, current_line,
1005       current_column);
1006     switch (YY_START) {
1007     case SC_blockcomment:
1008       loc.error("Unterminated block comment");
1009       break;
1010     case SC_binstring:
1011       Free(binstr);
1012       /* no break */
1013     case SC_binstring_bad:
1014       loc.error("Unterminated binary string literal");
1015       break;
1016     case SC_cstring:
1017       Free(yylval.str);
1018       loc.error("Unterminated character string literal");
1019     }
1020     BEGIN(INITIAL);
1021   }
1022   if (dot_flag) {
1023     dot_flag = false;
1024     RETURN_SAVED_DOT;
1025   } else {
1026     yylloc.first_line = current_line;
1027     yylloc.first_column = current_column;
1028     yylloc.last_line = current_line;
1029     yylloc.last_column = current_column + 1;
1030     return EOF;
1031   }
1032 }
1033
1034 %%
1035
1036 void init_ttcn3_lex()
1037 {
1038   dot_flag = false;
1039   current_line = 1;
1040   current_column = 0;
1041   real_infile = infile;
1042   real_lineno_offset = 0;
1043   MD5_Init(&md5_ctx);
1044 }
1045
1046 void init_erroneous_lex(const char* p_infile, int p_line, int p_column)
1047 {
1048   infile = p_infile;
1049   current_line = p_line;
1050   current_column = p_column;
1051   real_infile = infile;
1052   real_lineno_offset = 0;
1053   dot_flag = false;
1054 }
1055
1056 void free_dot_flag_stuff()
1057 {
1058   if (dot_flag) {
1059     dot_flag = false;
1060     /* clean up the semantic value of the token that was backed up */
1061     switch (backup_token) {
1062     case IDentifier:
1063       delete backup_lval.id;
1064       break;
1065     case Bstring:
1066     case Hstring:
1067     case Ostring:
1068     case BitStringMatch:
1069     case HexStringMatch:
1070     case OctetStringMatch:
1071       delete backup_lval.string_val;
1072       break;
1073     case Cstring:
1074       Free(backup_lval.str);
1075     default:
1076       break;
1077     }
1078   }
1079 }
1080
1081 void free_ttcn3_lex()
1082 {
1083   free_dot_flag_stuff();
1084   fclose(ttcn3_in);
1085   ttcn3_lex_destroy();
1086 }
1087
1088 /* called from ttcn3_parse_file to finalize MD5 and add it to the module */
1089 void set_md5_checksum(Ttcn::Module *m)
1090 {
1091   unsigned char md5_sum[MD5_DIGEST_LENGTH];
1092   MD5_Final(md5_sum, &md5_ctx);
1093   m->set_checksum(sizeof(md5_sum), md5_sum);
1094 }