configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_DISABLE_OPTION_CHECKING
  35
  36 progname=$0
  37 # if PWD already has a value, it is probably wrong.
  38 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  39
  40 # Export original configure arguments for use by sub-configures.
  41 # Quote arguments with shell meta charatcers.
  42 TOPLEVEL_CONFIGURE_ARGUMENTS=
  43 set -- "$progname" "$@"
  44 for ac_arg
  45 do
  46   case "$ac_arg" in
  47   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  48     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  49     # if the argument is of the form -foo=baz, quote the baz part only
  50     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  51   *) ;;
  52   esac
  53   # Add the quoted argument to the list.
  54   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  55 done
  56 if test "$silent" = yes; then
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  58 fi
  59 # Remove the initial space we just introduced and, as these will be
  60 # expanded by make, quote '$'.
  61 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  62 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  63
  64 # Find the build, host, and target systems.
  65 ACX_NONCANONICAL_BUILD
  66 ACX_NONCANONICAL_HOST
  67 ACX_NONCANONICAL_TARGET
  68
  69 dnl Autoconf 2.5x and later will set a default program prefix if
  70 dnl --target was used, even if it was the same as --host.  Disable
  71 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  72 dnl to take effect.
  73 test "$host_noncanonical" = "$target_noncanonical" &&
  74   test "$program_prefix$program_suffix$program_transform_name" = \
  75     NONENONEs,x,x, &&
  76   program_transform_name=s,y,y,
  77
  78 AC_CANONICAL_SYSTEM
  79 AC_ARG_PROGRAM
  80
  81 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  82 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  83
  84 # Get 'install' or 'install-sh' and its variants.
  85 AC_PROG_INSTALL
  86 ACX_PROG_LN
  87 AC_PROG_LN_S
  88 AC_PROG_SED
  89 AC_PROG_AWK
  90
  91 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  92
  93 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  94 # a relative path.
  95 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  96   INSTALL="${srcpwd}/install-sh -c"
  97 fi
  98
  99 # Set srcdir to "." if that's what it is.
 100 # This is important for multilib support.
 101 pwd=`${PWDCMD-pwd}`
 102 if test "${pwd}" = "${srcpwd}" ; then
 103   srcdir=.
 104 fi
 105
 106 topsrcdir=$srcpwd
 107
 108 extra_host_args=
 109
 110 ### To add a new directory to the tree, first choose whether it is a target
 111 ### or a host dependent tool.  Then put it into the appropriate list
 112 ### (library or tools, host or target), doing a dependency sort.
 113
 114 # Subdirs will be configured in the order listed in build_configdirs,
 115 # configdirs, or target_configdirs; see the serialization section below.
 116
 117 # Dependency sorting is only needed when *configuration* must be done in
 118 # a particular order.  In all cases a dependency should be specified in
 119 # the Makefile, whether or not it's implicitly specified here.
 120
 121 # Double entries in build_configdirs, configdirs, or target_configdirs may
 122 # cause circular dependencies and break everything horribly.
 123
 124 # these library is used by various programs built for the build
 125 # environment
 126 #
 127 build_libs="build-libiberty build-libcpp"
 128
 129 # these tools are built for the build environment
 130 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 131
 132 # these libraries are used by various programs built for the host environment
 133 #f
 134 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 135
 136 # these tools are built for the host environment
 137 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 138 # know that we are building the simulator.
 139 # binutils, gas and ld appear in that order because it makes sense to run
 140 # "make check" in that particular order.
 141 # If --enable-gold is used, "gold" may replace "ld".
 142 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 143
 144 # these libraries are built for the target environment, and are built after
 145 # the host libraries and the host tools (which may be a cross compiler)
 146 # Note that libiberty is not a target library.
 147 target_libraries="target-libgcc \
 148                 target-libbacktrace \
 149                 target-libgloss \
 150                 target-newlib \
 151                 target-libgomp \
 152                 target-liboffloadmic \
 153                 target-libhsail-rt \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo"
 166
 167 # these tools are built using the target libraries, and are intended to
 168 # run only in the target environment
 169 #
 170 # note: any program that *uses* libraries that are in the "target_libraries"
 171 # list belongs in this list.
 172 #
 173 target_tools="target-rda"
 174
 175 ################################################################################
 176
 177 ## All tools belong in one of the four categories, and are assigned above
 178 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 179 ## is important because configure will choke if they ever get through.
 180 ## ${configdirs} is directories we build using the host tools.
 181 ## ${target_configdirs} is directories we build using the target tools.
 182 configdirs=`echo ${host_libs} ${host_tools}`
 183 target_configdirs=`echo ${target_libraries} ${target_tools}`
 184 build_configdirs=`echo ${build_libs} ${build_tools}`
 185
 186 m4_divert_text([PARSE_ARGS],
 187 [case $srcdir in
 188   *" "*)
 189 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 190     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 191 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 192     ;;
 193 esac
 194 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 195 ])
 196
 197 ################################################################################
 198
 199 srcname="gnu development package"
 200
 201 # This gets set non-empty for some net releases of packages.
 202 appdirs=""
 203
 204 # Define is_cross_compiler to save on calls to 'test'.
 205 is_cross_compiler=
 206 if test x"${host}" = x"${target}" ; then
 207   is_cross_compiler=no
 208 else
 209   is_cross_compiler=yes
 210 fi
 211
 212 # Find the build and target subdir names.
 213 GCC_TOPLEV_SUBDIRS
 214 # Be sure to cover against remnants of an in-tree build.
 215 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 216   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 217 Use a pristine source tree when building in a separate tree])
 218 fi
 219
 220 # Skipdirs are removed silently.
 221 skipdirs=
 222 # Noconfigdirs are removed loudly.
 223 noconfigdirs=""
 224
 225 use_gnu_ld=
 226 # Make sure we don't let GNU ld be added if we didn't want it.
 227 if test x$with_gnu_ld = xno ; then
 228   use_gnu_ld=no
 229   noconfigdirs="$noconfigdirs ld gold"
 230 fi
 231
 232 use_gnu_as=
 233 # Make sure we don't let GNU as be added if we didn't want it.
 234 if test x$with_gnu_as = xno ; then
 235   use_gnu_as=no
 236   noconfigdirs="$noconfigdirs gas"
 237 fi
 238
 239 use_included_zlib=
 240 AC_ARG_WITH(system-zlib,
 241 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 249 # is provided.
 250 if test x$with_system_readline = xyes ; then
 251   noconfigdirs="$noconfigdirs readline"
 252 fi
 253
 254 # some tools are so dependent upon X11 that if we're not building with X,
 255 # it's not even worth trying to configure, much less build, that tool.
 256
 257 case ${with_x} in
 258   yes | "") ;; # the default value for this tree is that X11 is available
 259   no)
 260     skipdirs="${skipdirs} tk itcl libgui"
 261     # We won't be able to build gdbtk without X.
 262     enable_gdbtk=no
 263     ;;
 264   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 265 esac
 266
 267 # Some are only suitable for cross toolchains.
 268 # Remove these if host=target.
 269 cross_only="target-libgloss target-newlib target-opcodes"
 270
 271 case $is_cross_compiler in
 272   no) skipdirs="${skipdirs} ${cross_only}" ;;
 273 esac
 274
 275 # If both --with-headers and --with-libs are specified, default to
 276 # --without-newlib.
 277 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 278    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 279   if test x"${with_newlib}" = x ; then
 280     with_newlib=no
 281   fi
 282 fi
 283
 284 # Recognize --with-newlib/--without-newlib.
 285 case ${with_newlib} in
 286   no) skipdirs="${skipdirs} target-newlib" ;;
 287   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 288 esac
 289
 290 AC_ARG_ENABLE(as-accelerator-for,
 291 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 292                 [build as offload target compiler.
 293                 Specify offload host triple by ARG])])
 294
 295 AC_ARG_ENABLE(offload-targets,
 296 [AS_HELP_STRING([--enable-offload-targets=LIST],
 297                 [enable offloading to devices from comma-separated LIST of
 298                 TARGET[=DIR]. Use optional path to find offload target compiler
 299                 during the build])],
 300 [
 301   if test x"$enable_offload_targets" = x; then
 302     AC_MSG_ERROR([no offload targets specified])
 303   fi
 304 ], [enable_offload_targets=])
 305
 306 # Handle --enable-gold, --enable-ld.
 307 # --disable-gold [--enable-ld]
 308 #     Build only ld.  Default option.
 309 # --enable-gold [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 311 #     as "ld.bfd" and "ld".
 312 # --enable-gold=default [--enable-ld]
 313 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 314 #     install ld as "ld.bfd".
 315 # --enable-gold[=default] --disable-ld
 316 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 317 # --enable-gold --enable-ld=default
 318 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 319 #     and ld.bfd).
 320 #     In other words, ld is default
 321 # --enable-gold=default --enable-ld=default
 322 #     Error.
 323
 324 default_ld=
 325 AC_ARG_ENABLE(gold,
 326 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 327                 [build gold @<:@ARG={default,yes,no}@:>@])],
 328 ENABLE_GOLD=$enableval,
 329 ENABLE_GOLD=no)
 330 case "${ENABLE_GOLD}" in
 331   yes|default)
 332     # Check for ELF target.
 333     is_elf=no
 334     case "${target}" in
 335       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 336       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 337       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 338       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 339         case "${target}" in
 340           *-*-linux*aout* | *-*-linux*oldld*)
 341             ;;
 342           *)
 343             is_elf=yes
 344             ;;
 345         esac
 346     esac
 347
 348     if test "$is_elf" = "yes"; then
 349       # Check for target supported by gold.
 350       case "${target}" in
 351         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 352         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 353           configdirs="$configdirs gold"
 354           if test x${ENABLE_GOLD} = xdefault; then
 355             default_ld=gold
 356           fi
 357           ENABLE_GOLD=yes
 358           ;;
 359       esac
 360     fi
 361     ;;
 362   no)
 363     ;;
 364   *)
 365     AC_MSG_ERROR([invalid --enable-gold argument])
 366     ;;
 367 esac
 368
 369 AC_ARG_ENABLE(ld,
 370 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 371                 [build ld @<:@ARG={default,yes,no}@:>@])],
 372 ENABLE_LD=$enableval,
 373 ENABLE_LD=yes)
 374
 375 case "${ENABLE_LD}" in
 376   default)
 377     if test x${default_ld} != x; then
 378       AC_MSG_ERROR([either gold or ld can be the default ld])
 379     fi
 380     ;;
 381   yes)
 382     ;;
 383   no)
 384     if test x${ENABLE_GOLD} != xyes; then
 385       AC_MSG_WARN([neither ld nor gold are enabled])
 386     fi
 387     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 388     ;;
 389   *)
 390     AC_MSG_ERROR([invalid --enable-ld argument])
 391     ;;
 392 esac
 393
 394 # PR gas/19109
 395 # Decide the default method for compressing debug sections.
 396 # Provide a configure time option to override our default.
 397 AC_ARG_ENABLE(compressed_debug_sections,
 398 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 399                 [Enable compressed debug sections for gas, gold or ld by
 400                  default])],
 401 [
 402   if test x"$enable_compressed_debug_sections" = xyes; then
 403     AC_MSG_ERROR([no program with compressed debug sections specified])
 404   fi
 405 ], [enable_compressed_debug_sections=])
 406
 407 # Configure extra directories which are host specific
 408
 409 case "${host}" in
 410   *-cygwin*)
 411     configdirs="$configdirs libtermcap" ;;
 412 esac
 413
 414 # A target can indicate whether a language isn't supported for some reason.
 415 # Only spaces may be used in this macro; not newlines or tabs.
 416 unsupported_languages=
 417
 418 # Remove more programs from consideration, based on the host or
 419 # target this usually means that a port of the program doesn't
 420 # exist yet.
 421
 422 case "${host}" in
 423   i[[3456789]]86-*-msdosdjgpp*)
 424     noconfigdirs="$noconfigdirs tcl tk itcl"
 425     ;;
 426 esac
 427
 428
 429 AC_ARG_ENABLE(libquadmath,
 430 AS_HELP_STRING([--disable-libquadmath],
 431   [do not build libquadmath directory]),
 432 ENABLE_LIBQUADMATH=$enableval,
 433 ENABLE_LIBQUADMATH=yes)
 434 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 435   noconfigdirs="$noconfigdirs target-libquadmath"
 436 fi
 437
 438
 439 AC_ARG_ENABLE(libquadmath-support,
 440 AS_HELP_STRING([--disable-libquadmath-support],
 441   [disable libquadmath support for Fortran]),
 442 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 443 ENABLE_LIBQUADMATH_SUPPORT=yes)
 444 enable_libquadmath_support=
 445 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 446   enable_libquadmath_support=no
 447 fi
 448
 449
 450 AC_ARG_ENABLE(libada,
 451 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 452 ENABLE_LIBADA=$enableval,
 453 ENABLE_LIBADA=yes)
 454 if test "${ENABLE_LIBADA}" != "yes" ; then
 455   noconfigdirs="$noconfigdirs gnattools"
 456 fi
 457
 458 AC_ARG_ENABLE(libssp,
 459 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 460 ENABLE_LIBSSP=$enableval,
 461 ENABLE_LIBSSP=yes)
 462
 463 AC_ARG_ENABLE(libstdcxx,
 464 AS_HELP_STRING([--disable-libstdcxx],
 465   [do not build libstdc++-v3 directory]),
 466 ENABLE_LIBSTDCXX=$enableval,
 467 ENABLE_LIBSTDCXX=default)
 468 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 469   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 470 fi]
 471
 472 # If this is accelerator compiler and its target is intelmic we enable
 473 # target liboffloadmic by default.  If this is compiler with offloading
 474 # for intelmic we enable host liboffloadmic by default.  Otherwise
 475 # liboffloadmic is disabled by default.
 476 AC_ARG_ENABLE([liboffloadmic],
 477 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 478                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 479 [case "$enableval" in
 480   no | host | target)
 481     enable_liboffloadmic=$enableval ;;
 482   *)
 483     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 484 esac],
 485 [if test x"$enable_as_accelerator_for" != x; then
 486   case "${target}" in
 487     *-intelmic-* | *-intelmicemul-*)
 488       enable_liboffloadmic=target
 489       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 490       ;;
 491     *)
 492       enable_liboffloadmic=no
 493       ;;
 494   esac
 495 else
 496   case "${enable_offload_targets}" in
 497     *-intelmic-* | *-intelmicemul-*)
 498       enable_liboffloadmic=host
 499       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 500       ;;
 501     *)
 502       enable_liboffloadmic=no
 503       ;;
 504     esac
 505 fi])
 506 AC_SUBST(extra_liboffloadmic_configure_flags)
 507
 508 # Enable libgomp by default on hosted POSIX systems, and a few others.
 509 if test x$enable_libgomp = x ; then
 510     case "${target}" in
 511     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 512         ;;
 513     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 514         ;;
 515     *-*-solaris2* | *-*-hpux11*)
 516         ;;
 517     *-*-darwin* | *-*-aix*)
 518         ;;
 519     nvptx*-*-*)
 520         ;;
 521     *)
 522         noconfigdirs="$noconfigdirs target-libgomp"
 523         ;;
 524     esac
 525 fi
 526
 527 # Disable libatomic on unsupported systems.
 528 if test -d ${srcdir}/libatomic; then
 529     if test x$enable_libatomic = x; then
 530         AC_MSG_CHECKING([for libatomic support])
 531         if (srcdir=${srcdir}/libatomic; \
 532                 . ${srcdir}/configure.tgt; \
 533                 test -n "$UNSUPPORTED")
 534         then
 535             AC_MSG_RESULT([no])
 536             noconfigdirs="$noconfigdirs target-libatomic"
 537         else
 538             AC_MSG_RESULT([yes])
 539         fi
 540     fi
 541 fi
 542
 543 # Disable liboffloadmic on unsupported systems.
 544 if test -d ${srcdir}/liboffloadmic; then
 545     if test x$enable_liboffloadmic != xno; then
 546         AC_MSG_CHECKING([for liboffloadmic support])
 547         if (srcdir=${srcdir}/liboffloadmic; \
 548                 . ${srcdir}/configure.tgt; \
 549                 test -n "$UNSUPPORTED")
 550         then
 551             AC_MSG_RESULT([no])
 552             noconfigdirs="$noconfigdirs target-liboffloadmic"
 553         else
 554             AC_MSG_RESULT([yes])
 555         fi
 556     fi
 557 fi
 558
 559 # Disable libitm on unsupported systems.
 560 if test -d ${srcdir}/libitm; then
 561     if test x$enable_libitm = x; then
 562         AC_MSG_CHECKING([for libitm support])
 563         if (srcdir=${srcdir}/libitm; \
 564                 . ${srcdir}/configure.tgt; \
 565                 test -n "$UNSUPPORTED")
 566         then
 567             AC_MSG_RESULT([no])
 568             noconfigdirs="$noconfigdirs target-libitm"
 569         else
 570             AC_MSG_RESULT([yes])
 571         fi
 572     fi
 573 fi
 574
 575 # Disable libsanitizer on unsupported systems.
 576 if test -d ${srcdir}/libsanitizer; then
 577     if test x$enable_libsanitizer = x; then
 578         AC_MSG_CHECKING([for libsanitizer support])
 579         if (srcdir=${srcdir}/libsanitizer; \
 580                 . ${srcdir}/configure.tgt; \
 581                 test -n "$UNSUPPORTED")
 582         then
 583             AC_MSG_RESULT([no])
 584             noconfigdirs="$noconfigdirs target-libsanitizer"
 585         else
 586             AC_MSG_RESULT([yes])
 587         fi
 588     fi
 589 fi
 590
 591 # Disable libvtv on unsupported systems.
 592 if test -d ${srcdir}/libvtv; then
 593     if test x$enable_libvtv = x; then
 594         AC_MSG_CHECKING([for libvtv support])
 595         if (srcdir=${srcdir}/libvtv; \
 596                 . ${srcdir}/configure.tgt; \
 597                 test "$VTV_SUPPORTED" != "yes")
 598         then
 599             AC_MSG_RESULT([no])
 600             noconfigdirs="$noconfigdirs target-libvtv"
 601         else
 602             AC_MSG_RESULT([yes])
 603         fi
 604     fi
 605 fi
 606
 607
 608 # Disable libhsail-rt on unsupported systems.
 609 if test -d ${srcdir}/libhsail-rt; then
 610     if test x$enable_libhsail_rt = x; then
 611         AC_MSG_CHECKING([for libhsail-rt support])
 612         if (srcdir=${srcdir}/libhsail-rt; \
 613                 . ${srcdir}/configure.tgt; \
 614                 test -n "$UNSUPPORTED")
 615         then
 616             AC_MSG_RESULT([no])
 617             unsupported_languages="$unsupported_languages brig"
 618             # This implicitly disables also target-libhsail-rt as it won't
 619             # get added to the build without BRIG FE.
 620         else
 621             AC_MSG_RESULT([yes])
 622         fi
 623     fi
 624 fi
 625
 626
 627 # Disable libquadmath for some systems.
 628 case "${target}" in
 629   avr-*-*)
 630     noconfigdirs="$noconfigdirs target-libquadmath"
 631     ;;
 632   # libquadmath is unused on AIX and libquadmath build process use of
 633   # LD_LIBRARY_PATH can break AIX bootstrap.
 634   powerpc-*-aix* | rs6000-*-aix*)
 635     noconfigdirs="$noconfigdirs target-libquadmath"
 636     ;;
 637 esac
 638
 639 # Disable libssp for some systems.
 640 case "${target}" in
 641   avr-*-*)
 642     # No hosted I/O support.
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   powerpc-*-aix* | rs6000-*-aix*)
 646     noconfigdirs="$noconfigdirs target-libssp"
 647     ;;
 648   rl78-*-*)
 649     # libssp uses a misaligned load to trigger a fault, but the RL78
 650     # doesn't fault for those - instead, it gives a build-time error
 651     # for explicit misaligned loads.
 652     noconfigdirs="$noconfigdirs target-libssp"
 653     ;;
 654   visium-*-*)
 655     # No hosted I/O support.
 656     noconfigdirs="$noconfigdirs target-libssp"
 657     ;;
 658 esac
 659
 660 # Disable libstdc++-v3 for some systems.
 661 # Allow user to override this if they pass --enable-libstdc++-v3
 662 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 663   case "${target}" in
 664     *-*-vxworks*)
 665       # VxWorks uses the Dinkumware C++ library.
 666       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 667       ;;
 668     arm*-wince-pe*)
 669       # the C++ libraries don't build on top of CE's C libraries
 670       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 671       ;;
 672     avr-*-*)
 673       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 674       ;;
 675     ft32-*-*)
 676       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 677       ;;
 678   esac
 679 fi
 680
 681 # Disable Fortran for some systems.
 682 case "${target}" in
 683   mmix-*-*)
 684     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 685     unsupported_languages="$unsupported_languages fortran"
 686     ;;
 687 esac
 688
 689 # Disable libffi for some systems.
 690 case "${target}" in
 691   powerpc-*-darwin*)
 692     ;;
 693   i[[3456789]]86-*-darwin*)
 694     ;;
 695   x86_64-*-darwin[[912]]*)
 696     ;;
 697   *-*-darwin*)
 698     noconfigdirs="$noconfigdirs target-libffi"
 699     ;;
 700   *-*-netware*)
 701     noconfigdirs="$noconfigdirs target-libffi"
 702     ;;
 703   *-*-phoenix*)
 704     noconfigdirs="$noconfigdirs target-libffi"
 705     ;;
 706   *-*-rtems*)
 707     noconfigdirs="$noconfigdirs target-libffi"
 708     ;;
 709   *-*-tpf*)
 710     noconfigdirs="$noconfigdirs target-libffi"
 711     ;;
 712   *-*-uclinux*)
 713     noconfigdirs="$noconfigdirs target-libffi"
 714     ;;
 715   *-*-vxworks*)
 716     noconfigdirs="$noconfigdirs target-libffi"
 717     ;;
 718   aarch64*-*-freebsd*)
 719     noconfigdirs="$noconfigdirs target-libffi"
 720     ;;
 721   alpha*-*-*vms*)
 722     noconfigdirs="$noconfigdirs target-libffi"
 723     ;;
 724   arm*-*-freebsd*)
 725     noconfigdirs="$noconfigdirs target-libffi"
 726     ;;
 727   arm-wince-pe)
 728     noconfigdirs="$noconfigdirs target-libffi"
 729     ;;
 730   arm*-*-symbianelf*)
 731     noconfigdirs="$noconfigdirs target-libffi"
 732     ;;
 733   cris-*-* | crisv32-*-*)
 734     case "${target}" in
 735       *-*-linux*)
 736         ;;
 737       *) # See PR46792 regarding target-libffi.
 738         noconfigdirs="$noconfigdirs target-libffi";;
 739     esac
 740     ;;
 741   hppa*64*-*-hpux*)
 742     noconfigdirs="$noconfigdirs target-libffi"
 743     ;;
 744   hppa*-hp-hpux11*)
 745     ;;
 746   hppa*-*-hpux*)
 747     noconfigdirs="$noconfigdirs target-libffi"
 748     ;;
 749   ia64*-*-*vms*)
 750     noconfigdirs="$noconfigdirs target-libffi"
 751     ;;
 752   i[[3456789]]86-w64-mingw*)
 753     noconfigdirs="$noconfigdirs target-libffi"
 754     ;;
 755   i[[3456789]]86-*-mingw*)
 756     noconfigdirs="$noconfigdirs target-libffi"
 757     ;;
 758   x86_64-*-mingw*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   mmix-*-*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   powerpc-*-aix*)
 765     ;;
 766   rs6000-*-aix*)
 767     ;;
 768   ft32-*-*)
 769     noconfigdirs="$noconfigdirs target-libffi"
 770     ;;
 771   *-*-lynxos*)
 772     noconfigdirs="$noconfigdirs target-libffi"
 773     ;;
 774 esac
 775
 776 # Disable the go frontend on systems where it is known to not work. Please keep
 777 # this in sync with contrib/config-list.mk.
 778 case "${target}" in
 779 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 780     unsupported_languages="$unsupported_languages go"
 781     ;;
 782 esac
 783
 784 # Disable libgo for some systems where it is known to not work.
 785 # For testing, you can easily override this with --enable-libgo.
 786 if test x$enable_libgo = x; then
 787     case "${target}" in
 788     *-*-darwin*)
 789         # PR 46986
 790         noconfigdirs="$noconfigdirs target-libgo"
 791         ;;
 792     *-*-cygwin* | *-*-mingw*)
 793         noconfigdirs="$noconfigdirs target-libgo"
 794         ;;
 795     esac
 796 fi
 797
 798 # Default libgloss CPU subdirectory.
 799 libgloss_dir="$target_cpu"
 800
 801 case "${target}" in
 802   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 803     libgloss_dir=wince
 804     ;;
 805   aarch64*-*-* )
 806     libgloss_dir=aarch64
 807     ;;
 808   arm*-*-*)
 809     libgloss_dir=arm
 810     ;;
 811   cris-*-* | crisv32-*-*)
 812     libgloss_dir=cris
 813     ;;
 814   hppa*-*-*)
 815     libgloss_dir=pa
 816     ;;
 817   i[[3456789]]86-*-*)
 818     libgloss_dir=i386
 819     ;;
 820   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 821     libgloss_dir=m68hc11
 822     ;;
 823   m68*-*-* | fido-*-*)
 824     libgloss_dir=m68k
 825     ;;
 826   mips*-*-*)
 827     libgloss_dir=mips
 828     ;;
 829   powerpc*-*-*)
 830     libgloss_dir=rs6000
 831     ;;
 832   sparc*-*-*)
 833     libgloss_dir=sparc
 834     ;;
 835 esac
 836
 837 # Disable newlib and libgloss for various target OSes.
 838 case "${target}" in
 839   alpha*-dec-osf*)
 840     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 841     ;;
 842   i[[3456789]]86-*-linux*)
 843     # This section makes it possible to build newlib natively on linux.
 844     # If we are using a cross compiler then don't configure newlib.
 845     if test x${is_cross_compiler} != xno ; then
 846       noconfigdirs="$noconfigdirs target-newlib"
 847     fi
 848     noconfigdirs="$noconfigdirs target-libgloss"
 849     # If we are not using a cross compiler, do configure newlib.
 850     # Note however, that newlib will only be configured in this situation
 851     # if the --with-newlib option has been given, because otherwise
 852     # 'target-newlib' will appear in skipdirs.
 853     ;;
 854   i[[3456789]]86-*-rdos*)
 855     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 856     ;;
 857   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 858     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 859     ;;
 860   sparc-*-sunos4*)
 861     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 862     ;;
 863   *-*-aix*)
 864     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 865     ;;
 866   *-*-beos*)
 867     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 868     ;;
 869   *-*-chorusos)
 870     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 871     ;;
 872   *-*-dragonfly*)
 873     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 874     ;;
 875   *-*-freebsd*)
 876     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 877     ;;
 878   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 879     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 880     ;;
 881   *-*-lynxos*)
 882     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 883     ;;
 884   *-*-mingw*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   *-*-netbsd*)
 888     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 889     ;;
 890   *-*-netware*)
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   *-*-tpf*)
 894     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 895     ;;
 896   *-*-uclinux*)
 897     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 898     ;;
 899   *-*-vxworks*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902 esac
 903
 904 case "${target}" in
 905   *-*-chorusos)
 906     ;;
 907   aarch64-*-darwin*)
 908     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 909     noconfigdirs="$noconfigdirs sim target-rda"
 910     ;;
 911   arm-*-darwin*)
 912     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 913     noconfigdirs="$noconfigdirs sim target-rda"
 914     ;;
 915   powerpc-*-darwin*)
 916     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 917     noconfigdirs="$noconfigdirs sim target-rda"
 918     ;;
 919   i[[3456789]]86-*-darwin*)
 920     noconfigdirs="$noconfigdirs ld gprof"
 921     noconfigdirs="$noconfigdirs sim target-rda"
 922     ;;
 923   x86_64-*-darwin[[912]]*)
 924     noconfigdirs="$noconfigdirs ld gas gprof"
 925     noconfigdirs="$noconfigdirs sim target-rda"
 926     ;;
 927   *-*-darwin*)
 928     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 929     noconfigdirs="$noconfigdirs sim target-rda"
 930     ;;
 931   *-*-dragonfly*)
 932     ;;
 933   *-*-freebsd*)
 934     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 935         && test -f /usr/local/include/gmp.h; then
 936       with_gmp=/usr/local
 937     fi
 938     ;;
 939   *-*-kaos*)
 940     # Remove unsupported stuff on all kaOS configurations.
 941     noconfigdirs="$noconfigdirs target-libgloss"
 942     ;;
 943   *-*-netbsd*)
 944     ;;
 945   *-*-netware*)
 946     ;;
 947   *-*-phoenix*)
 948     noconfigdirs="$noconfigdirs target-libgloss"
 949     ;;
 950   *-*-rtems*)
 951     noconfigdirs="$noconfigdirs target-libgloss"
 952     ;;
 953     # The tpf target doesn't support gdb yet.
 954   *-*-tpf*)
 955     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 956     ;;
 957   *-*-uclinux*)
 958     noconfigdirs="$noconfigdirs target-rda"
 959     ;;
 960   *-*-vxworks*)
 961     ;;
 962   alpha*-dec-osf*)
 963     # ld works, but does not support shared libraries.
 964     # gas doesn't generate exception information.
 965     noconfigdirs="$noconfigdirs gas ld"
 966     ;;
 967   alpha*-*-*vms*)
 968     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 969     ;;
 970   alpha*-*-*)
 971     # newlib is not 64 bit ready
 972     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 973     ;;
 974   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 975     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 976     ;;
 977   arc*-*-*)
 978     noconfigdirs="$noconfigdirs sim"
 979     ;;
 980   arm-*-pe*)
 981     noconfigdirs="$noconfigdirs target-libgloss"
 982     ;;
 983   arm-*-riscix*)
 984     noconfigdirs="$noconfigdirs ld target-libgloss"
 985     ;;
 986   avr-*-*)
 987     if test x${with_avrlibc} != xno; then
 988       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     fi
 990     ;;
 991   c4x-*-* | tic4x-*-*)
 992     noconfigdirs="$noconfigdirs target-libgloss"
 993     ;;
 994   tic54x-*-*)
 995     noconfigdirs="$noconfigdirs target-libgloss gdb"
 996     ;;
 997   d10v-*-*)
 998     noconfigdirs="$noconfigdirs target-libgloss"
 999     ;;
