configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 ### we might need to use some other shell than /bin/sh for running subshells
  93 ### If we are on Windows, search for the shell.  This will permit people
  94 ### to not have /bin/sh, but to be able to see /SOME/PATH/sh configure
  95 ### without also having to set CONFIG_SHELL.  This code will work when
  96 ### using bash, which sets OSTYPE.
  97 case "${OSTYPE}" in
  98 *win32*)
  99   if test x${CONFIG_SHELL} = x ; then
 100     if test ! -f /bin/sh ; then
 101       if test x${SHELL} != x && test -f ${SHELL} ; then
 102         CONFIG_SHELL=${SHELL}
 103         export CONFIG_SHELL
 104       else
 105         for prog in sh sh.exe bash bash.exe; do
 106           IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
 107           for dir in $PATH; do
 108             test -z "$dir" && dir=.
 109             if test -f $dir/$prog; then
 110               CONFIG_SHELL=$dir/$prog
 111               export CONFIG_SHELL
 112               break
 113             fi
 114           done
 115           IFS="$save_ifs"
 116           test -n "${CONFIG_SHELL}" && break
 117         done
 118       fi
 119     fi
 120   fi
 121   ;;
 122 esac
 123
 124 config_shell=${CONFIG_SHELL-/bin/sh}
 125
 126 moveifchange=${srcdir}/move-if-change
 127
 128 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
 129
 130 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
 131 # a relative path.
 132 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 133   INSTALL="${srcpwd}/install-sh -c"
 134 fi
 135
 136 # Set srcdir to "." if that's what it is.
 137 # This is important for multilib support.
 138 pwd=`${PWDCMD-pwd}`
 139 if test "${pwd}" = "${srcpwd}" ; then
 140   srcdir=.
 141 fi
 142
 143 topsrcdir=$srcpwd
 144
 145 extra_host_args=
 146
 147 ### To add a new directory to the tree, first choose whether it is a target
 148 ### or a host dependent tool.  Then put it into the appropriate list
 149 ### (library or tools, host or target), doing a dependency sort.
 150
 151 # Subdirs will be configured in the order listed in build_configdirs,
 152 # configdirs, or target_configdirs; see the serialization section below.
 153
 154 # Dependency sorting is only needed when *configuration* must be done in
 155 # a particular order.  In all cases a dependency should be specified in
 156 # the Makefile, whether or not it's implicitly specified here.
 157
 158 # Double entries in build_configdirs, configdirs, or target_configdirs may
 159 # cause circular dependencies and break everything horribly.
 160
 161 # these library is used by various programs built for the build
 162 # environment
 163 #
 164 build_libs="build-libiberty"
 165
 166 # these tools are built for the build environment
 167 build_tools="build-texinfo build-byacc build-flex build-bison build-m4 build-fixincludes"
 168
 169 # these libraries are used by various programs built for the host environment
 170 #
 171 host_libs="intl mmalloc libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 172
 173 # these tools are built for the host environment
 174 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 175 # know that we are building the simulator.
 176 # binutils, gas and ld appear in that order because it makes sense to run
 177 # "make check" in that particular order.
 178 # If --enable-gold is used, "gold" may replace "ld".
 179 host_tools="texinfo byacc flex bison binutils gas ld fixincludes gcc cgen sid sim gdb make patch prms send-pr gprof etc expect dejagnu ash bash bzip2 m4 autoconf automake libtool diff rcs fileutils shellutils time textutils wdiff find uudecode hello tar gzip indent recode release sed utils guile perl gawk findutils gettext zip fastjar gnattools"
 180
 181 # libgcj represents the runtime libraries only used by gcj.
 182 libgcj="target-libffi \
 183         target-zlib \
 184         target-qthreads \
 185         target-libjava"
 186
 187 # these libraries are built for the target environment, and are built after
 188 # the host libraries and the host tools (which may be a cross compiler)
 189 #
 190 target_libraries="target-libgcc \
 191                 target-libiberty \
 192                 target-libgloss \
 193                 target-newlib \
 194                 target-libgomp \
 195                 target-libstdc++-v3 \
 196                 target-libmudflap \
 197                 target-libssp \
 198                 target-libquadmath \
 199                 target-libgfortran \
 200                 target-boehm-gc \
 201                 ${libgcj} \
 202                 target-libobjc \
 203                 target-libada \
 204                 target-libgo"
 205
 206 # these tools are built using the target libraries, and are intended to
 207 # run only in the target environment
 208 #
 209 # note: any program that *uses* libraries that are in the "target_libraries"
 210 # list belongs in this list.  those programs are also very likely
 211 # candidates for the "native_only" list which follows
 212 #
 213 target_tools="target-examples target-groff target-gperf target-rda"
 214
 215 ################################################################################
 216
 217 ## All tools belong in one of the four categories, and are assigned above
 218 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 219 ## is important because configure will choke if they ever get through.
 220 ## ${configdirs} is directories we build using the host tools.
 221 ## ${target_configdirs} is directories we build using the target tools.
 222 configdirs=`echo ${host_libs} ${host_tools}`
 223 target_configdirs=`echo ${target_libraries} ${target_tools}`
 224 build_configdirs=`echo ${build_libs} ${build_tools}`
 225
 226 m4_divert_text([PARSE_ARGS],
 227 [case $srcdir in
 228   *" "*)
 229 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 230     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 231 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 232     ;;
 233 esac
 234 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 235 ])
 236
 237 ################################################################################
 238
 239 srcname="gnu development package"
 240
 241 # This gets set non-empty for some net releases of packages.
 242 appdirs=""
 243
 244 # Define is_cross_compiler to save on calls to 'test'.
 245 is_cross_compiler=
 246 if test x"${host}" = x"${target}" ; then
 247   is_cross_compiler=no
 248 else
 249   is_cross_compiler=yes
 250 fi
 251
 252 # Find the build and target subdir names.
 253 GCC_TOPLEV_SUBDIRS
 254 # Be sure to cover against remnants of an in-tree build.
 255 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 256   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 257 Use a pristine source tree when building in a separate tree])
 258 fi
 259
 260 # Skipdirs are removed silently.
 261 skipdirs=
 262 # Noconfigdirs are removed loudly.
 263 noconfigdirs=""
 264
 265 use_gnu_ld=
 266 # Make sure we don't let GNU ld be added if we didn't want it.
 267 if test x$with_gnu_ld = xno ; then
 268   use_gnu_ld=no
 269   noconfigdirs="$noconfigdirs ld gold"
 270 fi
 271
 272 use_gnu_as=
 273 # Make sure we don't let GNU as be added if we didn't want it.
 274 if test x$with_gnu_as = xno ; then
 275   use_gnu_as=no
 276   noconfigdirs="$noconfigdirs gas"
 277 fi
 278
 279 use_included_zlib=
 280 # Make sure we don't let ZLIB be added if we didn't want it.
 281 if test x$with_system_zlib = xyes ; then
 282   use_included_zlib=no
 283   noconfigdirs="$noconfigdirs zlib"
 284 fi
 285
 286 # some tools are so dependent upon X11 that if we're not building with X,
 287 # it's not even worth trying to configure, much less build, that tool.
 288
 289 case ${with_x} in
 290   yes | "") ;; # the default value for this tree is that X11 is available
 291   no)
 292     skipdirs="${skipdirs} tk itcl libgui"
 293     # We won't be able to build gdbtk without X.
 294     enable_gdbtk=no
 295     ;;
 296   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 297 esac
 298
 299 # Some tools are only suitable for building in a "native" situation.
 300 # Remove these if host!=target.
 301 native_only="autoconf automake libtool fileutils find gawk gettext gzip hello indent m4 rcs recode sed shellutils tar textutils uudecode wdiff target-groff guile perl time ash bash bzip2 prms gnuserv target-gperf"
 302
 303 # Similarly, some are only suitable for cross toolchains.
 304 # Remove these if host=target.
 305 cross_only="target-libgloss target-newlib target-opcodes"
 306
 307 case $is_cross_compiler in
 308   no) skipdirs="${skipdirs} ${cross_only}" ;;
 309   yes) skipdirs="${skipdirs} ${native_only}" ;;
 310 esac
 311
 312 # If both --with-headers and --with-libs are specified, default to
 313 # --without-newlib.
 314 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 315    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 316   if test x"${with_newlib}" = x ; then
 317     with_newlib=no
 318   fi
 319 fi
 320
 321 # Recognize --with-newlib/--without-newlib.
 322 case ${with_newlib} in
 323   no) skipdirs="${skipdirs} target-newlib" ;;
 324   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 325 esac
 326
 327 # Handle --enable-gold, --enable-ld.
 328 # --disable-gold [--enable-ld]
 329 #     Build only ld.  Default option.
 330 # --enable-gold [--enable-ld]
 331 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 332 #     as "ld.bfd" and "ld".
 333 # --enable-gold=default [--enable-ld]
 334 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 335 #     install ld as "ld.bfd".
 336 # --enable-gold[=default] --disable-ld
 337 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 338 # --enable-gold --enable-ld=default
 339 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 340 #     and ld.bfd).
 341 #     In other words, ld is default
 342 # --enable-gold=default --enable-ld=default
 343 #     Error.
 344
 345 default_ld=
 346 AC_ARG_ENABLE(gold,
 347 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 348                 [build gold @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_GOLD=$enableval,
 350 ENABLE_GOLD=no)
 351 case "${ENABLE_GOLD}" in
 352   yes|default)
 353     # Check for ELF target.
 354     is_elf=no
 355     case "${target}" in
 356       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 357       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 358       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-solaris2* | *-*-nto*)
 359         case "${target}" in
 360           *-*-linux*aout* | *-*-linux*oldld*)
 361             ;;
 362           *)
 363             is_elf=yes
 364             ;;
 365         esac
 366     esac
 367
 368     if test "$is_elf" = "yes"; then
 369       # Check for target supported by gold.
 370       case "${target}" in
 371         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 372           configdirs="$configdirs gold"
 373           if test x${ENABLE_GOLD} = xdefault; then
 374             default_ld=gold
 375           fi
 376           ENABLE_GOLD=yes
 377           ;;
 378       esac
 379     fi
 380     ;;
 381   no)
 382     ;;
 383   *)
 384     AC_MSG_ERROR([invalid --enable-gold argument])
 385     ;;
 386 esac
 387
 388 AC_ARG_ENABLE(ld,
 389 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 390                 [build ld @<:@ARG={default,yes,no}@:>@])],
 391 ENABLE_LD=$enableval,
 392 ENABLE_LD=yes)
 393
 394 case "${ENABLE_LD}" in
 395   default)
 396     if test x${default_ld} != x; then
 397       AC_MSG_ERROR([either gold or ld can be the default ld])
 398     fi
 399     ;;
 400   yes)
 401     ;;
 402   no)
 403     if test x${ENABLE_GOLD} != xyes; then
 404       AC_MSG_WARN([neither ld nor gold are enabled])
 405     fi
 406     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 407     ;;
 408   *)
 409     AC_MSG_ERROR([invalid --enable-ld argument])
 410     ;;
 411 esac
 412
 413 # Configure extra directories which are host specific
 414
 415 case "${host}" in
 416   *-cygwin*)
 417     configdirs="$configdirs libtermcap" ;;
 418 esac
 419
 420 # A target can indicate whether a language isn't supported for some reason.
 421 # Only spaces may be used in this macro; not newlines or tabs.
 422 unsupported_languages=
 423
 424 # Remove more programs from consideration, based on the host or
 425 # target this usually means that a port of the program doesn't
 426 # exist yet.
 427
 428 case "${host}" in
 429   hppa*64*-*-*)
 430     noconfigdirs="$noconfigdirs byacc"
 431     ;;
 432   i[[3456789]]86-*-vsta)
 433     noconfigdirs="$noconfigdirs tcl expect dejagnu make texinfo bison patch flex byacc send-pr gprof uudecode dejagnu diff guile perl itcl gnuserv gettext"
 434     ;;
 435   i[[3456789]]86-*-go32* | i[[3456789]]86-*-msdosdjgpp*)
 436     noconfigdirs="$noconfigdirs tcl tk expect dejagnu send-pr uudecode guile itcl gnuserv libffi"
 437     ;;
 438   x86_64-*-mingw*)
 439     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 440     ;;
 441   i[[3456789]]86-*-mingw32*)
 442     # noconfigdirs="tcl tk expect dejagnu make texinfo bison patch flex byacc send-pr uudecode dejagnu diff guile perl itcl gnuserv"
 443     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 444     ;;
 445   i[[3456789]]86-*-beos*)
 446     noconfigdirs="$noconfigdirs tk itcl libgui gdb"
 447     ;;
 448   *-*-cygwin*)
 449     noconfigdirs="$noconfigdirs autoconf automake send-pr rcs guile perl"
 450     ;;
 451   *-*-netbsd*)
 452     noconfigdirs="$noconfigdirs rcs"
 453     ;;
 454   ppc*-*-pe)
 455     noconfigdirs="$noconfigdirs patch diff make tk tcl expect dejagnu autoconf automake texinfo bison send-pr gprof rcs guile perl itcl gnuserv"
 456     ;;
 457   powerpc-*-beos*)
 458     noconfigdirs="$noconfigdirs tk itcl libgui gdb dejagnu readline"
 459     ;;
 460 esac
 461
 462
 463 AC_ARG_ENABLE(libquadmath,
 464 AS_HELP_STRING([--disable-libquadmath],
 465   [do not build libquadmath directory]),
 466 ENABLE_LIBQUADMATH=$enableval,
 467 ENABLE_LIBQUADMATH=yes)
 468 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 469   noconfigdirs="$noconfigdirs target-libquadmath"
 470 fi
 471
 472
 473 AC_ARG_ENABLE(libquadmath-support,
 474 AS_HELP_STRING([--disable-libquadmath-support],
 475   [disable libquadmath support for Fortran]),
 476 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 477 ENABLE_LIBQUADMATH_SUPPORT=yes)
 478 enable_libquadmath_support=
 479 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 480   enable_libquadmath_support=no
 481 fi
 482
 483
 484 AC_ARG_ENABLE(libada,
 485 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 486 ENABLE_LIBADA=$enableval,
 487 ENABLE_LIBADA=yes)
 488 if test "${ENABLE_LIBADA}" != "yes" ; then
 489   noconfigdirs="$noconfigdirs gnattools"
 490 fi
 491
 492 AC_ARG_ENABLE(libssp,
 493 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 494 ENABLE_LIBSSP=$enableval,
 495 ENABLE_LIBSSP=yes)
 496
 497 # Save it here so that, even in case of --enable-libgcj, if the Java
 498 # front-end isn't enabled, we still get libgcj disabled.
 499 libgcj_saved=$libgcj
 500 case $enable_libgcj in
 501 yes)
 502   # If we reset it here, it won't get added to noconfigdirs in the
 503   # target-specific build rules, so it will be forcibly enabled
 504   # (unless the Java language itself isn't enabled).
 505   libgcj=
 506   ;;
 507 no)
 508   # Make sure we get it printed in the list of not supported target libs.
 509   # Don't disable libffi, though, other languages use it.
 510   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 511   # Clear libgcj_saved so that even if java is enabled libffi won't be
 512   # built.
 513   libgcj_saved=
 514   ;;
 515 esac
 516
 517
 518 # Disable libmudflap on some systems.
 519 if test x$enable_libmudflap = x ; then
 520     case "${target}" in
 521     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 522         # Enable libmudflap by default in GNU and friends.
 523         ;;
 524     *-*-freebsd*)
 525         # Enable libmudflap by default in FreeBSD.
 526         ;;
 527     *)
 528         # Disable it by default everywhere else.
 529         noconfigdirs="$noconfigdirs target-libmudflap"
 530         ;;
 531     esac
 532 fi
 533
 534 # Disable libgomp on non POSIX hosted systems.
 535 if test x$enable_libgomp = x ; then
 536     # Enable libgomp by default on hosted POSIX systems.
 537     case "${target}" in
 538     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 539         ;;
 540     *-*-netbsd* | *-*-freebsd* | *-*-openbsd*)
 541         ;;
 542     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 543         ;;
 544     *-*-darwin* | *-*-aix*)
 545         ;;
 546     *)
 547         noconfigdirs="$noconfigdirs target-libgomp"
 548         ;;
 549     esac
 550 fi
 551
 552 # Default libgloss CPU subdirectory.
 553 libgloss_dir="$target_cpu"
 554
 555 case "${target}" in
 556   *-*-chorusos)
 557     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 558     ;;
 559   powerpc-*-darwin*)
 560     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 561     noconfigdirs="$noconfigdirs sim target-rda"
 562     ;;
 563   i[[3456789]]86-*-darwin*)
 564     noconfigdirs="$noconfigdirs ld gprof"
 565     noconfigdirs="$noconfigdirs sim target-rda"
 566     ;;
 567   x86_64-*-darwin[[912]]*)
 568     noconfigdirs="$noconfigdirs ld gas gprof"
 569     noconfigdirs="$noconfigdirs sim target-rda"
 570     ;;
 571   *-*-darwin*)
 572     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 573     noconfigdirs="$noconfigdirs sim target-rda"
 574     noconfigdirs="$noconfigdirs ${libgcj}"
 575     ;;
 576   *-*-freebsd[[12]] | *-*-freebsd[[12]].* | *-*-freebsd*aout*)
 577     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 578     ;;
 579   *-*-freebsd*)
 580     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 581     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 582         && test -f /usr/local/include/gmp.h; then
 583       with_gmp=/usr/local
 584     fi
 585
 586     # Skip some stuff that's unsupported on some FreeBSD configurations.
 587     case "${target}" in
 588       i*86-*-*) ;;
 589       alpha*-*-*) ;;
 590       x86_64-*-*) ;;
 591       *)
 592         noconfigdirs="$noconfigdirs ${libgcj}"
 593         ;;
 594     esac
 595     ;;
 596   *-*-kaos*)
 597     # Remove unsupported stuff on all kaOS configurations.
 598     skipdirs="target-libiberty ${libgcj} target-libstdc++-v3 target-librx"
 599     skipdirs="$skipdirs target-libobjc target-examples target-groff target-gperf"
 600     skipdirs="$skipdirs zlib fastjar target-libjava target-boehm-gc target-zlib"
 601     noconfigdirs="$noconfigdirs target-libgloss"
 602     ;;
 603   *-*-netbsd*)
 604     # Skip some stuff on all NetBSD configurations.
 605     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss"
 606
 607     # Skip some stuff that's unsupported on some NetBSD configurations.
 608     case "${target}" in
 609       i*86-*-netbsdelf*) ;;
 610       arm*-*-netbsdelf*) ;;
 611       *)
 612         noconfigdirs="$noconfigdirs ${libgcj}"
 613         ;;
 614     esac
 615     ;;
 616   *-*-netware*)
 617     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss ${libgcj} target-libmudflap"
 618     ;;
 619   *-*-rtems*)
 620     skipdirs="${skipdirs} target-libiberty"
 621     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 622     ;;
 623     # The tpf target doesn't support gdb yet.
 624   *-*-tpf*)
 625     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty ${libgcj} target-libmudflap gdb tcl tk libgui itcl"
 626     ;;
 627   *-*-uclinux*)
 628     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda ${libgcj}"
 629     ;;
 630   *-*-vxworks*)
 631     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty target-libstdc++-v3 ${libgcj}"
 632     ;;
 633   alpha*-dec-osf*)
 634     # ld works, but does not support shared libraries.
 635     # newlib is not 64 bit ready.  I'm not sure about fileutils.
 636     # gas doesn't generate exception information.
 637     noconfigdirs="$noconfigdirs gas ld fileutils target-newlib target-libgloss"
 638     ;;
 639   alpha*-*-*vms*)
 640     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 641     ;;
 642   alpha*-*-linux*)
 643     # newlib is not 64 bit ready
 644     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 645     ;;
 646   alpha*-*-*)
 647     # newlib is not 64 bit ready
 648     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 649     ;;
 650   am33_2.0-*-linux*)
 651     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 652     ;;
 653   sh-*-linux*)
 654     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 655     ;;
 656   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 657     noconfigdirs="$noconfigdirs ${libgcj}"
 658     noconfigdirs="$noconfigdirs target-examples"
 659     noconfigdirs="$noconfigdirs target-libiberty texinfo send-pr"
 660     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 661     noconfigdirs="$noconfigdirs expect dejagnu"
 662     # the C++ libraries don't build on top of CE's C libraries
 663     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 664     noconfigdirs="$noconfigdirs target-newlib"
 665     case "${host}" in
 666       *-*-cygwin*) ;; # keep gdb and readline
 667       *) noconfigdirs="$noconfigdirs gdb readline"
 668          ;;
 669     esac
 670     libgloss_dir=wince
 671     ;;
 672   arc-*-*)
 673     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 674     ;;
 675   arm-semi-aof )
 676     ;;
 677   arm-*-coff | strongarm-*-coff | xscale-*-coff)
 678     noconfigdirs="$noconfigdirs ${libgcj}"
 679     libgloss_dir=arm
 680     ;;
 681   arm-*-elf* | strongarm-*-elf* | xscale-*-elf* | arm*-*-eabi* )
 682     noconfigdirs="$noconfigdirs target-libffi target-qthreads"
 683     libgloss_dir=arm
 684     ;;
 685   arm*-*-linux-gnueabi)
 686     noconfigdirs="$noconfigdirs target-qthreads"
 687     case ${with_newlib} in
 688       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 689     esac
 690     libgloss_dir=arm
 691     ;;
 692   arm*-*-symbianelf*)
 693     noconfigdirs="$noconfigdirs ${libgcj} target-libiberty"
 694     libgloss_dir=arm
 695     ;;
 696   arm-*-pe*)
 697     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 698     ;;
 699   thumb-*-coff)
 700     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 701     ;;
 702   thumb-*-elf)
 703     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 704     ;;
 705   thumb-*-pe)
 706     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 707     ;;
 708   arm-*-riscix*)
 709     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 710     ;;
 711   avr-*-*)
 712     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj} target-libssp"
 713     ;;
 714   bfin-*-*)
 715     unsupported_languages="$unsupported_languages java"
 716     noconfigdirs="$noconfigdirs target-boehm-gc"
 717     if test x${is_cross_compiler} != xno ; then
 718       target_configdirs="${target_configdirs} target-bsp target-cygmon"
 719     fi
 720     ;;
 721   c4x-*-* | tic4x-*-*)
 722     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 723     ;;
 724   c54x*-*-* | tic54x-*-*)
 725     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj} gcc gdb newlib"
 726     ;;
 727   cr16-*-*)
 728     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 729     ;;
 730   cris-*-* | crisv32-*-*)
 731     unsupported_languages="$unsupported_languages java"
 732     case "${target}" in
 733       *-*-aout)
 734         unsupported_languages="$unsupported_languages fortran"
 735         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 736       *-*-elf) # See PR46792 regarding target-libffi.
 737         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 738       *-*-linux*)
 739         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
 740       *)
 741         unsupported_languages="$unsupported_languages fortran"
 742         noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss";;
 743     esac
 744     libgloss_dir=cris
 745     ;;
 746   crx-*-*)
 747     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-mudflap ${libgcj}"
 748     ;;
 749   d10v-*-*)
 750     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 751     ;;
 752   d30v-*-*)
 753     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 754     ;;
 755   ep9312-*-elf | ep9312-*-coff)
 756     libgloss_dir=arm
 757     ;;
 758   fr30-*-elf*)
 759     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 760     ;;
 761   frv-*-*)
 762     noconfigdirs="$noconfigdirs ${libgcj}"
 763     ;;
 764   moxie-*-*)
 765     noconfigdirs="$noconfigdirs ${libgcj}"
 766     noconfigdirs="$noconfigdirs gprof"
 767     ;;
 768   h8300*-*-*)
 769     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 770     ;;
 771   h8500-*-*)
 772     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 773     ;;
 774   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 775     ;;
 776   hppa*64*-*-linux* | parisc*64*-*-linux*)
 777     # In this case, it's because the hppa64-linux target is for
 778     # the kernel only at this point and has no libc, and thus no
 779     # headers, crt*.o, etc., all of which are needed by these.
 780     noconfigdirs="$noconfigdirs target-zlib"
 781     ;;
 782   parisc*-*-linux* | hppa*-*-linux*)
 783     ;;
 784   hppa*-*-*elf* | \
 785   hppa*-*-lites* | \
 786   hppa*-*-openbsd* | \
 787   hppa*64*-*-*)
 788     noconfigdirs="$noconfigdirs ${libgcj}"
 789     ;;
 790   hppa*-hp-hpux11*)
 791     noconfigdirs="$noconfigdirs ld shellutils"
 792     ;;
 793   hppa*-*-pro*)
 794     libgloss_dir=pa
 795     ;;
 796   hppa*-*-*)
 797     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 798     # build on HP-UX 10.20.
 799     noconfigdirs="$noconfigdirs ld shellutils ${libgcj}"
 800     ;;
 801   i960-*-*)
 802     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 803     ;;
 804   ia64*-*-elf*)
 805     # No gdb support yet.
 806     noconfigdirs="$noconfigdirs readline mmalloc libgui itcl gdb"
 807     ;;
 808   ia64*-**-hpux*)
 809     # No ld support yet.
 810     noconfigdirs="$noconfigdirs ${libgcj} libgui itcl ld"
 811     ;;
 812   ia64*-*-*vms*)
 813     # No gdb or ld support yet.
 814     noconfigdirs="$noconfigdirs ${libgcj} tix readline mmalloc libgui itcl gdb ld"
 815     ;;
 816   i370-*-opened*)
 817     ;;
 818   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
 819     noconfigdirs="$noconfigdirs ${libgcj}"
 820     libgloss_dir=i386
 821     ;;
 822   i[[3456789]]86-*-linux*)
 823     # The GCC port for glibc1 has no MD_FALLBACK_FRAME_STATE_FOR, so let's
 824     # not build java stuff by default.
 825     case "${target}" in
 826       *-*-*libc1*)
 827         noconfigdirs="$noconfigdirs ${libgcj}";;
 828     esac
 829
 830     # This section makes it possible to build newlib natively on linux.
 831     # If we are using a cross compiler then don't configure newlib.
 832     if test x${is_cross_compiler} != xno ; then
 833       noconfigdirs="$noconfigdirs target-newlib"
 834     fi
 835     noconfigdirs="$noconfigdirs target-libgloss"
 836     # If we are not using a cross compiler, do configure newlib.
 837     # Note however, that newlib will only be configured in this situation
 838     # if the --with-newlib option has been given, because otherwise
 839     # 'target-newlib' will appear in skipdirs.
 840     ;;
 841   i[[3456789]]86-w64-mingw*)
 842     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 843     ;;
 844   i[[3456789]]86-*-mingw*)
 845     target_configdirs="$target_configdirs target-winsup"
 846     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 847     ;;
 848   x86_64-*-mingw*)
 849     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 850     ;;
 851   *-*-cygwin*)
 852     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 853     noconfigdirs="$noconfigdirs target-gperf target-libgloss"
 854     # always build newlib if winsup directory is present.
 855     if test -d "$srcdir/winsup/cygwin"; then
 856       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 857     elif test -d "$srcdir/newlib"; then
 858       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 859     fi
 860     ;;
 861   i[[3456789]]86-moss-msdos | i[[3456789]]86-*-moss* | \
 862   i[[3456789]]86-*-uwin* | i[[3456789]]86-*-interix* )
 863     ;;
 864   i[[3456789]]86-*-pe)
 865     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 866     ;;
 867   i[[3456789]]86-*-sco3.2v5*)
 868     # The linker does not yet know about weak symbols in COFF,
 869     # and is not configured to handle mixed ELF and COFF.
 870     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 871     ;;
 872   i[[3456789]]86-*-sco*)
 873     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 874     ;;
 875   i[[3456789]]86-*-solaris2*)
 876     noconfigdirs="$noconfigdirs target-libgloss"
 877     ;;
 878   i[[3456789]]86-*-sysv4*)
 879     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 880     ;;
 881   i[[3456789]]86-*-beos*)
 882     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 883     ;;
 884   i[[3456789]]86-*-rdos*)
 885     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 886     ;;
 887   m32r-*-*)
 888     noconfigdirs="$noconfigdirs ${libgcj}"
 889     ;;
 890   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 891     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
 892     libgloss_dir=m68hc11
 893     ;;
 894   m68k-*-elf*)
 895     noconfigdirs="$noconfigdirs ${libgcj}"
 896     ;;
 897   m68k-*-coff*)
 898     noconfigdirs="$noconfigdirs ${libgcj}"
 899     ;;
 900   m68*-*-* | fido-*-*)
 901     libgloss_dir=m68k
 902     ;;
 903   mcore-*-pe*)
 904   # The EPOC C++ environment does not support exceptions or rtti,
 905   # and so building libstdc++-v3 tends not to always work.
 906     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 907     ;;
 908   mmix-*-*)
 909     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc gdb libgloss"
 910     unsupported_languages="$unsupported_languages fortran java"
 911     ;;
 912   mn10200-*-*)
 913     noconfigdirs="$noconfigdirs ${libgcj}"
 914     ;;
 915   mn10300-*-*)
 916     noconfigdirs="$noconfigdirs ${libgcj}"
 917     ;;
 918   mt-*-*)
 919     noconfigdirs="$noconfigdirs sim"
 920     ;;
 921   picochip-*-*)
 922     noconfigdirs="$noconfigdirs target-libiberty"
 923     ;;
 924   powerpc-*-aix*)
 925     # copied from rs6000-*-* entry
 926     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 927     ;;
 928   powerpc*-*-winnt* | powerpc*-*-pe* | ppc*-*-pe)
 929     target_configdirs="$target_configdirs target-winsup"
 930     noconfigdirs="$noconfigdirs gdb tcl tk make expect target-libgloss itcl gnuserv ${libgcj}"
 931     # always build newlib.
 932     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 933     ;;
 934     # This is temporary until we can link against shared libraries
 935   powerpcle-*-solaris*)
 936     noconfigdirs="$noconfigdirs gdb sim make tcl tk expect itcl gnuserv ${libgcj}"
 937     libgloss_dir=rs6000
 938     ;;
 939   powerpc-*-beos*)
 940     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 941     ;;
 942   powerpc-*-eabi)
 943     noconfigdirs="$noconfigdirs ${libgcj}"
 944     libgloss_dir=rs6000
 945     ;;
 946   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
 947     libgloss_dir=rs6000
 948     ;;
 949   rs6000-*-lynxos*)
 950     noconfigdirs="$noconfigdirs target-newlib gprof ${libgcj}"
 951     ;;
 952   rs6000-*-aix*)
 953     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 954     ;;
 955   rs6000-*-*)
 956     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 957     ;;
 958   m68k-apollo-*)
 959     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss ${libgcj}"
 960     ;;
 961   microblaze*)
 962     noconfigdirs="$noconfigdirs gprof target-libssp ${libgcj}"
 963     ;;
 964   mips*-sde-elf*)
 965     skipdirs="$skipdirs target-libiberty"
 966     noconfigdirs="$noconfigdirs ${libgcj}"
 967     if test x$with_newlib = xyes; then
 968       noconfigdirs="$noconfigdirs gprof"
 969     fi
 970     libgloss_dir=mips
 971     ;;
 972   mips*-*-irix5*)
 973     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 974     ;;
 975   mips*-*-irix6*)
 976     # Linking libjava exceeds command-line length limits on at least
 977     # IRIX 6.2, but not on IRIX 6.5.
 978     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 979     # <oldham@codesourcery.com>
 980     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 981     ;;
 982   mips*-*-bsd*)
 983     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 984     ;;
 985   mips*-*-linux*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   mips*-*-*)
 989     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 990     libgloss_dir=mips
 991     ;;
 992   romp-*-*)
 993     noconfigdirs="$noconfigdirs bfd binutils ld gas opcodes target-libgloss ${libgcj}"
 994     ;;
 995   sh-*-* | sh64-*-*)
 996     case "${host}" in
 997       i[[3456789]]86-*-vsta) ;; # don't add gprof back in
 998       i[[3456789]]86-*-go32*) ;; # don't add gprof back in
 999       i[[3456789]]86-*-msdosdjgpp*) ;; # don't add gprof back in
