configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation,
   3 #   Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25
  26 AC_INIT(move-if-change)
  27 AC_PREREQ(2.64)
  28 AC_DISABLE_OPTION_CHECKING
  29
  30 progname=$0
  31 # if PWD already has a value, it is probably wrong.
  32 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  33
  34 # Export original configure arguments for use by sub-configures.
  35 # Quote arguments with shell meta charatcers.
  36 TOPLEVEL_CONFIGURE_ARGUMENTS=
  37 set -- "$progname" "$@"
  38 for ac_arg
  39 do
  40   case "$ac_arg" in
  41   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  42     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  43     # if the argument is of the form -foo=baz, quote the baz part only
  44     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  45   *) ;;
  46   esac
  47   # Add the quoted argument to the list.
  48   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  49 done
  50 if test "$silent" = yes; then
  51   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  52 fi
  53 # Remove the initial space we just introduced and, as these will be
  54 # expanded by make, quote '$'.
  55 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  56 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  57
  58 # Find the build, host, and target systems.
  59 ACX_NONCANONICAL_BUILD
  60 ACX_NONCANONICAL_HOST
  61 ACX_NONCANONICAL_TARGET
  62
  63 dnl Autoconf 2.5x and later will set a default program prefix if
  64 dnl --target was used, even if it was the same as --host.  Disable
  65 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  66 dnl to take effect.
  67 test "$host_noncanonical" = "$target_noncanonical" &&
  68   test "$program_prefix$program_suffix$program_transform_name" = \
  69     NONENONEs,x,x, &&
  70   program_transform_name=s,y,y,
  71
  72 AC_CANONICAL_SYSTEM
  73 AC_ARG_PROGRAM
  74
  75 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  76 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  77
  78 # Get 'install' or 'install-sh' and its variants.
  79 AC_PROG_INSTALL
  80 ACX_PROG_LN
  81 AC_PROG_LN_S
  82 AC_PROG_SED
  83 AC_PROG_AWK
  84
  85 ### we might need to use some other shell than /bin/sh for running subshells
  86 ### If we are on Windows, search for the shell.  This will permit people
  87 ### to not have /bin/sh, but to be able to see /SOME/PATH/sh configure
  88 ### without also having to set CONFIG_SHELL.  This code will work when
  89 ### using bash, which sets OSTYPE.
  90 case "${OSTYPE}" in
  91 *win32*)
  92   if test x${CONFIG_SHELL} = x ; then
  93     if test ! -f /bin/sh ; then
  94       if test x${SHELL} != x && test -f ${SHELL} ; then
  95         CONFIG_SHELL=${SHELL}
  96         export CONFIG_SHELL
  97       else
  98         for prog in sh sh.exe bash bash.exe; do
  99           IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
 100           for dir in $PATH; do
 101             test -z "$dir" && dir=.
 102             if test -f $dir/$prog; then
 103               CONFIG_SHELL=$dir/$prog
 104               export CONFIG_SHELL
 105               break
 106             fi
 107           done
 108           IFS="$save_ifs"
 109           test -n "${CONFIG_SHELL}" && break
 110         done
 111       fi
 112     fi
 113   fi
 114   ;;
 115 esac
 116
 117 config_shell=${CONFIG_SHELL-/bin/sh}
 118
 119 moveifchange=${srcdir}/move-if-change
 120
 121 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
 122
 123 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
 124 # a relative path.
 125 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 126   INSTALL="${srcpwd}/install-sh -c"
 127 fi
 128
 129 # Set srcdir to "." if that's what it is.
 130 # This is important for multilib support.
 131 pwd=`${PWDCMD-pwd}`
 132 if test "${pwd}" = "${srcpwd}" ; then
 133   srcdir=.
 134 fi
 135
 136 topsrcdir=$srcpwd
 137
 138 extra_host_args=
 139
 140 ### To add a new directory to the tree, first choose whether it is a target
 141 ### or a host dependent tool.  Then put it into the appropriate list
 142 ### (library or tools, host or target), doing a dependency sort.
 143
 144 # Subdirs will be configured in the order listed in build_configdirs,
 145 # configdirs, or target_configdirs; see the serialization section below.
 146
 147 # Dependency sorting is only needed when *configuration* must be done in
 148 # a particular order.  In all cases a dependency should be specified in
 149 # the Makefile, whether or not it's implicitly specified here.
 150
 151 # Double entries in build_configdirs, configdirs, or target_configdirs may
 152 # cause circular dependencies and break everything horribly.
 153
 154 # these library is used by various programs built for the build
 155 # environment
 156 #
 157 build_libs="build-libiberty"
 158
 159 # these tools are built for the build environment
 160 build_tools="build-texinfo build-byacc build-flex build-bison build-m4 build-fixincludes"
 161
 162 # these libraries are used by various programs built for the host environment
 163 #
 164 host_libs="intl mmalloc libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libiconv"
 165
 166 # these tools are built for the host environment
 167 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 168 # know that we are building the simulator.
 169 # binutils, gas and ld appear in that order because it makes sense to run
 170 # "make check" in that particular order.
 171 # If --enable-gold is used, "gold" will replace "ld".
 172 host_tools="texinfo byacc flex bison binutils gas ld fixincludes gcc cgen sid sim gdb make patch prms send-pr gprof etc expect dejagnu ash bash bzip2 m4 autoconf automake libtool diff rcs fileutils shellutils time textutils wdiff find uudecode hello tar gzip indent recode release sed utils guile perl gawk findutils gettext zip fastjar gnattools"
 173
 174 # libgcj represents the runtime libraries only used by gcj.
 175 libgcj="target-libffi \
 176         target-zlib \
 177         target-qthreads \
 178         target-libjava"
 179
 180 # these libraries are built for the target environment, and are built after
 181 # the host libraries and the host tools (which may be a cross compiler)
 182 #
 183 target_libraries="target-libgcc \
 184                 target-libiberty \
 185                 target-libgloss \
 186                 target-newlib \
 187                 target-libgomp \
 188                 target-libstdc++-v3 \
 189                 target-libmudflap \
 190                 target-libssp \
 191                 target-libgfortran \
 192                 target-boehm-gc \
 193                 ${libgcj} \
 194                 target-libobjc \
 195                 target-libada"
 196
 197 # these tools are built using the target libraries, and are intended to
 198 # run only in the target environment
 199 #
 200 # note: any program that *uses* libraries that are in the "target_libraries"
 201 # list belongs in this list.  those programs are also very likely
 202 # candidates for the "native_only" list which follows
 203 #
 204 target_tools="target-examples target-groff target-gperf target-rda"
 205
 206 ################################################################################
 207
 208 ## All tools belong in one of the four categories, and are assigned above
 209 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 210 ## is important because configure will choke if they ever get through.
 211 ## ${configdirs} is directories we build using the host tools.
 212 ## ${target_configdirs} is directories we build using the target tools.
 213 configdirs=`echo ${host_libs} ${host_tools}`
 214 target_configdirs=`echo ${target_libraries} ${target_tools}`
 215 build_configdirs=`echo ${build_libs} ${build_tools}`
 216
 217 m4_divert_text([PARSE_ARGS],
 218 [ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 219 ])
 220
 221 ################################################################################
 222
 223 srcname="gnu development package"
 224
 225 # This gets set non-empty for some net releases of packages.
 226 appdirs=""
 227
 228 # Define is_cross_compiler to save on calls to 'test'.
 229 is_cross_compiler=
 230 if test x"${host}" = x"${target}" ; then
 231   is_cross_compiler=no
 232 else
 233   is_cross_compiler=yes
 234 fi
 235
 236 # Find the build and target subdir names.
 237 GCC_TOPLEV_SUBDIRS
 238 # Be sure to cover against remnants of an in-tree build.
 239 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 240   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 241 Use a pristine source tree when building in a separate tree])
 242 fi
 243
 244 # Skipdirs are removed silently.
 245 skipdirs=
 246 # Noconfigdirs are removed loudly.
 247 noconfigdirs=""
 248
 249 use_gnu_ld=
 250 # Make sure we don't let GNU ld be added if we didn't want it.
 251 if test x$with_gnu_ld = xno ; then
 252   use_gnu_ld=no
 253   noconfigdirs="$noconfigdirs ld gold"
 254 fi
 255
 256 use_gnu_as=
 257 # Make sure we don't let GNU as be added if we didn't want it.
 258 if test x$with_gnu_as = xno ; then
 259   use_gnu_as=no
 260   noconfigdirs="$noconfigdirs gas"
 261 fi
 262
 263 use_included_zlib=
 264 # Make sure we don't let ZLIB be added if we didn't want it.
 265 if test x$with_system_zlib = xyes ; then
 266   use_included_zlib=no
 267   noconfigdirs="$noconfigdirs zlib"
 268 fi
 269
 270 # some tools are so dependent upon X11 that if we're not building with X,
 271 # it's not even worth trying to configure, much less build, that tool.
 272
 273 case ${with_x} in
 274   yes | "") ;; # the default value for this tree is that X11 is available
 275   no)
 276     skipdirs="${skipdirs} tk itcl libgui"
 277     # We won't be able to build gdbtk without X.
 278     enable_gdbtk=no
 279     ;;
 280   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 281 esac
 282
 283 # Some tools are only suitable for building in a "native" situation.
 284 # Remove these if host!=target.
 285 native_only="autoconf automake libtool fileutils find gawk gettext gzip hello indent m4 rcs recode sed shellutils tar textutils uudecode wdiff target-groff guile perl time ash bash bzip2 prms gnuserv target-gperf"
 286
 287 # Similarly, some are only suitable for cross toolchains.
 288 # Remove these if host=target.
 289 cross_only="target-libgloss target-newlib target-opcodes"
 290
 291 case $is_cross_compiler in
 292   no) skipdirs="${skipdirs} ${cross_only}" ;;
 293   yes) skipdirs="${skipdirs} ${native_only}" ;;
 294 esac
 295
 296 # If both --with-headers and --with-libs are specified, default to
 297 # --without-newlib.
 298 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 299    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 300   if test x"${with_newlib}" = x ; then
 301     with_newlib=no
 302   fi
 303 fi
 304
 305 # Recognize --with-newlib/--without-newlib.
 306 case ${with_newlib} in
 307   no) skipdirs="${skipdirs} target-newlib" ;;
 308   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 309 esac
 310
 311 # Handle --enable-gold.
 312
 313 AC_ARG_ENABLE(gold,
 314 [  --enable-gold           use gold instead of ld],
 315 ENABLE_GOLD=$enableval,
 316 ENABLE_GOLD=no)
 317 if test "${ENABLE_GOLD}" = "yes"; then
 318   # Check for ELF target.
 319   is_elf=no
 320   case "${target}" in
 321     *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 322     | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 323     | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-solaris2* | *-*-nto*)
 324       case "${target}" in
 325         *-*-linux*aout* | *-*-linux*oldld*)
 326           ;;
 327         *)
 328           is_elf=yes
 329           ;;
 330       esac
 331   esac
 332
 333   if test "$is_elf" = "yes"; then
 334     # Check for target supported by gold.
 335     case "${target}" in
 336       i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 337         configdirs="`echo " ${configdirs} " | sed -e 's/ ld / gold /'`"
 338         ;;
 339     esac
 340   fi
 341 fi
 342
 343 # Configure extra directories which are host specific
 344
 345 case "${host}" in
 346   *-cygwin*)
 347     configdirs="$configdirs libtermcap" ;;
 348 esac
 349
 350 # A target can indicate whether a language isn't supported for some reason.
 351 # Only spaces may be used in this macro; not newlines or tabs.
 352 unsupported_languages=
 353
 354 # Remove more programs from consideration, based on the host or
 355 # target this usually means that a port of the program doesn't
 356 # exist yet.
 357
 358 case "${host}" in
 359   hppa*64*-*-*)
 360     noconfigdirs="$noconfigdirs byacc"
 361     ;;
 362   i[[3456789]]86-*-vsta)
 363     noconfigdirs="$noconfigdirs tcl expect dejagnu make texinfo bison patch flex byacc send-pr gprof uudecode dejagnu diff guile perl itcl gnuserv gettext"
 364     ;;
 365   i[[3456789]]86-*-go32* | i[[3456789]]86-*-msdosdjgpp*)
 366     noconfigdirs="$noconfigdirs tcl tk expect dejagnu send-pr uudecode guile itcl gnuserv libffi"
 367     ;;
 368   x86_64-*-mingw*)
 369     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 370     ;;
 371   i[[3456789]]86-*-mingw32*)
 372     # noconfigdirs="tcl tk expect dejagnu make texinfo bison patch flex byacc send-pr uudecode dejagnu diff guile perl itcl gnuserv"
 373     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 374     ;;
 375   i[[3456789]]86-*-beos*)
 376     noconfigdirs="$noconfigdirs tk itcl libgui gdb"
 377     ;;
 378   *-*-cygwin*)
 379     noconfigdirs="$noconfigdirs autoconf automake send-pr rcs guile perl"
 380     ;;
 381   *-*-netbsd*)
 382     noconfigdirs="$noconfigdirs rcs"
 383     ;;
 384   ppc*-*-pe)
 385     noconfigdirs="$noconfigdirs patch diff make tk tcl expect dejagnu autoconf automake texinfo bison send-pr gprof rcs guile perl itcl gnuserv"
 386     ;;
 387   powerpc-*-beos*)
 388     noconfigdirs="$noconfigdirs tk itcl libgui gdb dejagnu readline"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libada,
 394 [  --enable-libada         build libada directory],
 395 ENABLE_LIBADA=$enableval,
 396 ENABLE_LIBADA=yes)
 397 if test "${ENABLE_LIBADA}" != "yes" ; then
 398   noconfigdirs="$noconfigdirs gnattools"
 399 fi
 400
 401 AC_ARG_ENABLE(libssp,
 402 [  --enable-libssp         build libssp directory],
 403 ENABLE_LIBSSP=$enableval,
 404 ENABLE_LIBSSP=yes)
 405
 406 # Save it here so that, even in case of --enable-libgcj, if the Java
 407 # front-end isn't enabled, we still get libgcj disabled.
 408 libgcj_saved=$libgcj
 409 case $enable_libgcj in
 410 yes)
 411   # If we reset it here, it won't get added to noconfigdirs in the
 412   # target-specific build rules, so it will be forcibly enabled
 413   # (unless the Java language itself isn't enabled).
 414   libgcj=
 415   ;;
 416 no)
 417   # Make sure we get it printed in the list of not supported target libs.
 418   noconfigdirs="$noconfigdirs ${libgcj}"
 419   ;;
 420 esac
 421
 422
 423 # Disable libmudflap on some systems.
 424 if test x$enable_libmudflap = x ; then
 425     case "${target}" in
 426     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 427         # Enable libmudflap by default in GNU and friends.
 428         ;;
 429     *-*-freebsd*)
 430         # Enable libmudflap by default in FreeBSD.
 431         ;;
 432     *)
 433         # Disable it by default everywhere else.
 434         noconfigdirs="$noconfigdirs target-libmudflap"
 435         ;;
 436     esac
 437 fi
 438
 439 # Disable libgomp on non POSIX hosted systems.
 440 if test x$enable_libgomp = x ; then
 441     # Enable libgomp by default on hosted POSIX systems.
 442     case "${target}" in
 443     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 444         ;;
 445     *-*-netbsd* | *-*-freebsd* | *-*-openbsd*)
 446         ;;
 447     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 448         ;;
 449     *-*-darwin* | *-*-aix*)
 450         ;;
 451     *)
 452         noconfigdirs="$noconfigdirs target-libgomp"
 453         ;;
 454     esac
 455 fi
 456
 457 # Default libgloss CPU subdirectory.
 458 libgloss_dir="$target_cpu"
 459
 460 case "${target}" in
 461   *-*-chorusos)
 462     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 463     ;;
 464   powerpc-*-darwin*)
 465     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 466     noconfigdirs="$noconfigdirs sim target-rda"
 467     ;;
 468   i[[3456789]]86-*-darwin*)
 469     noconfigdirs="$noconfigdirs ld gprof"
 470     noconfigdirs="$noconfigdirs sim target-rda"
 471     ;;
 472   x86_64-*-darwin[[912]]*)
 473     noconfigdirs="$noconfigdirs ld gas gprof"
 474     noconfigdirs="$noconfigdirs sim target-rda"
 475     ;;
 476   *-*-darwin*)
 477     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 478     noconfigdirs="$noconfigdirs sim target-rda"
 479     noconfigdirs="$noconfigdirs ${libgcj}"
 480     ;;
 481   *-*-freebsd[[12]] | *-*-freebsd[[12]].* | *-*-freebsd*aout*)
 482     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 483     ;;
 484   *-*-freebsd*)
 485     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 486     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 487         && test -f /usr/local/include/gmp.h; then
 488       with_gmp=/usr/local
 489     fi
 490
 491     # Skip some stuff that's unsupported on some FreeBSD configurations.
 492     case "${target}" in
 493       i*86-*-*) ;;
 494       alpha*-*-*) ;;
 495       *)
 496         noconfigdirs="$noconfigdirs ${libgcj}"
 497         ;;
 498     esac
 499     ;;
 500   *-*-kaos*)
 501     # Remove unsupported stuff on all kaOS configurations.
 502     skipdirs="target-libiberty ${libgcj} target-libstdc++-v3 target-librx"
 503     skipdirs="$skipdirs target-libobjc target-examples target-groff target-gperf"
 504     skipdirs="$skipdirs zlib fastjar target-libjava target-boehm-gc target-zlib"
 505     noconfigdirs="$noconfigdirs target-libgloss"
 506     ;;
 507   *-*-netbsd*)
 508     # Skip some stuff on all NetBSD configurations.
 509     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss"
 510
 511     # Skip some stuff that's unsupported on some NetBSD configurations.
 512     case "${target}" in
 513       i*86-*-netbsdelf*) ;;
 514       arm*-*-netbsdelf*) ;;
 515       *)
 516         noconfigdirs="$noconfigdirs ${libgcj}"
 517         ;;
 518     esac
 519     ;;
 520   *-*-netware*)
 521     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss ${libgcj} target-libmudflap"
 522     ;;
 523   *-*-rtems*)
 524     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 525     ;;
 526     # The tpf target doesn't support gdb yet.
 527   *-*-tpf*)
 528     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty ${libgcj} target-libmudflap gdb tcl tk libgui itcl"
 529     ;;
 530   *-*-uclinux*)
 531     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda ${libgcj}"
 532     ;;
 533   *-*-vxworks*)
 534     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty target-libstdc++-v3 ${libgcj}"
 535     ;;
 536   alpha*-dec-osf*)
 537     # ld works, but does not support shared libraries.
 538     # newlib is not 64 bit ready.  I'm not sure about fileutils.
 539     # gas doesn't generate exception information.
 540     noconfigdirs="$noconfigdirs gas ld fileutils target-newlib target-libgloss"
 541     ;;
 542   alpha*-*-*vms*)
 543     noconfigdirs="$noconfigdirs gdb ld target-newlib target-libgloss ${libgcj}"
 544     ;;
 545   alpha*-*-linux*)
 546     # newlib is not 64 bit ready
 547     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 548     ;;
 549   alpha*-*-*)
 550     # newlib is not 64 bit ready
 551     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 552     ;;
 553   am33_2.0-*-linux*)
 554     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 555     ;;
 556   sh-*-linux*)
 557     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 558     ;;
 559   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 560     noconfigdirs="$noconfigdirs ${libgcj}"
 561     noconfigdirs="$noconfigdirs target-examples"
 562     noconfigdirs="$noconfigdirs target-libiberty texinfo send-pr"
 563     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 564     noconfigdirs="$noconfigdirs expect dejagnu"
 565     # the C++ libraries don't build on top of CE's C libraries
 566     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 567     noconfigdirs="$noconfigdirs target-newlib"
 568     case "${host}" in
 569       *-*-cygwin*) ;; # keep gdb and readline
 570       *) noconfigdirs="$noconfigdirs gdb readline"
 571          ;;
 572     esac
 573     libgloss_dir=wince
 574     ;;
 575   arc-*-*)
 576     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 577     ;;
 578   arm-semi-aof )
 579     ;;
 580   arm-*-coff | strongarm-*-coff | xscale-*-coff)
 581     noconfigdirs="$noconfigdirs ${libgcj}"
 582     libgloss_dir=arm
 583     ;;
 584   arm-*-elf* | strongarm-*-elf* | xscale-*-elf* | arm*-*-eabi* )
 585     noconfigdirs="$noconfigdirs target-libffi target-qthreads"
 586     libgloss_dir=arm
 587     ;;
 588   arm*-*-linux-gnueabi)
 589     noconfigdirs="$noconfigdirs target-qthreads"
 590     case ${with_newlib} in
 591       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 592     esac
 593     libgloss_dir=arm
 594     ;;
 595   arm*-*-symbianelf*)
 596     noconfigdirs="$noconfigdirs ${libgcj} target-libiberty"
 597     libgloss_dir=arm
 598     ;;
 599   arm-*-pe*)
 600     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 601     ;;
 602   thumb-*-coff)
 603     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 604     ;;
 605   thumb-*-elf)
 606     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 607     ;;
 608   thumb-*-pe)
 609     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 610     ;;
 611   arm-*-riscix*)
 612     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 613     ;;
 614   avr-*-*)
 615     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj} target-libssp"
 616     ;;
 617   bfin-*-*)
 618     unsupported_languages="$unsupported_languages java"
 619     noconfigdirs="$noconfigdirs target-boehm-gc gdb"
 620     if test x${is_cross_compiler} != xno ; then
 621       target_configdirs="${target_configdirs} target-bsp target-cygmon"
 622     fi
 623     ;;
 624   c4x-*-* | tic4x-*-*)
 625     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 626     ;;
 627   c54x*-*-* | tic54x-*-*)
 628     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj} gcc gdb newlib"
 629     ;;
 630   cr16-*-*)
 631     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 632     ;;
 633   cris-*-* | crisv32-*-*)
 634     unsupported_languages="$unsupported_languages java"
 635     case "${target}" in
 636       *-*-aout)
 637         unsupported_languages="$unsupported_languages fortran"
 638         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 639       *-*-elf)
 640         noconfigdirs="$noconfigdirs target-boehm-gc";;
 641       *-*-linux*)
 642         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
 643       *)
 644         unsupported_languages="$unsupported_languages fortran"
 645         noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss";;
 646     esac
 647     libgloss_dir=cris
 648     ;;
 649   crx-*-*)
 650     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-mudflap ${libgcj}"
 651     ;;
 652   d10v-*-*)
 653     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 654     ;;
 655   d30v-*-*)
 656     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 657     ;;
 658   ep9312-*-elf | ep9312-*-coff)
 659     libgloss_dir=arm
 660     ;;
 661   fr30-*-elf*)
 662     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 663     ;;
 664   frv-*-*)
 665     noconfigdirs="$noconfigdirs ${libgcj}"
 666     ;;
 667   moxie-*-*)
 668     noconfigdirs="$noconfigdirs ${libgcj}"
 669     noconfigdirs="$noconfigdirs gprof"
 670     ;;
 671   h8300*-*-*)
 672     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 673     ;;
 674   h8500-*-*)
 675     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 676     ;;
 677   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 678     ;;
 679   hppa*64*-*-linux* | parisc*64*-*-linux*)
 680     # In this case, it's because the hppa64-linux target is for
 681     # the kernel only at this point and has no libc, and thus no
 682     # headers, crt*.o, etc., all of which are needed by these.
 683     noconfigdirs="$noconfigdirs target-zlib"
 684     ;;
 685   parisc*-*-linux* | hppa*-*-linux*)
 686     ;;
 687   hppa*-*-*elf* | \
 688   hppa*-*-lites* | \
 689   hppa*-*-openbsd* | \
 690   hppa*64*-*-*)
 691     noconfigdirs="$noconfigdirs ${libgcj}"
 692     ;;
 693   hppa*-hp-hpux11*)
 694     noconfigdirs="$noconfigdirs ld shellutils"
 695     ;;
 696   hppa*-*-pro*)
 697     libgloss_dir=pa
 698     ;;
 699   hppa*-*-*)
 700     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 701     # build on HP-UX 10.20.
 702     noconfigdirs="$noconfigdirs ld shellutils ${libgcj}"
 703     ;;
 704   i960-*-*)
 705     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 706     ;;
 707   ia64*-*-elf*)
 708     # No gdb support yet.
 709     noconfigdirs="$noconfigdirs readline mmalloc libgui itcl gdb"
 710     ;;
 711   ia64*-**-hpux*)
 712     # No gdb or ld support yet.
 713     noconfigdirs="$noconfigdirs ${libgcj} readline mmalloc libgui itcl gdb ld"
 714     ;;
 715   ia64*-*-*vms*)
 716     # No gdb or ld support yet.
 717     noconfigdirs="$noconfigdirs ${libgcj} tix readline mmalloc libgui itcl gdb ld"
 718     ;;
 719   i370-*-opened*)
 720     ;;
 721   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
 722     noconfigdirs="$noconfigdirs ${libgcj}"
 723     libgloss_dir=i386
 724     ;;
 725   i[[3456789]]86-*-linux*)
 726     # The GCC port for glibc1 has no MD_FALLBACK_FRAME_STATE_FOR, so let's
 727     # not build java stuff by default.
 728     case "${target}" in
 729       *-*-*libc1*)
 730         noconfigdirs="$noconfigdirs ${libgcj}";;
 731     esac
 732
 733     # This section makes it possible to build newlib natively on linux.
 734     # If we are using a cross compiler then don't configure newlib.
 735     if test x${is_cross_compiler} != xno ; then
 736       noconfigdirs="$noconfigdirs target-newlib"
 737     fi
 738     noconfigdirs="$noconfigdirs target-libgloss"
 739     # If we are not using a cross compiler, do configure newlib.
 740     # Note however, that newlib will only be configured in this situation
 741     # if the --with-newlib option has been given, because otherwise
 742     # 'target-newlib' will appear in skipdirs.
 743     ;;
 744   i[[3456789]]86-*-mingw32*)
 745     target_configdirs="$target_configdirs target-winsup"
 746     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 747     ;;
 748   x86_64-*-mingw*)
 749     target_configdirs="$target_configdirs target-winsup"
 750     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 751     ;;
 752   *-*-cygwin*)
 753     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 754     noconfigdirs="$noconfigdirs target-gperf target-libgloss"
 755     # always build newlib if winsup directory is present.
 756     if test -d "$srcdir/winsup/cygwin"; then
 757       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 758     elif test -d "$srcdir/newlib"; then
 759       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 760     fi
 761     ;;
 762   i[[3456789]]86-moss-msdos | i[[3456789]]86-*-moss* | \
 763   i[[3456789]]86-*-uwin* | i[[3456789]]86-*-interix* )
 764     ;;
 765   i[[3456789]]86-*-pe)
 766     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 767     ;;
 768   i[[3456789]]86-*-sco3.2v5*)
 769     # The linker does not yet know about weak symbols in COFF,
 770     # and is not configured to handle mixed ELF and COFF.
 771     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 772     ;;
 773   i[[3456789]]86-*-sco*)
 774     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 775     ;;
 776   i[[3456789]]86-*-solaris2*)
 777     noconfigdirs="$noconfigdirs target-libgloss"
 778     ;;
 779   i[[3456789]]86-*-sysv4*)
 780     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 781     ;;
 782   i[[3456789]]86-*-beos*)
 783     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 784     ;;
 785   i[[3456789]]86-*-rdos*)
 786     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 787     ;;
 788   m32r-*-*)
 789     noconfigdirs="$noconfigdirs ${libgcj}"
 790     ;;
 791   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 792     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
 793     libgloss_dir=m68hc11
 794     ;;
 795   m68k-*-elf*)
 796     noconfigdirs="$noconfigdirs ${libgcj}"
 797     ;;
 798   m68k-*-coff*)
 799     noconfigdirs="$noconfigdirs ${libgcj}"
 800     ;;
 801   m68*-*-* | fido-*-*)
 802     libgloss_dir=m68k
 803     ;;
 804   mcore-*-pe*)
 805   # The EPOC C++ environment does not support exceptions or rtti,
 806   # and so building libstdc++-v3 tends not to always work.
 807     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 808     ;;
 809   mmix-*-*)
 810     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc gdb libgloss"
 811     unsupported_languages="$unsupported_languages fortran java"
 812     ;;
 813   mn10200-*-*)
 814     noconfigdirs="$noconfigdirs ${libgcj}"
 815     ;;
 816   mn10300-*-*)
 817     noconfigdirs="$noconfigdirs ${libgcj}"
 818     ;;
 819   mt-*-*)
 820     noconfigdirs="$noconfigdirs sim"
 821     ;;
 822   powerpc-*-aix*)
 823     # copied from rs6000-*-* entry
 824     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 825     ;;
 826   powerpc*-*-winnt* | powerpc*-*-pe* | ppc*-*-pe)
 827     target_configdirs="$target_configdirs target-winsup"
 828     noconfigdirs="$noconfigdirs gdb tcl tk make expect target-libgloss itcl gnuserv ${libgcj}"
 829     # always build newlib.
 830     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 831     ;;
 832     # This is temporary until we can link against shared libraries
 833   powerpcle-*-solaris*)
 834     noconfigdirs="$noconfigdirs gdb sim make tcl tk expect itcl gnuserv ${libgcj}"
 835     libgloss_dir=rs6000
 836     ;;
 837   powerpc-*-beos*)
 838     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 839     ;;
 840   powerpc-*-eabi)
 841     noconfigdirs="$noconfigdirs ${libgcj}"
 842     libgloss_dir=rs6000
 843     ;;
 844   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
 845     libgloss_dir=rs6000
 846     ;;
 847   rs6000-*-lynxos*)
 848     noconfigdirs="$noconfigdirs target-newlib gprof ${libgcj}"
 849     ;;
 850   rs6000-*-aix*)
 851     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 852     ;;
 853   rs6000-*-*)
 854     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 855     ;;
 856   m68k-apollo-*)
 857     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss ${libgcj}"
 858     ;;
 859   microblaze*)
 860     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 861     ;;
 862   mips*-sde-elf*)
 863     skipdirs="$skipdirs target-libiberty"
 864     noconfigdirs="$noconfigdirs ${libgcj}"
 865     if test x$with_newlib = xyes; then
 866       noconfigdirs="$noconfigdirs gprof"
 867     fi
 868     libgloss_dir=mips
 869     ;;
 870   mips*-*-irix5*)
 871     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 872     ;;
 873   mips*-*-irix6*)
 874     # Linking libjava exceeds command-line length limits on at least
 875     # IRIX 6.2, but not on IRIX 6.5.
 876     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 877     # <oldham@codesourcery.com>
 878     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 879     ;;
 880   mips*-*-bsd*)
 881     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 882     ;;
 883   mips*-*-linux*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   mips*-*-*)
 887     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 888     libgloss_dir=mips
 889     ;;
 890   romp-*-*)
 891     noconfigdirs="$noconfigdirs bfd binutils ld gas opcodes target-libgloss ${libgcj}"
 892     ;;
 893   sh-*-* | sh64-*-*)
 894     case "${host}" in
 895       i[[3456789]]86-*-vsta) ;; # don't add gprof back in
 896       i[[3456789]]86-*-go32*) ;; # don't add gprof back in
 897       i[[3456789]]86-*-msdosdjgpp*) ;; # don't add gprof back in
 898       *) skipdirs=`echo " ${skipdirs} " | sed -e 's/ gprof / /'` ;;
 899     esac
 900     case "${target}" in
 901       sh*-*-elf)
 902          noconfigdirs="$noconfigdirs ${libgcj}" ;;
 903       *)
 904          noconfigdirs="$noconfigdirs target-libgloss ${libgcj}" ;;
 905     esac
 906     ;;
 907   sparclet-*-aout* | sparc86x-*-*)
 908     libgloss_dir=sparc
 909     ;;
 910   sparc-*-elf*)
 911     noconfigdirs="$noconfigdirs ${libgcj}"
 912     ;;
 913   sparc64-*-elf*)
 914     noconfigdirs="$noconfigdirs ${libgcj}"
 915     libgloss_dir=sparc
 916     ;;
 917   sparclite-*-*)
 918     noconfigdirs="$noconfigdirs ${libgcj}"
 919     libgloss_dir=sparc
 920     ;;
 921   sparc-*-sunos4*)
 922     noconfigdirs="$noconfigdirs ${libgcj}"
 923     if test x${is_cross_compiler} != xno ; then
 924            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 925     else
 926            use_gnu_ld=no
 927     fi
 928     ;;
 929   sparc-*-solaris2.[[0-6]] | sparc-*-solaris2.[[0-6]].*)
 930     noconfigdirs="$noconfigdirs ${libgcj}"
 931     ;;
 932   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
 933     ;;
 934   v810-*-*)
 935     noconfigdirs="$noconfigdirs bfd binutils gas gcc gdb ld target-libstdc++-v3 opcodes target-libgloss ${libgcj}"
 936     ;;
 937   v850-*-*)
 938     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 939     ;;
 940   v850e-*-*)
 941     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 942     ;;
 943   v850ea-*-*)
 944     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 945     ;;
 946   vax-*-vms)
 947     noconfigdirs="$noconfigdirs bfd binutils gdb ld target-newlib opcodes target-libgloss ${libgcj}"
 948     ;;
 949   vax-*-*)
 950     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 951     ;;
 952   xtensa*-*-*)
 953     noconfigdirs="$noconfigdirs ${libgcj}"
 954     ;;
 955   ip2k-*-*)
 956     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
 957     ;;
 958   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   *-*-lynxos*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 963     ;;
 964   *-*-*)
 965     noconfigdirs="$noconfigdirs ${libgcj}"
 966     ;;
 967 esac
 968
 969 # If we aren't building newlib, then don't build libgloss, since libgloss
 970 # depends upon some newlib header files.
 971 case "${noconfigdirs}" in
 972   *target-libgloss*) ;;
 973   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
 974 esac
 975
 976 # Work in distributions that contain no compiler tools, like Autoconf.
 977 tentative_cc=""
 978 host_makefile_frag=/dev/null
 979 if test -d ${srcdir}/config ; then
 980 case "${host}" in
 981   m68k-hp-hpux*)
 982     # Avoid "too much defining" errors from HPUX compiler.
 983     tentative_cc="cc -Wp,-H256000"
 984     # If "ar" in $PATH is GNU ar, the symbol table may need rebuilding.
 985     # If it's HP/UX ar, this should be harmless.
 986     RANLIB="ar ts"
 987     ;;
 988   m68k-apollo-sysv*)
 989     tentative_cc="cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DUSG"
 990     ;;
 991   m68k-apollo-bsd*)
 992     #None of the Apollo compilers can compile gas or binutils.  The preprocessor
 993     # chokes on bfd, the compiler won't let you assign integers to enums, and
 994     # other problems.  Defining CC to gcc is a questionable way to say "don't use
 995     # the apollo compiler" (the preferred version of GCC could be called cc,
 996     # or whatever), but I'm not sure leaving CC as cc is any better...
 997     #CC=cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DNO_STDARG
 998     # Used to have BISON=yacc.
 999     tentative_cc=gcc
