gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2018 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 AC_PREREQ(2.59)
  24 m4_include([../bfd/version.m4])
  25 AC_INIT([gas], BFD_VERSION)
  26 AC_CONFIG_SRCDIR(as.h)
  27
  28 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  29 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  30 dnl gas/ instead of gas/../.
  31 AC_CONFIG_AUX_DIR(..)
  32 AC_CANONICAL_TARGET
  33 AC_ISC_POSIX
  34
  35 AM_INIT_AUTOMAKE
  36
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_USE_SYSTEM_EXTENSIONS
  40
  41 LT_INIT
  42 ACX_LARGEFILE
  43 ACX_PROG_CMP_IGNORE_INITIAL
  44
  45 AC_ARG_ENABLE(targets,
  46 [  --enable-targets        alternative target configurations besides the primary],
  47 [case "${enableval}" in
  48   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  49             ;;
  50   no)       enable_targets= ;;
  51   *)        enable_targets=$enableval ;;
  52 esac])dnl
  53
  54 ac_checking=yes
  55 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  56   ac_checking=
  57 fi
  58 AC_ARG_ENABLE(checking,
  59 [  --enable-checking       enable run-time checks],
  60 [case "${enableval}" in
  61   no|none)  ac_checking= ;;
  62   *)        ac_checking=yes ;;
  63 esac])dnl
  64 if test x$ac_checking != x ; then
  65   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  66 fi
  67
  68 # PR gas/19109
  69 # Decide the default method for compressing debug sections.
  70 ac_default_compressed_debug_sections=unset
  71 # Provide a configure time option to override our default.
  72 AC_ARG_ENABLE(compressed_debug_sections,
  73               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  74               [compress debug sections by default]),
  75 [case ,"${enableval}", in
  76   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  77   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  78   *)   ac_default_compressed_debug_sections=unset ;;
  79 esac])dnl
  80
  81 # PR gas/19520
  82 # Decide if x86 assembler should generate relax relocations.
  83 ac_default_x86_relax_relocations=unset
  84 # Provide a configure time option to override our default.
  85 AC_ARG_ENABLE(x86_relax_relocations,
  86               AS_HELP_STRING([--enable-x86-relax-relocations],
  87               [generate x86 relax relocations by default]),
  88 [case "${enableval}" in
  89   no)  ac_default_x86_relax_relocations=0 ;;
  90 esac])dnl
  91
  92 # Decide if ELF assembler should generate common symbols with the
  93 # STT_COMMON type.
  94 ac_default_elf_stt_common=unset
  95 # Provide a configure time option to override our default.
  96 AC_ARG_ENABLE(elf_stt_common,
  97               AS_HELP_STRING([--enable-elf-stt-common],
  98               [generate ELF common symbols with STT_COMMON type by default]),
  99 [case "${enableval}" in
 100   yes)  ac_default_elf_stt_common=1 ;;
 101 esac])dnl
 102
 103
 104 # Decide if the ELF assembler should default to generating
 105 # GNU Build notes if none are provided by the input.
 106 ac_default_generate_build_notes=0
 107 # Provide a configuration option to override the default.
 108 AC_ARG_ENABLE(generate_build_notes,
 109               AS_HELP_STRING([--enable-generate-build-notes],
 110               [generate GNU Build notes if none are provided by the input]),
 111 [case "${enableval}" in
 112   yes)  ac_default_generate_build_notes=1 ;;
 113   no)   ac_default_generate_build_notes=0 ;;
 114 esac])dnl
 115
 116
 117 using_cgen=no
 118
 119 AM_BINUTILS_WARNINGS
 120
 121 # Generate a header file
 122 AC_CONFIG_HEADERS(config.h:config.in)
 123
 124 dnl Option --with-cpu=TYPE allows configure type control of the default
 125 dnl cpu type within the assembler.  Currently only the ARC target
 126 dnl supports this feature, but others may be added in the future.
 127 AC_ARG_WITH(cpu,
 128             AS_HELP_STRING([--with-cpu=CPU],
 129             [default cpu variant is CPU (currently only supported on ARC)]),
 130             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 131                                 "${with_cpu}",
 132                                 [Target specific CPU.])],
 133             [])
 134
 135 # PR 14072
 136 AH_VERBATIM([00_CONFIG_H_CHECK],
 137 [/* Check that config.h is #included before system headers
 138    (this works only for glibc, but that should be enough).  */
 139 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 140 #  error config.h must be #included before system headers
 141 #endif
 142 #define __CONFIG_H__ 1])
 143
 144 # If we are on a DOS filesystem, we must use gdb.ini rather than
 145 # .gdbinit.
 146 case "${host}" in
 147   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 148     GDBINIT="gdb.ini"
 149     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 150     ;;
 151   *)
 152     GDBINIT=".gdbinit"
 153     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 154     ;;
 155 esac
 156 AC_SUBST(GDBINIT)
 157
 158 #We need this for the host.
 159 AC_C_BIGENDIAN
 160
 161 te_file=generic
 162
 163 # Makefile target for installing gas in $(tooldir)/bin.
 164 install_tooldir=install-exec-tooldir
 165
 166 canon_targets=""
 167 all_targets=no
 168 if test -n "$enable_targets" ; then
 169   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 170     if test $t = "all"; then
 171       all_targets=yes
 172       continue
 173     fi
 174     result=`$ac_config_sub $t 2>/dev/null`
 175     if test -n "$result" ; then
 176       canon_targets="$canon_targets $result"
 177 #    else
 178 #      # Permit "all", etc.  We don't support it yet though.
 179 #      canon_targets="$canon_targets $t"
 180     fi
 181   done
 182   GAS_UNIQ(canon_targets)
 183 fi
 184
 185 emulations=""
 186
 187 for this_target in $target $canon_targets ; do
 188
 189     targ=${this_target}
 190     . ${srcdir}/configure.tgt
 191
 192     case ${target_cpu} in
 193       crisv32)
 194         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 195                            [Default CRIS architecture.])
 196         ;;
 197     esac
 198
 199     if test ${this_target} = $target ; then
 200       target_cpu_type=${cpu_type}
 201     elif test ${target_cpu_type} != ${cpu_type} ; then
 202       continue
 203     fi
 204
 205     generic_target=${cpu_type}-${target_vendor}-${target_os}
 206     case ${generic_target} in
 207       i386-*-msdosdjgpp* \
 208       | i386-*-go32* \
 209       | i386-go32-rtems*)
 210         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 211         ;;
 212
 213       i386-*-solaris2 \
 214       | x86_64-*-solaris2 \
 215       | i386-*-solaris2.[[0-9]] \
 216       | i386-*-solaris2.1[[01]] \
 217       | x86_64-*-solaris2.1[[01]])
 218         if test ${this_target} = $target \
 219            && test ${ac_default_x86_relax_relocations} = unset; then
 220           ac_default_x86_relax_relocations=0
 221         fi
 222         ;;
 223
 224       microblaze*)
 225         ;;
 226
 227 changequote(,)dnl
 228       ppc-*-aix[5-9].*)
 229 changequote([,])dnl
 230         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 231                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 232         ;;
 233       ppc-*-solaris*)
 234         if test ${this_target} = $target; then
 235           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 236                     [Define if default target is PowerPC Solaris.])
 237         fi
 238         if test x${endian} = xbig; then
 239           AC_MSG_ERROR(Solaris must be configured little endian)
 240         fi
 241         ;;
 242     esac
 243
 244     if test ${this_target} = $target ; then
 245       endian_def=
 246       if test x${endian} = xbig; then
 247         endian_def=1
 248       elif test x${endian} = xlittle; then
 249         endian_def=0
 250       fi
 251       if test x${endian_def} != x; then
 252         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 253                            [Define as 1 if big endian.])
 254       fi
 255     fi
 256
 257 # Other random stuff.
 258
 259     case ${cpu_type} in
 260       mips)
 261         # Set mips_cpu to the name of the default CPU.
 262         case ${target_cpu} in
 263           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 264             mips_cpu=from-abi
 265             ;;
 266           mipsisa32 | mipsisa32el)
 267             mips_cpu=mips32
 268             ;;
 269           mipsisa32r2 | mipsisa32r2el)
 270             mips_cpu=mips32r2
 271             ;;
 272           mipsisa32r3 | mipsisa32r3el)
 273             mips_cpu=mips32r3
 274             ;;
 275           mipsisa32r5 | mipsisa32r5el)
 276             mips_cpu=mips32r5
 277             ;;
 278           mipsisa32r6 | mipsisa32r6el)
 279             mips_cpu=mips32r6
 280             ;;
 281           mipsisa64 | mipsisa64el)
 282             mips_cpu=mips64
 283             ;;
 284           mipsisa64r2 | mipsisa64r2el)
 285             mips_cpu=mips64r2
 286             ;;
 287           mipsisa64r3 | mipsisa64r3el)
 288             mips_cpu=mips64r3
 289             ;;
 290           mipsisa64r5 | mipsisa64r5el)
 291             mips_cpu=mips64r5
 292             ;;
 293           mipsisa64r6 | mipsisa64r6el)
 294             mips_cpu=mips64r6
 295             ;;
 296           mipstx39 | mipstx39el)
 297             mips_cpu=r3900
 298             ;;
 299           mips64vr | mips64vrel)
 300             mips_cpu=vr4100
 301             ;;
 302           mipsisa32r2* | mipsisa64r2*)
 303 changequote(,)dnl
 304             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 305 changequote([,])dnl
 306             ;;
 307           mipsisa32r6* | mipsisa64r6*)
 308 changequote(,)dnl
 309             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 310 changequote([,])dnl
 311             ;;
 312           mips64* | mipsisa64* | mipsisa32*)
 313 changequote(,)dnl
 314             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 315 changequote([,])dnl
 316             ;;
 317           mips*)
 318 changequote(,)dnl
 319             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 320 changequote([,])dnl
 321             ;;
 322           *)
 323             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 324             ;;
 325         esac
 326         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 327         # binaries.  It's a GNU extension that some OSes don't understand.
 328         case ${target} in
 329           *-*-irix*)
 330             use_e_mips_abi_o32=0
 331             ;;
 332           *)
 333             use_e_mips_abi_o32=1
 334             ;;
 335         esac
 336         # Decide whether to generate 32-bit or 64-bit code by default.
 337         # Used to resolve -march=from-abi when an embedded ABI is selected.
 338         case ${target} in
 339           mips64*-*-* | mipsisa64*-*-*)
 340             mips_default_64bit=1
 341             ;;
 342           *)
 343             mips_default_64bit=0
 344             ;;
 345         esac
 346         # Decide which ABI to target by default.
 347         case ${target} in
 348           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 349           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 350             mips_default_abi=N32_ABI
 351             ;;
 352           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 353             mips_default_abi=O32_ABI
 354             ;;
 355           mips64*-openbsd*)
 356             mips_default_abi=N64_ABI
 357             ;;
 358           *)
 359             mips_default_abi=NO_ABI
 360             ;;
 361         esac
 362         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 363                            [Default CPU for MIPS targets. ])
 364         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 365                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 366         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 367                            [Generate 64-bit code by default on MIPS targets. ])
 368         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 369                            [Choose a default ABI for MIPS targets. ])
 370         ;;
 371     esac
 372
 373     # Do we need the opcodes library?
 374     case ${cpu_type} in
 375       vax | tic30)
 376         ;;
 377
 378       *)
 379         need_opcodes=yes
 380
 381         case "${enable_shared}" in
 382         yes) shared_opcodes=true ;;
 383         *opcodes*) shared_opcodes=true ;;
 384         *) shared_opcodes=false ;;
 385         esac
 386         ;;
 387     esac
 388
 389     # Any other special object files needed ?
 390     case ${cpu_type} in
 391
 392       bfin)
 393         echo ${extra_objects} | grep -s "bfin-parse.o"
 394         if test $? -ne 0 ; then
 395           extra_objects="$extra_objects bfin-parse.o"
 396         fi
 397
 398         echo ${extra_objects} | grep -s "bfin-lex-wrapper.o"
 399         if test $? -ne 0 ; then
 400           extra_objects="$extra_objects bfin-lex-wrapper.o"
 401         fi
 402         ;;
 403
 404       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 405         using_cgen=yes
 406         ;;
 407
 408       m32c)
 409         using_cgen=yes
 410         ;;
 411       frv)
 412         using_cgen=yes
 413         ;;
 414       m68k)
 415         case ${extra_objects} in
 416         *m68k-parse.o*) ;;
 417         *) extra_objects="$extra_objects m68k-parse.o" ;;
 418         esac
 419         ;;
 420
 421       mep)
 422         using_cgen=yes
 423         ;;
 424
 425       mips)
 426         echo ${extra_objects} | grep -s "itbl-parse.o"
 427         if test $? -ne 0 ; then
 428           extra_objects="$extra_objects itbl-parse.o"
 429         fi
 430
 431         echo ${extra_objects} | grep -s "itbl-lex-wrapper.o"
 432         if test $? -ne 0 ; then
 433           extra_objects="$extra_objects itbl-lex-wrapper.o"
 434         fi
 435
 436         echo ${extra_objects} | grep -s "itbl-ops.o"
 437         if test $? -ne 0 ; then
 438           extra_objects="$extra_objects itbl-ops.o"
 439         fi
 440         ;;
 441
 442       mt)
 443         using_cgen=yes
 444         ;;
 445
 446       nds32)
 447         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 448         # based on arch_name.
 449         AC_MSG_CHECKING(for default configuration of --with-arch)
 450         if test "x${with_arch}" != x; then
 451           case ${with_arch} in
 452             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 453               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 454                                  [Define value for nds32_arch_name])
 455               ;;
 456             *)
 457               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 458               ;;
 459           esac
 460         fi
 461         AC_MSG_RESULT($with_arch)
 462
 463         # Decide features one by one.
 464         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 465         if test "x${enable_dx_regs}" = xyes; then
 466           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 467                     [Define value for nds32_dx_regs])
 468         else
 469           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 470                     [Define default value for nds32_dx_regs])
 471         fi
 472         AC_MSG_RESULT($enable_dx_regs)
 473
 474         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 475         if test "x${enable_perf_ext}" = xno; then
 476           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 477                     [Define value for nds32_perf_ext])
 478         else
 479           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 480                     [Define default value for nds32_perf_ext])
 481         fi
 482         AC_MSG_RESULT($enable_perf_ext)
 483
 484         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 485         if test "x${enable_perf_ext2}" = xno; then
 486           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 487                     [Define value for nds32_perf_ext2])
 488         else
 489           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 490                     [Define default value for nds32_perf_ext2])
 491         fi
 492         AC_MSG_RESULT($enable_perf_ext2)
 493
 494         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 495         if test "x${enable_string_ext}" = xno; then
 496           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 497                     [Define value for nds32_string_ext])
 498         else
 499           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 500                     [Define default value for nds32_string_ext])
 501         fi
 502         AC_MSG_RESULT($enable_string_ext)
 503
 504         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 505         if test "x${enable_audio_ext}" = xno; then
 506           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 507                     [Define value for nds32_audio_ext])
 508         else
 509           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 510                     [Define default value for nds32_audio_ext])
 511         fi
 512         AC_MSG_RESULT($enable_audio_ext)
 513         ;;
 514
 515       aarch64 | i386 | riscv | s390 | sparc)
 516         if test $this_target = $target ; then
 517           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 518         fi
 519         ;;
 520
 521       rl78)
 522         echo ${extra_objects} | grep -s "rl78-parse.o"
 523         if test $? -ne 0 ; then
 524           extra_objects="$extra_objects rl78-parse.o"
 525         fi
 526         ;;
 527
 528       rx)
 529         echo ${extra_objects} | grep -s "rx-parse.o"
 530         if test $? -ne 0 ; then
 531           extra_objects="$extra_objects rx-parse.o"
 532         fi
 533         ;;
 534
 535       xstormy16)
 536         using_cgen=yes
 537         ;;
 538
 539       xc16x)
 540         using_cgen=yes
 541         ;;
 542
 543       xtensa)
 544         echo ${extra_objects} | grep -s "xtensa-relax.o"
 545         if test $? -ne 0 ; then
 546           extra_objects="$extra_objects xtensa-relax.o"
 547         fi
 548         ;;
 549
 550       *)
 551         ;;
 552     esac
 553
 554     if test $using_cgen = yes ; then
 555         case "x${extra_objects}" in
 556         *cgen.o*) ;;
 557         *) extra_objects="$extra_objects cgen.o" ;;
 558         esac
 559     fi
 560
 561 # See if we really can support this configuration with the emulation code.
 562
 563     if test $this_target = $target ; then
 564       obj_format=$fmt
 565       te_file=$em
 566     fi
 567
 568    case ${te_file} in
 569       vms) extra_objects="$extra_objects te-vms.o" ;;
 570    esac
 571
 572 # From target name and format, produce a list of supported emulations.
 573
 574     case ${generic_target}-${fmt} in
 575       mips-*-*-*)       case "$endian" in
 576                         big)    emulation="mipsbelf mipslelf mipself" ;;
 577                         *)      emulation="mipslelf mipsbelf mipself" ;;
 578                         esac ;;
 579       # i386-pc-pe-coff != i386-pc-coff.
 580       i386-*-pe-coff)   ;;
 581       # Uncommenting the next line will turn on support for i386 AOUT
 582       # for the default linux configuration
 583       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 584       #
 585       i386-*-aout)      emulation="i386aout" ;;
 586       i386-*-coff)      emulation="i386coff" ;;
 587       i386-*-elf)       emulation="i386elf" ;;
 588
 589       # Always all formats.  The first stated emulation becomes the default.
 590       cris-*-*aout*)    emulation="crisaout criself" ;;
 591       cris-*-*)         emulation="criself crisaout" ;;
 592     esac
 593
 594     emulations="$emulations $emulation"
 595
 596 done
 597
 598 if test ${ac_default_x86_relax_relocations} = unset; then
 599   ac_default_x86_relax_relocations=1
 600 fi
 601 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 602   $ac_default_x86_relax_relocations,
 603   [Define to 1 if you want to generate x86 relax relocations by default.])
 604
 605 if test ${ac_default_elf_stt_common} = unset; then
 606   ac_default_elf_stt_common=0
 607 fi
 608 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 609   $ac_default_elf_stt_common,
 610   [Define to 1 if you want to generate ELF common symbols with the
 611    STT_COMMON type by default.])
 612
 613 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 614   $ac_default_generate_build_notes,
 615   [Define to 1 if you want to generate GNU Build attribute notes
 616    by default, if none are contained in the input.])
 617
 618 if test x$ac_default_compressed_debug_sections = xyes ; then
 619   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 620 fi
 621
 622 # Turn on all targets if possible
 623 if test ${all_targets} = "yes"; then
 624   case ${target_cpu_type} in
 625   i386)
 626     case ${obj_format} in
 627     aout)
 628       emulations="$emulations i386coff i386elf"
 629       ;;
 630     coff)
 631       emulations="$emulations i386aout i386elf"
 632     ;;
 633     elf)
 634       emulations="$emulations i386aout i386coff"
 635       ;;
 636     esac
 637   ;;
 638   x86_64)
 639     case ${obj_format} in
 640     aout)
 641       emulations="$emulations i386coff i386elf"
 642       ;;
 643     coff)
 644       emulations="$emulations i386aout i386elf"
 645     ;;
 646     elf)
 647       emulations="$emulations i386aout i386coff"
 648       ;;
 649     esac
 650   ;;
 651   esac
 652 fi
 653
 654 # PE code has way too many macros tweaking behaviour
 655 case ${te_file} in
 656   pe*) emulations="" ;;
 657 esac
 658
 659 # Assign floating point type.  Most processors with FP support
 660 # IEEE FP.  On those that don't support FP at all, usually IEEE
 661 # is emulated.
 662 case ${target_cpu} in
 663   vax | pdp11 ) atof=vax ;;
 664   *)            atof=ieee ;;
 665 esac
 666
 667 case "${obj_format}" in
 668   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 669 esac
 670
 671 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 672 cgen_cpu_prefix=""
 673 if test $using_cgen = yes ; then
 674   case ${target_cpu} in
 675     or1knd)
 676        cgen_cpu_prefix=or1k ;;
 677     *) cgen_cpu_prefix=${target_cpu} ;;
 678   esac
 679   AC_SUBST(cgen_cpu_prefix)
 680   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 681 fi
 682
 683 dnl
 684 dnl Make sure the desired support files exist.
 685 dnl
 686
 687 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 688   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 689 fi
 690
 691 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 692   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 693 fi
 694
 695 # Some COFF configurations want these random other flags set.
 696 case ${obj_format} in
 697   coff)
 698     case ${target_cpu_type} in
 699       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 700       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 701     esac
 702     ;;
 703 esac
 704
 705 # Getting this done right is going to be a bitch.  Each configuration specified
 706 # with --enable-targets=... should be checked for environment, format, cpu
 707 # setting.
 708 #
 709 # For each configuration, the necessary object file support code must be linked
 710 # in.  This might be only one, it might be up to four.  The necessary emulation
 711 # code needs to be provided, too.
 712 #
 713 # And then there's "--enable-targets=all"....
 714 #
 715 # For now, just always do it for MIPS ELF configurations.  Sigh.
 716
 717 formats="${obj_format}"
 718 emfiles=""
 719 EMULATIONS=""
 720 GAS_UNIQ(emulations)
 721 for em in . $emulations ; do
 722   case $em in
 723     .)  continue ;;
 724     mipsbelf | mipslelf | mipself)
 725         fmt=elf   file=mipself ;;
 726     *coff)
 727         fmt=coff  file=$em ;;
 728     *aout)
 729         fmt=aout file=$em ;;
 730     *elf)
 731         fmt=elf file=$em ;;
 732   esac
 733   formats="$formats $fmt"
 734   emfiles="$emfiles e-$file.o"
 735   EMULATIONS="$EMULATIONS &$em,"
 736 done
 737 GAS_UNIQ(formats)
 738 GAS_UNIQ(emfiles)
 739 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 740   for fmt in $formats ; do
 741     case $fmt in
 742       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 743       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 744       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 745       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 746       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 747       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 748     esac
 749     extra_objects="$extra_objects obj-$fmt.o"
 750   done
 751   obj_format=multi
 752 fi
 753 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 754   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 755   # e-mipself has more than one emulation per file, e-i386* has just one at the
 756   # moment.  If only one emulation is specified, then don't define
 757   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 758   case "${obj_format}${emfiles}" in
 759     multi* | *mipself*)
 760       extra_objects="$extra_objects $emfiles"
 761       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 762   esac
 763 fi
 764 AC_SUBST(extra_objects)
 765 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 766 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 767                    [Default emulation.])
 768
 769 reject_dev_configs=yes
 770
 771 case ${reject_dev_configs}-${dev} in
 772   yes-yes) # Oops.
 773     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 774     ;;
 775 esac
 776
 777 AC_SUBST(target_cpu_type)
 778 AC_SUBST(obj_format)
 779 AC_SUBST(te_file)
 780 AC_SUBST(install_tooldir)
 781 AC_SUBST(atof)
 782 dnl AC_SUBST(emulation)
 783
 784 # do we need the opcodes library?
 785 case "${need_opcodes}" in
 786 yes)
 787   OPCODES_LIB=../opcodes/libopcodes.la
 788   ;;
 789 esac
 790
 791 AC_SUBST(OPCODES_LIB)
 792
 793 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 794 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 795 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 796 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 797 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 798
 799 AC_PROG_YACC
 800 AM_PROG_LEX
 801
 802 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 803 ZW_GNU_GETTEXT_SISTER_DIR
 804 AM_PO_SUBDIRS
 805
 806 AM_MAINTAINER_MODE
 807 AM_CONDITIONAL(GENINSRC_NEVER, false)
 808 AC_EXEEXT
 809
 810 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 811 ACX_HEADER_STRING
 812
 813 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 814 # people who are not cross-compiling but are compiling cross-assemblers.
 815 AC_MSG_CHECKING(whether compiling a cross-assembler)
 816 if test "${host}" = "${target}"; then
 817   cross_gas=no
 818 else
 819   cross_gas=yes
 820   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 821 fi
 822 AC_MSG_RESULT($cross_gas)
 823
 824 dnl ansidecl.h will deal with const
 825 dnl AC_C_CONST
 826 AC_FUNC_ALLOCA
 827 AC_C_INLINE
 828
 829 # VMS doesn't have unlink.
 830 AC_CHECK_FUNCS(unlink remove, break)
 831 AC_CHECK_FUNCS(sbrk setlocale)
 832 AC_CHECK_FUNCS(strsignal)
 833
 834 AM_LC_MESSAGES
 835
 836 # do we need the math library?
 837 case "${need_libm}" in
 838 yes)
 839   LT_LIB_M
 840   AC_SUBST(LIBM)
 841   ;;
 842 esac
 843
 844 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 845 # enough, but on some of those systems, the assert macro relies on requoting
 846 # working properly!
 847 GAS_WORKING_ASSERT
 848
 849 # On some systems, the system header files may not declare malloc, realloc,
 850 # and free.  There are places where gas needs these functions to have been
 851 # declared -- such as when taking their addresses.
 852 gas_test_headers="
 853 #ifdef HAVE_MEMORY_H
 854 #include <memory.h>
 855 #endif
 856 #ifdef HAVE_STRING_H
 857 #include <string.h>
 858 #else
 859 #ifdef HAVE_STRINGS_H
 860 #include <strings.h>
 861 #endif
 862 #endif
 863 #ifdef HAVE_STDLIB_H
 864 #include <stdlib.h>
 865 #endif
 866 #ifdef HAVE_UNISTD_H
 867 #include <unistd.h>
 868 #endif
 869 "
 870
 871 # Does errno.h declare errno, or do we have to add a separate declaration
 872 # for it?
 873 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 874 #ifdef HAVE_ERRNO_H
 875 #include <errno.h>
 876 #endif
 877 ])
 878
 879 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 880 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 881 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 882 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 883 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 884 if test $gas_cv_decl_getopt_unistd_h = yes; then
 885   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 886             [Is the prototype for getopt in <unistd.h> in the expected format?])
 887 fi
 888
 889 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 890 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 891 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 892 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 893 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 894 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 895
 896 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf, asprintf])
 897
 898 BFD_BINARY_FOPEN
 899
 900 # Link in zlib if we can.  This allows us to write compressed debug sections.
 901 AM_ZLIB
 902
 903 # Support for VMS timestamps via cross compile
 904
 905 if test "$ac_cv_header_time_h" = yes; then
 906   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 907 fi
 908
 909 if test "$ac_cv_header_sys_stat_h" = yes; then
 910     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 911     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 912 fi
 913
 914
 915 dnl Required for html, pdf, install-pdf and install-html targets.
 916 AC_SUBST(datarootdir)
 917 AC_SUBST(docdir)
 918 AC_SUBST(htmldir)
 919 AC_SUBST(pdfdir)
 920
 921 dnl This must come last.
 922
 923 dnl We used to make symlinks to files in the source directory, but now
 924 dnl we just use the right name for .c files, and create .h files in
 925 dnl the build directory which include the right .h file.  Make sure
 926 dnl the old symlinks don't exist, so that a reconfigure in an existing
 927 dnl directory behaves reasonably.
 928
 929 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 930 AC_CONFIG_COMMANDS([default],
 931 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 932  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 933  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 934  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 935  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 936  if test "x$cgen_cpu_prefix" != x ; then
 937    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 938  fi],
 939 [target_cpu_type=${target_cpu_type}
 940  cgen_cpu_prefix=${cgen_cpu_prefix}
 941  obj_format=${obj_format}
 942  te_file=${te_file}])
 943
 944 AC_OUTPUT