1000       *) skipdirs=`echo " ${skipdirs} " | sed -e 's/ gprof / /'` ;;
1001     esac
1002     case "${target}" in
1003       sh*-*-elf)
1004          noconfigdirs="$noconfigdirs ${libgcj}" ;;
1005       *)
1006          noconfigdirs="$noconfigdirs target-libgloss ${libgcj}" ;;
1007     esac
1008     ;;
1009   sparclet-*-aout* | sparc86x-*-*)
1010     libgloss_dir=sparc
1011     ;;
1012   sparc-*-elf*)
1013     noconfigdirs="$noconfigdirs ${libgcj}"
1014     ;;
1015   sparc64-*-elf*)
1016     noconfigdirs="$noconfigdirs ${libgcj}"
1017     libgloss_dir=sparc
1018     ;;
1019   sparclite-*-*)
1020     noconfigdirs="$noconfigdirs ${libgcj}"
1021     libgloss_dir=sparc
1022     ;;
1023   sparc-*-sunos4*)
1024     noconfigdirs="$noconfigdirs ${libgcj}"
1025     if test x${is_cross_compiler} != xno ; then
1026            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1027     else
1028            use_gnu_ld=no
1029     fi
1030     ;;
1031   sparc-*-solaris2.[[0-6]] | sparc-*-solaris2.[[0-6]].*)
1032     noconfigdirs="$noconfigdirs ${libgcj}"
1033     ;;
1034   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
1035     ;;
1036   tic6x-*-*)
1037     noconfigdirs="$noconfigdirs gdb sim ${libgcj}"
1038     ;;
1039   v810-*-*)
1040     noconfigdirs="$noconfigdirs bfd binutils gas gcc gdb ld target-libstdc++-v3 opcodes target-libgloss ${libgcj}"
1041     ;;
1042   v850*-*-*)
1043     noconfigdirs="$noconfigdirs ${libgcj}"
1044     ;;
1045   vax-*-vms)
1046     noconfigdirs="$noconfigdirs bfd binutils gdb ld target-newlib opcodes target-libgloss ${libgcj}"
1047     ;;
1048   vax-*-*)
1049     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1050     ;;
1051   xtensa*-*-*)
1052     noconfigdirs="$noconfigdirs ${libgcj}"
1053     ;;
1054   ip2k-*-*)
1055     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
1056     ;;
1057   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1058     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1059     ;;
1060   *-*-lynxos*)
1061     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1062     ;;
1063   *-*-*)
1064     noconfigdirs="$noconfigdirs ${libgcj}"
1065     ;;
1066 esac
1067
1068 # If we aren't building newlib, then don't build libgloss, since libgloss
1069 # depends upon some newlib header files.
1070 case "${noconfigdirs}" in
1071   *target-libgloss*) ;;
1072   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1073 esac
1074
1075 # Work in distributions that contain no compiler tools, like Autoconf.
1076 tentative_cc=""
1077 host_makefile_frag=/dev/null
1078 if test -d ${srcdir}/config ; then
1079 case "${host}" in
1080   m68k-hp-hpux*)
1081     # Avoid "too much defining" errors from HPUX compiler.
1082     tentative_cc="cc -Wp,-H256000"
1083     # If "ar" in $PATH is GNU ar, the symbol table may need rebuilding.
1084     # If it's HP/UX ar, this should be harmless.
1085     RANLIB="ar ts"
1086     ;;
1087   m68k-apollo-sysv*)
1088     tentative_cc="cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DUSG"
1089     ;;
1090   m68k-apollo-bsd*)
1091     #None of the Apollo compilers can compile gas or binutils.  The preprocessor
1092     # chokes on bfd, the compiler won't let you assign integers to enums, and
1093     # other problems.  Defining CC to gcc is a questionable way to say "don't use
1094     # the apollo compiler" (the preferred version of GCC could be called cc,
1095     # or whatever), but I'm not sure leaving CC as cc is any better...
1096     #CC=cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DNO_STDARG
1097     # Used to have BISON=yacc.
1098     tentative_cc=gcc
1099     ;;
1100   m88k-dg-dgux*)
1101     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
1102     ;;
1103   m88k-harris-cxux*)
1104     # Under CX/UX, we want to tell the compiler to use ANSI mode.
1105     tentative_cc="cc -Xa"
1106     host_makefile_frag="config/mh-cxux"
1107     ;;
1108   m88k-motorola-sysv*)
1109     ;;
1110   mips*-dec-ultrix*)
1111     tentative_cc="cc -Wf,-XNg1000"
1112     host_makefile_frag="config/mh-decstation"
1113     ;;
1114   mips*-nec-sysv4*)
1115     # The C compiler on NEC MIPS SVR4 needs bigger tables.
1116     tentative_cc="cc -ZXNd=5000 -ZXNg=1000"
1117     host_makefile_frag="config/mh-necv4"
1118     ;;
1119   mips*-sgi-irix4*)
1120     # Tell compiler to use K&R C.  We can't compile under the SGI Ansi
1121     # environment.  Also bump switch table size so that cp-parse will
1122     # compile.  Bump string length limit so linker builds.
1123     tentative_cc="cc -cckr -Wf,-XNg1500 -Wf,-XNk1000 -Wf,-XNh2000 -Wf,-XNl8192"
1124     ;;
1125   mips*-*-sysv4*)
1126     host_makefile_frag="config/mh-sysv4"
1127     ;;
1128   mips*-*-sysv*)
1129     # This is for a MIPS running RISC/os 4.52C.
1130
1131     # This is needed for GDB, but needs to be in the top-level make because
1132     # if a library is compiled with the bsd headers and gets linked with the
1133     # sysv system libraries all hell can break loose (e.g. a jmp_buf might be
1134     # a different size).
1135     # ptrace(2) apparently has problems in the BSD environment.  No workaround is
1136     # known except to select the sysv environment.  Could we use /proc instead?
1137     # These "sysv environments" and "bsd environments" often end up being a pain.
1138     #
1139     # This is not part of CFLAGS because perhaps not all C compilers have this
1140     # option.
1141     tentative_cc="cc -systype sysv"
1142     ;;
1143   i370-ibm-opened*)
1144     tentative_cc="c89"
1145     ;;
1146   i[[3456789]]86-*-sysv5*)
1147     host_makefile_frag="config/mh-sysv5"
1148     ;;
1149   i[[3456789]]86-*-dgux*)
1150     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
1151     host_makefile_frag="config/mh-dgux386"
1152     ;;
1153   i[[3456789]]86-ncr-sysv4.3*)
1154     # The MetaWare compiler will generate a copyright message unless you
1155     # turn it off by adding the -Hnocopyr flag.
1156     tentative_cc="cc -Hnocopyr"
1157     ;;
1158   i[[3456789]]86-ncr-sysv4*)
1159     # for an NCR 3000 (i486/SVR4) system.
1160     # The NCR 3000 ships with a MetaWare compiler installed as /bin/cc.
1161     # This compiler not only emits obnoxious copyright messages every time
1162     # you run it, but it chokes and dies on a whole bunch of GNU source
1163     # files.  Default to using the AT&T compiler installed in /usr/ccs/ATT/cc.
1164     tentative_cc="/usr/ccs/ATT/cc"
1165     host_makefile_frag="config/mh-ncr3000"
1166     ;;
1167   i[[3456789]]86-*-sco3.2v5*)
1168     ;;
1169   i[[3456789]]86-*-sco*)
1170     # The native C compiler botches some simple uses of const.  Unfortunately,
1171     # it doesn't defined anything like "__sco__" for us to test for in ansidecl.h.
1172     tentative_cc="cc -Dconst="
1173     host_makefile_frag="config/mh-sco"
1174     ;;
1175   i[[3456789]]86-*-udk*)
1176     host_makefile_frag="config/mh-sysv5"
1177     ;;
1178   i[[3456789]]86-*-solaris2*)
1179     host_makefile_frag="config/mh-sysv4"
1180     ;;
1181   i[[3456789]]86-*-msdosdjgpp*)
1182     host_makefile_frag="config/mh-djgpp"
1183     ;;
1184   *-cygwin*)
1185     ACX_CHECK_CYGWIN_CAT_WORKS
1186     host_makefile_frag="config/mh-cygwin"
1187     ;;
1188   *-mingw*)
1189     host_makefile_frag="config/mh-mingw"
1190     ;;
1191   *-interix*)
1192     host_makefile_frag="config/mh-interix"
1193     ;;
1194   vax-*-ultrix2*)
1195     # The old BSD pcc isn't up to compiling parts of gdb so use gcc
1196     tentative_cc=gcc
1197     ;;
1198   *-*-solaris2*)
1199     host_makefile_frag="config/mh-solaris"
1200     ;;
1201   m68k-sun-sunos*)
1202     # Sun's C compiler needs the -J flag to be able to compile cp-parse.c
1203     # without overflowing the jump tables (-J says to use a 32 bit table)
1204     tentative_cc="cc -J"
1205     ;;
1206   hppa*-hp-hpux10*)
1207     tentative_cc="cc -Wp,-H256000"
1208     host_makefile_frag="config/mh-pa-hpux10"
1209     ;;
1210   hppa*-hp-hpux* | hppa*-*-hiux*)
1211     tentative_cc="cc -Wp,-H256000"
1212     host_makefile_frag="config/mh-pa"
1213     ;;
1214   hppa*-*)
1215     host_makefile_frag="config/mh-pa"
1216     ;;
1217   *-hp-hpux* | *-*-hiux*)
1218     tentative_cc="cc -Wp,-H256000"
1219     ;;
1220   rs6000-*-lynxos*)
1221     # /bin/cc is less than useful for our purposes.  Always use GCC
1222     tentative_cc="/usr/cygnus/progressive/bin/gcc"
1223     host_makefile_frag="config/mh-lynxrs6k"
1224     ;;
1225   *-*-darwin*)
1226     host_makefile_frag="config/mh-darwin"
1227     ;;
1228   powerpc-*-aix*)
1229     host_makefile_frag="config/mh-ppc-aix"
1230     ;;
1231   rs6000-*-aix*)
1232     host_makefile_frag="config/mh-ppc-aix"
1233     ;;
1234   *-*-lynxos*)
1235     # /bin/cc is less than useful for our purposes.  Always use GCC
1236     tentative_cc="/bin/gcc"
1237     ;;
1238   *-*-sysv4*)
1239     host_makefile_frag="config/mh-sysv4"
1240     ;;
1241   # This is placed last to prevent interfering with the cases above.
1242   i[[3456789]]86-*-*)
1243     # Build the stage2 and stage3 compilers with -fomit-frame-pointer.
1244     host_makefile_frag="config/mh-x86omitfp"
1245     ;;
1246 esac
1247 fi
1248
1249 # If we aren't going to be using gcc, see if we can extract a definition
1250 # of CC from the fragment.
1251 # Actually, use the 'pre-extracted' version above.
1252 if test -z "${CC}" && test "${build}" = "${host}" ; then
1253   IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
1254   found=
1255   for dir in $PATH; do
1256     test -z "$dir" && dir=.
1257     if test -f $dir/gcc; then
1258       found=yes
1259       break
1260     fi
1261   done
1262   IFS="$save_ifs"
1263   if test -z "${found}" && test -n "${tentative_cc}" ; then
1264     CC=$tentative_cc
1265   fi
1266 fi
1267
1268 if test "${build}" != "${host}" ; then
1269   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1270   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1271   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1272   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1273   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1274   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1275   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1276   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1277   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1278   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1279   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1280   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1281   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1282 else
1283   AR_FOR_BUILD="\$(AR)"
1284   AS_FOR_BUILD="\$(AS)"
1285   CC_FOR_BUILD="\$(CC)"
1286   CXX_FOR_BUILD="\$(CXX)"
1287   GCJ_FOR_BUILD="\$(GCJ)"
1288   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1289   GOC_FOR_BUILD="\$(GOC)"
1290   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1291   LD_FOR_BUILD="\$(LD)"
1292   NM_FOR_BUILD="\$(NM)"
1293   RANLIB_FOR_BUILD="\$(RANLIB)"
1294   WINDRES_FOR_BUILD="\$(WINDRES)"
1295   WINDMC_FOR_BUILD="\$(WINDMC)"
1296 fi
1297
1298 AC_PROG_CC
1299 AC_PROG_CXX
1300
1301 # We must set the default linker to the linker used by gcc for the correct
1302 # operation of libtool.  If LD is not defined and we are using gcc, try to
1303 # set the LD default to the ld used by gcc.
1304 if test -z "$LD"; then
1305   if test "$GCC" = yes; then
1306     case $build in
1307     *-*-mingw*)
1308       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1309     *)
1310       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1311     esac
1312     case $gcc_prog_ld in
1313     # Accept absolute paths.
1314     [[\\/]* | [A-Za-z]:[\\/]*)]
1315       LD="$gcc_prog_ld" ;;
1316     esac
1317   fi
1318 fi
1319
1320 ACX_PROG_GNAT
1321 ACX_PROG_CMP_IGNORE_INITIAL
1322
1323 # See if we are building gcc with C++.
1324 AC_ARG_ENABLE(build-with-cxx,
1325 [AS_HELP_STRING([--enable-build-with-cxx],
1326                 [build with C++ compiler instead of C compiler])],
1327 ENABLE_BUILD_WITH_CXX=$enableval,
1328 ENABLE_BUILD_WITH_CXX=no)
1329
1330 # Used for setting $lt_cv_objdir
1331 _LT_CHECK_OBJDIR
1332
1333 # Check for GMP, MPFR and MPC
1334 gmplibs="-lmpc -lmpfr -lgmp"
1335 gmpinc=
1336 have_gmp=no
1337
1338 # Specify a location for mpc
1339 # check for this first so it ends up on the link line before mpfr.
1340 AC_ARG_WITH(mpc,
1341 [AS_HELP_STRING([--with-mpc=PATH],
1342                 [specify prefix directory for installed MPC package.
1343                  Equivalent to --with-mpc-include=PATH/include
1344                  plus --with-mpc-lib=PATH/lib])])
1345 AC_ARG_WITH(mpc-include,
1346 [AS_HELP_STRING([--with-mpc-include=PATH],
1347                 [specify directory for installed MPC include files])])
1348 AC_ARG_WITH(mpc-lib,
1349 [AS_HELP_STRING([--with-mpc-lib=PATH],
1350                 [specify directory for the installed MPC library])])
1351
1352 if test "x$with_mpc" != x; then
1353   gmplibs="-L$with_mpc/lib $gmplibs"
1354   gmpinc="-I$with_mpc/include $gmpinc"
1355 fi
1356 if test "x$with_mpc_include" != x; then
1357   gmpinc="-I$with_mpc_include $gmpinc"
1358 fi
1359 if test "x$with_mpc_lib" != x; then
1360   gmplibs="-L$with_mpc_lib $gmplibs"
1361 fi
1362 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1363   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1364   gmpinc='-I$$s/mpc/src '"$gmpinc"
1365   # Do not test the mpc version.  Assume that it is sufficient, since
1366   # it is in the source tree, and the library has not been built yet
1367   # but it would be included on the link line in the version check below
1368   # hence making the test fail.
1369   have_gmp=yes
1370 fi
1371
1372 # Specify a location for mpfr
1373 # check for this first so it ends up on the link line before gmp.
1374 AC_ARG_WITH(mpfr-dir,
1375 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1376 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1377 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1378
1379 AC_ARG_WITH(mpfr,
1380 [AS_HELP_STRING([--with-mpfr=PATH],
1381                 [specify prefix directory for installed MPFR package.
1382                  Equivalent to --with-mpfr-include=PATH/include
1383                  plus --with-mpfr-lib=PATH/lib])])
1384 AC_ARG_WITH(mpfr-include,
1385 [AS_HELP_STRING([--with-mpfr-include=PATH],
1386                 [specify directory for installed MPFR include files])])
1387 AC_ARG_WITH(mpfr-lib,
1388 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1389                 [specify directory for the installed MPFR library])])
1390
1391 if test "x$with_mpfr" != x; then
1392   gmplibs="-L$with_mpfr/lib $gmplibs"
1393   gmpinc="-I$with_mpfr/include $gmpinc"
1394 fi
1395 if test "x$with_mpfr_include" != x; then
1396   gmpinc="-I$with_mpfr_include $gmpinc"
1397 fi
1398 if test "x$with_mpfr_lib" != x; then
1399   gmplibs="-L$with_mpfr_lib $gmplibs"
1400 fi
1401 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1402   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1403   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1404   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1405   # Do not test the mpfr version.  Assume that it is sufficient, since
1406   # it is in the source tree, and the library has not been built yet
1407   # but it would be included on the link line in the version check below
1408   # hence making the test fail.
1409   have_gmp=yes
1410 fi
1411
1412 # Specify a location for gmp
1413 AC_ARG_WITH(gmp-dir,
1414 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1415 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1416 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1417
1418 AC_ARG_WITH(gmp,
1419 [AS_HELP_STRING([--with-gmp=PATH],
1420                 [specify prefix directory for the installed GMP package.
1421                  Equivalent to --with-gmp-include=PATH/include
1422                  plus --with-gmp-lib=PATH/lib])])
1423 AC_ARG_WITH(gmp-include,
1424 [AS_HELP_STRING([--with-gmp-include=PATH],
1425                 [specify directory for installed GMP include files])])
1426 AC_ARG_WITH(gmp-lib,
1427 [AS_HELP_STRING([--with-gmp-lib=PATH],
1428                 [specify directory for the installed GMP library])])
1429
1430
1431 if test "x$with_gmp" != x; then
1432   gmplibs="-L$with_gmp/lib $gmplibs"
1433   gmpinc="-I$with_gmp/include $gmpinc"
1434 fi
1435 if test "x$with_gmp_include" != x; then
1436   gmpinc="-I$with_gmp_include $gmpinc"
1437 fi
1438 if test "x$with_gmp_lib" != x; then
1439   gmplibs="-L$with_gmp_lib $gmplibs"
1440 fi
1441 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1442   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1443   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1444   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1445   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1446   # Do not test the gmp version.  Assume that it is sufficient, since
1447   # it is in the source tree, and the library has not been built yet
1448   # but it would be included on the link line in the version check below
1449   # hence making the test fail.
1450   have_gmp=yes
1451 fi
1452
1453 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1454   have_gmp=yes
1455   saved_CFLAGS="$CFLAGS"
1456   CFLAGS="$CFLAGS $gmpinc"
1457   # Check for the recommended and required versions of GMP.
1458   AC_MSG_CHECKING([for the correct version of gmp.h])
1459   AC_TRY_COMPILE([#include "gmp.h"],[
1460   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1461   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1462   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1463   choke me
1464   #endif
1465   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1466   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1467   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1468   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1469   choke me
1470   #endif
1471   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1472    [AC_MSG_RESULT([no]); have_gmp=no])
1473
1474   # If we have GMP, check the MPFR version.
1475   if test x"$have_gmp" = xyes; then
1476     # Check for the recommended and required versions of MPFR.
1477     AC_MSG_CHECKING([for the correct version of mpfr.h])
1478     AC_TRY_COMPILE([#include <gmp.h>
1479     #include <mpfr.h>],[
1480     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1481     choke me
1482     #endif
1483     ], [AC_TRY_COMPILE([#include <gmp.h>
1484     #include <mpfr.h>],[
1485     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1486     choke me
1487     #endif
1488     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1489      [AC_MSG_RESULT([no]); have_gmp=no])
1490   fi
1491
1492   # Check for the MPC header version.
1493   if test x"$have_gmp" = xyes ; then
1494     # Check for the recommended and required versions of MPC.
1495     AC_MSG_CHECKING([for the correct version of mpc.h])
1496     AC_TRY_COMPILE([#include <mpc.h>],[
1497     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1498     choke me
1499     #endif
1500     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1501     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1502     choke me
1503     #endif
1504     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1505      [AC_MSG_RESULT([no]); have_gmp=no])
1506   fi
1507
1508   # Now check the MPFR library.
1509   if test x"$have_gmp" = xyes; then
1510     saved_LIBS="$LIBS"
1511     LIBS="$LIBS $gmplibs"
1512     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1513     AC_TRY_LINK([#include <mpc.h>],[
1514     mpfr_t n;
1515     mpfr_t x;
1516     mpc_t c;
1517     int t;
1518     mpfr_init (n);
1519     mpfr_init (x);
1520     mpfr_atan2 (n, n, x, GMP_RNDN);
1521     mpfr_erfc (n, x, GMP_RNDN);
1522     mpfr_subnormalize (x, t, GMP_RNDN);
1523     mpfr_clear(n);
1524     mpfr_clear(x);
1525     mpc_init2 (c, 53);
1526     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1527     mpc_cosh (c, c, MPC_RNDNN);
1528     mpc_pow (c, c, c, MPC_RNDNN);
1529     mpc_acosh (c, c, MPC_RNDNN);
1530     mpc_clear (c);
1531     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1532     LIBS="$saved_LIBS"
1533   fi
1534
1535   CFLAGS="$saved_CFLAGS"
1536
1537 # The library versions listed in the error message below should match
1538 # the HARD-minimums enforced above.
1539   if test x$have_gmp != xyes; then
1540     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1541 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1542 their locations.  Source code for these libraries can be found at
1543 their respective hosting sites as well as at
1544 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1545 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1546 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1547 make sure that you have installed both the libraries and the header
1548 files.  They may be located in separate packages.])
1549   fi
1550 fi
1551
1552 # Flags needed for both GMP, MPFR and/or MPC.
1553 AC_SUBST(gmplibs)
1554 AC_SUBST(gmpinc)
1555 AC_SUBST(extra_mpfr_configure_flags)
1556 AC_SUBST(extra_mpc_gmp_configure_flags)
1557 AC_SUBST(extra_mpc_mpfr_configure_flags)
1558
1559 # Allow host libstdc++ to be specified for static linking with PPL.
1560 AC_ARG_WITH(host-libstdcxx,
1561 [AS_HELP_STRING([--with-host-libstdcxx=L],
1562                 [use linker arguments L to link with libstdc++
1563                  when linking with PPL])])
1564
1565 case $with_host_libstdcxx in
1566   no|yes)
1567     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1568     ;;
1569 esac
1570
1571 # Linker flags to use for stage1 or when not boostrapping.
1572 AC_ARG_WITH(stage1-ldflags,
1573 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1574 [if test "$withval" = "no" -o "$withval" = "yes"; then
1575    stage1_ldflags=
1576  else
1577    stage1_ldflags=$withval
1578  fi],
1579 [stage1_ldflags=])
1580 AC_SUBST(stage1_ldflags)
1581
1582 # Libraries to use for stage1 or when not bootstrapping.
1583 AC_ARG_WITH(stage1-libs,
1584 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1585 [if test "$withval" = "no" -o "$withval" = "yes"; then
1586    stage1_libs=
1587  else
1588    stage1_libs=$withval
1589  fi],
1590 [stage1_libs=$with_host_libstdcxx])
1591 AC_SUBST(stage1_libs)
1592
1593 # Libraries to use for stage2 and later builds.  This defaults to the
1594 # argument passed to --with-host-libstdcxx.
1595 AC_ARG_WITH(boot-libs,
1596 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1597 [if test "$withval" = "no" -o "$withval" = "yes"; then
1598    poststage1_libs=
1599  else
1600    poststage1_libs=$withval
1601  fi],
1602 [poststage1_libs=$with_host_libstdcxx])
1603 AC_SUBST(poststage1_libs)
1604
1605 # Linker flags to use for stage2 and later builds.
1606 AC_ARG_WITH(boot-ldflags,
1607 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1608                 [linker flags for stage2 and later])],
1609 [if test "$withval" = "no" -o "$withval" = "yes"; then
1610    poststage1_ldflags=
1611  else
1612    poststage1_ldflags=$withval
1613  fi],
1614 [poststage1_ldflags=
1615  # In stages 2 and 3, default to linking libstdc++ and libgcc
1616  # statically.  But if the user explicitly specified the libraries to
1617  # use, trust that they are doing what they want.
1618  if test "$poststage1_libs" = ""; then
1619    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1620  fi])
1621 AC_SUBST(poststage1_ldflags)
1622
1623 # Check for PPL
1624 ppllibs=" -lppl_c -lppl -lgmpxx"
1625 pplinc=
1626
1627 AC_ARG_WITH(ppl,
1628 [AS_HELP_STRING([--with-ppl=PATH],
1629                 [specify prefix directory for the installed PPL package.
1630                  Equivalent to --with-ppl-include=PATH/include
1631                  plus --with-ppl-lib=PATH/lib])])
1632 AC_ARG_WITH(ppl-include,
1633 [AS_HELP_STRING([--with-ppl-include=PATH],
1634                 [specify directory for installed PPL include files])])
1635 AC_ARG_WITH(ppl-lib,
1636 [AS_HELP_STRING([--with-ppl-lib=PATH],
1637                 [specify directory for the installed PPL library])])
1638
1639 case $with_ppl in
1640   no)
1641     ppllibs=
1642     ;;
1643   "" | yes)
1644     ;;
1645   *)
1646     ppllibs="-L$with_ppl/lib -lppl_c -lppl -lgmpxx"
1647     pplinc="-I$with_ppl/include $pplinc"
1648     ;;
1649 esac
1650 if test "x$with_ppl_include" != x; then
1651   pplinc="-I$with_ppl_include $pplinc"
1652 fi
1653 if test "x$with_ppl_lib" != x; then
1654   ppllibs="-L$with_ppl_lib -lppl_c -lppl -lgmpxx"
1655 fi
1656 if test "x$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1657   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"' -lppl_c -lppl -lgmpxx '
1658   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1659   enable_ppl_version_check=no
1660 fi
1661
1662 AC_ARG_ENABLE(ppl-version-check,
1663 [AS_HELP_STRING([--disable-ppl-version-check],
1664                 [disable check for PPL version])],
1665 ENABLE_PPL_CHECK=$enableval,
1666 ENABLE_PPL_CHECK=yes)
1667
1668 if test "x$with_ppl" != "xno" -a "${ENABLE_PPL_CHECK}" = "yes"; then
1669   saved_CFLAGS="$CFLAGS"
1670   CFLAGS="$CFLAGS $pplinc $gmpinc"
1671   AC_MSG_CHECKING([for version 0.10 (or later revision) of PPL])
1672   AC_TRY_COMPILE([#include "ppl_c.h"],[
1673   #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 10
1674   choke me
1675   #endif
1676   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1677   CFLAGS="$saved_CFLAGS"
1678 fi
1679
1680 # Flags needed for PPL
1681 AC_SUBST(ppllibs)
1682 AC_SUBST(pplinc)
1683
1684
1685 # Check for CLOOG
1686
1687 dnl Provide configure switches and initialize clooginc & clooglibs
1688 dnl with user input.
1689 CLOOG_INIT_FLAGS
1690 if test "x$with_ppl" = "xno"; then
1691   with_cloog=no
1692 fi
1693 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1694   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1695   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1696   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1697 fi
1698 if test "x$with_cloog" != "xno"; then
1699   dnl Version check for CLooG-Org
1700   dnl As long as there is no new release of CLooG,
1701   dnl we will check for 0.14.0.
1702   dnl
1703   dnl The first git revision that will work with
1704   dnl GCC is: bd91b845a65805c290d43fc1bef8139864a163fb
1705   dnl This is enforced implictly, as this is the commit that
1706   dnl introduced the versioning information used within our
1707   dnl checks.
1708   dnl
1709   dnl If we're using CLooG-Legacy, the provided version information
1710   dnl will be ignored.
1711   CLOOG_CHECK_VERSION(0,14,0)
1712
1713   dnl Only execute fail-action, if CLooG has been
1714   dnl requested.
1715   CLOOG_IF_FAILED([
1716     AC_MSG_ERROR([Unable to find a usable CLooG. See config.log for details.])])
1717 fi
1718
1719 # Check for LTO support.
1720 AC_ARG_ENABLE(lto,
1721 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1722 enable_lto=$enableval,
1723 enable_lto=yes; default_enable_lto=yes)
1724
1725 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1726   build_lto_plugin=yes
1727 ],[if test x"$default_enable_lto" = x"yes" ; then
1728     case $target in
1729       *-apple-darwin* | *-cygwin* | *-mingw*) ;;
1730       # On other non-ELF platforms, LTO has yet to be validated.
1731       *) enable_lto=no ;;
1732     esac
1733   else
1734   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1735   # It would also be nice to check the binutils support, but we don't
1736   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1737   # warn during gcc/ subconfigure; unless you're bootstrapping with
1738   # -flto it won't be needed until after installation anyway.
1739     case $target in
1740       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1741       *) if test x"$enable_lto" = x"yes"; then
1742         AC_MSG_ERROR([LTO support is not enabled for this target.])
1743         fi
1744       ;;
1745     esac
1746   fi
1747   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1748   # Build it unless LTO was explicitly disabled.
1749   case $target in
1750     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1751     *) ;;
1752   esac
1753 ])
1754
1755
1756 # By default, C is the only stage 1 language.
1757 stage1_languages=,c,
1758
1759 # Target libraries that we bootstrap.
1760 bootstrap_target_libs=,target-libgcc,
1761
1762 # Figure out what language subdirectories are present.
1763 # Look if the user specified --enable-languages="..."; if not, use
1764 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1765 # go away some day.
1766 # NB:  embedded tabs in this IF block -- do not untabify
1767 if test -d ${srcdir}/gcc; then
1768   if test x"${enable_languages+set}" != xset; then
1769     if test x"${LANGUAGES+set}" = xset; then
1770       enable_languages="${LANGUAGES}"
1771         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1772     else
1773       enable_languages=all
1774     fi
1775   else
1776     if test x"${enable_languages}" = x ||
1777        test x"${enable_languages}" = xyes;
1778        then
1779       echo configure.in: --enable-languages needs at least one language argument 1>&2
1780       exit 1
1781     fi
1782   fi
1783   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1784
1785   # 'f95' is the old name for the 'fortran' language. We issue a warning
1786   # and make the substitution.
1787   case ,${enable_languages}, in
1788     *,f95,*)
1789       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1790       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1791       ;;
1792   esac
1793
1794   # First scan to see if an enabled language requires some other language.
1795   # We assume that a given config-lang.in will list all the language
1796   # front ends it requires, even if some are required indirectly.
1797   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1798     case ${lang_frag} in
1799       ..) ;;
1800       # The odd quoting in the next line works around
1801       # an apparent bug in bash 1.12 on linux.
1802       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1803       *)
1804         # From the config-lang.in, get $language, $lang_requires, and
1805         # $lang_requires_boot_languages.
1806         language=
1807         lang_requires=
1808         lang_requires_boot_languages=
1809         . ${lang_frag}
1810         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1811           case ,${enable_languages}, in
1812             *,$other,*) ;;
1813             *,all,*) ;;
1814             *,$language,*)
1815               echo " \`$other' language required by \`$language'; enabling" 1>&2
1816               enable_languages="${enable_languages},${other}"
1817               ;;
1818           esac
1819         done
1820         for other in ${lang_requires_boot_languages} ; do
1821           if test "$other" != "c"; then
1822             case ,${enable_stage1_languages}, in
1823               *,$other,*) ;;
1824               *,all,*) ;;
1825               *)
1826                 case ,${enable_languages}, in
1827                   *,$language,*)
1828                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1829                     enable_stage1_languages="$enable_stage1_languages,${other}"
1830                     ;;
1831                 esac
1832                 ;;
1833             esac
1834           fi
1835         done
1836         ;;
1837     esac
1838   done
1839
1840   new_enable_languages=,c,
1841
1842   # If LTO is enabled, add the LTO front end.
1843   extra_host_libiberty_configure_flags=
1844   if test "$enable_lto" = "yes" ; then
1845     case ,${enable_languages}, in
1846       *,lto,*) ;;
1847       *) enable_languages="${enable_languages},lto" ;;
1848     esac
1849     if test "${build_lto_plugin}" = "yes" ; then
1850       configdirs="$configdirs lto-plugin"
1851       extra_host_libiberty_configure_flags=--enable-shared
1852     fi
1853   fi
1854   AC_SUBST(extra_host_libiberty_configure_flags)
1855
1856   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1857   potential_languages=,c,
1858
1859   enabled_target_libs=
1860   disabled_target_libs=
1861
1862   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1863     case ${lang_frag} in
1864       ..) ;;
1865       # The odd quoting in the next line works around
1866       # an apparent bug in bash 1.12 on linux.
1867       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1868       *)
1869         # From the config-lang.in, get $language, $target_libs,
1870         # $lang_dirs, $boot_language, and $build_by_default
1871         language=
1872         target_libs=
1873         lang_dirs=
1874         subdir_requires=
1875         boot_language=no
1876         build_by_default=yes
1877         . ${lang_frag}
1878         if test x${language} = x; then
1879           echo "${lang_frag} doesn't set \$language." 1>&2
1880           exit 1
1881         fi
1882
1883         if test "$language" = "c++" \
1884            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1885           boot_language=yes
1886         fi
1887
1888         case ,${enable_languages}, in
1889           *,${language},*)
1890             # Language was explicitly selected; include it.
1891             add_this_lang=yes
1892             ;;
1893           *,all,*)
1894             # 'all' was selected, select it if it is a default language
1895             add_this_lang=${build_by_default}
1896             ;;
1897           *)
1898             add_this_lang=no
1899             ;;
1900         esac
1901
1902         # Disable languages that need other directories if these aren't available.
1903         for i in $subdir_requires; do
1904           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1905           case ,${enable_languages}, in
1906             *,${language},*)
1907               # Specifically requested language; tell them.
1908               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1909               ;;
1910             *)
1911               # Silently disable.
1912               add_this_lang=unsupported
1913               ;;
1914           esac
1915         done
1916
1917         # Disable Ada if no preexisting GNAT is available.
1918         case ,${enable_languages},:${language}:${have_gnat} in
1919           *,${language},*:ada:no)
1920             # Specifically requested language; tell them.
1921             AC_MSG_ERROR([GNAT is required to build $language])
1922             ;;
1923           *:ada:no)
1924             # Silently disable.
1925             add_this_lang=unsupported
1926             ;;
1927         esac
1928
1929         # Disable a language that is unsupported by the target.
1930         case " $unsupported_languages " in
1931           *" $language "*)
1932             add_this_lang=unsupported
1933             ;;
1934         esac
1935
1936         case $add_this_lang in
1937           unsupported)
1938             # Remove language-dependent dirs.
1939             disabled_target_libs="$disabled_target_libs $target_libs"
1940             noconfigdirs="$noconfigdirs $lang_dirs"
1941             ;;
1942           no)
1943             # Remove language-dependent dirs; still show language as supported.
1944             disabled_target_libs="$disabled_target_libs $target_libs"
1945             noconfigdirs="$noconfigdirs $lang_dirs"
1946             potential_languages="${potential_languages}${language},"
1947             ;;
1948           yes)
1949             new_enable_languages="${new_enable_languages}${language},"
1950             potential_languages="${potential_languages}${language},"
1951             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1952             enabled_target_libs="$enabled_target_libs $target_libs"
1953             case "${boot_language}:,$enable_stage1_languages," in
1954               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1955                 # Add to (comma-separated) list of stage 1 languages.
1956                 case ",$stage1_languages," in
1957                   *,$language,* | ,yes, | ,all,) ;;
1958                   *) stage1_languages="${stage1_languages}${language}," ;;
1959                 esac
1960                 # We need to bootstrap any supporting libraries.
1961                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1962                 ;;
1963             esac
1964             ;;
1965         esac
1966         ;;
1967     esac
1968   done
1969
1970   # Add target libraries which are only needed for disabled languages
1971   # to noconfigdirs.
1972   if test -n "$disabled_target_libs"; then
1973     for dir in $disabled_target_libs; do
1974       case " $enabled_target_libs " in
1975       *" ${dir} "*) ;;
1976       *) noconfigdirs="$noconfigdirs $dir" ;;
1977       esac
1978     done
1979   fi
1980
1981   AC_ARG_ENABLE(stage1-languages,
1982   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1983                   [choose additional languages to build during
1984                   stage1.  Mostly useful for compiler development])],
1985   [case ,${enable_stage1_languages}, in
1986     ,no,|,,)
1987       # Set it to something that will have no effect in the loop below
1988       enable_stage1_languages=c ;;
1989     ,yes,)
1990       enable_stage1_languages=`echo $new_enable_languages | \
1991         sed -e "s/^,//" -e "s/,$//" ` ;;
1992     *,all,*)
1993       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1994         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1995   esac
1996
1997   # Add "good" languages from enable_stage1_languages to stage1_languages,
1998   # while "bad" languages go in missing_languages.  Leave no duplicates.
1999   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2000     case $potential_languages in
2001       *,$i,*)
2002         case $stage1_languages in
2003           *,$i,*) ;;
2004           *) stage1_languages="$stage1_languages$i," ;;
2005         esac ;;
2006       *)
2007         case $missing_languages in
2008           *,$i,*) ;;
2009           *) missing_languages="$missing_languages$i," ;;
2010         esac ;;
2011      esac
2012   done])
2013
2014   # Remove leading/trailing commas that were added for simplicity
2015   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2016   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2017   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2018   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2019
2020   if test "x$missing_languages" != x; then
2021     AC_MSG_ERROR([
2022 The following requested languages could not be built: ${missing_languages}
2023 Supported languages are: ${potential_languages}])
2024   fi
2025   if test "x$new_enable_languages" != "x$enable_languages"; then
2026     echo The following languages will be built: ${new_enable_languages}
2027     enable_languages="$new_enable_languages"
2028   fi
2029
2030   AC_SUBST(stage1_languages)
2031   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2032 fi
2033
2034 # Handle --disable-<component> generically.
2035 for dir in $configdirs $build_configdirs $target_configdirs ; do
2036   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2037   varname=`echo $dirname | sed -e s/+/_/g`
2038   if eval test x\${enable_${varname}} "=" xno ; then
2039     noconfigdirs="$noconfigdirs $dir"
2040   fi
2041 done
2042
2043 # Check for Boehm's garbage collector
2044 AC_ARG_ENABLE(objc-gc,
2045 [AS_HELP_STRING([--enable-objc-gc],
2046                 [enable use of Boehm's garbage collector with the
2047                  GNU Objective-C runtime])],
2048 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
2049   *,objc,*:*:yes:*target-boehm-gc*)
2050     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2051     ;;
2052 esac])
2053
2054 # Make sure we only build Boehm's garbage collector if required.
2055 case ,${enable_languages},:${enable_objc_gc} in
2056   *,objc,*:yes)
2057     # Keep target-boehm-gc if requested for Objective-C.
2058     ;;
2059   *)
2060     # Otherwise remove target-boehm-gc depending on target-libjava.
2061     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2062       noconfigdirs="$noconfigdirs target-boehm-gc"
2063     fi
2064     ;;
2065 esac
2066
2067 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2068 # $build_configdirs and $target_configdirs.
2069 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2070
2071 notsupp=""
2072 for dir in . $skipdirs $noconfigdirs ; do
2073   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2074   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2075     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2076     if test -r $srcdir/$dirname/configure ; then
2077       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2078         true
2079       else
2080         notsupp="$notsupp $dir"
2081       fi
2082     fi
2083   fi
2084   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2085     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2086     if test -r $srcdir/$dirname/configure ; then
2087       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2088         true
2089       else
2090         notsupp="$notsupp $dir"
2091       fi
2092     fi
2093   fi
2094   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2095     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2096     if test -r $srcdir/$dirname/configure ; then
2097       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2098         true
2099       else
2100         notsupp="$notsupp $dir"
2101       fi
2102     fi
2103   fi
2104 done
2105
2106 # Sometimes the tools are distributed with libiberty but with no other
2107 # libraries.  In that case, we don't want to build target-libiberty.
2108 # Don't let libgcc imply libiberty either.
2109 if test -n "${target_configdirs}" ; then
2110   libgcc=
2111   others=
2112   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
2113     if test "$i" = "libgcc"; then
2114       libgcc=target-libgcc
2115     elif test "$i" != "libiberty" ; then
2116       if test -r $srcdir/$i/configure ; then
2117         others=yes;
2118         break;
2119       fi
2120     fi
2121   done
2122   if test -z "${others}" ; then
2123     target_configdirs=$libgcc
2124   fi
2125 fi
2126
2127 # Quietly strip out all directories which aren't configurable in this tree.
2128 # This relies on all configurable subdirectories being autoconfiscated, which
2129 # is now the case.
2130 build_configdirs_all="$build_configdirs"
2131 build_configdirs=
2132 for i in ${build_configdirs_all} ; do
2133   j=`echo $i | sed -e s/build-//g`
2134   if test -f ${srcdir}/$j/configure ; then
2135     build_configdirs="${build_configdirs} $i"
2136   fi
2137 done
2138
2139 configdirs_all="$configdirs"
2140 configdirs=
2141 for i in ${configdirs_all} ; do
2142   if test -f ${srcdir}/$i/configure ; then
2143     configdirs="${configdirs} $i"
2144   fi
2145 done
2146
2147 target_configdirs_all="$target_configdirs"
2148 target_configdirs=
2149 for i in ${target_configdirs_all} ; do
2150   j=`echo $i | sed -e s/target-//g`
2151   if test -f ${srcdir}/$j/configure ; then
2152     target_configdirs="${target_configdirs} $i"
2153   fi
2154 done
2155
2156 # Produce a warning message for the subdirs we can't configure.
2157 # This isn't especially interesting in the Cygnus tree, but in the individual
2158 # FSF releases, it's important to let people know when their machine isn't
2159 # supported by the one or two programs in a package.
2160
2161 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2162   # If $appdirs is non-empty, at least one of those directories must still
2163   # be configured, or we error out.  (E.g., if the gas release supports a
2164   # specified target in some subdirs but not the gas subdir, we shouldn't
2165   # pretend that all is well.)
2166   if test -n "$appdirs" ; then
2167     for dir in $appdirs ; do
2168       if test -r $dir/Makefile.in ; then
2169         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2170           appdirs=""
2171           break
2172         fi
2173         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2174           appdirs=""
2175           break
2176         fi
2177       fi
2178     done
2179     if test -n "$appdirs" ; then
2180       echo "*** This configuration is not supported by this package." 1>&2
2181       exit 1
2182     fi
2183   fi
2184   # Okay, some application will build, or we don't care to check.  Still
2185   # notify of subdirs not getting built.
2186   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2187   echo "    ${notsupp}" 1>&2
2188   echo "    (Any other directories should still work fine.)" 1>&2
2189 fi
2190
2191 case "$host" in
2192   *msdosdjgpp*)
2193     enable_gdbtk=no ;;
2194 esac
2195
2196 # To find our prefix, in gcc_cv_tool_prefix.
2197 ACX_TOOL_DIRS
2198
2199 copy_dirs=
2200
2201 AC_ARG_WITH([build-sysroot],
2202   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2203                   [use sysroot as the system root during the build])],
2204   [if test x"$withval" != x ; then
2205      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2206    fi],
2207   [SYSROOT_CFLAGS_FOR_TARGET=])
2208 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2209
2210 AC_ARG_WITH([debug-prefix-map],
2211   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2212                   [map A to B, C to D ... in debug information])],
2213   [if test x"$withval" != x; then
2214      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2215      for debug_map in $withval; do
2216        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2217      done
2218    fi],
2219   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2220 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2221
2222 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2223 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2224 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2225 # We want to ensure that TARGET libraries (which we know are built with
2226 # gcc) are built with "-O2 -g", so include those options when setting
2227 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2228 if test "x$CFLAGS_FOR_TARGET" = x; then
2229   CFLAGS_FOR_TARGET=$CFLAGS
2230   case " $CFLAGS " in
2231     *" -O2 "*) ;;
2232     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2233   esac
2234   case " $CFLAGS " in
2235     *" -g "* | *" -g3 "*) ;;
2236     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2237   esac
2238 fi
2239 AC_SUBST(CFLAGS_FOR_TARGET)
2240
2241 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2242   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2243   case " $CXXFLAGS " in
2244     *" -O2 "*) ;;
2245     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2246   esac
2247   case " $CXXFLAGS " in
2248     *" -g "* | *" -g3 "*) ;;
2249     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2250   esac
2251 fi
2252 AC_SUBST(CXXFLAGS_FOR_TARGET)
2253
2254 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2255 # the named directory are copied to $(tooldir)/sys-include.
2256 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2257   if test x${is_cross_compiler} = xno ; then
2258     echo 1>&2 '***' --with-headers is only supported when cross compiling
2259     exit 1
2260   fi
2261   if test x"${with_headers}" != xyes ; then
2262     x=${gcc_cv_tool_prefix}
2263     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2264   fi
2265 fi
2266
2267 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2268 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2269 # are permitted.
2270 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2271   if test x${is_cross_compiler} = xno ; then
2272     echo 1>&2 '***' --with-libs is only supported when cross compiling
2273     exit 1
2274   fi
2275   if test x"${with_libs}" != xyes ; then
2276     # Copy the libraries in reverse order, so that files in the first named
2277     # library override files in subsequent libraries.
2278     x=${gcc_cv_tool_prefix}
2279     for l in ${with_libs}; do
2280       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2281     done
2282   fi
2283 fi
2284
2285 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2286 #
2287 # This is done by determining whether or not the appropriate directory
2288 # is available, and by checking whether or not specific configurations
2289 # have requested that this magic not happen.
2290 #
2291 # The command line options always override the explicit settings in
2292 # configure.in, and the settings in configure.in override this magic.
2293 #
2294 # If the default for a toolchain is to use GNU as and ld, and you don't
2295 # want to do that, then you should use the --without-gnu-as and
2296 # --without-gnu-ld options for the configure script.  Similarly, if
2297 # the default is to use the included zlib and you don't want to do that,
2298 # you should use the --with-system-zlib option for the configure script.
2299
2300 if test x${use_gnu_as} = x &&
2301    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2302   with_gnu_as=yes
2303   extra_host_args="$extra_host_args --with-gnu-as"
2304 fi
2305
2306 if test x${use_gnu_ld} = x &&
2307    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2308   with_gnu_ld=yes
2309   extra_host_args="$extra_host_args --with-gnu-ld"
2310 fi
2311
2312 if test x${use_included_zlib} = x &&
2313    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2314   :
2315 else
2316   with_system_zlib=yes
2317   extra_host_args="$extra_host_args --with-system-zlib"
2318 fi
2319
2320 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2321 # can detect this case.
2322
2323 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2324   with_newlib=yes
2325   extra_host_args="$extra_host_args --with-newlib"
2326 fi
2327
2328 # Handle ${copy_dirs}
2329 set fnord ${copy_dirs}
2330 shift
2331 while test $# != 0 ; do
2332   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2333     :
2334   else
2335     echo Copying $1 to $2
2336
2337     # Use the install script to create the directory and all required
2338     # parent directories.
2339     if test -d $2 ; then
2340       :
2341     else
2342       echo >config.temp
2343       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2344     fi
2345
2346     # Copy the directory, assuming we have tar.
2347     # FIXME: Should we use B in the second tar?  Not all systems support it.
2348     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2349
2350     # It is the responsibility of the user to correctly adjust all
2351     # symlinks.  If somebody can figure out how to handle them correctly
2352     # here, feel free to add the code.
2353
2354     echo $1 > $2/COPIED
2355   fi
2356   shift; shift
2357 done
2358
2359 # Determine a target-dependent exec_prefix that the installed
2360 # gcc will search in.  Keep this list sorted by triplet, with
2361 # the *-*-osname triplets last.
2362 md_exec_prefix=
2363 case "${target}" in
2364   alpha*-*-*vms*)
2365     md_exec_prefix=/gnu/lib/gcc-lib
2366     ;;
2367   i[[34567]]86-pc-msdosdjgpp*)
2368     md_exec_prefix=/dev/env/DJDIR/bin
2369     ;;
2370   i[[34567]]86-*-sco3.2v5*)
2371     if test $with_gnu_as = yes; then
2372       md_exec_prefix=/usr/gnu/bin
2373     else
2374       md_exec_prefix=/usr/ccs/bin/elf
2375     fi
2376     ;;
2377
2378   mn10300-*-* | \
2379   powerpc-*-chorusos* | \
2380   powerpc*-*-eabi* | \
2381   powerpc*-*-sysv* | \
2382   powerpc*-*-kaos* | \
2383   s390x-ibm-tpf*)
2384     md_exec_prefix=/usr/ccs/bin
2385     ;;
2386   sparc64-*-elf*)
2387     ;;
2388   v850*-*-*)
2389     md_exec_prefix=/usr/ccs/bin
2390     ;;
2391   xtensa*-*-elf*)
2392     ;;
2393
2394   *-*-beos* | \
2395   *-*-elf* | \
2396   *-*-hpux* | \
2397   *-*-netware* | \
2398   *-*-nto-qnx* | \
2399   *-*-rtems* | \
2400   *-*-solaris2* | \
2401   *-*-sysv[[45]]* | \
2402   *-*-vxworks* | \
2403   *-wrs-windiss)
2404     md_exec_prefix=/usr/ccs/bin
2405     ;;
2406 esac
2407
2408 extra_arflags_for_target=
2409 extra_nmflags_for_target=
2410 extra_ranlibflags_for_target=
2411 target_makefile_frag=/dev/null
2412 case "${target}" in
2413   mep*-*-*)
2414     target_makefile_frag="config/mt-mep"
2415     ;;
2416   spu-*-*)
2417     target_makefile_frag="config/mt-spu"
2418     ;;
2419   mips*-sde-elf*)
2420     target_makefile_frag="config/mt-sde"
2421     ;;
2422   mipsisa*-*-elfoabi*)
2423     target_makefile_frag="config/mt-mips-elfoabi"
2424     ;;
2425   mips*-*-*linux* | mips*-*-gnu*)
2426     target_makefile_frag="config/mt-mips-gnu"
2427     ;;
2428   *-*-netware*)
2429     target_makefile_frag="config/mt-netware"
2430     ;;
2431   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2432     target_makefile_frag="config/mt-gnu"
2433     ;;
2434   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2435     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2436     # commands to handle both 32-bit and 64-bit objects.  These flags are
2437     # harmless if we're using GNU nm or ar.
2438     extra_arflags_for_target=" -X32_64"
2439     extra_nmflags_for_target=" -B -X32_64"
2440     ;;
2441   *-*-darwin[[3-9]]*)
2442     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2443     extra_ranlibflags_for_target=" -c"
2444     ;;
2445   mips*-*-pe | sh*-*-pe | *arm-wince-pe)
2446     target_makefile_frag="config/mt-wince"
2447     ;;
2448 esac
2449
2450 alphaieee_frag=/dev/null
2451 case $target in
2452   alpha*-*-*)
2453     # This just makes sure to use the -mieee option to build target libs.
2454     # This should probably be set individually by each library.
2455     alphaieee_frag="config/mt-alphaieee"
2456     ;;
2457 esac
2458
2459 # If --enable-target-optspace always use -Os instead of -O2 to build
2460 # the target libraries, similarly if it is not specified, use -Os
2461 # on selected platforms.
2462 ospace_frag=/dev/null
2463 case "${enable_target_optspace}:${target}" in
2464   yes:*)
2465     ospace_frag="config/mt-ospace"
2466     ;;
2467   :d30v-*)
2468     ospace_frag="config/mt-d30v"
2469     ;;
2470   :m32r-* | :d10v-* | :fr30-*)
2471     ospace_frag="config/mt-ospace"
2472     ;;
2473   no:* | :*)
2474     ;;
2475   *)
2476     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2477     ;;
2478 esac
2479
2480 # Default to using --with-stabs for certain targets.
2481 if test x${with_stabs} = x ; then
2482   case "${target}" in
2483   mips*-*-irix[[56]]*)
2484     ;;
2485   mips*-*-* | alpha*-*-osf*)
2486     with_stabs=yes;
2487     extra_host_args="${extra_host_args} --with-stabs"
2488     ;;
2489   esac
2490 fi
2491
2492 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2493 # them automatically.
2494 case "${host}" in
2495   hppa*64*-*-hpux11*)
2496     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2497     ;;
2498 esac
2499
2500 # Some systems (e.g., one of the i386-aix systems the gas testers are
2501 # using) don't handle "\$" correctly, so don't use it here.
2502 tooldir='${exec_prefix}'/${target_noncanonical}
2503 build_tooldir=${tooldir}
2504
2505 # Create a .gdbinit file which runs the one in srcdir
2506 # and tells GDB to look there for source files.
2507
2508 if test -r ${srcdir}/.gdbinit ; then
2509   case ${srcdir} in
2510     .) ;;
2511     *) cat > ./.gdbinit <<EOF
2512 # ${NO_EDIT}
2513 dir ${srcdir}
2514 dir .
2515 source ${srcdir}/.gdbinit
2516 EOF
2517     ;;
2518   esac
2519 fi
2520
2521 # Make sure that the compiler is able to generate an executable.  If it
2522 # can't, we are probably in trouble.  We don't care whether we can run the
2523 # executable--we might be using a cross compiler--we only care whether it
2524 # can be created.  At this point the main configure script has set CC.
2525 we_are_ok=no
2526 echo "int main () { return 0; }" > conftest.c
2527 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2528 if test $? = 0 ; then
2529   if test -s conftest || test -s conftest.exe ; then
2530     we_are_ok=yes
2531   fi
2532 fi
2533 case $we_are_ok in
2534   no)
2535     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2536     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2537     rm -f conftest*
2538     exit 1
2539     ;;
2540 esac
2541 rm -f conftest*
2542
2543 # The Solaris /usr/ucb/cc compiler does not appear to work.
2544 case "${host}" in
2545   sparc-sun-solaris2*)
2546       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2547       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2548           could_use=
2549           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2550           if test -d /opt/cygnus/bin ; then
2551               if test "$could_use" = "" ; then
2552                   could_use="/opt/cygnus/bin"
2553               else
2554                   could_use="$could_use or /opt/cygnus/bin"
2555               fi
2556           fi
2557         if test "$could_use" = "" ; then
2558             echo "Warning: compilation may fail because you're using"
2559             echo "/usr/ucb/cc.  You should change your PATH or CC "
2560             echo "variable and rerun configure."
2561         else
2562             echo "Warning: compilation may fail because you're using"
2563             echo "/usr/ucb/cc, when you should use the C compiler from"
2564             echo "$could_use.  You should change your"
2565             echo "PATH or CC variable and rerun configure."
2566         fi
2567       fi
2568   ;;
2569 esac
2570
2571 # Decide which environment variable is used to find dynamic libraries.
2572 case "${host}" in
2573   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2574   *-*-darwin* | *-*-rhapsody* ) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2575   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2576   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2577 esac
2578
2579 # On systems where the dynamic library environment variable is PATH,
2580 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2581 # built executables to PATH.
2582 if test "$RPATH_ENVVAR" = PATH; then
2583   GCC_SHLIB_SUBDIR=/shlib
2584 else
2585   GCC_SHLIB_SUBDIR=
2586 fi
2587
2588 # Record target_configdirs and the configure arguments for target and
2589 # build configuration in Makefile.
2590 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2591 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2592
2593 # If we are building libgomp, bootstrap it.
2594 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2595   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2596 fi
2597
2598 # Determine whether gdb needs tk/tcl or not.
2599 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2600 # and in that case we want gdb to be built without tk.  Ugh!
2601 # In fact I believe gdb is the *only* package directly dependent on tk,
2602 # so we should be able to put the 'maybe's in unconditionally and
2603 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2604 # 100% sure that that's safe though.
2605
2606 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2607 case "$enable_gdbtk" in
2608   no)
2609     GDB_TK="" ;;
2610   yes)
2611     GDB_TK="${gdb_tk}" ;;
2612   *)
2613     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2614     # distro.  Eventually someone will fix this and move Insight, nee
2615     # gdbtk to a separate directory.
2616     if test -d ${srcdir}/gdb/gdbtk ; then
2617       GDB_TK="${gdb_tk}"
2618     else
2619       GDB_TK=""
2620     fi
2621     ;;
2622 esac
2623 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2624 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2625
2626 # Strip out unwanted targets.
2627
2628 # While at that, we remove Makefiles if we were started for recursive
2629 # configuration, so that the top-level Makefile reconfigures them,
2630 # like we used to do when configure itself was recursive.
2631
2632 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2633 # but now we're fixing up the Makefile ourselves with the additional
2634 # commands passed to AC_CONFIG_FILES.  Use separate variables
2635 # extrasub-{build,host,target} not because there is any reason to split
2636 # the substitutions up that way, but only to remain below the limit of
2637 # 99 commands in a script, for HP-UX sed.
2638 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2639
2640 AC_ARG_ENABLE([bootstrap],
2641 [AS_HELP_STRING([--enable-bootstrap],
2642                 [enable bootstrapping @<:@yes if native build@:>@])],,
2643 enable_bootstrap=default)
2644
2645 # Issue errors and warnings for invalid/strange bootstrap combinations.
2646 case "$configdirs" in
2647   *gcc*) have_compiler=yes ;;
2648   *) have_compiler=no ;;
2649 esac
2650
2651 case "$have_compiler:$host:$target:$enable_bootstrap" in
2652   *:*:*:no) ;;
2653
2654   # Default behavior.  Enable bootstrap if we have a compiler
2655   # and we are in a native configuration.
2656   yes:$build:$build:default)
2657     enable_bootstrap=yes ;;
2658
2659   *:*:*:default)
2660     enable_bootstrap=no ;;
2661
2662   # We have a compiler and we are in a native configuration, bootstrap is ok
2663   yes:$build:$build:yes)
2664     ;;
2665
2666   # Other configurations, but we have a compiler.  Assume the user knows
2667   # what he's doing.
2668   yes:*:*:yes)
2669     AC_MSG_WARN([trying to bootstrap a cross compiler])
2670     ;;
2671
2672   # No compiler: if they passed --enable-bootstrap explicitly, fail
2673   no:*:*:yes)
2674     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2675
2676   # Fail if wrong command line
2677   *)
2678     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2679     ;;
2680 esac
2681
2682 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2683   *,c++,*:yes:yes) ;;
2684   *:yes:yes)
2685     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2686     ;;
2687 esac
2688
2689 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2690   yes:yes:*\ gold\ *:*,c++,*) ;;
2691   yes:yes:*\ gold\ *:*)
2692     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2693     ;;
2694 esac
2695
2696 # Adjust the toplevel makefile according to whether bootstrap was selected.
2697 case $enable_bootstrap in
2698   yes)
2699     bootstrap_suffix=bootstrap
2700     BUILD_CONFIG=bootstrap-debug
2701     ;;
2702   no)
2703     bootstrap_suffix=no-bootstrap
2704     BUILD_CONFIG=
2705     ;;
2706 esac
2707
2708 AC_MSG_CHECKING(for default BUILD_CONFIG)
2709
2710 AC_ARG_WITH([build-config],
2711   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2712                   [use config/NAME.mk build configuration])],
2713   [case $with_build_config in
2714    yes) with_build_config= ;;
2715    no) with_build_config= BUILD_CONFIG= ;;
2716    esac])
2717
2718 if test "x${with_build_config}" != x; then
2719   BUILD_CONFIG=$with_build_config
2720 else
2721   case $BUILD_CONFIG in
2722   bootstrap-debug)
2723     if echo "int f (void) { return 0; }" > conftest.c &&
2724        ${CC} -c conftest.c &&
2725        mv conftest.o conftest.o.g0 &&
2726        ${CC} -c -g conftest.c &&
2727        mv conftest.o conftest.o.g &&
2728        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2729       :
2730     else
2731       BUILD_CONFIG=
2732     fi
2733     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2734     ;;
2735   esac
2736 fi
2737 AC_MSG_RESULT($BUILD_CONFIG)
2738 AC_SUBST(BUILD_CONFIG)
2739
2740 extrasub_build=
2741 for module in ${build_configdirs} ; do
2742   if test -z "${no_recursion}" \
2743      && test -f ${build_subdir}/${module}/Makefile; then
2744     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2745     rm -f ${build_subdir}/${module}/Makefile
2746   fi
2747   extrasub_build="$extrasub_build
2748 /^@if build-$module\$/d
2749 /^@endif build-$module\$/d
2750 /^@if build-$module-$bootstrap_suffix\$/d
2751 /^@endif build-$module-$bootstrap_suffix\$/d"
2752 done
2753 extrasub_host=
2754 for module in ${configdirs} ; do
2755   if test -z "${no_recursion}"; then
2756     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2757       if test -f ${file}; then
2758         echo 1>&2 "*** removing ${file} to force reconfigure"
2759         rm -f ${file}
2760       fi
2761     done
2762   fi
2763   extrasub_host="$extrasub_host
2764 /^@if $module\$/d
2765 /^@endif $module\$/d
2766 /^@if $module-$bootstrap_suffix\$/d
2767 /^@endif $module-$bootstrap_suffix\$/d"
2768 done
2769 extrasub_target=
2770 for module in ${target_configdirs} ; do
2771   if test -z "${no_recursion}" \
2772      && test -f ${target_subdir}/${module}/Makefile; then
2773     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2774     rm -f ${target_subdir}/${module}/Makefile
2775   fi
2776
2777   # We only bootstrap target libraries listed in bootstrap_target_libs.
2778   case $bootstrap_target_libs in
2779     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2780     *) target_bootstrap_suffix=no-bootstrap ;;
2781   esac
2782
2783   extrasub_target="$extrasub_target
2784 /^@if target-$module\$/d
2785 /^@endif target-$module\$/d
2786 /^@if target-$module-$target_bootstrap_suffix\$/d
2787 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2788 done
2789
2790 # Do the final fixup along with target modules.
2791 extrasub_target="$extrasub_target
2792 /^@if /,/^@endif /d"
2793
2794 # Create the serialization dependencies.  This uses a temporary file.
2795
2796 AC_ARG_ENABLE([serial-configure],
2797 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2798                 [force sequential configuration of
2799                  sub-packages for the host, target or build
2800                  machine, or all sub-packages])])
2801
2802 case ${enable_serial_configure} in
2803   yes)
2804     enable_serial_build_configure=yes
2805     enable_serial_host_configure=yes
2806     enable_serial_target_configure=yes
2807     ;;
2808 esac
2809
2810 # These force 'configure's to be done one at a time, to avoid problems
2811 # with contention over a shared config.cache.
2812 rm -f serdep.tmp
2813 echo '# serdep.tmp' > serdep.tmp
2814 olditem=
2815 test "x${enable_serial_build_configure}" = xyes &&
2816 for item in ${build_configdirs} ; do
2817   case ${olditem} in
2818     "") ;;
2819     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2820   esac
2821   olditem=${item}
2822 done
2823 olditem=
2824 test "x${enable_serial_host_configure}" = xyes &&
2825 for item in ${configdirs} ; do
2826   case ${olditem} in
2827     "") ;;
2828     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2829   esac
2830   olditem=${item}
2831 done
2832 olditem=
2833 test "x${enable_serial_target_configure}" = xyes &&
2834 for item in ${target_configdirs} ; do
2835   case ${olditem} in
2836     "") ;;
2837     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2838   esac
2839   olditem=${item}
2840 done
2841 serialization_dependencies=serdep.tmp
2842 AC_SUBST_FILE(serialization_dependencies)
2843
2844 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2845 # target, nonopt, and variable assignments.  These are the ones we
2846 # might not want to pass down to subconfigures.  The exception being
2847 # --cache-file=/dev/null, which is used to turn off the use of cache
2848 # files altogether, and which should be passed on to subconfigures.
2849 # Also strip program-prefix, program-suffix, and program-transform-name,
2850 # so that we can pass down a consistent program-transform-name.
2851 baseargs=
2852 keep_next=no
2853 skip_next=no
2854 eval "set -- $ac_configure_args"
2855 for ac_arg
2856 do
2857   if test X"$skip_next" = X"yes"; then
2858     skip_next=no
2859     continue
2860   fi
2861   if test X"$keep_next" = X"yes"; then
2862     case $ac_arg in
2863       *\'*)
2864         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2865     esac
2866     baseargs="$baseargs '$ac_arg'"
2867     keep_next=no
2868     continue
2869   fi
2870
2871   # Handle separated arguments.  Based on the logic generated by
2872   # autoconf 2.59.
2873   case $ac_arg in
2874     *=* | --config-cache | -C | -disable-* | --disable-* \
2875       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2876       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2877       | -with-* | --with-* | -without-* | --without-* | --x)
2878       separate_arg=no
2879       ;;
2880     -*)
2881       separate_arg=yes
2882       ;;
2883     *)
2884       separate_arg=no
2885       ;;
2886   esac
2887
2888   case "$ac_arg" in
2889     --cache-file=/dev/null | \
2890     -cache-file=/dev/null )
2891       # Handled here to avoid the test to skip args below.
2892       baseargs="$baseargs '$ac_arg'"
2893       # Assert: $separate_arg should always be no.
2894       keep_next=$separate_arg
2895       ;;
2896     --no*)
2897       continue
2898       ;;
2899     --c* | \
2900     --sr* | \
2901     --ho* | \
2902     --bu* | \
2903     --t* | \
2904     --program-* | \
2905     -cache_file* | \
2906     -srcdir* | \
2907     -host* | \
2908     -build* | \
2909     -target* | \
2910     -program-prefix* | \
2911     -program-suffix* | \
2912     -program-transform-name* )
2913       skip_next=$separate_arg
2914       continue
2915       ;;
2916     -*)
2917       # An option.  Add it.
2918       case $ac_arg in
2919         *\'*)
2920           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2921       esac
2922       baseargs="$baseargs '$ac_arg'"
2923       keep_next=$separate_arg
2924       ;;
2925     *)
2926       # Either a variable assignment, or a nonopt (triplet).  Don't
2927       # pass it down; let the Makefile handle this.
2928       continue
2929       ;;
2930   esac
2931 done
2932 # Remove the initial space we just introduced and, as these will be
2933 # expanded by make, quote '$'.
2934 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2935
2936 # Add in --program-transform-name, after --program-prefix and
2937 # --program-suffix have been applied to it.  Autoconf has already
2938 # doubled dollar signs and backslashes in program_transform_name; we want
2939 # the backslashes un-doubled, and then the entire thing wrapped in single
2940 # quotes, because this will be expanded first by make and then by the shell.
2941 # Also, because we want to override the logic in subdir configure scripts to
2942 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2943 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2944 ${program_transform_name}
2945 EOF_SED
2946 gcc_transform_name=`cat conftestsed.out`
2947 rm -f conftestsed.out
2948 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2949 if test "$silent" = yes; then
2950   baseargs="$baseargs --silent"
2951 fi
2952 baseargs="$baseargs --disable-option-checking"
2953
2954 # Record and document user additions to sub configure arguments.
2955 AC_ARG_VAR([build_configargs],
2956            [additional configure arguments for build directories])
2957 AC_ARG_VAR([host_configargs],
2958            [additional configure arguments for host directories])
2959 AC_ARG_VAR([target_configargs],
2960            [additional configure arguments for target directories])
2961
2962 # For the build-side libraries, we just need to pretend we're native,
2963 # and not use the same cache file.  Multilibs are neither needed nor
2964 # desired.
2965 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2966
2967 # For host modules, accept cache file option, or specification as blank.
2968 case "${cache_file}" in
2969 "") # empty
2970   cache_file_option="" ;;
2971 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2972   cache_file_option="--cache-file=${cache_file}" ;;
2973 *) # relative path
2974   cache_file_option="--cache-file=../${cache_file}" ;;
2975 esac
2976
2977 # Host dirs don't like to share a cache file either, horribly enough.
2978 # This seems to be due to autoconf 2.5x stupidity.
2979 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2980
2981 target_configargs="$target_configargs ${baseargs}"
2982
2983 # Passing a --with-cross-host argument lets the target libraries know
2984 # whether they are being built with a cross-compiler or being built
2985 # native.  However, it would be better to use other mechanisms to make the
2986 # sorts of decisions they want to make on this basis.  Please consider
2987 # this option to be deprecated.  FIXME.
2988 if test x${is_cross_compiler} = xyes ; then
2989   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2990 fi
2991
2992 # Default to --enable-multilib.
2993 if test x${enable_multilib} = x ; then
2994   target_configargs="--enable-multilib ${target_configargs}"
2995 fi
2996
2997 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2998 # changed from the earlier setting of with_newlib.
2999 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3000   target_configargs="--with-newlib ${target_configargs}"
3001 fi
3002
3003 # Different target subdirs use different values of certain variables
3004 # (notably CXX).  Worse, multilibs use *lots* of different values.
3005 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3006 # it doesn't automatically accept command-line overrides of them.
3007 # This means it's not safe for target subdirs to share a cache file,
3008 # which is disgusting, but there you have it.  Hopefully this can be
3009 # fixed in future.  It's still worthwhile to use a cache file for each
3010 # directory.  I think.
3011
3012 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3013 # We need to pass --target, as newer autoconf's requires consistency
3014 # for target_alias and gcc doesn't manage it consistently.
3015 target_configargs="--cache-file=./config.cache ${target_configargs}"
3016
3017 FLAGS_FOR_TARGET=
3018 case " $target_configdirs " in
3019  *" newlib "*)
3020   case " $target_configargs " in
3021   *" --with-newlib "*)
3022    case "$target" in
3023     *-cygwin*)
3024       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
3025       ;;
3026    esac
3027
3028    # If we're not building GCC, don't discard standard headers.
3029    if test -d ${srcdir}/gcc; then
3030      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3031
3032      if test "${build}" != "${host}"; then
3033        # On Canadian crosses, CC_FOR_TARGET will have already been set
3034        # by `configure', so we won't have an opportunity to add -Bgcc/
3035        # to it.  This is right: we don't want to search that directory
3036        # for binaries, but we want the header files in there, so add
3037        # them explicitly.
3038        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3039
3040        # Someone might think of using the pre-installed headers on
3041        # Canadian crosses, in case the installed compiler is not fully
3042        # compatible with the compiler being built.  In this case, it
3043        # would be better to flag an error than risking having
3044        # incompatible object files being constructed.  We can't
3045        # guarantee that an error will be flagged, but let's hope the
3046        # compiler will do it, when presented with incompatible header
3047        # files.
3048      fi
3049    fi
3050
3051    case "${target}-${is_cross_compiler}" in
3052    i[[3456789]]86-*-linux*-no)
3053       # Here host == target, so we don't need to build gcc,
3054       # so we don't want to discard standard headers.
3055       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3056       ;;
3057    *)
3058       # If we're building newlib, use its generic headers last, but search
3059       # for any libc-related directories first (so make it the last -B
3060       # switch).
3061       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3062
3063       # If we're building libgloss, find the startup file, simulator library
3064       # and linker script.
3065       case " $target_configdirs " in
3066         *" libgloss "*)
3067         # Look for startup file, simulator library and maybe linker script.
3068         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3069         # Look for libnosys.a in case the target needs it.
3070         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3071         # Most targets have the linker script in the source directory.
3072         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3073         ;;
3074       esac
3075       ;;
3076    esac
3077    ;;
3078   esac
3079   ;;
3080 esac
3081
3082 case "$target" in
3083   x86_64-*mingw* | *-w64-mingw*)
3084   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3085   # however, use a symlink named 'mingw' in ${prefix} .
3086     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3087     ;;
3088   *-mingw*)
3089   # MinGW can't be handled as Cygwin above since it does not use newlib.
3090     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3091     ;;
3092 esac
3093
3094 # Allow the user to override the flags for
3095 # our build compiler if desired.
3096 if test x"${build}" = x"${host}" ; then
3097   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3098   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3099   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3100 fi
3101
3102 # On Canadian crosses, we'll be searching the right directories for
3103 # the previously-installed cross compiler, so don't bother to add
3104 # flags for directories within the install tree of the compiler
3105 # being built; programs in there won't even run.
3106 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3107   # Search for pre-installed headers if nothing else fits.
3108   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3109 fi
3110
3111 if test "x${use_gnu_ld}" = x &&
3112    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3113   # Arrange for us to find uninstalled linker scripts.
3114   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3115 fi
3116
3117 # Search for other target-specific linker scripts and such.
3118 case "${target}" in
3119   mep*)
3120     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3121     ;;
3122 esac
3123
3124 # Makefile fragments.
3125 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3126 do
3127   eval fragval=\$$frag
3128   if test $fragval != /dev/null; then
3129     eval $frag=${srcdir}/$fragval
3130   fi
3131 done
3132 AC_SUBST_FILE(host_makefile_frag)
3133 AC_SUBST_FILE(target_makefile_frag)
3134 AC_SUBST_FILE(alphaieee_frag)
3135 AC_SUBST_FILE(ospace_frag)
3136
3137 # Miscellanea: directories, flags, etc.
3138 AC_SUBST(RPATH_ENVVAR)
3139 AC_SUBST(GCC_SHLIB_SUBDIR)
3140 AC_SUBST(tooldir)
3141 AC_SUBST(build_tooldir)
3142 AC_SUBST(CONFIGURE_GDB_TK)
3143 AC_SUBST(GDB_TK)
3144 AC_SUBST(INSTALL_GDB_TK)
3145
3146 # Build module lists & subconfigure args.
3147 AC_SUBST(build_configargs)
3148 AC_SUBST(build_configdirs)
3149
3150 # Host module lists & subconfigure args.
3151 AC_SUBST(host_configargs)
3152 AC_SUBST(configdirs)
3153 AC_SUBST(target_configdirs)
3154
3155 # Target module lists & subconfigure args.
3156 AC_SUBST(target_configargs)
3157
3158
3159 # Build tools.
3160 AC_SUBST(AR_FOR_BUILD)
3161 AC_SUBST(AS_FOR_BUILD)
3162 AC_SUBST(CC_FOR_BUILD)
3163 AC_SUBST(CFLAGS_FOR_BUILD)
3164 AC_SUBST(CXXFLAGS_FOR_BUILD)
3165 AC_SUBST(CXX_FOR_BUILD)
3166 AC_SUBST(DLLTOOL_FOR_BUILD)
3167 AC_SUBST(GCJ_FOR_BUILD)
3168 AC_SUBST(GFORTRAN_FOR_BUILD)
3169 AC_SUBST(GOC_FOR_BUILD)
3170 AC_SUBST(LDFLAGS_FOR_BUILD)
3171 AC_SUBST(LD_FOR_BUILD)
3172 AC_SUBST(NM_FOR_BUILD)
3173 AC_SUBST(RANLIB_FOR_BUILD)
3174 AC_SUBST(WINDMC_FOR_BUILD)
3175 AC_SUBST(WINDRES_FOR_BUILD)
3176 AC_SUBST(config_shell)
3177
3178 # Generate default definitions for YACC, M4, LEX and other programs that run
3179 # on the build machine.  These are used if the Makefile can't locate these
3180 # programs in objdir.
3181 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3182
3183 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3184 case " $build_configdirs " in
3185   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3186   *" byacc "*) YACC='$$r/$(BUILD_SUBDIR)/byacc/byacc' ;;
3187 esac
3188
3189 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3190 case " $build_configdirs " in
3191   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3192 esac
3193
3194 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3195 case " $build_configdirs " in
3196   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3197 esac
3198
3199 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3200 case " $build_configdirs " in
3201   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3202   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3203 esac
3204
3205 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3206 case " $build_configdirs " in
3207   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3208 esac
3209
3210 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3211 case " $build_configdirs " in
3212   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3213   *)
3214 changequote(,)
3215     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3216     # higher, else we use the "missing" dummy.
3217     if ${MAKEINFO} --version \
3218        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3219       :
3220     else
3221       MAKEINFO="$MISSING makeinfo"
3222     fi
3223     ;;
3224 changequote([,])
3225 esac
3226
3227 # FIXME: expect and dejagnu may become build tools?
3228
3229 AC_CHECK_PROGS(EXPECT, expect, expect)
3230 case " $configdirs " in
3231   *" expect "*)
3232     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3233     ;;
3234 esac
3235
3236 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3237 case " $configdirs " in
3238   *" dejagnu "*)
3239     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3240     ;;
3241 esac
3242
3243
3244 # Host tools.
3245 NCN_STRICT_CHECK_TOOLS(AR, ar)
3246 NCN_STRICT_CHECK_TOOLS(AS, as)
3247 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3248 NCN_STRICT_CHECK_TOOLS(LD, ld)
3249 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3250 NCN_STRICT_CHECK_TOOLS(NM, nm)
3251 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3252 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3253 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3254 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3255 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3256 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3257 AC_SUBST(CC)
3258 AC_SUBST(CXX)
3259 AC_SUBST(CFLAGS)
3260 AC_SUBST(CXXFLAGS)
3261
3262 # Target tools.
3263 AC_ARG_WITH([build-time-tools],
3264   [AS_HELP_STRING([--with-build-time-tools=PATH],
3265                   [use given path to find target tools during the build])],
3266   [case x"$withval" in
3267      x/*) ;;
3268      *)
3269        with_build_time_tools=
3270        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3271        ;;
3272    esac],
3273   [with_build_time_tools=])
3274
3275 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3276 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3277 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3278 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3279 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3280 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3281
3282 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3283 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3284 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3285 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3286 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3287 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3288 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3289 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3290 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3291 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3292 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3293
3294 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3295
3296 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3297 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3298 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3299 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3300 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3301                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3302                 c++)
3303 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3304                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3305                 c++)
3306 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3307 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3308 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3309                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3310 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3311                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3312 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3313                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3314 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3315 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3316 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3317 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3318 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3319 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3320 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3321 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3322
3323 AC_SUBST(FLAGS_FOR_TARGET)
3324 AC_SUBST(RAW_CXX_FOR_TARGET)
3325
3326 # Certain tools may need extra flags.
3327 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3328 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3329 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3330
3331 # When building target libraries, except in a Canadian cross, we use
3332 # the same toolchain as the compiler we just built.
3333 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3334 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3335 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3336 if test $host = $build; then
3337   case " $configdirs " in
3338     *" gcc "*)
3339       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3340       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3341       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3342       ;;
3343   esac
3344 fi
3345
3346 AC_SUBST(COMPILER_AS_FOR_TARGET)
3347 AC_SUBST(COMPILER_LD_FOR_TARGET)
3348 AC_SUBST(COMPILER_NM_FOR_TARGET)
3349
3350 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3351 AC_ARG_ENABLE(maintainer-mode,
3352 [AS_HELP_STRING([--enable-maintainer-mode],
3353                 [enable make rules and dependencies not useful
3354                  (and sometimes confusing) to the casual installer])],
3355       USE_MAINTAINER_MODE=$enableval,
3356       USE_MAINTAINER_MODE=no)
3357 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3358 AC_SUBST(MAINTAINER_MODE_TRUE)
3359 AC_SUBST(MAINTAINER_MODE_FALSE)
3360 if test "$USE_MAINTAINER_MODE" = yes; then
3361   MAINTAINER_MODE_TRUE=
3362   MAINTAINER_MODE_FALSE='#'
3363 else
3364   MAINTAINER_MODE_TRUE='#'
3365   MAINTAINER_MODE_FALSE=
3366 fi
3367 MAINT=$MAINTAINER_MODE_TRUE
3368 AC_SUBST(MAINT)dnl
3369
3370 # ---------------------
3371 # GCC bootstrap support
3372 # ---------------------
3373
3374 # Stage specific cflags for build.
3375 stage1_cflags="-g"
3376 case $build in
3377   vax-*-*)
3378     case ${GCC} in
3379       yes) stage1_cflags="-g -Wa,-J" ;;
3380       *) stage1_cflags="-g -J" ;;
3381     esac ;;
3382 esac
3383
3384 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3385 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3386   saved_CFLAGS="$CFLAGS"
3387
3388   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3389   CFLAGS="$CFLAGS -fkeep-inline-functions"
3390   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3391   AC_TRY_COMPILE([
3392 #if (__GNUC__ < 3) \
3393     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3394                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3395 #error http://gcc.gnu.org/PR29382
3396 #endif
3397     ],,
3398     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3399     [AC_MSG_RESULT([no])])
3400
3401   CFLAGS="$saved_CFLAGS"
3402 fi
3403
3404 AC_SUBST(stage1_cflags)
3405
3406 # Enable --enable-checking in stage1 of the compiler.
3407 AC_ARG_ENABLE(stage1-checking,
3408 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3409                 [choose additional checking for stage1 of the compiler])],
3410 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3411 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3412   stage1_checking=--enable-checking=yes,types
3413 else
3414   stage1_checking=--enable-checking=$enable_checking,types
3415 fi])
3416 AC_SUBST(stage1_checking)
3417
3418 # Enable -Werror in bootstrap stage2 and later.
3419 AC_ARG_ENABLE(werror,
3420 [AS_HELP_STRING([--enable-werror],
3421                 [enable -Werror in bootstrap stage2 and later])], [],
3422 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3423   enable_werror=yes
3424 else
3425   enable_werror=no
3426 fi])
3427 case ${enable_werror} in
3428   yes) stage2_werror_flag="--enable-werror-always" ;;
3429   *) stage2_werror_flag="" ;;
3430 esac
3431 AC_SUBST(stage2_werror_flag)
3432
3433 # Specify what files to not compare during bootstrap.
3434
3435 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3436 case "$target" in
3437   hppa*64*-*-hpux*) ;;
3438   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3439 esac
3440 case " $configdirs " in
3441 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3442 esac
3443 AC_SUBST(compare_exclusions)
3444
3445 AC_CONFIG_FILES([Makefile],
3446   [sed "$extrasub_build" Makefile |
3447    sed "$extrasub_host" |
3448    sed "$extrasub_target" > mf$$
3449    mv -f mf$$ Makefile],
3450   [extrasub_build="$extrasub_build"
3451    extrasub_host="$extrasub_host"
3452    extrasub_target="$extrasub_target"])
3453 AC_OUTPUT