1000     ;;
1001   m88k-dg-dgux*)
1002     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
1003     ;;
1004   m88k-harris-cxux*)
1005     # Under CX/UX, we want to tell the compiler to use ANSI mode.
1006     tentative_cc="cc -Xa"
1007     host_makefile_frag="config/mh-cxux"
1008     ;;
1009   m88k-motorola-sysv*)
1010     ;;
1011   mips*-dec-ultrix*)
1012     tentative_cc="cc -Wf,-XNg1000"
1013     host_makefile_frag="config/mh-decstation"
1014     ;;
1015   mips*-nec-sysv4*)
1016     # The C compiler on NEC MIPS SVR4 needs bigger tables.
1017     tentative_cc="cc -ZXNd=5000 -ZXNg=1000"
1018     host_makefile_frag="config/mh-necv4"
1019     ;;
1020   mips*-sgi-irix4*)
1021     # Tell compiler to use K&R C.  We can't compile under the SGI Ansi
1022     # environment.  Also bump switch table size so that cp-parse will
1023     # compile.  Bump string length limit so linker builds.
1024     tentative_cc="cc -cckr -Wf,-XNg1500 -Wf,-XNk1000 -Wf,-XNh2000 -Wf,-XNl8192"
1025     ;;
1026   mips*-*-sysv4*)
1027     host_makefile_frag="config/mh-sysv4"
1028     ;;
1029   mips*-*-sysv*)
1030     # This is for a MIPS running RISC/os 4.52C.
1031
1032     # This is needed for GDB, but needs to be in the top-level make because
1033     # if a library is compiled with the bsd headers and gets linked with the
1034     # sysv system libraries all hell can break loose (e.g. a jmp_buf might be
1035     # a different size).
1036     # ptrace(2) apparently has problems in the BSD environment.  No workaround is
1037     # known except to select the sysv environment.  Could we use /proc instead?
1038     # These "sysv environments" and "bsd environments" often end up being a pain.
1039     #
1040     # This is not part of CFLAGS because perhaps not all C compilers have this
1041     # option.
1042     tentative_cc="cc -systype sysv"
1043     ;;
1044   i370-ibm-opened*)
1045     tentative_cc="c89"
1046     ;;
1047   i[[3456789]]86-*-sysv5*)
1048     host_makefile_frag="config/mh-sysv5"
1049     ;;
1050   i[[3456789]]86-*-dgux*)
1051     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
1052     host_makefile_frag="config/mh-dgux386"
1053     ;;
1054   i[[3456789]]86-ncr-sysv4.3*)
1055     # The MetaWare compiler will generate a copyright message unless you
1056     # turn it off by adding the -Hnocopyr flag.
1057     tentative_cc="cc -Hnocopyr"
1058     ;;
1059   i[[3456789]]86-ncr-sysv4*)
1060     # for an NCR 3000 (i486/SVR4) system.
1061     # The NCR 3000 ships with a MetaWare compiler installed as /bin/cc.
1062     # This compiler not only emits obnoxious copyright messages every time
1063     # you run it, but it chokes and dies on a whole bunch of GNU source
1064     # files.  Default to using the AT&T compiler installed in /usr/ccs/ATT/cc.
1065     tentative_cc="/usr/ccs/ATT/cc"
1066     host_makefile_frag="config/mh-ncr3000"
1067     ;;
1068   i[[3456789]]86-*-sco3.2v5*)
1069     ;;
1070   i[[3456789]]86-*-sco*)
1071     # The native C compiler botches some simple uses of const.  Unfortunately,
1072     # it doesn't defined anything like "__sco__" for us to test for in ansidecl.h.
1073     tentative_cc="cc -Dconst="
1074     host_makefile_frag="config/mh-sco"
1075     ;;
1076   i[[3456789]]86-*-udk*)
1077     host_makefile_frag="config/mh-sysv5"
1078     ;;
1079   i[[3456789]]86-*-solaris2*)
1080     host_makefile_frag="config/mh-sysv4"
1081     ;;
1082   i[[3456789]]86-*-msdosdjgpp*)
1083     host_makefile_frag="config/mh-djgpp"
1084     ;;
1085   *-cygwin*)
1086     ACX_CHECK_CYGWIN_CAT_WORKS
1087     host_makefile_frag="config/mh-cygwin"
1088     ;;
1089   *-mingw*)
1090     host_makefile_frag="config/mh-mingw"
1091     ;;
1092   *-interix*)
1093     host_makefile_frag="config/mh-interix"
1094     ;;
1095   vax-*-ultrix2*)
1096     # The old BSD pcc isn't up to compiling parts of gdb so use gcc
1097     tentative_cc=gcc
1098     ;;
1099   *-*-solaris2*)
1100     host_makefile_frag="config/mh-solaris"
1101     ;;
1102   m68k-sun-sunos*)
1103     # Sun's C compiler needs the -J flag to be able to compile cp-parse.c
1104     # without overflowing the jump tables (-J says to use a 32 bit table)
1105     tentative_cc="cc -J"
1106     ;;
1107   hppa*-hp-hpux10*)
1108     tentative_cc="cc -Wp,-H256000"
1109     host_makefile_frag="config/mh-pa-hpux10"
1110     ;;
1111   hppa*-hp-hpux* | hppa*-*-hiux*)
1112     tentative_cc="cc -Wp,-H256000"
1113     host_makefile_frag="config/mh-pa"
1114     ;;
1115   hppa*-*)
1116     host_makefile_frag="config/mh-pa"
1117     ;;
1118   *-hp-hpux* | *-*-hiux*)
1119     tentative_cc="cc -Wp,-H256000"
1120     ;;
1121   rs6000-*-lynxos*)
1122     # /bin/cc is less than useful for our purposes.  Always use GCC
1123     tentative_cc="/usr/cygnus/progressive/bin/gcc"
1124     host_makefile_frag="config/mh-lynxrs6k"
1125     ;;
1126   powerpc-*-darwin*)
1127     host_makefile_frag="config/mh-ppc-darwin"
1128     ;;
1129   powerpc-*-aix*)
1130     host_makefile_frag="config/mh-ppc-aix"
1131     ;;
1132   rs6000-*-aix*)
1133     host_makefile_frag="config/mh-ppc-aix"
1134     ;;
1135   *-*-lynxos*)
1136     # /bin/cc is less than useful for our purposes.  Always use GCC
1137     tentative_cc="/bin/gcc"
1138     ;;
1139   *-*-sysv4*)
1140     host_makefile_frag="config/mh-sysv4"
1141     ;;
1142   # This is placed last to prevent interfering with the cases above.
1143   i[[3456789]]86-*-*)
1144     # Build the stage2 and stage3 compilers with -fomit-frame-pointer.
1145     host_makefile_frag="config/mh-x86omitfp"
1146     ;;
1147 esac
1148 fi
1149
1150 # If we aren't going to be using gcc, see if we can extract a definition
1151 # of CC from the fragment.
1152 # Actually, use the 'pre-extracted' version above.
1153 if test -z "${CC}" && test "${build}" = "${host}" ; then
1154   IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
1155   found=
1156   for dir in $PATH; do
1157     test -z "$dir" && dir=.
1158     if test -f $dir/gcc; then
1159       found=yes
1160       break
1161     fi
1162   done
1163   IFS="$save_ifs"
1164   if test -z "${found}" && test -n "${tentative_cc}" ; then
1165     CC=$tentative_cc
1166   fi
1167 fi
1168
1169 if test "${build}" != "${host}" ; then
1170   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1171   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1172   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1173   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1174   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1175   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1176   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1177   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1178   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1179   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1180   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1181   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1182 else
1183   AR_FOR_BUILD="\$(AR)"
1184   AS_FOR_BUILD="\$(AS)"
1185   CC_FOR_BUILD="\$(CC)"
1186   CXX_FOR_BUILD="\$(CXX)"
1187   GCJ_FOR_BUILD="\$(GCJ)"
1188   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1189   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1190   LD_FOR_BUILD="\$(LD)"
1191   NM_FOR_BUILD="\$(NM)"
1192   RANLIB_FOR_BUILD="\$(RANLIB)"
1193   WINDRES_FOR_BUILD="\$(WINDRES)"
1194   WINDMC_FOR_BUILD="\$(WINDMC)"
1195 fi
1196
1197 AC_PROG_CC
1198 AC_PROG_CXX
1199
1200 # We must set the default linker to the linker used by gcc for the correct
1201 # operation of libtool.  If LD is not defined and we are using gcc, try to
1202 # set the LD default to the ld used by gcc.
1203 if test -z "$LD"; then
1204   if test "$GCC" = yes; then
1205     case $build in
1206     *-*-mingw*)
1207       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1208     *)
1209       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1210     esac
1211     case $gcc_prog_ld in
1212     # Accept absolute paths.
1213     [[\\/]* | [A-Za-z]:[\\/]*)]
1214       LD="$gcc_prog_ld" ;;
1215     esac
1216   fi
1217 fi
1218
1219 ACX_PROG_GNAT
1220 ACX_PROG_CMP_IGNORE_INITIAL
1221
1222 # See if we are building gcc with C++.
1223 AC_ARG_ENABLE(build-with-cxx,
1224 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
1225 ENABLE_BUILD_WITH_CXX=$enableval,
1226 ENABLE_BUILD_WITH_CXX=no)
1227
1228 # Check for GMP, MPFR and MPC
1229 gmplibs="-lmpfr -lgmp"
1230 gmpinc=
1231 have_gmp=no
1232 mpclibs=-lmpc
1233 mpcinc=
1234 have_mpc=no
1235
1236 # Specify a location for mpc
1237 # check for this first so it ends up on the link line before mpfr.
1238 AC_ARG_WITH(mpc, [  --with-mpc=PATH        specify prefix directory for installed MPC package.
1239                           Equivalent to --with-mpc-include=PATH/include
1240                           plus --with-mpc-lib=PATH/lib])
1241 AC_ARG_WITH(mpc_include, [  --with-mpc-include=PATH
1242                           specify directory for installed MPC include files])
1243 AC_ARG_WITH(mpc_lib, [  --with-mpc-lib=PATH    specify directory for the installed MPC library])
1244
1245 if test "x$with_mpc" != x; then
1246   mpclibs="-L$with_mpc/lib -lmpc"
1247   mpcinc="-I$with_mpc/include $mpcinc"
1248 fi
1249 if test "x$with_mpc_include" != x; then
1250   mpcinc="-I$with_mpc_include $mpcinc"
1251 fi
1252 if test "x$with_mpc_lib" != x; then
1253   mpclibs="-L$with_mpc_lib -lmpc"
1254 fi
1255 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1256   mpclibs='-L$$r/$(HOST_SUBDIR)/mpc/src/.libs -L$$r/$(HOST_SUBDIR)/mpc/src/_libs -lmpc'
1257   mpcinc='-I$$s/mpc/src '"$mpcinc"
1258   # Do not test the mpc version.  Assume that it is sufficient, since
1259   # it is in the source tree, and the library has not been built yet
1260   # but it would be included on the link line in the version check below
1261   # hence making the test fail.
1262   have_mpc=yes
1263 fi
1264
1265 # Specify a location for mpfr
1266 # check for this first so it ends up on the link line before gmp.
1267 AC_ARG_WITH(mpfr-dir, [  --with-mpfr-dir=PATH    this option has been REMOVED],
1268   AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1269 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH]))
1270
1271 AC_ARG_WITH(mpfr, [  --with-mpfr=PATH        specify prefix directory for installed MPFR package.
1272                           Equivalent to --with-mpfr-include=PATH/include
1273                           plus --with-mpfr-lib=PATH/lib])
1274 AC_ARG_WITH(mpfr_include, [  --with-mpfr-include=PATH
1275                           specify directory for installed MPFR include files])
1276 AC_ARG_WITH(mpfr_lib, [  --with-mpfr-lib=PATH    specify directory for the installed MPFR library])
1277
1278 if test "x$with_mpfr" != x; then
1279   gmplibs="-L$with_mpfr/lib $gmplibs"
1280   gmpinc="-I$with_mpfr/include"
1281 fi
1282 if test "x$with_mpfr_include" != x; then
1283   gmpinc="-I$with_mpfr_include"
1284 fi
1285 if test "x$with_mpfr_lib" != x; then
1286   gmplibs="-L$with_mpfr_lib $gmplibs"
1287 fi
1288 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1289   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/.libs -L$$r/$(HOST_SUBDIR)/mpfr/_libs '"$gmplibs"
1290   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1291   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr'
1292   # Do not test the mpfr version.  Assume that it is sufficient, since
1293   # it is in the source tree, and the library has not been built yet
1294   # but it would be included on the link line in the version check below
1295   # hence making the test fail.
1296   have_gmp=yes
1297 fi
1298
1299 # Specify a location for gmp
1300 AC_ARG_WITH(gmp-dir, [  --with-gmp-dir=PATH     this option has been REMOVED],
1301   AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1302 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH]))
1303
1304 AC_ARG_WITH(gmp, [  --with-gmp=PATH         specify prefix directory for the installed GMP package.
1305                           Equivalent to --with-gmp-include=PATH/include
1306                           plus --with-gmp-lib=PATH/lib])
1307 AC_ARG_WITH(gmp_include, [  --with-gmp-include=PATH specify directory for installed GMP include files])
1308 AC_ARG_WITH(gmp_lib, [  --with-gmp-lib=PATH     specify directory for the installed GMP library])
1309
1310
1311 if test "x$with_gmp" != x; then
1312   gmplibs="-L$with_gmp/lib $gmplibs"
1313   gmpinc="-I$with_gmp/include $gmpinc"
1314 fi
1315 if test "x$with_gmp_include" != x; then
1316   gmpinc="-I$with_gmp_include $gmpinc"
1317 fi
1318 if test "x$with_gmp_lib" != x; then
1319   gmplibs="-L$with_gmp_lib $gmplibs"
1320 fi
1321 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1322   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/.libs -L$$r/$(HOST_SUBDIR)/gmp/_libs '"$gmplibs"
1323   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1324   extra_mpfr_configure_flags='--with-gmp-build=$$r/$(HOST_SUBDIR)/gmp'
1325   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp'
1326   # Do not test the gmp version.  Assume that it is sufficient, since
1327   # it is in the source tree, and the library has not been built yet
1328   # but it would be included on the link line in the version check below
1329   # hence making the test fail.
1330   have_gmp=yes
1331 fi
1332
1333 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1334   have_gmp=yes
1335   saved_CFLAGS="$CFLAGS"
1336   CFLAGS="$CFLAGS $gmpinc"
1337   # Check GMP actually works
1338   AC_MSG_CHECKING([for correct version of gmp.h])
1339   AC_TRY_COMPILE([#include "gmp.h"],[
1340   #if __GNU_MP_VERSION < 4 || (__GNU_MP_VERSION == 4 && __GNU_MP_VERSION_MINOR < 2)
1341   choke me
1342   #endif
1343   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1344
1345   # If we have GMP, check the MPFR version.
1346   if test x"$have_gmp" = xyes; then
1347     dnl MPFR 2.3.1 is acceptable, but MPFR 2.3.2 is better.
1348     AC_MSG_CHECKING([for correct version of mpfr.h])
1349     AC_TRY_COMPILE([#include <gmp.h>
1350     #include <mpfr.h>],[
1351     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1352     choke me
1353     #endif
1354     ], AC_TRY_COMPILE([#include <gmp.h>
1355     #include <mpfr.h>],[
1356     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,2)
1357     choke me
1358     #endif
1359     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])]),
1360      [AC_MSG_RESULT([no]); have_gmp=no])
1361   fi
1362
1363   # Check for the MPC header version.
1364   if test x"$have_mpc" != xyes ; then
1365     CFLAGS="$CFLAGS $mpcinc"
1366     AC_MSG_CHECKING([for the correct version of mpc.h])
1367     AC_TRY_COMPILE([#include <mpc.h>],[
1368     #if MPC_VERSION < MPC_VERSION_NUM (0,7,0)
1369     choke me
1370     #endif
1371     ], [AC_MSG_RESULT([yes]); have_mpc=maybe],
1372        [AC_MSG_RESULT([no]); have_mpc=no; mpclibs= ; mpcinc= ])
1373   fi
1374
1375   # Now check the MPFR library.
1376   if test x"$have_gmp" = xyes; then
1377     saved_LIBS="$LIBS"
1378     LIBS="$LIBS $gmplibs"
1379     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1380     AC_TRY_LINK([#include <gmp.h>
1381     #include <mpfr.h>],[
1382     mpfr_t n;
1383     mpfr_t x;
1384     int t;
1385     mpfr_init (n);
1386     mpfr_init (x);
1387     mpfr_atan2 (n, n, x, GMP_RNDN);
1388     mpfr_erfc (n, x, GMP_RNDN);
1389     mpfr_subnormalize (x, t, GMP_RNDN);
1390     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1391     LIBS="$saved_LIBS"
1392   fi
1393
1394   if test x"$have_mpc" = xmaybe; then
1395     saved_LIBS="$LIBS"
1396     LIBS="$LIBS $mpclibs $gmplibs"
1397     AC_MSG_CHECKING([for the correct version of the mpc library])
1398     AC_TRY_LINK([#include <mpc.h>],[
1399     mpc_t n;
1400     mpc_init2 (n, 53);
1401     mpc_set_ui_ui (n, 1, 1, MPC_RNDNN);
1402     mpc_sin (n, n, MPC_RNDNN);
1403     mpc_cos (n, n, MPC_RNDNN);
1404     mpc_tan (n, n, MPC_RNDNN);
1405     mpc_sinh (n, n, MPC_RNDNN);
1406     mpc_cosh (n, n, MPC_RNDNN);
1407     mpc_tanh (n, n, MPC_RNDNN);
1408     mpc_exp (n, n, MPC_RNDNN);
1409     mpc_log (n, n, MPC_RNDNN);
1410     mpc_sqrt (n, n, MPC_RNDNN);
1411     mpc_proj (n, n, MPC_RNDNN);
1412     mpc_neg (n, n, MPC_RNDNN);
1413     mpc_sqr (n, n, MPC_RNDNN);
1414     mpc_pow (n, n, n, MPC_RNDNN);
1415     mpc_clear (n);
1416     ], [AC_MSG_RESULT([yes]); have_mpc=yes],
1417        [AC_MSG_RESULT([no]); have_mpc=no; mpclibs= ; mpcinc= ])
1418     LIBS="$saved_LIBS"
1419   fi
1420
1421   CFLAGS="$saved_CFLAGS"
1422
1423   if test x$have_gmp != xyes; then
1424     AC_MSG_ERROR([Building GCC requires GMP 4.2+ and MPFR 2.3.2+.
1425 Try the --with-gmp and/or --with-mpfr options to specify their locations.
1426 Copies of these libraries' source code can be found at their respective
1427 hosting sites as well as at ftp://gcc.gnu.org/pub/gcc/infrastructure/.
1428 See also http://gcc.gnu.org/install/prerequisites.html for additional info.
1429 If you obtained GMP and/or MPFR from a vendor distribution package, make
1430 sure that you have installed both the libraries and the header files.
1431 They may be located in separate packages.])
1432   fi
1433 fi
1434
1435 if test x$have_mpc != xyes ; then
1436   mpcinc=
1437   mpclibs=
1438 fi
1439
1440 gmpinc="$mpcinc $gmpinc"
1441 gmplibs="$mpclibs $gmplibs"
1442
1443 # Flags needed for both GMP, MPFR and/or MPC.
1444 AC_SUBST(gmplibs)
1445 AC_SUBST(gmpinc)
1446 AC_SUBST(extra_mpfr_configure_flags)
1447 AC_SUBST(extra_mpc_gmp_configure_flags)
1448 AC_SUBST(extra_mpc_mpfr_configure_flags)
1449
1450 # Allow host libstdc++ to be specified for static linking with PPL.
1451 AC_ARG_WITH(host-libstdcxx, [  --with-host-libstdcxx=L Use linker arguments L to link with libstdc++
1452                           when linking with PPL])
1453
1454 case $with_host_libstdcxx in
1455   no|yes)
1456     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1457     ;;
1458 esac
1459
1460 # Linker flags to use for stage1 or when not boostrapping.
1461 AC_ARG_WITH(stage1-ldflags,
1462 [  --with-stage1-ldflags=FLAGS Linker flags for stage1],
1463 [if test "$withval" = "no" -o "$withval" = "yes"; then
1464    stage1_ldflags=
1465  else
1466    stage1_ldflags=$withval
1467  fi],
1468 [stage1_ldflags=])
1469 AC_SUBST(stage1_ldflags)
1470
1471 # Libraries to use for stage1 or when not bootstrapping.
1472 AC_ARG_WITH(stage1-libs,
1473 [  -with-stage1-libs=LIBS      Libraries for stage1],
1474 [if test "$withval" = "no" -o "$withval" = "yes"; then
1475    stage1_libs=
1476  else
1477    stage1_libs=$withval
1478  fi],
1479 [stage1_libs=$with_host_libstdcxx])
1480 AC_SUBST(stage1_libs)
1481
1482 # Linker flags to use for stage2 and later builds.
1483 AC_ARG_WITH(boot-ldflags,
1484 [  --with-boot-ldflags=FLAGS Linker flags for stage2 and later],
1485 [if test "$withval" = "no" -o "$withval" = "yes"; then
1486    poststage1_ldflags=
1487  else
1488    poststage1_ldflags=$withval
1489  fi],
1490 [if test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1491    poststage1_ldflags=-static-libstdc++
1492  else
1493    poststage1_ldflags=
1494  fi])
1495 AC_SUBST(poststage1_ldflags)
1496
1497 # Libraries to use for stage2 and later builds.  This defaults to the
1498 # argument passed to --with-host-libstdcxx.
1499 AC_ARG_WITH(boot-libs,
1500 [  --with-boot-libs=LIBS     Libraries for stage2 and later],
1501 [if test "$withval" = "no" -o "$withval" = "yes"; then
1502    poststage1_libs=
1503  else
1504    poststage1_libs=$withval
1505  fi],
1506 [poststage1_libs=$with_host_libstdcxx])
1507 AC_SUBST(poststage1_libs)
1508
1509 # Check for PPL
1510 ppl_major_version=0
1511 ppl_minor_version=10
1512 ppllibs=" -lppl_c -lppl -lgmpxx"
1513 pplinc=
1514
1515 AC_ARG_WITH(ppl, [  --with-ppl=PATH         Specify prefix directory for the installed PPL package
1516                           Equivalent to --with-ppl-include=PATH/include
1517                           plus --with-ppl-lib=PATH/lib],, with_ppl=no)
1518 AC_ARG_WITH(ppl_include, [  --with-ppl-include=PATH Specify directory for installed PPL include files])
1519 AC_ARG_WITH(ppl_lib, [  --with-ppl-lib=PATH     Specify the directory for the installed PPL library])
1520
1521 case $with_ppl in
1522   no)
1523     ppllibs=
1524     ;;
1525   *)
1526     ppllibs="-L$with_ppl/lib -lppl_c -lppl -lgmpxx"
1527     pplinc="-I$with_ppl/include $pplinc"
1528     LIBS="$ppllibs $LIBS"
1529     ;;
1530 esac
1531 if test "x$with_ppl_include" != x; then
1532   pplinc="-I$with_ppl_include $pplinc"
1533 fi
1534 if test "x$with_ppl_lib" != x; then
1535   ppllibs="-L$with_ppl_lib -lppl_c -lppl -lgmpxx"
1536   LIBS="$ppllibs $LIBS"
1537 fi
1538 if test "x$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1539   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/.libs -L$$r/$(HOST_SUBDIR)/ppl/_libs -lppl_c -lppl -lgmpxx '
1540   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/include -I$$s/ppl/include '
1541   LIBS="$ppllibs $LIBS"
1542 fi
1543
1544 AC_ARG_ENABLE(ppl-version-check,
1545 [  --disable-ppl-version-check    disable check for PPL version],
1546 ENABLE_PPL_CHECK=$enableval,
1547 ENABLE_PPL_CHECK=yes)
1548
1549 if test "${ENABLE_PPL_CHECK}" = "yes"; then
1550   saved_CFLAGS="$CFLAGS"
1551   CFLAGS="$CFLAGS $pplinc $gmpinc"
1552   AC_MSG_CHECKING([for version $ppl_major_version.$ppl_minor_version of PPL])
1553   AC_TRY_COMPILE([#include "ppl_c.h"],[
1554   #if PPL_VERSION_MAJOR != $ppl_major_version || PPL_VERSION_MINOR != $ppl_minor_version
1555   choke me
1556   #endif
1557   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ])
1558   CFLAGS="$saved_CFLAGS"
1559 fi
1560
1561 # Flags needed for PPL
1562 AC_SUBST(ppllibs)
1563 AC_SUBST(pplinc)
1564
1565
1566 # Check for CLOOG
1567 clooglibs=" -lcloog "
1568 clooginc=" -DCLOOG_PPL_BACKEND "
1569
1570 AC_ARG_WITH(cloog, [  --with-cloog=PATH       Specify prefix directory for the installed CLooG-PPL package
1571                           Equivalent to --with-cloog-include=PATH/include
1572                           plus --with-cloog-lib=PATH/lib],, with_cloog=no)
1573 AC_ARG_WITH(cloog_include, [  --with-cloog-include=PATH Specify directory for installed CLooG include files])
1574 AC_ARG_WITH(cloog_lib, [  --with-cloog-lib=PATH   Specify the directory for the installed CLooG library])
1575
1576 case $with_cloog in
1577   no)
1578     clooglibs=
1579     clooginc=
1580     ;;
1581   *)
1582     clooglibs="-L$with_cloog/lib -lcloog"
1583     clooginc="-I$with_cloog/include -DCLOOG_PPL_BACKEND "
1584     LIBS="$clooglibs $LIBS"
1585     ;;
1586 esac
1587 if test "x$with_cloog_include" != x; then
1588   clooginc="-I$with_cloog_include -DCLOOG_PPL_BACKEND "
1589 fi
1590 if test "x$with_cloog_lib" != x; then
1591   clooglibs="-L$with_cloog_lib -lcloog"
1592   LIBS="$clooglibs $LIBS"
1593 fi
1594 if test "x$with_cloog$with_cloog_include$with_cloog_lib" = x && test -d ${srcdir}/cloog; then
1595   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/.libs -L$$r/$(HOST_SUBDIR)/cloog/_libs -lcloog '
1596   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include -DCLOOG_PPL_BACKEND '
1597   LIBS="$clooglibs $LIBS"
1598 fi
1599
1600 AC_ARG_ENABLE(cloog-version-check,
1601 [  --disable-cloog-version-check  disable check for CLooG version],
1602 ENABLE_CLOOG_CHECK=$enableval,
1603 ENABLE_CLOOG_CHECK=yes)
1604
1605 if test "${ENABLE_CLOOG_CHECK}" = "yes"; then
1606   saved_CFLAGS="$CFLAGS"
1607   CFLAGS="$CFLAGS $clooginc $gmpinc $pplinc"
1608   AC_MSG_CHECKING([for correct version of CLooG])
1609   AC_TRY_COMPILE([#include "cloog/cloog.h"],[
1610   #if CLOOG_VERSION_MAJOR != 0 || CLOOG_VERSION_MINOR != 15
1611   choke me
1612   #endif
1613   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); clooglibs= ; clooginc= ])
1614   CFLAGS="$saved_CFLAGS"
1615 fi
1616
1617 # Flags needed for CLOOG
1618 AC_SUBST(clooglibs)
1619 AC_SUBST(clooginc)
1620
1621 # Check for LTO support.
1622 AC_ARG_ENABLE(lto,
1623 [  --enable-lto            enable link time optimization support],
1624 enable_lto=$enableval,
1625 enable_lto=yes; default_enable_lto=yes)
1626
1627 if test x"$enable_lto" = x"yes" ; then
1628   # Make sure that libelf.h and gelf.h are available.
1629   AC_ARG_WITH(libelf, [  --with-libelf=PATH       Specify prefix directory for the installed libelf package
1630                           Equivalent to --with-libelf-include=PATH/include
1631                           plus --with-libelf-lib=PATH/lib])
1632
1633   AC_ARG_WITH(libelf_include, [  --with-libelf-include=PATH Specify directory for installed libelf include files])
1634
1635   AC_ARG_WITH(libelf_lib, [  --with-libelf-lib=PATH   Specify the directory for the installed libelf library])
1636
1637   case $with_libelf in
1638     "")
1639       libelflibs="-lelf"
1640       libelfinc="-I/usr/include/libelf"
1641       ;;
1642     *)
1643       libelflibs="-L$with_libelf/lib -lelf"
1644       libelfinc="-I$with_libelf/include -I$with_libelf/include/libelf"
1645       LIBS="$libelflibs $LIBS"
1646       ;;
1647   esac
1648
1649   if test "x$with_libelf_include" != x; then
1650     libelfinc="-I$with_libelf_include"
1651   fi
1652
1653   if test "x$with_libelf_lib" != x; then
1654     libelflibs="-L$with_libelf_lib -lelf"
1655     LIBS="$libelflibs $LIBS"
1656   fi
1657
1658   if test "x$with_libelf$with_libelf_include$with_libelf_lib" = x \
1659      && test -d ${srcdir}/libelf; then
1660     libelflibs='-L$$r/$(HOST_SUBDIR)/libelf/.libs -L$$r/$(HOST_SUBDIR)/libelf/_libs -lelf '
1661     libelfinc='-I$$r/$(HOST_SUBDIR)/libelf/include -I$$s/libelf/include'
1662     LIBS="$libelflibs $LIBS"
1663   fi
1664
1665   saved_CFLAGS="$CFLAGS"
1666   saved_CPPFLAGS="$CPPFLAGS"
1667   saved_LIBS="$LIBS"
1668
1669   CFLAGS="$CFLAGS $libelfinc"
1670   CPPFLAGS="$CPPFLAGS $libelfinc"
1671   LIBS="$LIBS $libelflibs"
1672
1673   AC_CHECK_HEADERS(libelf.h, [have_libelf_h=yes])
1674   AC_CHECK_HEADERS(gelf.h, [have_gelf_h=yes])
1675
1676   AC_CHECK_HEADERS(libelf/libelf.h, [have_libelf_libelf_h=yes])
1677   AC_CHECK_HEADERS(libelf/gelf.h, [have_libelf_gelf_h=yes])
1678
1679   # If we couldn't find libelf.h and the user forced it, emit an error.
1680   if test x"$have_libelf_h" != x"yes" \
1681      && test x"$have_libelf_libelf_h" != x"yes" ; then
1682     if test x"$default_enable_lto" != x"yes" ; then
1683       AC_MSG_ERROR([LTO support requires libelf.h or libelf/libelf.h.])
1684     else
1685       enable_lto=no
1686       libelflibs=
1687       libelfinc=
1688     fi
1689   fi
1690
1691   # If we couldn't find gelf.h and the user forced it, emit an error.
1692   if test x"$have_gelf_h" != x"yes" \
1693      && test x"$have_libelf_gelf_h" != x"yes" ; then
1694     if test x"$default_enable_lto" != x"yes" ; then
1695       AC_MSG_ERROR([LTO support requires gelf.h or libelf/gelf.h.])
1696     else
1697       enable_lto=no
1698       libelflibs=
1699       libelfinc=
1700     fi
1701   fi
1702
1703   # Check that the detected libelf has the functions we need.  We cannot
1704   # rely on just detecting the headers since they do not include
1705   # versioning information.  Add functions, if needed.
1706   if test x"$enable_lto" = x"yes" ; then
1707     AC_MSG_CHECKING([for the correct version of libelf])
1708     AC_TRY_LINK(
1709       [#include <libelf.h>],[
1710       elf_errmsg (0);
1711       elf_getscn (0, 0);
1712       elf_nextscn (0, 0);
1713       elf_strptr (0, 0, 0);
1714       elf_getident (0, 0);
1715       elf_getshdrstrndx (0, 0);
1716       elf_begin (0, 0, 0);
1717       elf_ndxscn (0);
1718       elf_end (0);
1719       ],
1720       [AC_MSG_RESULT([yes]);],
1721       [AC_MSG_RESULT([no]); enable_lto=no; libelflibs= ; libelfinc= ]
1722     )
1723
1724     # If we couldn't enable LTO and the user forced it, emit an error.
1725     if test x"$enable_lto" = x"no" \
1726        && test x"$default_enable_lto" != x"yes" ; then
1727       AC_MSG_ERROR([To enable LTO, GCC requires libelf v0.8.12+.
1728 Try the --with-libelf, --with-libelf-include and --with-libelf-lib options
1729 to specify its location.])
1730     fi
1731   fi
1732
1733   CFLAGS="$saved_CFLAGS"
1734   CPPFLAGS="$saved_CPPFLAGS"
1735   LIBS="$saved_LIBS"
1736
1737   # Flags needed for libelf.
1738   AC_SUBST(libelflibs)
1739   AC_SUBST(libelfinc)
1740 fi
1741
1742
1743 # By default, C is the only stage 1 language.
1744 stage1_languages=,c,
1745
1746 # Target libraries that we bootstrap.
1747 bootstrap_target_libs=,target-libgcc,
1748
1749 # Figure out what language subdirectories are present.
1750 # Look if the user specified --enable-languages="..."; if not, use
1751 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1752 # go away some day.
1753 # NB:  embedded tabs in this IF block -- do not untabify
1754 if test -d ${srcdir}/gcc; then
1755   if test x"${enable_languages+set}" != xset; then
1756     if test x"${LANGUAGES+set}" = xset; then
1757       enable_languages="${LANGUAGES}"
1758         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1759     else
1760       enable_languages=all
1761     fi
1762   else
1763     if test x"${enable_languages}" = x ||
1764        test x"${enable_languages}" = xyes;
1765        then
1766       echo configure.in: --enable-languages needs at least one language argument 1>&2
1767       exit 1
1768     fi
1769   fi
1770   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1771
1772   # 'f95' is the old name for the 'fortran' language. We issue a warning
1773   # and make the substitution.
1774   case ,${enable_languages}, in
1775     *,f95,*)
1776       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1777       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1778       ;;
1779   esac
1780
1781   # First scan to see if an enabled language requires some other language.
1782   # We assume that a given config-lang.in will list all the language
1783   # front ends it requires, even if some are required indirectly.
1784   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1785     case ${lang_frag} in
1786       ..) ;;
1787       # The odd quoting in the next line works around
1788       # an apparent bug in bash 1.12 on linux.
1789       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1790       *)
1791         # From the config-lang.in, get $language, $lang_requires
1792         language=
1793         lang_requires=
1794         . ${lang_frag}
1795         for other in ${lang_requires} ; do
1796           case ,${enable_languages}, in
1797             *,$other,*) ;;
1798             *,all,*) ;;
1799             *,$language,*)
1800               echo " \`$other' language required by \`$language'; enabling" 1>&2
1801               enable_languages="${enable_languages},${other}"
1802               ;;
1803           esac
1804         done
1805         ;;
1806     esac
1807   done
1808
1809   new_enable_languages=,c,
1810
1811   # If LTO is enabled, add the LTO front end.
1812   extra_host_libiberty_configure_flags=
1813   if test "$enable_lto" = "yes" ; then
1814     case ,${enable_languages}, in
1815       *,lto,*) ;;
1816       *) enable_languages="${enable_languages},lto" ;;
1817     esac
1818     if test "${ENABLE_GOLD}" = "yes" ; then
1819       configdirs="$configdirs lto-plugin"
1820       extra_host_libiberty_configure_flags=--enable-shared
1821     fi
1822   fi
1823   AC_SUBST(extra_host_libiberty_configure_flags)
1824
1825   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1826   potential_languages=,c,
1827
1828   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1829     case ${lang_frag} in
1830       ..) ;;
1831       # The odd quoting in the next line works around
1832       # an apparent bug in bash 1.12 on linux.
1833       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1834       *)
1835         # From the config-lang.in, get $language, $target_libs,
1836         # $lang_dirs, $boot_language, and $build_by_default
1837         language=
1838         target_libs=
1839         lang_dirs=
1840         subdir_requires=
1841         boot_language=no
1842         build_by_default=yes
1843         . ${lang_frag}
1844         if test x${language} = x; then
1845           echo "${lang_frag} doesn't set \$language." 1>&2
1846           exit 1
1847         fi
1848
1849         if test "$language" = "c++" -a "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1850           boot_language=yes
1851         fi
1852
1853         case ,${enable_languages}, in
1854           *,${language},*)
1855             # Language was explicitly selected; include it.
1856             add_this_lang=yes
1857             ;;
1858           *,all,*)
1859             # 'all' was selected, select it if it is a default language
1860             add_this_lang=${build_by_default}
1861             ;;
1862           *)
1863             add_this_lang=no
1864             ;;
1865         esac
1866
1867         # Disable languages that need other directories if these aren't available.
1868         for i in $subdir_requires; do
1869           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1870           case ,${enable_languages}, in
1871             *,${language},*)
1872               # Specifically requested language; tell them.
1873               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1874               ;;
1875             *)
1876               # Silently disable.
1877               add_this_lang=unsupported
1878               ;;
1879           esac
1880         done
1881
1882         # Disable Ada if no preexisting GNAT is available.
1883         case ,${enable_languages},:${language}:${have_gnat} in
1884           *,${language},*:ada:no)
1885             # Specifically requested language; tell them.
1886             AC_MSG_ERROR([GNAT is required to build $language])
1887             ;;
1888           *:ada:no)
1889             # Silently disable.
1890             add_this_lang=unsupported
1891             ;;
1892         esac
1893
1894         # Disable a language that is unsupported by the target.
1895         case " $unsupported_languages " in
1896           *" $language "*)
1897             add_this_lang=unsupported
1898             ;;
1899         esac
1900
1901         case $add_this_lang in
1902           unsupported)
1903             # Remove language-dependent dirs.
1904             eval noconfigdirs='"$noconfigdirs "'\"$target_libs $lang_dirs\"
1905             ;;
1906           no)
1907             # Remove language-dependent dirs; still show language as supported.
1908             eval noconfigdirs='"$noconfigdirs "'\"$target_libs $lang_dirs\"
1909             potential_languages="${potential_languages}${language},"
1910             ;;
1911           yes)
1912             new_enable_languages="${new_enable_languages}${language},"
1913             potential_languages="${potential_languages}${language},"
1914             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1915             case "${boot_language}:,$enable_stage1_languages," in
1916               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1917                 # Add to (comma-separated) list of stage 1 languages.
1918                 case ",$stage1_languages," in
1919                   *,$language,* | ,yes, | ,all,) ;;
1920                   *) stage1_languages="${stage1_languages}${language}," ;;
1921                 esac
1922                 # We need to bootstrap any supporting libraries.
1923                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1924                 ;;
1925             esac
1926             ;;
1927         esac
1928         ;;
1929     esac
1930   done
1931
1932   AC_ARG_ENABLE(stage1-languages,
1933 [  --enable-stage1-languages@<:@=all@:>@   choose additional languages to build during
1934                           stage1.  Mostly useful for compiler development.],
1935   [case ,${enable_stage1_languages}, in
1936     ,no,|,,)
1937       # Set it to something that will have no effect in the loop below
1938       enable_stage1_languages=c ;;
1939     ,yes,)
1940       enable_stage1_languages=`echo $new_enable_languages | \
1941         sed -e "s/^,//" -e "s/,$//" ` ;;
1942     *,all,*)
1943       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1944         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1945   esac
1946
1947   # Add "good" languages from enable_stage1_languages to stage1_languages,
1948   # while "bad" languages go in missing_languages.  Leave no duplicates.
1949   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1950     case $potential_languages in
1951       *,$i,*)
1952         case $stage1_languages in
1953           *,$i,*) ;;
1954           *) stage1_languages="$stage1_languages$i," ;;
1955         esac ;;
1956       *)
1957         case $missing_languages in
1958           *,$i,*) ;;
1959           *) missing_languages="$missing_languages$i," ;;
1960         esac ;;
1961      esac
1962   done])
1963
1964   # Remove leading/trailing commas that were added for simplicity
1965   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1966   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1967   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1968   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1969
1970   if test "x$missing_languages" != x; then
1971     AC_MSG_ERROR([
1972 The following requested languages could not be built: ${missing_languages}
1973 Supported languages are: ${potential_languages}])
1974   fi
1975   if test "x$new_enable_languages" != "x$enable_languages"; then
1976     echo The following languages will be built: ${new_enable_languages}
1977     enable_languages="$new_enable_languages"
1978   fi
1979
1980   AC_SUBST(stage1_languages)
1981   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1982 fi
1983
1984 # Handle --disable-<component> generically.
1985 for dir in $configdirs $build_configdirs $target_configdirs ; do
1986   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1987   varname=`echo $dirname | sed -e s/+/_/g`
1988   if eval test x\${enable_${varname}} "=" xno ; then
1989     noconfigdirs="$noconfigdirs $dir"
1990   fi
1991 done
1992
1993 # Check for Boehm's garbage collector
1994 AC_ARG_ENABLE(objc-gc,
1995 [  --enable-objc-gc        enable use of Boehm's garbage collector with the
1996                           GNU Objective-C runtime],
1997 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1998   *,objc,*:*:yes:*target-boehm-gc*)
1999     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2000     ;;
2001 esac])
2002
2003 # Make sure we only build Boehm's garbage collector if required.
2004 case ,${enable_languages},:${enable_objc_gc} in
2005   *,objc,*:yes)
2006     # Keep target-boehm-gc if requested for Objective-C.
2007     ;;
2008   *)
2009     # Otherwise remove target-boehm-gc depending on target-libjava.
2010     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2011       noconfigdirs="$noconfigdirs target-boehm-gc"
2012     fi
2013     ;;
2014 esac
2015
2016 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2017 # $build_configdirs and $target_configdirs.
2018 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2019
2020 notsupp=""
2021 for dir in . $skipdirs $noconfigdirs ; do
2022   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2023   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2024     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2025     if test -r $srcdir/$dirname/configure ; then
2026       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2027         true
2028       else
2029         notsupp="$notsupp $dir"
2030       fi
2031     fi
2032   fi
2033   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2034     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2035     if test -r $srcdir/$dirname/configure ; then
2036       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2037         true
2038       else
2039         notsupp="$notsupp $dir"
2040       fi
2041     fi
2042   fi
2043   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2044     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2045     if test -r $srcdir/$dirname/configure ; then
2046       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2047         true
2048       else
2049         notsupp="$notsupp $dir"
2050       fi
2051     fi
2052   fi
2053 done
2054
2055 # Sometimes the tools are distributed with libiberty but with no other
2056 # libraries.  In that case, we don't want to build target-libiberty.
2057 # Don't let libgcc imply libiberty either.
2058 if test -n "${target_configdirs}" ; then
2059   libgcc=
2060   others=
2061   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
2062     if test "$i" = "libgcc"; then
2063       libgcc=target-libgcc
2064     elif test "$i" != "libiberty" ; then
2065       if test -r $srcdir/$i/configure ; then
2066         others=yes;
2067         break;
2068       fi
2069     fi
2070   done
2071   if test -z "${others}" ; then
2072     target_configdirs=$libgcc
2073   fi
2074 fi
2075
2076 # Quietly strip out all directories which aren't configurable in this tree.
2077 # This relies on all configurable subdirectories being autoconfiscated, which
2078 # is now the case.
2079 build_configdirs_all="$build_configdirs"
2080 build_configdirs=
2081 for i in ${build_configdirs_all} ; do
2082   j=`echo $i | sed -e s/build-//g`
2083   if test -f ${srcdir}/$j/configure ; then
2084     build_configdirs="${build_configdirs} $i"
2085   fi
2086 done
2087
2088 configdirs_all="$configdirs"
2089 configdirs=
2090 for i in ${configdirs_all} ; do
2091   if test -f ${srcdir}/$i/configure ; then
2092     configdirs="${configdirs} $i"
2093   fi
2094 done
2095
2096 target_configdirs_all="$target_configdirs"
2097 target_configdirs=
2098 for i in ${target_configdirs_all} ; do
2099   j=`echo $i | sed -e s/target-//g`
2100   if test -f ${srcdir}/$j/configure ; then
2101     target_configdirs="${target_configdirs} $i"
2102   fi
2103 done
2104
2105 # Produce a warning message for the subdirs we can't configure.
2106 # This isn't especially interesting in the Cygnus tree, but in the individual
2107 # FSF releases, it's important to let people know when their machine isn't
2108 # supported by the one or two programs in a package.
2109
2110 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2111   # If $appdirs is non-empty, at least one of those directories must still
2112   # be configured, or we error out.  (E.g., if the gas release supports a
2113   # specified target in some subdirs but not the gas subdir, we shouldn't
2114   # pretend that all is well.)
2115   if test -n "$appdirs" ; then
2116     for dir in $appdirs ; do
2117       if test -r $dir/Makefile.in ; then
2118         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2119           appdirs=""
2120           break
2121         fi
2122         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2123           appdirs=""
2124           break
2125         fi
2126       fi
2127     done
2128     if test -n "$appdirs" ; then
2129       echo "*** This configuration is not supported by this package." 1>&2
2130       exit 1
2131     fi
2132   fi
2133   # Okay, some application will build, or we don't care to check.  Still
2134   # notify of subdirs not getting built.
2135   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2136   echo "    ${notsupp}" 1>&2
2137   echo "    (Any other directories should still work fine.)" 1>&2
2138 fi
2139
2140 case "$host" in
2141   *msdosdjgpp*)
2142     enable_gdbtk=no ;;
2143 esac
2144
2145 # To find our prefix, in gcc_cv_tool_prefix.
2146 ACX_TOOL_DIRS
2147
2148 copy_dirs=
2149
2150 AC_ARG_WITH([build-sysroot],
2151   [  --with-build-sysroot=SYSROOT
2152                           use sysroot as the system root during the build],
2153   [if test x"$withval" != x ; then
2154      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2155    fi],
2156   [SYSROOT_CFLAGS_FOR_TARGET=])
2157 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2158
2159 AC_ARG_WITH([debug-prefix-map],
2160   [  --with-debug-prefix-map='A=B C=D ...'
2161                              map A to B, C to D ... in debug information],
2162   [if test x"$withval" != x; then
2163      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2164      for debug_map in $withval; do
2165        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2166      done
2167    fi],
2168   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2169 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2170
2171 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2172 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2173 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2174 # We want to ensure that TARGET libraries (which we know are built with
2175 # gcc) are built with "-O2 -g", so include those options when setting
2176 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2177 if test "x$CFLAGS_FOR_TARGET" = x; then
2178   CFLAGS_FOR_TARGET=$CFLAGS
2179   case " $CFLAGS " in
2180     *" -O2 "*) ;;
2181     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2182   esac
2183   case " $CFLAGS " in
2184     *" -g "* | *" -g3 "*) ;;
2185     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2186   esac
2187 fi
2188 AC_SUBST(CFLAGS_FOR_TARGET)
2189
2190 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2191   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2192   case " $CXXFLAGS " in
2193     *" -O2 "*) ;;
2194     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2195   esac
2196   case " $CXXFLAGS " in
2197     *" -g "* | *" -g3 "*) ;;
2198     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2199   esac
2200 fi
2201 AC_SUBST(CXXFLAGS_FOR_TARGET)
2202
2203 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2204 # the named directory are copied to $(tooldir)/sys-include.
2205 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2206   if test x${is_cross_compiler} = xno ; then
2207     echo 1>&2 '***' --with-headers is only supported when cross compiling
2208     exit 1
2209   fi
2210   if test x"${with_headers}" != xyes ; then
2211     x=${gcc_cv_tool_prefix}
2212     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2213   fi
2214 fi
2215
2216 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2217 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2218 # are permitted.
2219 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2220   if test x${is_cross_compiler} = xno ; then
2221     echo 1>&2 '***' --with-libs is only supported when cross compiling
2222     exit 1
2223   fi
2224   if test x"${with_libs}" != xyes ; then
2225     # Copy the libraries in reverse order, so that files in the first named
2226     # library override files in subsequent libraries.
2227     x=${gcc_cv_tool_prefix}
2228     for l in ${with_libs}; do
2229       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2230     done
2231   fi
2232 fi
2233
2234 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2235 #
2236 # This is done by determining whether or not the appropriate directory
2237 # is available, and by checking whether or not specific configurations
2238 # have requested that this magic not happen.
2239 #
2240 # The command line options always override the explicit settings in
2241 # configure.in, and the settings in configure.in override this magic.
2242 #
2243 # If the default for a toolchain is to use GNU as and ld, and you don't
2244 # want to do that, then you should use the --without-gnu-as and
2245 # --without-gnu-ld options for the configure script.  Similarly, if
2246 # the default is to use the included zlib and you don't want to do that,
2247 # you should use the --with-system-zlib option for the configure script.
2248
2249 if test x${use_gnu_as} = x &&
2250    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2251   with_gnu_as=yes
2252   extra_host_args="$extra_host_args --with-gnu-as"
2253 fi
2254
2255 if test x${use_gnu_ld} = x &&
2256    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2257   with_gnu_ld=yes
2258   extra_host_args="$extra_host_args --with-gnu-ld"
2259 fi
2260
2261 if test x${use_included_zlib} = x &&
2262    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2263   :
2264 else
2265   with_system_zlib=yes
2266   extra_host_args="$extra_host_args --with-system-zlib"
2267 fi
2268
2269 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2270 # can detect this case.
2271
2272 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2273   with_newlib=yes
2274   extra_host_args="$extra_host_args --with-newlib"
2275 fi
2276
2277 # Handle ${copy_dirs}
2278 set fnord ${copy_dirs}
2279 shift
2280 while test $# != 0 ; do
2281   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2282     :
2283   else
2284     echo Copying $1 to $2
2285
2286     # Use the install script to create the directory and all required
2287     # parent directories.
2288     if test -d $2 ; then
2289       :
2290     else
2291       echo >config.temp
2292       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2293     fi
2294
2295     # Copy the directory, assuming we have tar.
2296     # FIXME: Should we use B in the second tar?  Not all systems support it.
2297     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2298
2299     # It is the responsibility of the user to correctly adjust all
2300     # symlinks.  If somebody can figure out how to handle them correctly
2301     # here, feel free to add the code.
2302
2303     echo $1 > $2/COPIED
2304   fi
2305   shift; shift
2306 done
2307
2308 # Determine a target-dependent exec_prefix that the installed
2309 # gcc will search in.  Keep this list sorted by triplet, with
2310 # the *-*-osname triplets last.
2311 md_exec_prefix=
2312 case "${target}" in
2313   alpha*-*-*vms*)
2314     md_exec_prefix=/gnu/lib/gcc-lib
2315     ;;
2316   i[[34567]]86-pc-msdosdjgpp*)
2317     md_exec_prefix=/dev/env/DJDIR/bin
2318     ;;
2319   i[[34567]]86-*-sco3.2v5*)
2320     if test $with_gnu_as = yes; then
2321       md_exec_prefix=/usr/gnu/bin
2322     else
2323       md_exec_prefix=/usr/ccs/bin/elf
2324     fi
2325     ;;
2326
2327   mn10300-*-* | \
2328   powerpc-*-chorusos* | \
2329   powerpc*-*-eabi* | \
2330   powerpc*-*-sysv* | \
2331   powerpc*-*-kaos* | \
2332   s390x-ibm-tpf*)
2333     md_exec_prefix=/usr/ccs/bin
2334     ;;
2335   sparc64-*-elf*)
2336     ;;
2337   v850*-*-*)
2338     md_exec_prefix=/usr/ccs/bin
2339     ;;
2340   xtensa*-*-elf*)
2341     ;;
2342
2343   *-*-beos* | \
2344   *-*-elf* | \
2345   *-*-hpux* | \
2346   *-*-netware* | \
2347   *-*-nto-qnx* | \
2348   *-*-rtems* | \
2349   *-*-solaris2* | \
2350   *-*-sysv[[45]]* | \
2351   *-*-vxworks* | \
2352   *-wrs-windiss)
2353     md_exec_prefix=/usr/ccs/bin
2354     ;;
2355 esac
2356
2357 extra_arflags_for_target=
2358 extra_nmflags_for_target=
2359 extra_ranlibflags_for_target=
2360 target_makefile_frag=/dev/null
2361 case "${target}" in
2362   mep*-*-*)
2363     target_makefile_frag="config/mt-mep"
2364     ;;
2365   spu-*-*)
2366     target_makefile_frag="config/mt-spu"
2367     ;;
2368   mips*-sde-elf*)
2369     target_makefile_frag="config/mt-sde"
2370     ;;
2371   mipsisa*-*-elfoabi*)
2372     target_makefile_frag="config/mt-mips-elfoabi"
2373     ;;
2374   mips*-*-*linux* | mips*-*-gnu*)
2375     target_makefile_frag="config/mt-mips-gnu"
2376     ;;
2377   *-*-netware*)
2378     target_makefile_frag="config/mt-netware"
2379     ;;
2380   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2381     target_makefile_frag="config/mt-gnu"
2382     ;;
2383   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2384     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2385     # commands to handle both 32-bit and 64-bit objects.  These flags are
2386     # harmless if we're using GNU nm or ar.
2387     extra_arflags_for_target=" -X32_64"
2388     extra_nmflags_for_target=" -B -X32_64"
2389     ;;
2390   *-*-darwin*)
2391     # ranlib from Darwin requires the -c flag to look at common symbols.
2392     extra_ranlibflags_for_target=" -c"
2393     ;;
2394   mips*-*-pe | sh*-*-pe | *arm-wince-pe)
2395     target_makefile_frag="config/mt-wince"
2396     ;;
2397 esac
2398
2399 alphaieee_frag=/dev/null
2400 case $target in
2401   alpha*-*-*)
2402     # This just makes sure to use the -mieee option to build target libs.
2403     # This should probably be set individually by each library.
2404     alphaieee_frag="config/mt-alphaieee"
2405     ;;
2406 esac
2407
2408 # If --enable-target-optspace always use -Os instead of -O2 to build
2409 # the target libraries, similarly if it is not specified, use -Os
2410 # on selected platforms.
2411 ospace_frag=/dev/null
2412 case "${enable_target_optspace}:${target}" in
2413   yes:*)
2414     ospace_frag="config/mt-ospace"
2415     ;;
2416   :d30v-*)
2417     ospace_frag="config/mt-d30v"
2418     ;;
2419   :m32r-* | :d10v-* | :fr30-*)
2420     ospace_frag="config/mt-ospace"
2421     ;;
2422   no:* | :*)
2423     ;;
2424   *)
2425     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2426     ;;
2427 esac
2428
2429 # Default to using --with-stabs for certain targets.
2430 if test x${with_stabs} = x ; then
2431   case "${target}" in
2432   mips*-*-irix[[56]]*)
2433     ;;
2434   mips*-*-* | alpha*-*-osf*)
2435     with_stabs=yes;
2436     extra_host_args="${extra_host_args} --with-stabs"
2437     ;;
2438   esac
2439 fi
2440
2441 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2442 # them automatically.
2443 case "${host}" in
2444   hppa*64*-*-hpux11*)
2445     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2446     ;;
2447 esac
2448
2449 # Some systems (e.g., one of the i386-aix systems the gas testers are
2450 # using) don't handle "\$" correctly, so don't use it here.
2451 tooldir='${exec_prefix}'/${target_noncanonical}
2452 build_tooldir=${tooldir}
2453
2454 # Create a .gdbinit file which runs the one in srcdir
2455 # and tells GDB to look there for source files.
2456
2457 if test -r ${srcdir}/.gdbinit ; then
2458   case ${srcdir} in
2459     .) ;;
2460     *) cat > ./.gdbinit <<EOF
2461 # ${NO_EDIT}
2462 dir ${srcdir}
2463 dir .
2464 source ${srcdir}/.gdbinit
2465 EOF
2466     ;;
2467   esac
2468 fi
2469
2470 # Make sure that the compiler is able to generate an executable.  If it
2471 # can't, we are probably in trouble.  We don't care whether we can run the
2472 # executable--we might be using a cross compiler--we only care whether it
2473 # can be created.  At this point the main configure script has set CC.
2474 we_are_ok=no
2475 echo "int main () { return 0; }" > conftest.c
2476 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2477 if test $? = 0 ; then
2478   if test -s conftest || test -s conftest.exe ; then
2479     we_are_ok=yes
2480   fi
2481 fi
2482 case $we_are_ok in
2483   no)
2484     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2485     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2486     rm -f conftest*
2487     exit 1
2488     ;;
2489 esac
2490 rm -f conftest*
2491
2492 # The Solaris /usr/ucb/cc compiler does not appear to work.
2493 case "${host}" in
2494   sparc-sun-solaris2*)
2495       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2496       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2497           could_use=
2498           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2499           if test -d /opt/cygnus/bin ; then
2500               if test "$could_use" = "" ; then
2501                   could_use="/opt/cygnus/bin"
2502               else
2503                   could_use="$could_use or /opt/cygnus/bin"
2504               fi
2505           fi
2506         if test "$could_use" = "" ; then
2507             echo "Warning: compilation may fail because you're using"
2508             echo "/usr/ucb/cc.  You should change your PATH or CC "
2509             echo "variable and rerun configure."
2510         else
2511             echo "Warning: compilation may fail because you're using"
2512             echo "/usr/ucb/cc, when you should use the C compiler from"
2513             echo "$could_use.  You should change your"
2514             echo "PATH or CC variable and rerun configure."
2515         fi
2516       fi
2517   ;;
2518 esac
2519
2520 # Decide which environment variable is used to find dynamic libraries.
2521 case "${host}" in
2522   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2523   *-*-darwin* | *-*-rhapsody* ) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2524   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2525   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2526 esac
2527
2528 # On systems where the dynamic library environment variable is PATH,
2529 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2530 # built executables to PATH.
2531 if test "$RPATH_ENVVAR" = PATH; then
2532   GCC_SHLIB_SUBDIR=/shlib
2533 else
2534   GCC_SHLIB_SUBDIR=
2535 fi
2536
2537 # Record target_configdirs and the configure arguments for target and
2538 # build configuration in Makefile.
2539 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2540 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2541
2542 # Determine whether gdb needs tk/tcl or not.
2543 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2544 # and in that case we want gdb to be built without tk.  Ugh!
2545 # In fact I believe gdb is the *only* package directly dependent on tk,
2546 # so we should be able to put the 'maybe's in unconditionally and
2547 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2548 # 100% sure that that's safe though.
2549
2550 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2551 case "$enable_gdbtk" in
2552   no)
2553     GDB_TK="" ;;
2554   yes)
2555     GDB_TK="${gdb_tk}" ;;
2556   *)
2557     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2558     # distro.  Eventually someone will fix this and move Insight, nee
2559     # gdbtk to a separate directory.
2560     if test -d ${srcdir}/gdb/gdbtk ; then
2561       GDB_TK="${gdb_tk}"
2562     else
2563       GDB_TK=""
2564     fi
2565     ;;
2566 esac
2567 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2568 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2569
2570 # Strip out unwanted targets.
2571
2572 # While at that, we remove Makefiles if we were started for recursive
2573 # configuration, so that the top-level Makefile reconfigures them,
2574 # like we used to do when configure itself was recursive.
2575
2576 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2577 # but now we're fixing up the Makefile ourselves with the additional
2578 # commands passed to AC_CONFIG_FILES.  Use separate variables
2579 # extrasub-{build,host,target} not because there is any reason to split
2580 # the substitutions up that way, but only to remain below the limit of
2581 # 99 commands in a script, for HP-UX sed.
2582 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2583
2584 AC_ARG_ENABLE([bootstrap],
2585 [  --enable-bootstrap      enable bootstrapping @<:@yes if native build@:>@],,
2586 enable_bootstrap=default)
2587
2588 # Issue errors and warnings for invalid/strange bootstrap combinations.
2589 case "$configdirs" in
2590   *gcc*) have_compiler=yes ;;
2591   *) have_compiler=no ;;
2592 esac
2593
2594 case "$have_compiler:$host:$target:$enable_bootstrap" in
2595   *:*:*:no) ;;
2596
2597   # Default behavior.  Enable bootstrap if we have a compiler
2598   # and we are in a native configuration.
2599   yes:$build:$build:default)
2600     enable_bootstrap=yes ;;
2601
2602   *:*:*:default)
2603     enable_bootstrap=no ;;
2604
2605   # We have a compiler and we are in a native configuration, bootstrap is ok
2606   yes:$build:$build:yes)
2607     ;;
2608
2609   # Other configurations, but we have a compiler.  Assume the user knows
2610   # what he's doing.
2611   yes:*:*:yes)
2612     AC_MSG_WARN([trying to bootstrap a cross compiler])
2613     ;;
2614
2615   # No compiler: if they passed --enable-bootstrap explicitly, fail
2616   no:*:*:yes)
2617     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2618
2619   # Fail if wrong command line
2620   *)
2621     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2622     ;;
2623 esac
2624
2625 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2626   *,c++,*:yes:yes) ;;
2627   *:yes:yes)
2628     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2629     ;;
2630 esac
2631
2632 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2633   yes:yes:*\ gold\ *:*,c++,*) ;;
2634   yes:yes:*\ gold\ *:*)
2635     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2636     ;;
2637 esac
2638
2639 # Adjust the toplevel makefile according to whether bootstrap was selected.
2640 case $enable_bootstrap in
2641   yes)
2642     bootstrap_suffix=bootstrap
2643     BUILD_CONFIG=bootstrap-debug
2644     ;;
2645   no)
2646     bootstrap_suffix=no-bootstrap
2647     BUILD_CONFIG=
2648     ;;
2649 esac
2650
2651 AC_MSG_CHECKING(for default BUILD_CONFIG)
2652
2653 AC_ARG_WITH([build-config],
2654   [--with-build-config='NAME NAME2...'
2655                           Use config/NAME.mk build configuration],
2656   [case $with_build_config in
2657    yes) with_build_config= ;;
2658    no) with_build_config= BUILD_CONFIG= ;;
2659    esac])
2660
2661 if test "x${with_build_config}" != x; then
2662   BUILD_CONFIG=$with_build_config
2663 else
2664   case $BUILD_CONFIG in
2665   bootstrap-debug)
2666     if echo "int f (void) { return 0; }" > conftest.c &&
2667        ${CC} -c conftest.c &&
2668        mv conftest.o conftest.o.g0 &&
2669        ${CC} -c -g conftest.c &&
2670        mv conftest.o conftest.o.g &&
2671        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g; then
2672       :
2673     else
2674       BUILD_CONFIG=
2675     fi
2676     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2677     ;;
2678   esac
2679 fi
2680 AC_MSG_RESULT($BUILD_CONFIG)
2681 AC_SUBST(BUILD_CONFIG)
2682
2683 extrasub_build=
2684 for module in ${build_configdirs} ; do
2685   if test -z "${no_recursion}" \
2686      && test -f ${build_subdir}/${module}/Makefile; then
2687     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2688     rm -f ${build_subdir}/${module}/Makefile
2689   fi
2690   extrasub_build="$extrasub_build
2691 /^@if build-$module\$/d
2692 /^@endif build-$module\$/d
2693 /^@if build-$module-$bootstrap_suffix\$/d
2694 /^@endif build-$module-$bootstrap_suffix\$/d"
2695 done
2696 extrasub_host=
2697 for module in ${configdirs} ; do
2698   if test -z "${no_recursion}"; then
2699     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2700       if test -f ${file}; then
2701         echo 1>&2 "*** removing ${file} to force reconfigure"
2702         rm -f ${file}
2703       fi
2704     done
2705   fi
2706   extrasub_host="$extrasub_host
2707 /^@if $module\$/d
2708 /^@endif $module\$/d
2709 /^@if $module-$bootstrap_suffix\$/d
2710 /^@endif $module-$bootstrap_suffix\$/d"
2711 done
2712 extrasub_target=
2713 for module in ${target_configdirs} ; do
2714   if test -z "${no_recursion}" \
2715      && test -f ${target_subdir}/${module}/Makefile; then
2716     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2717     rm -f ${target_subdir}/${module}/Makefile
2718   fi
2719
2720   # We only bootstrap target libraries listed in bootstrap_target_libs.
2721   case $bootstrap_target_libs in
2722     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2723     *) target_bootstrap_suffix=no-bootstrap ;;
2724   esac
2725
2726   extrasub_target="$extrasub_target
2727 /^@if target-$module\$/d
2728 /^@endif target-$module\$/d
2729 /^@if target-$module-$target_bootstrap_suffix\$/d
2730 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2731 done
2732
2733 # Do the final fixup along with target modules.
2734 extrasub_target="$extrasub_target
2735 /^@if /,/^@endif /d"
2736
2737 # Create the serialization dependencies.  This uses a temporary file.
2738
2739 AC_ARG_ENABLE([serial-configure],
2740 [  --enable-serial-@<:@{host,target,build}-@:>@configure
2741                           force sequential configuration of
2742                           sub-packages for the host, target or build
2743                           machine, or all sub-packages])
2744
2745 case ${enable_serial_configure} in
2746   yes)
2747     enable_serial_build_configure=yes
2748     enable_serial_host_configure=yes
2749     enable_serial_target_configure=yes
2750     ;;
2751 esac
2752
2753 # These force 'configure's to be done one at a time, to avoid problems
2754 # with contention over a shared config.cache.
2755 rm -f serdep.tmp
2756 echo '# serdep.tmp' > serdep.tmp
2757 olditem=
2758 test "x${enable_serial_build_configure}" = xyes &&
2759 for item in ${build_configdirs} ; do
2760   case ${olditem} in
2761     "") ;;
2762     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2763   esac
2764   olditem=${item}
2765 done
2766 olditem=
2767 test "x${enable_serial_host_configure}" = xyes &&
2768 for item in ${configdirs} ; do
2769   case ${olditem} in
2770     "") ;;
2771     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2772   esac
2773   olditem=${item}
2774 done
2775 olditem=
2776 test "x${enable_serial_target_configure}" = xyes &&
2777 for item in ${target_configdirs} ; do
2778   case ${olditem} in
2779     "") ;;
2780     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2781   esac
2782   olditem=${item}
2783 done
2784 serialization_dependencies=serdep.tmp
2785 AC_SUBST_FILE(serialization_dependencies)
2786
2787 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2788 # target, nonopt, and variable assignments.  These are the ones we
2789 # might not want to pass down to subconfigures.  The exception being
2790 # --cache-file=/dev/null, which is used to turn off the use of cache
2791 # files altogether, and which should be passed on to subconfigures.
2792 # Also strip program-prefix, program-suffix, and program-transform-name,
2793 # so that we can pass down a consistent program-transform-name.
2794 baseargs=
2795 keep_next=no
2796 skip_next=no
2797 eval "set -- $ac_configure_args"
2798 for ac_arg
2799 do
2800   if test X"$skip_next" = X"yes"; then
2801     skip_next=no
2802     continue
2803   fi
2804   if test X"$keep_next" = X"yes"; then
2805     case $ac_arg in
2806       *\'*)
2807         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2808     esac
2809     baseargs="$baseargs '$ac_arg'"
2810     keep_next=no
2811     continue
2812   fi
2813
2814   # Handle separated arguments.  Based on the logic generated by
2815   # autoconf 2.59.
2816   case $ac_arg in
2817     *=* | --config-cache | -C | -disable-* | --disable-* \
2818       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2819       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2820       | -with-* | --with-* | -without-* | --without-* | --x)
2821       separate_arg=no
2822       ;;
2823     -*)
2824       separate_arg=yes
2825       ;;
2826     *)
2827       separate_arg=no
2828       ;;
2829   esac
2830
2831   case "$ac_arg" in
2832     --cache-file=/dev/null | \
2833     -cache-file=/dev/null )
2834       # Handled here to avoid the test to skip args below.
2835       baseargs="$baseargs '$ac_arg'"
2836       # Assert: $separate_arg should always be no.
2837       keep_next=$separate_arg
2838       ;;
2839     --no*)
2840       continue
2841       ;;
2842     --c* | \
2843     --sr* | \
2844     --ho* | \
2845     --bu* | \
2846     --t* | \
2847     --program-* | \
2848     -cache_file* | \
2849     -srcdir* | \
2850     -host* | \
2851     -build* | \
2852     -target* | \
2853     -program-prefix* | \
2854     -program-suffix* | \
2855     -program-transform-name* )
2856       skip_next=$separate_arg
2857       continue
2858       ;;
2859     -*)
2860       # An option.  Add it.
2861       case $ac_arg in
2862         *\'*)
2863           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2864       esac
2865       baseargs="$baseargs '$ac_arg'"
2866       keep_next=$separate_arg
2867       ;;
2868     *)
2869       # Either a variable assignment, or a nonopt (triplet).  Don't
2870       # pass it down; let the Makefile handle this.
2871       continue
2872       ;;
2873   esac
2874 done
2875 # Remove the initial space we just introduced and, as these will be
2876 # expanded by make, quote '$'.
2877 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2878
2879 # Add in --program-transform-name, after --program-prefix and
2880 # --program-suffix have been applied to it.  Autoconf has already
2881 # doubled dollar signs and backslashes in program_transform_name; we want
2882 # the backslashes un-doubled, and then the entire thing wrapped in single
2883 # quotes, because this will be expanded first by make and then by the shell.
2884 # Also, because we want to override the logic in subdir configure scripts to
2885 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2886 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2887 ${program_transform_name}
2888 EOF_SED
2889 gcc_transform_name=`cat conftestsed.out`
2890 rm -f conftestsed.out
2891 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2892 if test "$silent" = yes; then
2893   baseargs="$baseargs --silent"
2894 fi
2895 baseargs="$baseargs --disable-option-checking"
2896
2897 # For the build-side libraries, we just need to pretend we're native,
2898 # and not use the same cache file.  Multilibs are neither needed nor
2899 # desired.
2900 build_configargs="--cache-file=../config.cache ${baseargs}"
2901
2902 # For host modules, accept cache file option, or specification as blank.
2903 case "${cache_file}" in
2904 "") # empty
2905   cache_file_option="" ;;
2906 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2907   cache_file_option="--cache-file=${cache_file}" ;;
2908 *) # relative path
2909   cache_file_option="--cache-file=../${cache_file}" ;;
2910 esac
2911
2912 # Host dirs don't like to share a cache file either, horribly enough.
2913 # This seems to be due to autoconf 2.5x stupidity.
2914 host_configargs="--cache-file=./config.cache ${extra_host_args} ${baseargs}"
2915
2916 target_configargs=${baseargs}
2917
2918 # Passing a --with-cross-host argument lets the target libraries know
2919 # whether they are being built with a cross-compiler or being built
2920 # native.  However, it would be better to use other mechanisms to make the
2921 # sorts of decisions they want to make on this basis.  Please consider
2922 # this option to be deprecated.  FIXME.
2923 if test x${is_cross_compiler} = xyes ; then
2924   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2925 fi
2926
2927 # Default to --enable-multilib.
2928 if test x${enable_multilib} = x ; then
2929   target_configargs="--enable-multilib ${target_configargs}"
2930 fi
2931
2932 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2933 # changed from the earlier setting of with_newlib.
2934 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2935   target_configargs="--with-newlib ${target_configargs}"
2936 fi
2937
2938 # Different target subdirs use different values of certain variables
2939 # (notably CXX).  Worse, multilibs use *lots* of different values.
2940 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2941 # it doesn't automatically accept command-line overrides of them.
2942 # This means it's not safe for target subdirs to share a cache file,
2943 # which is disgusting, but there you have it.  Hopefully this can be
2944 # fixed in future.  It's still worthwhile to use a cache file for each
2945 # directory.  I think.
2946
2947 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2948 # We need to pass --target, as newer autoconf's requires consistency
2949 # for target_alias and gcc doesn't manage it consistently.
2950 target_configargs="--cache-file=./config.cache ${target_configargs}"
2951
2952 FLAGS_FOR_TARGET=
2953 case " $target_configdirs " in
2954  *" newlib "*)
2955   case " $target_configargs " in
2956   *" --with-newlib "*)
2957    case "$target" in
2958    *-cygwin*)
2959      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include' ;;
2960    esac
2961
2962    # If we're not building GCC, don't discard standard headers.
2963    if test -d ${srcdir}/gcc; then
2964      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2965
2966      if test "${build}" != "${host}"; then
2967        # On Canadian crosses, CC_FOR_TARGET will have already been set
2968        # by `configure', so we won't have an opportunity to add -Bgcc/
2969        # to it.  This is right: we don't want to search that directory
2970        # for binaries, but we want the header files in there, so add
2971        # them explicitly.
2972        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include'
2973
2974        # Someone might think of using the pre-installed headers on
2975        # Canadian crosses, in case the installed compiler is not fully
2976        # compatible with the compiler being built.  In this case, it
2977        # would be better to flag an error than risking having
2978        # incompatible object files being constructed.  We can't
2979        # guarantee that an error will be flagged, but let's hope the
2980        # compiler will do it, when presented with incompatible header
2981        # files.
2982      fi
2983    fi
2984
2985    case "${target}-${is_cross_compiler}" in
2986    i[[3456789]]86-*-linux*-no)
2987       # Here host == target, so we don't need to build gcc,
2988       # so we don't want to discard standard headers.
2989       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2990       ;;
2991    *)
2992       # If we're building newlib, use its generic headers last, but search
2993       # for any libc-related directories first (so make it the last -B
2994       # switch).
2995       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2996
2997       # If we're building libgloss, find the startup file, simulator library
2998       # and linker script.
2999       case " $target_configdirs " in
3000         *" libgloss "*)
3001         # Look for startup file, simulator library and maybe linker script.
3002         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3003         # Look for libnosys.a in case the target needs it.
3004         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3005         # Most targets have the linker script in the source directory.
3006         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3007         ;;
3008       esac
3009       ;;
3010    esac
3011    ;;
3012   esac
3013   ;;
3014 esac
3015 case "$target" in
3016 *-mingw*)
3017   # Can't be handled as Cygwin above since Mingw does not use newlib.
3018   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include' ;;
3019 esac
3020
3021 # Allow the user to override the flags for
3022 # our build compiler if desired.
3023 if test x"${build}" = x"${host}" ; then
3024   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3025   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3026   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3027 fi
3028
3029 # On Canadian crosses, we'll be searching the right directories for
3030 # the previously-installed cross compiler, so don't bother to add
3031 # flags for directories within the install tree of the compiler
3032 # being built; programs in there won't even run.
3033 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3034   # Search for pre-installed headers if nothing else fits.
3035   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3036 fi
3037
3038 if test "x${use_gnu_ld}" = x &&
3039    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3040   # Arrange for us to find uninstalled linker scripts.
3041   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3042 fi
3043
3044 # Search for other target-specific linker scripts and such.
3045 case "${target}" in
3046   mep*)
3047     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3048     ;;
3049 esac
3050
3051 # Makefile fragments.
3052 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3053 do
3054   eval fragval=\$$frag
3055   if test $fragval != /dev/null; then
3056     eval $frag=${srcdir}/$fragval
3057   fi
3058 done
3059 AC_SUBST_FILE(host_makefile_frag)
3060 AC_SUBST_FILE(target_makefile_frag)
3061 AC_SUBST_FILE(alphaieee_frag)
3062 AC_SUBST_FILE(ospace_frag)
3063
3064 # Miscellanea: directories, flags, etc.
3065 AC_SUBST(RPATH_ENVVAR)
3066 AC_SUBST(GCC_SHLIB_SUBDIR)
3067 AC_SUBST(tooldir)
3068 AC_SUBST(build_tooldir)
3069 AC_SUBST(CONFIGURE_GDB_TK)
3070 AC_SUBST(GDB_TK)
3071 AC_SUBST(INSTALL_GDB_TK)
3072
3073 # Build module lists & subconfigure args.
3074 AC_SUBST(build_configargs)
3075 AC_SUBST(build_configdirs)
3076
3077 # Host module lists & subconfigure args.
3078 AC_SUBST(host_configargs)
3079 AC_SUBST(configdirs)
3080
3081 # Target module lists & subconfigure args.
3082 AC_SUBST(target_configargs)
3083
3084
3085 # Build tools.
3086 AC_SUBST(AR_FOR_BUILD)
3087 AC_SUBST(AS_FOR_BUILD)
3088 AC_SUBST(CC_FOR_BUILD)
3089 AC_SUBST(CFLAGS_FOR_BUILD)
3090 AC_SUBST(CXXFLAGS_FOR_BUILD)
3091 AC_SUBST(CXX_FOR_BUILD)
3092 AC_SUBST(DLLTOOL_FOR_BUILD)
3093 AC_SUBST(GCJ_FOR_BUILD)
3094 AC_SUBST(GFORTRAN_FOR_BUILD)
3095 AC_SUBST(LDFLAGS_FOR_BUILD)
3096 AC_SUBST(LD_FOR_BUILD)
3097 AC_SUBST(NM_FOR_BUILD)
3098 AC_SUBST(RANLIB_FOR_BUILD)
3099 AC_SUBST(WINDMC_FOR_BUILD)
3100 AC_SUBST(WINDRES_FOR_BUILD)
3101 AC_SUBST(config_shell)
3102
3103 # Generate default definitions for YACC, M4, LEX and other programs that run
3104 # on the build machine.  These are used if the Makefile can't locate these
3105 # programs in objdir.
3106 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3107
3108 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3109 case " $build_configdirs " in
3110   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3111   *" byacc "*) YACC='$$r/$(BUILD_SUBDIR)/byacc/byacc' ;;
3112 esac
3113
3114 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3115 case " $build_configdirs " in
3116   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3117 esac
3118
3119 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3120 case " $build_configdirs " in
3121   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3122 esac
3123
3124 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3125 case " $build_configdirs " in
3126   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3127   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3128 esac
3129
3130 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3131 case " $build_configdirs " in
3132   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3133 esac
3134
3135 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3136 case " $build_configdirs " in
3137   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3138   *)
3139 changequote(,)
3140     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3141     # higher, else we use the "missing" dummy.
3142     if ${MAKEINFO} --version \
3143        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3144       :
3145     else
3146       MAKEINFO="$MISSING makeinfo"
3147     fi
3148     ;;
3149 changequote([,])
3150 esac
3151
3152 # FIXME: expect and dejagnu may become build tools?
3153
3154 AC_CHECK_PROGS(EXPECT, expect, expect)
3155 case " $configdirs " in
3156   *" expect "*)
3157     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3158     ;;
3159 esac
3160
3161 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3162 case " $configdirs " in
3163   *" dejagnu "*)
3164     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3165     ;;
3166 esac
3167
3168
3169 # Host tools.
3170 NCN_STRICT_CHECK_TOOLS(AR, ar)
3171 NCN_STRICT_CHECK_TOOLS(AS, as)
3172 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3173 NCN_STRICT_CHECK_TOOLS(LD, ld)
3174 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3175 NCN_STRICT_CHECK_TOOLS(NM, nm)
3176 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, :)
3177 NCN_STRICT_CHECK_TOOLS(STRIP, strip, :)
3178 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3179 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3180 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3181 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3182 AC_SUBST(CC)
3183 AC_SUBST(CXX)
3184 AC_SUBST(CFLAGS)
3185 AC_SUBST(CXXFLAGS)
3186
3187 # Target tools.
3188 AC_ARG_WITH([build-time-tools],
3189   [  --with-build-time-tools=PATH
3190                           use given path to find target tools during the build],
3191   [case x"$withval" in
3192      x/*) ;;
3193      *)
3194        with_build_time_tools=
3195        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3196        ;;
3197    esac],
3198   [with_build_time_tools=])
3199
3200 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3201 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3202 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3203 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3204 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3205
3206 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3207 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3208 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3209 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3210 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3211 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3212 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3213 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib, :)
3214 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3215 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3216 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3217
3218 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3219
3220 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3221 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3222 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3223 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3224                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `test ! -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags || $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3225                 c++)
3226 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3227                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3228                 c++)
3229 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3230 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3231 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3232                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3233 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3234                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3235 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3236 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3237 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3238 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3239 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3240 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip])
3241 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3242 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3243
3244 AC_SUBST(FLAGS_FOR_TARGET)
3245 AC_SUBST(RAW_CXX_FOR_TARGET)
3246
3247 # Certain tools may need extra flags.
3248 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3249 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3250 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3251
3252 # When building target libraries, except in a Canadian cross, we use
3253 # the same toolchain as the compiler we just built.
3254 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3255 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3256 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3257 if test $host = $build; then
3258   case " $configdirs " in
3259     *" gcc "*)
3260       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3261       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3262       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3263       ;;
3264   esac
3265 fi
3266
3267 AC_SUBST(COMPILER_AS_FOR_TARGET)
3268 AC_SUBST(COMPILER_LD_FOR_TARGET)
3269 AC_SUBST(COMPILER_NM_FOR_TARGET)
3270
3271 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3272 AC_ARG_ENABLE(maintainer-mode,
3273 [  --enable-maintainer-mode enable make rules and dependencies not useful
3274                           (and sometimes confusing) to the casual installer],
3275       USE_MAINTAINER_MODE=$enableval,
3276       USE_MAINTAINER_MODE=no)
3277 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3278 AC_SUBST(MAINTAINER_MODE_TRUE)
3279 AC_SUBST(MAINTAINER_MODE_FALSE)
3280 if test "$USE_MAINTAINER_MODE" = yes; then
3281   MAINTAINER_MODE_TRUE=
3282   MAINTAINER_MODE_FALSE='#'
3283 else
3284   MAINTAINER_MODE_TRUE='#'
3285   MAINTAINER_MODE_FALSE=
3286 fi
3287 MAINT=$MAINTAINER_MODE_TRUE
3288 AC_SUBST(MAINT)dnl
3289
3290 # ---------------------
3291 # GCC bootstrap support
3292 # ---------------------
3293
3294 # Stage specific cflags for build.
3295 stage1_cflags="-g"
3296 case $build in
3297   vax-*-*)
3298     case ${GCC} in
3299       yes) stage1_cflags="-g -Wa,-J" ;;
3300       *) stage1_cflags="-g -J" ;;
3301     esac ;;
3302 esac
3303
3304 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3305 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3306   saved_CFLAGS="$CFLAGS"
3307
3308   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3309   CFLAGS="$CFLAGS -fkeep-inline-functions"
3310   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3311   AC_TRY_COMPILE([
3312 #if (__GNUC__ < 3) \
3313     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3314                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3315 #error http://gcc.gnu.org/PR29382
3316 #endif
3317     ],,
3318     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3319     [AC_MSG_RESULT([no])])
3320
3321   CFLAGS="$saved_CFLAGS"
3322 fi
3323
3324 AC_SUBST(stage1_cflags)
3325
3326 # Enable --enable-checking in stage1 of the compiler.
3327 AC_ARG_ENABLE(stage1-checking,
3328 [  --enable-stage1-checking@<:@=all@:>@   choose additional checking for stage1
3329                           of the compiler],
3330 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3331 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3332   stage1_checking=--enable-checking=yes,types
3333 else
3334   stage1_checking=--enable-checking=$enable_checking,types
3335 fi])
3336 AC_SUBST(stage1_checking)
3337
3338 # Enable -Werror in bootstrap stage2 and later.
3339 AC_ARG_ENABLE(werror,
3340 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
3341 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3342   enable_werror=yes
3343 else
3344   enable_werror=no
3345 fi])
3346 case ${enable_werror} in
3347   yes) stage2_werror_flag="--enable-werror-always" ;;
3348   *) stage2_werror_flag="" ;;
3349 esac
3350 AC_SUBST(stage2_werror_flag)
3351
3352 # Specify what files to not compare during bootstrap.
3353
3354 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3355 case "$target" in
3356   hppa*64*-*-hpux*) ;;
3357   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3358 esac
3359 AC_SUBST(compare_exclusions)
3360
3361 AC_CONFIG_FILES([Makefile],
3362   [sed "$extrasub_build" Makefile |
3363    sed "$extrasub_host" |
3364    sed "$extrasub_target" > mf$$
3365    mv -f mf$$ Makefile],
3366   [extrasub_build="$extrasub_build"
3367    extrasub_host="$extrasub_host"
3368    extrasub_target="$extrasub_target"])
3369 AC_OUTPUT