1000   d30v-*-*)
1001     noconfigdirs="$noconfigdirs gdb"
1002     ;;
1003   fr30-*-elf*)
1004     noconfigdirs="$noconfigdirs gdb"
1005     ;;
1006   ft32-*-*)
1007     noconfigdirs="$noconfigdirs target-rda gprof"
1008     ;;
1009   moxie-*-*)
1010     noconfigdirs="$noconfigdirs"
1011     ;;
1012   h8300*-*-*)
1013     noconfigdirs="$noconfigdirs target-libgloss"
1014     ;;
1015   h8500-*-*)
1016     noconfigdirs="$noconfigdirs target-libgloss"
1017     ;;
1018   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1019     ;;
1020   hppa*64*-*-hpux*)
1021     noconfigdirs="$noconfigdirs gdb"
1022     ;;
1023   hppa*-*-hpux11*)
1024     noconfigdirs="$noconfigdirs gdb ld"
1025     ;;
1026   hppa*64*-*-linux*)
1027     ;;
1028   hppa*-*-linux*)
1029     ;;
1030   hppa*-*-*elf* | \
1031   hppa*-*-lites* | \
1032   hppa*-*-openbsd* | \
1033   hppa*64*-*-*)
1034     ;;
1035   hppa*-*-pro*)
1036     ;;
1037   hppa*-*-*)
1038     noconfigdirs="$noconfigdirs ld"
1039     ;;
1040   i960-*-*)
1041     noconfigdirs="$noconfigdirs gdb"
1042     ;;
1043   ia64*-*-elf*)
1044     # No gdb support yet.
1045     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1046     ;;
1047   ia64*-**-hpux*)
1048     # No ld support yet.
1049     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1050     ;;
1051   ia64*-*-*vms*)
1052     # No ld support yet.
1053     noconfigdirs="$noconfigdirs libgui itcl ld"
1054     ;;
1055   i[[3456789]]86-w64-mingw*)
1056     ;;
1057   i[[3456789]]86-*-mingw*)
1058     target_configdirs="$target_configdirs target-winsup"
1059     ;;
1060   *-*-cygwin*)
1061     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1062     noconfigdirs="$noconfigdirs target-libgloss"
1063     # always build newlib if winsup directory is present.
1064     if test -d "$srcdir/winsup/cygwin"; then
1065       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1066     elif test -d "$srcdir/newlib"; then
1067       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1068     fi
1069     ;;
1070   i[[3456789]]86-*-pe)
1071     noconfigdirs="$noconfigdirs target-libgloss"
1072     ;;
1073   i[[3456789]]86-*-sco3.2v5*)
1074     # The linker does not yet know about weak symbols in COFF,
1075     # and is not configured to handle mixed ELF and COFF.
1076     noconfigdirs="$noconfigdirs ld target-libgloss"
1077     ;;
1078   i[[3456789]]86-*-sco*)
1079     noconfigdirs="$noconfigdirs gprof target-libgloss"
1080     ;;
1081   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1082     noconfigdirs="$noconfigdirs target-libgloss"
1083     ;;
1084   i[[3456789]]86-*-sysv4*)
1085     noconfigdirs="$noconfigdirs target-libgloss"
1086     ;;
1087   i[[3456789]]86-*-beos*)
1088     noconfigdirs="$noconfigdirs gdb"
1089     ;;
1090   i[[3456789]]86-*-rdos*)
1091     noconfigdirs="$noconfigdirs gdb"
1092     ;;
1093   mmix-*-*)
1094     noconfigdirs="$noconfigdirs gdb"
1095     ;;
1096   mt-*-*)
1097     noconfigdirs="$noconfigdirs sim"
1098     ;;
1099   nfp-*-*)
1100     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1101     noconfigdirs="$noconfigdirs $target_libraries"
1102     ;;
1103   powerpc-*-aix*)
1104     # copied from rs6000-*-* entry
1105     noconfigdirs="$noconfigdirs gprof"
1106     ;;
1107   powerpc*-*-winnt* | powerpc*-*-pe*)
1108     target_configdirs="$target_configdirs target-winsup"
1109     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1110     # always build newlib.
1111     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1112     ;;
1113     # This is temporary until we can link against shared libraries
1114   powerpcle-*-solaris*)
1115     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1116     ;;
1117   powerpc-*-beos*)
1118     noconfigdirs="$noconfigdirs gdb"
1119     ;;
1120   rs6000-*-lynxos*)
1121     noconfigdirs="$noconfigdirs gprof"
1122     ;;
1123   rs6000-*-aix*)
1124     noconfigdirs="$noconfigdirs gprof"
1125     ;;
1126   rs6000-*-*)
1127     noconfigdirs="$noconfigdirs gprof"
1128     ;;
1129   m68k-apollo-*)
1130     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1131     ;;
1132   microblaze*)
1133     noconfigdirs="$noconfigdirs gprof"
1134     ;;
1135   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1136     if test x$with_newlib = xyes; then
1137       noconfigdirs="$noconfigdirs gprof"
1138     fi
1139     ;;
1140   mips*-*-irix5*)
1141     noconfigdirs="$noconfigdirs gprof target-libgloss"
1142     ;;
1143   mips*-*-irix6*)
1144     noconfigdirs="$noconfigdirs gprof target-libgloss"
1145     ;;
1146   mips*-*-bsd*)
1147     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1148     ;;
1149   mips*-*-linux*)
1150     ;;
1151   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1152   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1153     noconfigdirs="$noconfigdirs ld gas gprof"
1154     ;;
1155   mips*-*-*)
1156     noconfigdirs="$noconfigdirs gprof"
1157     ;;
1158   nvptx*-*-*)
1159     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1160     ;;
1161   sh-*-*)
1162     case "${target}" in
1163       sh*-*-elf)
1164          ;;
1165       *)
1166          noconfigdirs="$noconfigdirs target-libgloss" ;;
1167     esac
1168     ;;
1169   sparc-*-sunos4*)
1170     if test x${is_cross_compiler} = xno ; then
1171            use_gnu_ld=no
1172     fi
1173     ;;
1174   tic6x-*-*)
1175     noconfigdirs="$noconfigdirs sim"
1176     ;;
1177   tilepro*-*-* | tilegx*-*-*)
1178     noconfigdirs="$noconfigdirs sim"
1179     ;;
1180   v810-*-*)
1181     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1182     ;;
1183   vax-*-*)
1184     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1185     ;;
1186   wasm32-*-*)
1187     noconfigdirs="$noconfigdirs ld"
1188     ;;
1189 esac
1190
1191 # If we aren't building newlib, then don't build libgloss, since libgloss
1192 # depends upon some newlib header files.
1193 case "${noconfigdirs}" in
1194   *target-libgloss*) ;;
1195   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1196 esac
1197
1198 # Work in distributions that contain no compiler tools, like Autoconf.
1199 host_makefile_frag=/dev/null
1200 if test -d ${srcdir}/config ; then
1201 case "${host}" in
1202   i[[3456789]]86-*-msdosdjgpp*)
1203     host_makefile_frag="config/mh-djgpp"
1204     ;;
1205   *-cygwin*)
1206     ACX_CHECK_CYGWIN_CAT_WORKS
1207     host_makefile_frag="config/mh-cygwin"
1208     ;;
1209   *-mingw*)
1210     host_makefile_frag="config/mh-mingw"
1211     ;;
1212   alpha*-linux*)
1213     host_makefile_frag="config/mh-alpha-linux"
1214     ;;
1215   hppa*-hp-hpux10*)
1216     host_makefile_frag="config/mh-pa-hpux10"
1217     ;;
1218   hppa*-hp-hpux*)
1219     host_makefile_frag="config/mh-pa"
1220     ;;
1221   hppa*-*)
1222     host_makefile_frag="config/mh-pa"
1223     ;;
1224   *-*-darwin*)
1225     host_makefile_frag="config/mh-darwin"
1226     ;;
1227   powerpc-*-aix*)
1228     host_makefile_frag="config/mh-ppc-aix"
1229     ;;
1230   rs6000-*-aix*)
1231     host_makefile_frag="config/mh-ppc-aix"
1232     ;;
1233 esac
1234 fi
1235
1236 if test "${build}" != "${host}" ; then
1237   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1238   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1239   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1240   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1241   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1242   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1243   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1244   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1245   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1246   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1247   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1248   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1249 else
1250   AR_FOR_BUILD="\$(AR)"
1251   AS_FOR_BUILD="\$(AS)"
1252   CC_FOR_BUILD="\$(CC)"
1253   CXX_FOR_BUILD="\$(CXX)"
1254   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1255   GOC_FOR_BUILD="\$(GOC)"
1256   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1257   LD_FOR_BUILD="\$(LD)"
1258   NM_FOR_BUILD="\$(NM)"
1259   RANLIB_FOR_BUILD="\$(RANLIB)"
1260   WINDRES_FOR_BUILD="\$(WINDRES)"
1261   WINDMC_FOR_BUILD="\$(WINDMC)"
1262 fi
1263
1264 AC_PROG_CC
1265 AC_PROG_CXX
1266
1267 # We must set the default linker to the linker used by gcc for the correct
1268 # operation of libtool.  If LD is not defined and we are using gcc, try to
1269 # set the LD default to the ld used by gcc.
1270 if test -z "$LD"; then
1271   if test "$GCC" = yes; then
1272     case $build in
1273     *-*-mingw*)
1274       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1275     *)
1276       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1277     esac
1278     case $gcc_prog_ld in
1279     # Accept absolute paths.
1280     [[\\/]* | [A-Za-z]:[\\/]*)]
1281       LD="$gcc_prog_ld" ;;
1282     esac
1283   fi
1284 fi
1285
1286 # Check whether -static-libstdc++ -static-libgcc is supported.
1287 have_static_libs=no
1288 if test "$GCC" = yes; then
1289   saved_LDFLAGS="$LDFLAGS"
1290
1291   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1292   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1293   AC_LANG_PUSH(C++)
1294   AC_LINK_IFELSE([AC_LANG_SOURCE([
1295 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1296 #error -static-libstdc++ not implemented
1297 #endif
1298 int main() {}])],
1299     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1300     [AC_MSG_RESULT([no])])
1301   AC_LANG_POP(C++)
1302
1303   LDFLAGS="$saved_LDFLAGS"
1304 fi
1305
1306 ACX_PROG_GNAT
1307 ACX_PROG_CMP_IGNORE_INITIAL
1308
1309 AC_ARG_ENABLE([bootstrap],
1310 [AS_HELP_STRING([--enable-bootstrap],
1311                 [enable bootstrapping @<:@yes if native build@:>@])],,
1312 enable_bootstrap=default)
1313
1314 # Issue errors and warnings for invalid/strange bootstrap combinations.
1315 if test -r $srcdir/gcc/configure; then
1316   have_compiler=yes
1317 else
1318   have_compiler=no
1319 fi
1320
1321 case "$have_compiler:$host:$target:$enable_bootstrap" in
1322   *:*:*:no) ;;
1323
1324   # Default behavior.  Enable bootstrap if we have a compiler
1325   # and we are in a native configuration.
1326   yes:$build:$build:default)
1327     enable_bootstrap=yes ;;
1328
1329   *:*:*:default)
1330     enable_bootstrap=no ;;
1331
1332   # We have a compiler and we are in a native configuration, bootstrap is ok
1333   yes:$build:$build:yes)
1334     ;;
1335
1336   # Other configurations, but we have a compiler.  Assume the user knows
1337   # what he's doing.
1338   yes:*:*:yes)
1339     AC_MSG_WARN([trying to bootstrap a cross compiler])
1340     ;;
1341
1342   # No compiler: if they passed --enable-bootstrap explicitly, fail
1343   no:*:*:yes)
1344     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1345
1346   # Fail if wrong command line
1347   *)
1348     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1349     ;;
1350 esac
1351
1352 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1353 # C++98 compiler can still start the bootstrap.
1354 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1355   CXX="$CXX -std=gnu++98"
1356 fi
1357
1358 # Used for setting $lt_cv_objdir
1359 _LT_CHECK_OBJDIR
1360
1361 # Check for GMP, MPFR and MPC
1362 gmplibs="-lmpc -lmpfr -lgmp"
1363 gmpinc=
1364 have_gmp=no
1365
1366 # Specify a location for mpc
1367 # check for this first so it ends up on the link line before mpfr.
1368 AC_ARG_WITH(mpc,
1369 [AS_HELP_STRING([--with-mpc=PATH],
1370                 [specify prefix directory for installed MPC package.
1371                  Equivalent to --with-mpc-include=PATH/include
1372                  plus --with-mpc-lib=PATH/lib])])
1373 AC_ARG_WITH(mpc-include,
1374 [AS_HELP_STRING([--with-mpc-include=PATH],
1375                 [specify directory for installed MPC include files])])
1376 AC_ARG_WITH(mpc-lib,
1377 [AS_HELP_STRING([--with-mpc-lib=PATH],
1378                 [specify directory for the installed MPC library])])
1379
1380 if test "x$with_mpc" != x; then
1381   gmplibs="-L$with_mpc/lib $gmplibs"
1382   gmpinc="-I$with_mpc/include $gmpinc"
1383 fi
1384 if test "x$with_mpc_include" != x; then
1385   gmpinc="-I$with_mpc_include $gmpinc"
1386 fi
1387 if test "x$with_mpc_lib" != x; then
1388   gmplibs="-L$with_mpc_lib $gmplibs"
1389 fi
1390 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1391   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1392   gmpinc='-I$$s/mpc/src '"$gmpinc"
1393   # Do not test the mpc version.  Assume that it is sufficient, since
1394   # it is in the source tree, and the library has not been built yet
1395   # but it would be included on the link line in the version check below
1396   # hence making the test fail.
1397   have_gmp=yes
1398 fi
1399
1400 # Specify a location for mpfr
1401 # check for this first so it ends up on the link line before gmp.
1402 AC_ARG_WITH(mpfr-dir,
1403 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1404 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1405 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1406
1407 AC_ARG_WITH(mpfr,
1408 [AS_HELP_STRING([--with-mpfr=PATH],
1409                 [specify prefix directory for installed MPFR package.
1410                  Equivalent to --with-mpfr-include=PATH/include
1411                  plus --with-mpfr-lib=PATH/lib])])
1412 AC_ARG_WITH(mpfr-include,
1413 [AS_HELP_STRING([--with-mpfr-include=PATH],
1414                 [specify directory for installed MPFR include files])])
1415 AC_ARG_WITH(mpfr-lib,
1416 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1417                 [specify directory for the installed MPFR library])])
1418
1419 if test "x$with_mpfr" != x; then
1420   gmplibs="-L$with_mpfr/lib $gmplibs"
1421   gmpinc="-I$with_mpfr/include $gmpinc"
1422 fi
1423 if test "x$with_mpfr_include" != x; then
1424   gmpinc="-I$with_mpfr_include $gmpinc"
1425 fi
1426 if test "x$with_mpfr_lib" != x; then
1427   gmplibs="-L$with_mpfr_lib $gmplibs"
1428 fi
1429 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1430   # MPFR v3.1.0 moved the sources into a src sub-directory.
1431   if ! test -d ${srcdir}/mpfr/src; then
1432     AC_MSG_ERROR([dnl
1433 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1434   fi
1435   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1436   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1437   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1438   # Do not test the mpfr version.  Assume that it is sufficient, since
1439   # it is in the source tree, and the library has not been built yet
1440   # but it would be included on the link line in the version check below
1441   # hence making the test fail.
1442   have_gmp=yes
1443 fi
1444
1445 # Specify a location for gmp
1446 AC_ARG_WITH(gmp-dir,
1447 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1448 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1449 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1450
1451 AC_ARG_WITH(gmp,
1452 [AS_HELP_STRING([--with-gmp=PATH],
1453                 [specify prefix directory for the installed GMP package.
1454                  Equivalent to --with-gmp-include=PATH/include
1455                  plus --with-gmp-lib=PATH/lib])])
1456 AC_ARG_WITH(gmp-include,
1457 [AS_HELP_STRING([--with-gmp-include=PATH],
1458                 [specify directory for installed GMP include files])])
1459 AC_ARG_WITH(gmp-lib,
1460 [AS_HELP_STRING([--with-gmp-lib=PATH],
1461                 [specify directory for the installed GMP library])])
1462
1463
1464 if test "x$with_gmp" != x; then
1465   gmplibs="-L$with_gmp/lib $gmplibs"
1466   gmpinc="-I$with_gmp/include $gmpinc"
1467 fi
1468 if test "x$with_gmp_include" != x; then
1469   gmpinc="-I$with_gmp_include $gmpinc"
1470 fi
1471 if test "x$with_gmp_lib" != x; then
1472   gmplibs="-L$with_gmp_lib $gmplibs"
1473 fi
1474 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1475   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1476   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1477   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1478   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1479   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1480   # Do not test the gmp version.  Assume that it is sufficient, since
1481   # it is in the source tree, and the library has not been built yet
1482   # but it would be included on the link line in the version check below
1483   # hence making the test fail.
1484   have_gmp=yes
1485 fi
1486
1487 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1488   have_gmp=yes
1489   saved_CFLAGS="$CFLAGS"
1490   CFLAGS="$CFLAGS $gmpinc"
1491   # Check for the recommended and required versions of GMP.
1492   AC_MSG_CHECKING([for the correct version of gmp.h])
1493   AC_TRY_COMPILE([#include "gmp.h"],[
1494   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1495   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1496   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1497   choke me
1498   #endif
1499   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1500   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1501   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1502   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1503   choke me
1504   #endif
1505   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1506    [AC_MSG_RESULT([no]); have_gmp=no])
1507
1508   # If we have GMP, check the MPFR version.
1509   if test x"$have_gmp" = xyes; then
1510     # Check for the recommended and required versions of MPFR.
1511     AC_MSG_CHECKING([for the correct version of mpfr.h])
1512     AC_TRY_COMPILE([#include <gmp.h>
1513     #include <mpfr.h>],[
1514     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1515     choke me
1516     #endif
1517     ], [AC_TRY_COMPILE([#include <gmp.h>
1518     #include <mpfr.h>],[
1519     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1520     choke me
1521     #endif
1522     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1523      [AC_MSG_RESULT([no]); have_gmp=no])
1524   fi
1525
1526   # Check for the MPC header version.
1527   if test x"$have_gmp" = xyes ; then
1528     # Check for the recommended and required versions of MPC.
1529     AC_MSG_CHECKING([for the correct version of mpc.h])
1530     AC_TRY_COMPILE([#include <mpc.h>],[
1531     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1532     choke me
1533     #endif
1534     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1535     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1536     choke me
1537     #endif
1538     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1539      [AC_MSG_RESULT([no]); have_gmp=no])
1540   fi
1541
1542   # Now check the MPFR library.
1543   if test x"$have_gmp" = xyes; then
1544     saved_LIBS="$LIBS"
1545     LIBS="$LIBS $gmplibs"
1546     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1547     AC_TRY_LINK([#include <mpc.h>],[
1548     mpfr_t n;
1549     mpfr_t x;
1550     mpc_t c;
1551     int t;
1552     mpfr_init (n);
1553     mpfr_init (x);
1554     mpfr_atan2 (n, n, x, GMP_RNDN);
1555     mpfr_erfc (n, x, GMP_RNDN);
1556     mpfr_subnormalize (x, t, GMP_RNDN);
1557     mpfr_clear(n);
1558     mpfr_clear(x);
1559     mpc_init2 (c, 53);
1560     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1561     mpc_cosh (c, c, MPC_RNDNN);
1562     mpc_pow (c, c, c, MPC_RNDNN);
1563     mpc_acosh (c, c, MPC_RNDNN);
1564     mpc_clear (c);
1565     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1566     LIBS="$saved_LIBS"
1567   fi
1568
1569   CFLAGS="$saved_CFLAGS"
1570
1571 # The library versions listed in the error message below should match
1572 # the HARD-minimums enforced above.
1573   if test x$have_gmp != xyes; then
1574     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1575 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1576 their locations.  Source code for these libraries can be found at
1577 their respective hosting sites as well as at
1578 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1579 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1580 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1581 make sure that you have installed both the libraries and the header
1582 files.  They may be located in separate packages.])
1583   fi
1584 fi
1585
1586 # Flags needed for both GMP, MPFR and/or MPC.
1587 AC_SUBST(gmplibs)
1588 AC_SUBST(gmpinc)
1589 AC_SUBST(extra_mpfr_configure_flags)
1590 AC_SUBST(extra_mpc_gmp_configure_flags)
1591 AC_SUBST(extra_mpc_mpfr_configure_flags)
1592 AC_SUBST(extra_isl_gmp_configure_flags)
1593
1594 # Libraries to use for stage1 or when not bootstrapping.
1595 AC_ARG_WITH(stage1-libs,
1596 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1597 [if test "$withval" = "no" -o "$withval" = "yes"; then
1598    stage1_libs=
1599  else
1600    stage1_libs=$withval
1601  fi],
1602 [stage1_libs=])
1603 AC_SUBST(stage1_libs)
1604
1605 # Linker flags to use for stage1 or when not bootstrapping.
1606 AC_ARG_WITH(stage1-ldflags,
1607 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1608 [if test "$withval" = "no" -o "$withval" = "yes"; then
1609    stage1_ldflags=
1610  else
1611    stage1_ldflags=$withval
1612  fi],
1613 [stage1_ldflags=
1614  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1615  # if supported.  But if the user explicitly specified the libraries to use,
1616  # trust that they are doing what they want.
1617  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1618    stage1_ldflags="-static-libstdc++ -static-libgcc"
1619  fi])
1620 AC_SUBST(stage1_ldflags)
1621
1622 # Libraries to use for stage2 and later builds.
1623 AC_ARG_WITH(boot-libs,
1624 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1625 [if test "$withval" = "no" -o "$withval" = "yes"; then
1626    poststage1_libs=
1627  else
1628    poststage1_libs=$withval
1629  fi],
1630 [poststage1_libs=])
1631 AC_SUBST(poststage1_libs)
1632
1633 # Linker flags to use for stage2 and later builds.
1634 AC_ARG_WITH(boot-ldflags,
1635 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1636                 [linker flags for stage2 and later])],
1637 [if test "$withval" = "no" -o "$withval" = "yes"; then
1638    poststage1_ldflags=
1639  else
1640    poststage1_ldflags=$withval
1641  fi],
1642 [poststage1_ldflags=
1643  # In stages 2 and 3, default to linking libstdc++ and libgcc
1644  # statically.  But if the user explicitly specified the libraries to
1645  # use, trust that they are doing what they want.
1646  if test "$poststage1_libs" = ""; then
1647    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1648  fi])
1649 AC_SUBST(poststage1_ldflags)
1650
1651 # GCC GRAPHITE dependency isl.
1652 # Basic setup is inlined here, actual checks are in config/isl.m4
1653
1654 AC_ARG_WITH(isl,
1655   [AS_HELP_STRING(
1656    [--with-isl=PATH],
1657    [Specify prefix directory for the installed isl package.
1658     Equivalent to --with-isl-include=PATH/include
1659     plus --with-isl-lib=PATH/lib])])
1660
1661 # Treat --without-isl as a request to disable
1662 # GRAPHITE support and skip all following checks.
1663 if test "x$with_isl" != "xno"; then
1664   # Check for isl
1665   dnl Provide configure switches and initialize islinc & isllibs
1666   dnl with user input.
1667   ISL_INIT_FLAGS
1668   dnl The versions of isl that work for Graphite
1669   ISL_CHECK_VERSION()
1670   dnl Only execute fail-action, if isl has been requested.
1671   ISL_IF_FAILED([
1672     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1673 fi
1674
1675 # If the isl check failed, disable builds of in-tree variant of isl
1676 if test "x$with_isl" = xno ||
1677    test "x$gcc_cv_isl" = xno; then
1678   noconfigdirs="$noconfigdirs isl"
1679   islinc=
1680 fi
1681
1682 AC_SUBST(isllibs)
1683 AC_SUBST(islinc)
1684
1685 # Check for LTO support.
1686 AC_ARG_ENABLE(lto,
1687 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1688 enable_lto=$enableval,
1689 enable_lto=yes; default_enable_lto=yes)
1690
1691 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1692   build_lto_plugin=yes
1693 ],[if test x"$default_enable_lto" = x"yes" ; then
1694     case $target in
1695       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1696       # On other non-ELF platforms, LTO has yet to be validated.
1697       *) enable_lto=no ;;
1698     esac
1699   else
1700   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1701   # It would also be nice to check the binutils support, but we don't
1702   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1703   # warn during gcc/ subconfigure; unless you're bootstrapping with
1704   # -flto it won't be needed until after installation anyway.
1705     case $target in
1706       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1707       *) if test x"$enable_lto" = x"yes"; then
1708         AC_MSG_ERROR([LTO support is not enabled for this target.])
1709         fi
1710       ;;
1711     esac
1712   fi
1713   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1714   # Build it unless LTO was explicitly disabled.
1715   case $target in
1716     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1717     *) ;;
1718   esac
1719 ])
1720
1721 AC_ARG_ENABLE(linker-plugin-configure-flags,
1722   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1723     [additional flags for configuring linker plugins @<:@none@:>@])],
1724   extra_linker_plugin_configure_flags=$enableval,
1725   extra_linker_plugin_configure_flags=)
1726 AC_SUBST(extra_linker_plugin_configure_flags)
1727 AC_ARG_ENABLE(linker-plugin-flags,
1728   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1729     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1730   extra_linker_plugin_flags=$enableval,
1731   extra_linker_plugin_flags=)
1732 AC_SUBST(extra_linker_plugin_flags)
1733
1734 # Enable --enable-host-shared.
1735 # Checked early to determine whether jit is an 'all' language
1736 AC_ARG_ENABLE(host-shared,
1737 [AS_HELP_STRING([--enable-host-shared],
1738                 [build host code as shared libraries])],
1739 [host_shared=$enableval], [host_shared=no])
1740 AC_SUBST(host_shared)
1741
1742 # By default, C and C++ are the only stage 1 languages.
1743 stage1_languages=,c,
1744
1745 # Target libraries that we bootstrap.
1746 bootstrap_target_libs=,target-libgcc,
1747
1748 # Figure out what language subdirectories are present.
1749 # Look if the user specified --enable-languages="..."; if not, use
1750 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1751 # go away some day.
1752 # NB:  embedded tabs in this IF block -- do not untabify
1753 if test -d ${srcdir}/gcc; then
1754   if test x"${enable_languages+set}" != xset; then
1755     if test x"${LANGUAGES+set}" = xset; then
1756       enable_languages="${LANGUAGES}"
1757         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1758     else
1759       enable_languages=default
1760     fi
1761   else
1762     if test x"${enable_languages}" = x ||
1763        test x"${enable_languages}" = xyes;
1764        then
1765       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1766       exit 1
1767     fi
1768   fi
1769   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1770
1771   # 'f95' is the old name for the 'fortran' language. We issue a warning
1772   # and make the substitution.
1773   case ,${enable_languages}, in
1774     *,f95,*)
1775       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1776       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1777       ;;
1778   esac
1779
1780   # If bootstrapping, C++ must be enabled.
1781   case ",$enable_languages,:$enable_bootstrap" in
1782     *,c++,*:*) ;;
1783     *:yes)
1784       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1785         enable_languages="${enable_languages},c++"
1786       else
1787         AC_MSG_ERROR([bootstrapping requires c++ sources])
1788       fi
1789       ;;
1790   esac
1791
1792   # First scan to see if an enabled language requires some other language.
1793   # We assume that a given config-lang.in will list all the language
1794   # front ends it requires, even if some are required indirectly.
1795   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1796     case ${lang_frag} in
1797       ..) ;;
1798       # The odd quoting in the next line works around
1799       # an apparent bug in bash 1.12 on linux.
1800       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1801       *)
1802         # From the config-lang.in, get $language, $lang_requires, and
1803         # $lang_requires_boot_languages.
1804         language=
1805         lang_requires=
1806         lang_requires_boot_languages=
1807         # set srcdir during sourcing lang_frag to the gcc dir.
1808         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1809         # polutes this shell
1810         saved_srcdir=${srcdir}
1811         srcdir=${srcdir}/gcc . ${lang_frag}
1812         srcdir=${saved_srcdir}
1813         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1814           case ,${enable_languages}, in
1815             *,$other,*) ;;
1816             *,default,*) ;;
1817             *,all,*) ;;
1818             *,$language,*)
1819               echo " \`$other' language required by \`$language'; enabling" 1>&2
1820               enable_languages="${enable_languages},${other}"
1821               ;;
1822           esac
1823         done
1824         for other in ${lang_requires_boot_languages} ; do
1825           if test "$other" != "c"; then
1826             case ,${enable_stage1_languages}, in
1827               *,$other,*) ;;
1828               *,default,*) ;;
1829               *,all,*) ;;
1830               *)
1831                 case ,${enable_languages}, in
1832                   *,$language,*)
1833                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1834                     enable_stage1_languages="$enable_stage1_languages,${other}"
1835                     ;;
1836                 esac
1837                 ;;
1838             esac
1839           fi
1840         done
1841         ;;
1842     esac
1843   done
1844
1845   new_enable_languages=,c,
1846
1847   # If LTO is enabled, add the LTO front end.
1848   if test "$enable_lto" = "yes" ; then
1849     case ,${enable_languages}, in
1850       *,lto,*) ;;
1851       *) enable_languages="${enable_languages},lto" ;;
1852     esac
1853     if test "${build_lto_plugin}" = "yes" ; then
1854       configdirs="$configdirs lto-plugin"
1855     fi
1856   fi
1857
1858   # If we're building an offloading compiler, add the LTO front end.
1859   if test x"$enable_as_accelerator_for" != x ; then
1860     case ,${enable_languages}, in
1861       *,lto,*) ;;
1862       *) enable_languages="${enable_languages},lto" ;;
1863     esac
1864   fi
1865
1866   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1867   potential_languages=,c,
1868
1869   enabled_target_libs=
1870   disabled_target_libs=
1871
1872   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1873     case ${lang_frag} in
1874       ..) ;;
1875       # The odd quoting in the next line works around
1876       # an apparent bug in bash 1.12 on linux.
1877       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1878       *)
1879         # From the config-lang.in, get $language, $target_libs,
1880         # $lang_dirs, $boot_language, and $build_by_default
1881         language=
1882         target_libs=
1883         lang_dirs=
1884         subdir_requires=
1885         boot_language=no
1886         build_by_default=yes
1887         # set srcdir during sourcing.  See above about save & restore
1888         saved_srcdir=${srcdir}
1889         srcdir=${srcdir}/gcc . ${lang_frag}
1890         srcdir=${saved_srcdir}
1891         if test x${language} = x; then
1892           echo "${lang_frag} doesn't set \$language." 1>&2
1893           exit 1
1894         fi
1895
1896         if test "$language" = "c++"; then
1897           boot_language=yes
1898         fi
1899
1900         add_this_lang=no
1901         # C is always enabled, so no need to add it again
1902         if test "$language" != "c"; then
1903           case ,${enable_languages}, in
1904             *,${language},*)
1905               # Language was explicitly selected; include it
1906               add_this_lang=yes
1907               ;;
1908             *,all,*)
1909               # All languages are enabled
1910               add_this_lang=all
1911               ;;
1912             *,default,*)
1913               # 'default' was selected, select it if it is a default language
1914               add_this_lang=${build_by_default}
1915               ;;
1916           esac
1917         fi
1918
1919         # Disable languages that need other directories if these aren't available.
1920         for i in $subdir_requires; do
1921           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1922           case ${add_this_lang} in
1923             yes)
1924               # Specifically requested language; tell them.
1925               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1926               ;;
1927             all)
1928               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1929               add_this_lang=unsupported
1930               ;;
1931             *)
1932               # Silently disable.
1933               add_this_lang=unsupported
1934               ;;
1935           esac
1936         done
1937
1938         # Disable Ada if no preexisting GNAT is available.
1939         case ${add_this_lang}:${language}:${have_gnat} in
1940           yes:ada:no)
1941             # Specifically requested language; tell them.
1942             AC_MSG_ERROR([GNAT is required to build $language])
1943             ;;
1944           all:ada:no)
1945             AC_MSG_WARN([GNAT is required to build $language])
1946             add_this_lang=unsupported
1947             ;;
1948           *:ada:no)
1949             # Silently disable.
1950             add_this_lang=unsupported
1951             ;;
1952         esac
1953
1954         # Disable jit if -enable-host-shared not specified
1955         case ${add_this_lang}:${language}:${host_shared} in
1956           yes:jit:no)
1957             # PR jit/64780: explicitly specify --enable-host-shared
1958             AC_MSG_ERROR([
1959 Enabling language "jit" requires --enable-host-shared.
1960
1961 --enable-host-shared typically slows the rest of the compiler down by
1962 a few %, so you must explicitly enable it.
1963
1964 If you want to build both the jit and the regular compiler, it is often
1965 best to do this via two separate configure/builds, in separate
1966 directories, to avoid imposing the performance cost of
1967 --enable-host-shared on the regular compiler.])
1968             ;;
1969           all:jit:no)
1970             AC_MSG_WARN([--enable-host-shared required to build $language])
1971             add_this_lang=unsupported
1972             ;;
1973           *:jit:no)
1974             # Silently disable.
1975             add_this_lang=unsupported
1976             ;;
1977         esac
1978
1979         # Disable a language that is unsupported by the target.
1980         case "${add_this_lang}: $unsupported_languages " in
1981           no:*) ;;
1982           unsupported:*) ;;
1983           *:*" $language "*)
1984             AC_MSG_WARN([${language} not supported for this target])
1985             add_this_lang=unsupported
1986             ;;
1987         esac
1988
1989         case $add_this_lang in
1990           unsupported)
1991             # Remove language-dependent dirs.
1992             disabled_target_libs="$disabled_target_libs $target_libs"
1993             noconfigdirs="$noconfigdirs $lang_dirs"
1994             ;;
1995           no)
1996             # Remove language-dependent dirs; still show language as supported.
1997             disabled_target_libs="$disabled_target_libs $target_libs"
1998             noconfigdirs="$noconfigdirs $lang_dirs"
1999             potential_languages="${potential_languages}${language},"
2000             ;;
2001           all|yes)
2002             new_enable_languages="${new_enable_languages}${language},"
2003             potential_languages="${potential_languages}${language},"
2004             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2005             enabled_target_libs="$enabled_target_libs $target_libs"
2006             case "${boot_language}:,$enable_stage1_languages," in
2007               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2008                 # Add to (comma-separated) list of stage 1 languages.
2009                 case ",$stage1_languages," in
2010                   *,$language,* | ,yes, | ,all,) ;;
2011                   *) stage1_languages="${stage1_languages}${language}," ;;
2012                 esac
2013                 # We need to bootstrap any supporting libraries.
2014                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2015                 ;;
2016             esac
2017             ;;
2018         esac
2019         ;;
2020     esac
2021   done
2022
2023   # Add target libraries which are only needed for disabled languages
2024   # to noconfigdirs.
2025   if test -n "$disabled_target_libs"; then
2026     for dir in $disabled_target_libs; do
2027       case " $enabled_target_libs " in
2028       *" ${dir} "*) ;;
2029       *) noconfigdirs="$noconfigdirs $dir" ;;
2030       esac
2031     done
2032   fi
2033
2034   AC_ARG_ENABLE(stage1-languages,
2035   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2036                   [choose additional languages to build during
2037                   stage1.  Mostly useful for compiler development])],
2038   [case ,${enable_stage1_languages}, in
2039     ,no,|,,)
2040       # Set it to something that will have no effect in the loop below
2041       enable_stage1_languages=c ;;
2042     ,yes,)
2043       enable_stage1_languages=`echo $new_enable_languages | \
2044         sed -e "s/^,//" -e "s/,$//" ` ;;
2045     *,all,*)
2046       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2047         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2048   esac
2049
2050   # Add "good" languages from enable_stage1_languages to stage1_languages,
2051   # while "bad" languages go in missing_languages.  Leave no duplicates.
2052   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2053     case $potential_languages in
2054       *,$i,*)
2055         case $stage1_languages in
2056           *,$i,*) ;;
2057           *) stage1_languages="$stage1_languages$i," ;;
2058         esac ;;
2059       *)
2060         case $missing_languages in
2061           *,$i,*) ;;
2062           *) missing_languages="$missing_languages$i," ;;
2063         esac ;;
2064      esac
2065   done])
2066
2067   # Remove leading/trailing commas that were added for simplicity
2068   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2069   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2070   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2071   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2072
2073   if test "x$missing_languages" != x; then
2074     AC_MSG_ERROR([
2075 The following requested languages could not be built: ${missing_languages}
2076 Supported languages are: ${potential_languages}])
2077   fi
2078   if test "x$new_enable_languages" != "x$enable_languages"; then
2079     echo The following languages will be built: ${new_enable_languages}
2080     enable_languages="$new_enable_languages"
2081   fi
2082
2083   AC_SUBST(stage1_languages)
2084   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2085 fi
2086
2087 # Handle --disable-<component> generically.
2088 for dir in $configdirs $build_configdirs $target_configdirs ; do
2089   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2090   varname=`echo $dirname | sed -e s/+/_/g`
2091   if eval test x\${enable_${varname}} "=" xno ; then
2092     noconfigdirs="$noconfigdirs $dir"
2093   fi
2094 done
2095
2096 # Check for Boehm's garbage collector
2097 AC_ARG_ENABLE(objc-gc,
2098 [AS_HELP_STRING([--enable-objc-gc],
2099                 [enable use of Boehm's garbage collector with the
2100                  GNU Objective-C runtime])])
2101 AC_ARG_WITH([target-bdw-gc],
2102 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2103                 [specify prefix directory for installed bdw-gc package.
2104                  Equivalent to --with-target-bdw-gc-include=PATH/include
2105                  plus --with-target-bdw-gc-lib=PATH/lib])])
2106 AC_ARG_WITH([target-bdw-gc-include],
2107 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2108                 [specify directories for installed bdw-gc include files])])
2109 AC_ARG_WITH([target-bdw-gc-lib],
2110 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2111                 [specify directories for installed bdw-gc library])])
2112
2113 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2114   AC_MSG_CHECKING([for bdw garbage collector])
2115   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2116     dnl no bdw-gw options, assume default locations
2117     AC_MSG_RESULT([using bdw-gc in default locations])
2118   else
2119     dnl bdw-gw options, first error checking, complete checking in libobjc
2120     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2121       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2122     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2123       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2124     else
2125       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2126     fi
2127   fi
2128 esac
2129
2130 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2131 case ,${enable_languages}, in
2132   *,c++,*)
2133     # Disable libitm, libsanitizer if we're not building libstdc++
2134     case "${noconfigdirs}" in
2135       *target-libstdc++-v3*)
2136         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2137         ;;
2138       *) ;;
2139     esac
2140     ;;
2141   *)
2142     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2143     ;;
2144 esac
2145
2146 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2147 # $build_configdirs and $target_configdirs.
2148 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2149
2150 notsupp=""
2151 for dir in . $skipdirs $noconfigdirs ; do
2152   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2153   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2154     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2155     if test -r $srcdir/$dirname/configure ; then
2156       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2157         true
2158       else
2159         notsupp="$notsupp $dir"
2160       fi
2161     fi
2162   fi
2163   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2164     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2165     if test -r $srcdir/$dirname/configure ; then
2166       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2167         true
2168       else
2169         notsupp="$notsupp $dir"
2170       fi
2171     fi
2172   fi
2173   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2174     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2175     if test -r $srcdir/$dirname/configure ; then
2176       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2177         true
2178       else
2179         notsupp="$notsupp $dir"
2180       fi
2181     fi
2182   fi
2183 done
2184
2185 # Quietly strip out all directories which aren't configurable in this tree.
2186 # This relies on all configurable subdirectories being autoconfiscated, which
2187 # is now the case.
2188 build_configdirs_all="$build_configdirs"
2189 build_configdirs=
2190 for i in ${build_configdirs_all} ; do
2191   j=`echo $i | sed -e s/build-//g`
2192   if test -f ${srcdir}/$j/configure ; then
2193     build_configdirs="${build_configdirs} $i"
2194   fi
2195 done
2196
2197 configdirs_all="$configdirs"
2198 configdirs=
2199 for i in ${configdirs_all} ; do
2200   if test -f ${srcdir}/$i/configure ; then
2201     configdirs="${configdirs} $i"
2202   fi
2203 done
2204
2205 target_configdirs_all="$target_configdirs"
2206 target_configdirs=
2207 for i in ${target_configdirs_all} ; do
2208   j=`echo $i | sed -e s/target-//g`
2209   if test -f ${srcdir}/$j/configure ; then
2210     target_configdirs="${target_configdirs} $i"
2211   fi
2212 done
2213
2214 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2215 # so we have to add it after the preceding checks.
2216 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2217 then
2218   case " $configdirs " in
2219     *" libiberty "*)
2220       # If we can build libiberty, we can also build libiberty-linker-plugin.
2221       configdirs="$configdirs libiberty-linker-plugin"
2222       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2223         --with-libiberty=../libiberty-linker-plugin";;
2224     *)
2225       AC_MSG_ERROR([libiberty missing]);;
2226   esac
2227 fi
2228
2229 # Sometimes we have special requirements for the host libiberty.
2230 extra_host_libiberty_configure_flags=
2231 extra_host_zlib_configure_flags=
2232 case " $configdirs " in
2233   *" lto-plugin "* | *" libcc1 "*)
2234     # When these are to be built as shared libraries, the same applies to
2235     # libiberty.
2236     extra_host_libiberty_configure_flags=--enable-shared
2237     ;;
2238   *" bfd "*)
2239     # When bfd is to be built as a shared library, the same applies to
2240     # zlib.
2241     if test "$enable_shared" = "yes"; then
2242       extra_host_zlib_configure_flags=--enable-host-shared
2243     fi
2244     ;;
2245 esac
2246 AC_SUBST(extra_host_libiberty_configure_flags)
2247 AC_SUBST(extra_host_zlib_configure_flags)
2248
2249 # Produce a warning message for the subdirs we can't configure.
2250 # This isn't especially interesting in the Cygnus tree, but in the individual
2251 # FSF releases, it's important to let people know when their machine isn't
2252 # supported by the one or two programs in a package.
2253
2254 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2255   # If $appdirs is non-empty, at least one of those directories must still
2256   # be configured, or we error out.  (E.g., if the gas release supports a
2257   # specified target in some subdirs but not the gas subdir, we shouldn't
2258   # pretend that all is well.)
2259   if test -n "$appdirs" ; then
2260     for dir in $appdirs ; do
2261       if test -r $dir/Makefile.in ; then
2262         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2263           appdirs=""
2264           break
2265         fi
2266         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2267           appdirs=""
2268           break
2269         fi
2270       fi
2271     done
2272     if test -n "$appdirs" ; then
2273       echo "*** This configuration is not supported by this package." 1>&2
2274       exit 1
2275     fi
2276   fi
2277   # Okay, some application will build, or we don't care to check.  Still
2278   # notify of subdirs not getting built.
2279   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2280   echo "    ${notsupp}" 1>&2
2281   echo "    (Any other directories should still work fine.)" 1>&2
2282 fi
2283
2284 case "$host" in
2285   *msdosdjgpp*)
2286     enable_gdbtk=no ;;
2287 esac
2288
2289 # To find our prefix, in gcc_cv_tool_prefix.
2290 ACX_TOOL_DIRS
2291
2292 copy_dirs=
2293
2294 AC_ARG_WITH([build-sysroot],
2295   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2296                   [use sysroot as the system root during the build])],
2297   [if test x"$withval" != x ; then
2298      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2299    fi],
2300   [SYSROOT_CFLAGS_FOR_TARGET=])
2301 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2302
2303 AC_ARG_WITH([debug-prefix-map],
2304   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2305                   [map A to B, C to D ... in debug information])],
2306   [if test x"$withval" != x; then
2307      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2308      for debug_map in $withval; do
2309        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2310      done
2311    fi],
2312   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2313 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2314
2315 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2316 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2317 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2318 # We want to ensure that TARGET libraries (which we know are built with
2319 # gcc) are built with "-O2 -g", so include those options when setting
2320 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2321 if test "x$CFLAGS_FOR_TARGET" = x; then
2322   if test "x${is_cross_compiler}" = xyes; then
2323     CFLAGS_FOR_TARGET="-g -O2"
2324   else
2325     CFLAGS_FOR_TARGET=$CFLAGS
2326     case " $CFLAGS " in
2327       *" -O2 "*) ;;
2328       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2329     esac
2330     case " $CFLAGS " in
2331       *" -g "* | *" -g3 "*) ;;
2332       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2333     esac
2334   fi
2335 fi
2336 AC_SUBST(CFLAGS_FOR_TARGET)
2337
2338 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2339   if test "x${is_cross_compiler}" = xyes; then
2340     CXXFLAGS_FOR_TARGET="-g -O2"
2341   else
2342     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2343     case " $CXXFLAGS " in
2344       *" -O2 "*) ;;
2345       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2346     esac
2347     case " $CXXFLAGS " in
2348       *" -g "* | *" -g3 "*) ;;
2349       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2350     esac
2351   fi
2352 fi
2353 AC_SUBST(CXXFLAGS_FOR_TARGET)
2354
2355 AC_SUBST(LDFLAGS_FOR_TARGET)
2356
2357 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2358 # the named directory are copied to $(tooldir)/sys-include.
2359 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2360   if test x${is_cross_compiler} = xno ; then
2361     echo 1>&2 '***' --with-headers is only supported when cross compiling
2362     exit 1
2363   fi
2364   if test x"${with_headers}" != xyes ; then
2365     x=${gcc_cv_tool_prefix}
2366     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2367   fi
2368 fi
2369
2370 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2371 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2372 # are permitted.
2373 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2374   if test x${is_cross_compiler} = xno ; then
2375     echo 1>&2 '***' --with-libs is only supported when cross compiling
2376     exit 1
2377   fi
2378   if test x"${with_libs}" != xyes ; then
2379     # Copy the libraries in reverse order, so that files in the first named
2380     # library override files in subsequent libraries.
2381     x=${gcc_cv_tool_prefix}
2382     for l in ${with_libs}; do
2383       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2384     done
2385   fi
2386 fi
2387
2388 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2389 #
2390 # This is done by determining whether or not the appropriate directory
2391 # is available, and by checking whether or not specific configurations
2392 # have requested that this magic not happen.
2393 #
2394 # The command line options always override the explicit settings in
2395 # configure.ac, and the settings in configure.ac override this magic.
2396 #
2397 # If the default for a toolchain is to use GNU as and ld, and you don't
2398 # want to do that, then you should use the --without-gnu-as and
2399 # --without-gnu-ld options for the configure script.  Similarly, if
2400 # the default is to use the included zlib and you don't want to do that,
2401 # you should use the --with-system-zlib option for the configure script.
2402
2403 if test x${use_gnu_as} = x &&
2404    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2405   with_gnu_as=yes
2406   extra_host_args="$extra_host_args --with-gnu-as"
2407 fi
2408
2409 if test x${use_gnu_ld} = x &&
2410    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2411   with_gnu_ld=yes
2412   extra_host_args="$extra_host_args --with-gnu-ld"
2413 fi
2414
2415 if test x${use_included_zlib} = x &&
2416    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2417   :
2418 else
2419   with_system_zlib=yes
2420   extra_host_args="$extra_host_args --with-system-zlib"
2421 fi
2422
2423 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2424 # can detect this case.
2425
2426 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2427   with_newlib=yes
2428   extra_host_args="$extra_host_args --with-newlib"
2429 fi
2430
2431 # Handle ${copy_dirs}
2432 set fnord ${copy_dirs}
2433 shift
2434 while test $# != 0 ; do
2435   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2436     :
2437   else
2438     echo Copying $1 to $2
2439
2440     # Use the install script to create the directory and all required
2441     # parent directories.
2442     if test -d $2 ; then
2443       :
2444     else
2445       echo >config.temp
2446       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2447     fi
2448
2449     # Copy the directory, assuming we have tar.
2450     # FIXME: Should we use B in the second tar?  Not all systems support it.
2451     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2452
2453     # It is the responsibility of the user to correctly adjust all
2454     # symlinks.  If somebody can figure out how to handle them correctly
2455     # here, feel free to add the code.
2456
2457     echo $1 > $2/COPIED
2458   fi
2459   shift; shift
2460 done
2461
2462 # Determine a target-dependent exec_prefix that the installed
2463 # gcc will search in.  Keep this list sorted by triplet, with
2464 # the *-*-osname triplets last.
2465 md_exec_prefix=
2466 case "${target}" in
2467   i[[34567]]86-pc-msdosdjgpp*)
2468     md_exec_prefix=/dev/env/DJDIR/bin
2469     ;;
2470   *-*-hpux* | \
2471   *-*-nto-qnx* | \
2472   *-*-solaris2*)
2473     md_exec_prefix=/usr/ccs/bin
2474     ;;
2475 esac
2476
2477 extra_arflags_for_target=
2478 extra_nmflags_for_target=
2479 extra_ranlibflags_for_target=
2480 target_makefile_frag=/dev/null
2481 case "${target}" in
2482   spu-*-*)
2483     target_makefile_frag="config/mt-spu"
2484     ;;
2485   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2486     target_makefile_frag="config/mt-sde"
2487     ;;
2488   mipsisa*-*-elfoabi*)
2489     target_makefile_frag="config/mt-mips-elfoabi"
2490     ;;
2491   mips*-*-*linux* | mips*-*-gnu*)
2492     target_makefile_frag="config/mt-mips-gnu"
2493     ;;
2494   nios2-*-elf*)
2495     target_makefile_frag="config/mt-nios2-elf"
2496     ;;
2497   *-*-linux-android*)
2498     target_makefile_frag="config/mt-android"
2499     ;;
2500   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2501     target_makefile_frag="config/mt-gnu"
2502     ;;
2503   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2504     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2505     # commands to handle both 32-bit and 64-bit objects.  These flags are
2506     # harmless if we're using GNU nm or ar.
2507     extra_arflags_for_target=" -X32_64"
2508     extra_nmflags_for_target=" -B -X32_64"
2509     ;;
2510 esac
2511
2512 alphaieee_frag=/dev/null
2513 case $target in
2514   alpha*-*-*)
2515     # This just makes sure to use the -mieee option to build target libs.
2516     # This should probably be set individually by each library.
2517     alphaieee_frag="config/mt-alphaieee"
2518     ;;
2519 esac
2520
2521 # If --enable-target-optspace always use -Os instead of -O2 to build
2522 # the target libraries, similarly if it is not specified, use -Os
2523 # on selected platforms.
2524 ospace_frag=/dev/null
2525 case "${enable_target_optspace}:${target}" in
2526   yes:*)
2527     ospace_frag="config/mt-ospace"
2528     ;;
2529   :d30v-*)
2530     ospace_frag="config/mt-d30v"
2531     ;;
2532   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2533     ospace_frag="config/mt-ospace"
2534     ;;
2535   no:* | :*)
2536     ;;
2537   *)
2538     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2539     ;;
2540 esac
2541
2542 # Some systems (e.g., one of the i386-aix systems the gas testers are
2543 # using) don't handle "\$" correctly, so don't use it here.
2544 tooldir='${exec_prefix}'/${target_noncanonical}
2545 build_tooldir=${tooldir}
2546
2547 # Create a .gdbinit file which runs the one in srcdir
2548 # and tells GDB to look there for source files.
2549
2550 if test -r ${srcdir}/.gdbinit ; then
2551   case ${srcdir} in
2552     .) ;;
2553     *) cat > ./.gdbinit <<EOF
2554 # ${NO_EDIT}
2555 dir ${srcdir}
2556 dir .
2557 source ${srcdir}/.gdbinit
2558 EOF
2559     ;;
2560   esac
2561 fi
2562
2563 # Make sure that the compiler is able to generate an executable.  If it
2564 # can't, we are probably in trouble.  We don't care whether we can run the
2565 # executable--we might be using a cross compiler--we only care whether it
2566 # can be created.  At this point the main configure script has set CC.
2567 we_are_ok=no
2568 echo "int main () { return 0; }" > conftest.c
2569 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2570 if test $? = 0 ; then
2571   if test -s conftest || test -s conftest.exe ; then
2572     we_are_ok=yes
2573   fi
2574 fi
2575 case $we_are_ok in
2576   no)
2577     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2578     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2579     rm -f conftest*
2580     exit 1
2581     ;;
2582 esac
2583 rm -f conftest*
2584
2585 # Decide which environment variable is used to find dynamic libraries.
2586 case "${host}" in
2587   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2588   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2589   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2590   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2591 esac
2592
2593 # On systems where the dynamic library environment variable is PATH,
2594 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2595 # built executables to PATH.
2596 if test "$RPATH_ENVVAR" = PATH; then
2597   GCC_SHLIB_SUBDIR=/shlib
2598 else
2599   GCC_SHLIB_SUBDIR=
2600 fi
2601
2602 # Adjust the toplevel makefile according to whether bootstrap was selected.
2603 case $enable_bootstrap in
2604   yes)
2605     bootstrap_suffix=bootstrap
2606     BUILD_CONFIG=bootstrap-debug
2607     ;;
2608   no)
2609     bootstrap_suffix=no-bootstrap
2610     BUILD_CONFIG=
2611     ;;
2612 esac
2613
2614 AC_MSG_CHECKING(for default BUILD_CONFIG)
2615
2616 AC_ARG_WITH([build-config],
2617   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2618                   [use config/NAME.mk build configuration])],
2619   [case $with_build_config in
2620    yes) with_build_config= ;;
2621    no) with_build_config= BUILD_CONFIG= ;;
2622    esac])
2623
2624 if test "x${with_build_config}" != x; then
2625   BUILD_CONFIG=$with_build_config
2626 else
2627   case $BUILD_CONFIG in
2628   bootstrap-debug)
2629     if echo "int f (void) { return 0; }" > conftest.c &&
2630        ${CC} -c conftest.c &&
2631        mv conftest.o conftest.o.g0 &&
2632        ${CC} -c -g conftest.c &&
2633        mv conftest.o conftest.o.g &&
2634        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2635       :
2636     else
2637       BUILD_CONFIG=
2638     fi
2639     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2640     ;;
2641   esac
2642 fi
2643 AC_MSG_RESULT($BUILD_CONFIG)
2644 AC_SUBST(BUILD_CONFIG)
2645
2646 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2647 AC_MSG_CHECKING([for --enable-vtable-verify])
2648 AC_ARG_ENABLE(vtable-verify,
2649 [AS_HELP_STRING([--enable-vtable-verify],
2650                 [Enable vtable verification feature])],
2651 [case "$enableval" in
2652  yes) enable_vtable_verify=yes ;;
2653  no)  enable_vtable_verify=no ;;
2654  *)   enable_vtable_verify=no;;
2655  esac],
2656 [enable_vtable_verify=no])
2657 AC_MSG_RESULT($enable_vtable_verify)
2658
2659 # Record target_configdirs and the configure arguments for target and
2660 # build configuration in Makefile.
2661 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2662 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2663 bootstrap_fixincludes=no
2664
2665 # If we are building libgomp, bootstrap it.
2666 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2667   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2668 fi
2669
2670 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2671 # or bootstrap-ubsan, bootstrap it.
2672 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2673   case "$BUILD_CONFIG" in
2674     *bootstrap-asan* | *bootstrap-ubsan* )
2675       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2676       bootstrap_fixincludes=yes
2677       ;;
2678   esac
2679 fi
2680
2681 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2682 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2683    test "$enable_vtable_verify" != no; then
2684   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2685 fi
2686
2687 # Determine whether gdb needs tk/tcl or not.
2688 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2689 # and in that case we want gdb to be built without tk.  Ugh!
2690 # In fact I believe gdb is the *only* package directly dependent on tk,
2691 # so we should be able to put the 'maybe's in unconditionally and
2692 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2693 # 100% sure that that's safe though.
2694
2695 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2696 case "$enable_gdbtk" in
2697   no)
2698     GDB_TK="" ;;
2699   yes)
2700     GDB_TK="${gdb_tk}" ;;
2701   *)
2702     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2703     # distro.  Eventually someone will fix this and move Insight, nee
2704     # gdbtk to a separate directory.
2705     if test -d ${srcdir}/gdb/gdbtk ; then
2706       GDB_TK="${gdb_tk}"
2707     else
2708       GDB_TK=""
2709     fi
2710     ;;
2711 esac
2712 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2713 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2714
2715 # gdb depends on gnulib, but as nothing else does, only include it if
2716 # gdb is built.
2717 if echo " ${configdirs} " | grep " gdb " > /dev/null 2>&1 ; then
2718   # The Makefile provides the ordering, so it's enough here to add
2719   # gnulib to the list.
2720   configdirs="${configdirs} gnulib"
2721 fi
2722
2723 # Strip out unwanted targets.
2724
2725 # While at that, we remove Makefiles if we were started for recursive
2726 # configuration, so that the top-level Makefile reconfigures them,
2727 # like we used to do when configure itself was recursive.
2728
2729 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2730 # but now we're fixing up the Makefile ourselves with the additional
2731 # commands passed to AC_CONFIG_FILES.  Use separate variables
2732 # extrasub-{build,host,target} not because there is any reason to split
2733 # the substitutions up that way, but only to remain below the limit of
2734 # 99 commands in a script, for HP-UX sed.
2735
2736 # Do not nest @if/@endif or @unless/@endunless pairs, because
2737 # configure will not warn you at all.
2738
2739 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2740   yes:yes:*\ gold\ *:*,c++,*) ;;
2741   yes:yes:*\ gold\ *:*)
2742     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2743     ;;
2744 esac
2745
2746 extrasub_build=
2747 for module in ${build_configdirs} ; do
2748   if test -z "${no_recursion}" \
2749      && test -f ${build_subdir}/${module}/Makefile; then
2750     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2751     rm -f ${build_subdir}/${module}/Makefile
2752   fi
2753   extrasub_build="$extrasub_build
2754 /^@if build-$module\$/d
2755 /^@endif build-$module\$/d
2756 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2757 /^@if build-$module-$bootstrap_suffix\$/d
2758 /^@endif build-$module-$bootstrap_suffix\$/d
2759 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2760 done
2761 extrasub_host=
2762 for module in ${configdirs} ; do
2763   if test -z "${no_recursion}"; then
2764     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2765       if test -f ${file}; then
2766         echo 1>&2 "*** removing ${file} to force reconfigure"
2767         rm -f ${file}
2768       fi
2769     done
2770   fi
2771   case ${module},${bootstrap_fixincludes} in
2772     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2773     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2774   esac
2775   extrasub_host="$extrasub_host
2776 /^@if $module\$/d
2777 /^@endif $module\$/d
2778 /^@unless $module\$/,/^@endunless $module\$/d
2779 /^@if $module-$host_bootstrap_suffix\$/d
2780 /^@endif $module-$host_bootstrap_suffix\$/d
2781 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2782 done
2783 extrasub_target=
2784 for module in ${target_configdirs} ; do
2785   if test -z "${no_recursion}" \
2786      && test -f ${target_subdir}/${module}/Makefile; then
2787     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2788     rm -f ${target_subdir}/${module}/Makefile
2789   fi
2790
2791   # We only bootstrap target libraries listed in bootstrap_target_libs.
2792   case $bootstrap_target_libs in
2793     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2794     *) target_bootstrap_suffix=no-bootstrap ;;
2795   esac
2796
2797   extrasub_target="$extrasub_target
2798 /^@if target-$module\$/d
2799 /^@endif target-$module\$/d
2800 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2801 /^@if target-$module-$target_bootstrap_suffix\$/d
2802 /^@endif target-$module-$target_bootstrap_suffix\$/d
2803 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2804 done
2805
2806 # Do the final fixup along with target modules.
2807 extrasub_target="$extrasub_target
2808 /^@if /,/^@endif /d
2809 /^@unless /d
2810 /^@endunless /d"
2811
2812 # Create the serialization dependencies.  This uses a temporary file.
2813
2814 AC_ARG_ENABLE([serial-configure],
2815 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2816                 [force sequential configuration of
2817                  sub-packages for the host, target or build
2818                  machine, or all sub-packages])])
2819
2820 case ${enable_serial_configure} in
2821   yes)
2822     enable_serial_build_configure=yes
2823     enable_serial_host_configure=yes
2824     enable_serial_target_configure=yes
2825     ;;
2826 esac
2827
2828 # These force 'configure's to be done one at a time, to avoid problems
2829 # with contention over a shared config.cache.
2830 rm -f serdep.tmp
2831 echo '# serdep.tmp' > serdep.tmp
2832 olditem=
2833 test "x${enable_serial_build_configure}" = xyes &&
2834 for item in ${build_configdirs} ; do
2835   case ${olditem} in
2836     "") ;;
2837     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2838   esac
2839   olditem=${item}
2840 done
2841 olditem=
2842 test "x${enable_serial_host_configure}" = xyes &&
2843 for item in ${configdirs} ; do
2844   case ${olditem} in
2845     "") ;;
2846     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2847   esac
2848   olditem=${item}
2849 done
2850 olditem=
2851 test "x${enable_serial_target_configure}" = xyes &&
2852 for item in ${target_configdirs} ; do
2853   case ${olditem} in
2854     "") ;;
2855     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2856   esac
2857   olditem=${item}
2858 done
2859 serialization_dependencies=serdep.tmp
2860 AC_SUBST_FILE(serialization_dependencies)
2861
2862 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2863 # target, nonopt, and variable assignments.  These are the ones we
2864 # might not want to pass down to subconfigures.  The exception being
2865 # --cache-file=/dev/null, which is used to turn off the use of cache
2866 # files altogether, and which should be passed on to subconfigures.
2867 # Also strip program-prefix, program-suffix, and program-transform-name,
2868 # so that we can pass down a consistent program-transform-name.
2869 baseargs=
2870 tbaseargs=
2871 keep_next=no
2872 skip_next=no
2873 eval "set -- $ac_configure_args"
2874 for ac_arg
2875 do
2876   if test X"$skip_next" = X"yes"; then
2877     skip_next=no
2878     continue
2879   fi
2880   if test X"$keep_next" = X"yes"; then
2881     case $ac_arg in
2882       *\'*)
2883         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2884     esac
2885     baseargs="$baseargs '$ac_arg'"
2886     tbaseargs="$tbaseargs '$ac_arg'"
2887     keep_next=no
2888     continue
2889   fi
2890
2891   # Handle separated arguments.  Based on the logic generated by
2892   # autoconf 2.59.
2893   case $ac_arg in
2894     *=* | --config-cache | -C | -disable-* | --disable-* \
2895       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2896       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2897       | -with-* | --with-* | -without-* | --without-* | --x)
2898       separate_arg=no
2899       ;;
2900     -*)
2901       separate_arg=yes
2902       ;;
2903     *)
2904       separate_arg=no
2905       ;;
2906   esac
2907
2908   skip_targ=no
2909   case $ac_arg in
2910 changequote(,)
2911   --with-* | --without-*)
2912     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2913
2914     case $libopt in
2915     *[-_]include)
2916       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2917       ;;
2918     *[-_]lib)
2919       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2920       ;;
2921     *)
2922       lib=$libopt
2923       ;;
2924     esac
2925 changequote([,])
2926
2927     case $lib in
2928     mpc | mpfr | gmp | isl)
2929       # If we're processing --with-$lib, --with-$lib-include or
2930       # --with-$lib-lib, for one of the libs above, and target is
2931       # different from host, don't pass the current argument to any
2932       # target library's configure.
2933       if test x$is_cross_compiler = xyes; then
2934         skip_targ=yes
2935       fi
2936       ;;
2937     esac
2938     ;;
2939   esac
2940
2941   case "$ac_arg" in
2942     --cache-file=/dev/null | \
2943     -cache-file=/dev/null )
2944       # Handled here to avoid the test to skip args below.
2945       baseargs="$baseargs '$ac_arg'"
2946       tbaseargs="$tbaseargs '$ac_arg'"
2947       # Assert: $separate_arg should always be no.
2948       keep_next=$separate_arg
2949       ;;
2950     --no*)
2951       continue
2952       ;;
2953     --c* | \
2954     --sr* | \
2955     --ho* | \
2956     --bu* | \
2957     --t* | \
2958     --program-* | \
2959     -cache_file* | \
2960     -srcdir* | \
2961     -host* | \
2962     -build* | \
2963     -target* | \
2964     -program-prefix* | \
2965     -program-suffix* | \
2966     -program-transform-name* )
2967       skip_next=$separate_arg
2968       continue
2969       ;;
2970     -*)
2971       # An option.  Add it.
2972       case $ac_arg in
2973         *\'*)
2974           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2975       esac
2976       baseargs="$baseargs '$ac_arg'"
2977       if test X"$skip_targ" = Xno; then
2978         tbaseargs="$tbaseargs '$ac_arg'"
2979       fi
2980       keep_next=$separate_arg
2981       ;;
2982     *)
2983       # Either a variable assignment, or a nonopt (triplet).  Don't
2984       # pass it down; let the Makefile handle this.
2985       continue
2986       ;;
2987   esac
2988 done
2989 # Remove the initial space we just introduced and, as these will be
2990 # expanded by make, quote '$'.
2991 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2992
2993 # Add in --program-transform-name, after --program-prefix and
2994 # --program-suffix have been applied to it.  Autoconf has already
2995 # doubled dollar signs and backslashes in program_transform_name; we want
2996 # the backslashes un-doubled, and then the entire thing wrapped in single
2997 # quotes, because this will be expanded first by make and then by the shell.
2998 # Also, because we want to override the logic in subdir configure scripts to
2999 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3000 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3001 ${program_transform_name}
3002 EOF_SED
3003 gcc_transform_name=`cat conftestsed.out`
3004 rm -f conftestsed.out
3005 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3006 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3007 if test "$silent" = yes; then
3008   baseargs="$baseargs --silent"
3009   tbaseargs="$tbaseargs --silent"
3010 fi
3011 baseargs="$baseargs --disable-option-checking"
3012 tbaseargs="$tbaseargs --disable-option-checking"
3013
3014 # Record and document user additions to sub configure arguments.
3015 AC_ARG_VAR([build_configargs],
3016            [additional configure arguments for build directories])
3017 AC_ARG_VAR([host_configargs],
3018            [additional configure arguments for host directories])
3019 AC_ARG_VAR([target_configargs],
3020            [additional configure arguments for target directories])
3021
3022 # For the build-side libraries, we just need to pretend we're native,
3023 # and not use the same cache file.  Multilibs are neither needed nor
3024 # desired.  We can't even use the same cache file for all build-side
3025 # libraries, as they're compiled differently; some with C, some with
3026 # C++ or with different feature-enabling options.
3027 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3028
3029 # For host modules, accept cache file option, or specification as blank.
3030 case "${cache_file}" in
3031 "") # empty
3032   cache_file_option="" ;;
3033 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3034   cache_file_option="--cache-file=${cache_file}" ;;
3035 *) # relative path
3036   cache_file_option="--cache-file=../${cache_file}" ;;
3037 esac
3038
3039 # Host dirs don't like to share a cache file either, horribly enough.
3040 # This seems to be due to autoconf 2.5x stupidity.
3041 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3042
3043 target_configargs="$target_configargs ${tbaseargs}"
3044
3045 # Passing a --with-cross-host argument lets the target libraries know
3046 # whether they are being built with a cross-compiler or being built
3047 # native.  However, it would be better to use other mechanisms to make the
3048 # sorts of decisions they want to make on this basis.  Please consider
3049 # this option to be deprecated.  FIXME.
3050 if test x${is_cross_compiler} = xyes ; then
3051   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3052 fi
3053
3054 # Special user-friendly check for native x86_64-linux build, if
3055 # multilib is not explicitly enabled.
3056 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3057   x86_64-*linux*:yes:$build:$build:)
3058     # Make sure we have a development environment that handles 32-bit
3059     dev64=no
3060     echo "int main () { return 0; }" > conftest.c
3061     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3062     if test $? = 0 ; then
3063       if test -s conftest || test -s conftest.exe ; then
3064         dev64=yes
3065       fi
3066     fi
3067     rm -f conftest*
3068     if test x${dev64} != xyes ; then
3069       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3070     fi
3071     ;;
3072 esac
3073
3074 # Default to --enable-multilib.
3075 if test x${enable_multilib} = x ; then
3076   target_configargs="--enable-multilib ${target_configargs}"
3077 fi
3078
3079 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3080 # changed from the earlier setting of with_newlib.
3081 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3082   target_configargs="--with-newlib ${target_configargs}"
3083 fi
3084
3085 # Different target subdirs use different values of certain variables
3086 # (notably CXX).  Worse, multilibs use *lots* of different values.
3087 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3088 # it doesn't automatically accept command-line overrides of them.
3089 # This means it's not safe for target subdirs to share a cache file,
3090 # which is disgusting, but there you have it.  Hopefully this can be
3091 # fixed in future.  It's still worthwhile to use a cache file for each
3092 # directory.  I think.
3093
3094 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3095 # We need to pass --target, as newer autoconf's requires consistency
3096 # for target_alias and gcc doesn't manage it consistently.
3097 target_configargs="--cache-file=./config.cache ${target_configargs}"
3098
3099 FLAGS_FOR_TARGET=
3100 case " $target_configdirs " in
3101  *" newlib "*)
3102   case " $target_configargs " in
3103   *" --with-newlib "*)
3104    case "$target" in
3105     *-cygwin*)
3106       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3107       ;;
3108    esac
3109
3110    # If we're not building GCC, don't discard standard headers.
3111    if test -d ${srcdir}/gcc; then
3112      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3113
3114      if test "${build}" != "${host}"; then
3115        # On Canadian crosses, CC_FOR_TARGET will have already been set
3116        # by `configure', so we won't have an opportunity to add -Bgcc/
3117        # to it.  This is right: we don't want to search that directory
3118        # for binaries, but we want the header files in there, so add
3119        # them explicitly.
3120        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3121
3122        # Someone might think of using the pre-installed headers on
3123        # Canadian crosses, in case the installed compiler is not fully
3124        # compatible with the compiler being built.  In this case, it
3125        # would be better to flag an error than risking having
3126        # incompatible object files being constructed.  We can't
3127        # guarantee that an error will be flagged, but let's hope the
3128        # compiler will do it, when presented with incompatible header
3129        # files.
3130      fi
3131    fi
3132
3133    case "${target}-${is_cross_compiler}" in
3134    i[[3456789]]86-*-linux*-no)
3135       # Here host == target, so we don't need to build gcc,
3136       # so we don't want to discard standard headers.
3137       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3138       ;;
3139    *)
3140       # If we're building newlib, use its generic headers last, but search
3141       # for any libc-related directories first (so make it the last -B
3142       # switch).
3143       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3144
3145       # If we're building libgloss, find the startup file, simulator library
3146       # and linker script.
3147       case " $target_configdirs " in
3148         *" libgloss "*)
3149         # Look for startup file, simulator library and maybe linker script.
3150         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3151         # Look for libnosys.a in case the target needs it.
3152         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3153         # Most targets have the linker script in the source directory.
3154         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3155         ;;
3156       esac
3157       ;;
3158    esac
3159    ;;
3160   esac
3161   ;;
3162 esac
3163
3164 case "$target" in
3165   x86_64-*mingw* | *-w64-mingw*)
3166   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3167   # however, use a symlink named 'mingw' in ${prefix} .
3168     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3169     ;;
3170   *-mingw*)
3171   # MinGW can't be handled as Cygwin above since it does not use newlib.
3172     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3173     ;;
3174 esac
3175
3176 # Allow the user to override the flags for
3177 # our build compiler if desired.
3178 if test x"${build}" = x"${host}" ; then
3179   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3180   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3181   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3182 fi
3183
3184 # On Canadian crosses, we'll be searching the right directories for
3185 # the previously-installed cross compiler, so don't bother to add
3186 # flags for directories within the install tree of the compiler
3187 # being built; programs in there won't even run.
3188 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3189   # Search for pre-installed headers if nothing else fits.
3190   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3191 fi
3192
3193 if test "x${use_gnu_ld}" = x &&
3194    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3195   # Arrange for us to find uninstalled linker scripts.
3196   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3197 fi
3198
3199 # Search for other target-specific linker scripts and such.
3200 case "${target}" in
3201   mep*)
3202     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3203     ;;
3204 esac
3205
3206 # Makefile fragments.
3207 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3208 do
3209   eval fragval=\$$frag
3210   if test $fragval != /dev/null; then
3211     eval $frag=${srcdir}/$fragval
3212   fi
3213 done
3214 AC_SUBST_FILE(host_makefile_frag)
3215 AC_SUBST_FILE(target_makefile_frag)
3216 AC_SUBST_FILE(alphaieee_frag)
3217 AC_SUBST_FILE(ospace_frag)
3218
3219 # Miscellanea: directories, flags, etc.
3220 AC_SUBST(RPATH_ENVVAR)
3221 AC_SUBST(GCC_SHLIB_SUBDIR)
3222 AC_SUBST(tooldir)
3223 AC_SUBST(build_tooldir)
3224 AC_SUBST(CONFIGURE_GDB_TK)
3225 AC_SUBST(GDB_TK)
3226 AC_SUBST(INSTALL_GDB_TK)
3227
3228 # Build module lists & subconfigure args.
3229 AC_SUBST(build_configargs)
3230 AC_SUBST(build_configdirs)
3231
3232 # Host module lists & subconfigure args.
3233 AC_SUBST(host_configargs)
3234 AC_SUBST(configdirs)
3235 AC_SUBST(target_configdirs)
3236
3237 # Target module lists & subconfigure args.
3238 AC_SUBST(target_configargs)
3239
3240
3241 # Build tools.
3242 AC_SUBST(AR_FOR_BUILD)
3243 AC_SUBST(AS_FOR_BUILD)
3244 AC_SUBST(CC_FOR_BUILD)
3245 AC_SUBST(CFLAGS_FOR_BUILD)
3246 AC_SUBST(CXXFLAGS_FOR_BUILD)
3247 AC_SUBST(CXX_FOR_BUILD)
3248 AC_SUBST(DLLTOOL_FOR_BUILD)
3249 AC_SUBST(GFORTRAN_FOR_BUILD)
3250 AC_SUBST(GOC_FOR_BUILD)
3251 AC_SUBST(LDFLAGS_FOR_BUILD)
3252 AC_SUBST(LD_FOR_BUILD)
3253 AC_SUBST(NM_FOR_BUILD)
3254 AC_SUBST(RANLIB_FOR_BUILD)
3255 AC_SUBST(WINDMC_FOR_BUILD)
3256 AC_SUBST(WINDRES_FOR_BUILD)
3257
3258 # Generate default definitions for YACC, M4, LEX and other programs that run
3259 # on the build machine.  These are used if the Makefile can't locate these
3260 # programs in objdir.
3261 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3262
3263 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3264 case " $build_configdirs " in
3265   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3266 esac
3267
3268 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3269 case " $build_configdirs " in
3270   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3271 esac
3272
3273 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3274 case " $build_configdirs " in
3275   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3276 esac
3277
3278 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3279 case " $build_configdirs " in
3280   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3281   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3282 esac
3283
3284 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3285 case " $build_configdirs " in
3286   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3287 esac
3288
3289 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3290 case " $build_configdirs " in
3291   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3292   *)
3293 changequote(,)
3294     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3295     # higher, else we use the "missing" dummy.
3296     if ${MAKEINFO} --version \
3297        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3298       :
3299     else
3300       MAKEINFO="$MISSING makeinfo"
3301     fi
3302     ;;
3303 changequote([,])
3304 esac
3305
3306 # FIXME: expect and dejagnu may become build tools?
3307
3308 AC_CHECK_PROGS(EXPECT, expect, expect)
3309 case " $configdirs " in
3310   *" expect "*)
3311     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3312     ;;
3313 esac
3314
3315 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3316 case " $configdirs " in
3317   *" dejagnu "*)
3318     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3319     ;;
3320 esac
3321
3322
3323 # Host tools.
3324 NCN_STRICT_CHECK_TOOLS(AR, ar)
3325 NCN_STRICT_CHECK_TOOLS(AS, as)
3326 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3327 NCN_STRICT_CHECK_TOOLS(LD, ld)
3328 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3329 NCN_STRICT_CHECK_TOOLS(NM, nm)
3330 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3331 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3332 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3333 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3334 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3335 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3336 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3337 AC_SUBST(CC)
3338 AC_SUBST(CXX)
3339 AC_SUBST(CFLAGS)
3340 AC_SUBST(CXXFLAGS)
3341
3342 # Target tools.
3343 AC_ARG_WITH([build-time-tools],
3344   [AS_HELP_STRING([--with-build-time-tools=PATH],
3345                   [use given path to find target tools during the build])],
3346   [case x"$withval" in
3347      x/*) ;;
3348      *)
3349        with_build_time_tools=
3350        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3351        ;;
3352    esac],
3353   [with_build_time_tools=])
3354
3355 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3356 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3357 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3358 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3359 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3360
3361 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3362 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3363 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3364 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3365 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3366 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3367 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3368 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3369 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3370 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3371 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3372 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3373 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3374
3375 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3376
3377 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3378 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3379 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3380 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3381 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3382                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3383                 c++)
3384 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3385                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3386                 c++)
3387 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3388 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3389 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3390                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3391 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3392                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3393 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3394 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3395 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3396 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3397 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3398 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3399 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3400 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3401 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3402 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3403
3404 AC_SUBST(FLAGS_FOR_TARGET)
3405 AC_SUBST(RAW_CXX_FOR_TARGET)
3406
3407 # Certain tools may need extra flags.
3408 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3409 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3410 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3411
3412 # When building target libraries, except in a Canadian cross, we use
3413 # the same toolchain as the compiler we just built.
3414 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3415 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3416 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3417 if test $host = $build; then
3418   case " $configdirs " in
3419     *" gcc "*)
3420       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3421       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3422       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3423       ;;
3424   esac
3425 fi
3426
3427 AC_SUBST(COMPILER_AS_FOR_TARGET)
3428 AC_SUBST(COMPILER_LD_FOR_TARGET)
3429 AC_SUBST(COMPILER_NM_FOR_TARGET)
3430
3431 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3432 AC_ARG_ENABLE(maintainer-mode,
3433 [AS_HELP_STRING([--enable-maintainer-mode],
3434                 [enable make rules and dependencies not useful
3435                  (and sometimes confusing) to the casual installer])],
3436       USE_MAINTAINER_MODE=$enableval,
3437       USE_MAINTAINER_MODE=no)
3438 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3439 AC_SUBST(MAINTAINER_MODE_TRUE)
3440 AC_SUBST(MAINTAINER_MODE_FALSE)
3441 if test "$USE_MAINTAINER_MODE" = yes; then
3442   MAINTAINER_MODE_TRUE=
3443   MAINTAINER_MODE_FALSE='#'
3444 else
3445   MAINTAINER_MODE_TRUE='#'
3446   MAINTAINER_MODE_FALSE=
3447 fi
3448 MAINT=$MAINTAINER_MODE_TRUE
3449 AC_SUBST(MAINT)dnl
3450
3451 # ---------------------
3452 # GCC bootstrap support
3453 # ---------------------
3454
3455 # Stage specific cflags for build.
3456 stage1_cflags="-g"
3457 case $build in
3458   vax-*-*)
3459     case ${GCC} in
3460       yes) stage1_cflags="-g -Wa,-J" ;;
3461       *) stage1_cflags="-g -J" ;;
3462     esac ;;
3463 esac
3464
3465 AC_SUBST(stage1_cflags)
3466
3467 # Enable --enable-checking in stage1 of the compiler.
3468 AC_ARG_ENABLE(stage1-checking,
3469 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3470                 [choose additional checking for stage1 of the compiler])],
3471 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3472 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3473   # For --disable-checking or implicit --enable-checking=release, avoid
3474   # setting --enable-checking=gc in the default stage1 checking for LTO
3475   # bootstraps.  See PR62077.
3476   case $BUILD_CONFIG in
3477     *lto*)
3478       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3479     *)
3480       stage1_checking=--enable-checking=yes,types;;
3481   esac
3482   if test "x$enable_checking" = x && \
3483      test -d ${srcdir}/gcc && \
3484      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3485     stage1_checking=--enable-checking=yes,types,extra
3486   fi
3487 else
3488   stage1_checking=--enable-checking=$enable_checking,types
3489 fi])
3490 AC_SUBST(stage1_checking)
3491
3492 # Enable -Werror in bootstrap stage2 and later.
3493 AC_ARG_ENABLE(werror,
3494 [AS_HELP_STRING([--enable-werror],
3495                 [enable -Werror in bootstrap stage2 and later])],
3496 [
3497 case ${enable_werror} in
3498   yes) stage2_werror_flag="--enable-werror-always" ;;
3499   *) stage2_werror_flag="" ;;
3500 esac
3501 ],
3502 [
3503 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3504   case $BUILD_CONFIG in
3505   bootstrap-debug)
3506       stage2_werror_flag="--enable-werror-always" ;;
3507   "")
3508       stage2_werror_flag="--enable-werror-always" ;;
3509   esac
3510 fi
3511 ])
3512
3513 AC_SUBST(stage2_werror_flag)
3514
3515 # Specify what files to not compare during bootstrap.
3516
3517 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3518 case "$target" in
3519   hppa*64*-*-hpux*) ;;
3520   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3521   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3522 esac
3523 AC_SUBST(compare_exclusions)
3524
3525 AC_CONFIG_FILES([Makefile],
3526   [sed "$extrasub_build" Makefile |
3527    sed "$extrasub_host" |
3528    sed "$extrasub_target" > mf$$
3529    mv -f mf$$ Makefile],
3530   [extrasub_build="$extrasub_build"
3531    extrasub_host="$extrasub_host"
3532    extrasub_target="$extrasub_target"])
3533 AC_OUTPUT