gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2014 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 AC_PREREQ(2.59)
  24 m4_include([../bfd/version.m4])
  25 AC_INIT([gas], BFD_VERSION)
  26 AC_CONFIG_SRCDIR(as.h)
  27
  28 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  29 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  30 dnl gas/ instead of gas/../.
  31 AC_CONFIG_AUX_DIR(..)
  32 AC_CANONICAL_TARGET
  33 AC_ISC_POSIX
  34
  35 AM_INIT_AUTOMAKE
  36
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_USE_SYSTEM_EXTENSIONS
  40
  41 LT_INIT
  42 ACX_LARGEFILE
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=yes
  54 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  55   ac_checking=
  56 fi
  57 AC_ARG_ENABLE(checking,
  58 [  --enable-checking       enable run-time checks],
  59 [case "${enableval}" in
  60   no|none)  ac_checking= ;;
  61   *)        ac_checking=yes ;;
  62 esac])dnl
  63 if test x$ac_checking != x ; then
  64   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  65 fi
  66
  67 using_cgen=no
  68
  69 AM_BINUTILS_WARNINGS
  70
  71 # Generate a header file
  72 AC_CONFIG_HEADERS(config.h:config.in)
  73
  74 # PR 14072
  75 AH_VERBATIM([00_CONFIG_H_CHECK],
  76 [/* Check that config.h is #included before system headers
  77    (this works only for glibc, but that should be enough).  */
  78 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  79 #  error config.h must be #included before system headers
  80 #endif
  81 #define __CONFIG_H__ 1])
  82
  83 # If we are on a DOS filesystem, we must use gdb.ini rather than
  84 # .gdbinit.
  85 case "${host}" in
  86   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  87     GDBINIT="gdb.ini"
  88     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  89     ;;
  90   *)
  91     GDBINIT=".gdbinit"
  92     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  93     ;;
  94 esac
  95 AC_SUBST(GDBINIT)
  96
  97 #We need this for the host.  BOUT header is in host order.
  98 AC_C_BIGENDIAN
  99
 100 te_file=generic
 101
 102 # Makefile target for installing gas in $(tooldir)/bin.
 103 install_tooldir=install-exec-tooldir
 104
 105 canon_targets=""
 106 all_targets=no
 107 if test -n "$enable_targets" ; then
 108   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 109     if test $t = "all"; then
 110       all_targets=yes
 111       continue
 112     fi
 113     result=`$ac_config_sub $t 2>/dev/null`
 114     if test -n "$result" ; then
 115       canon_targets="$canon_targets $result"
 116 #    else
 117 #      # Permit "all", etc.  We don't support it yet though.
 118 #      canon_targets="$canon_targets $t"
 119     fi
 120   done
 121   GAS_UNIQ(canon_targets)
 122 fi
 123
 124 emulations=""
 125
 126 for this_target in $target $canon_targets ; do
 127
 128     targ=${this_target}
 129     . ${srcdir}/configure.tgt
 130
 131     case ${target_cpu} in
 132       crisv32)
 133         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 134                            [Default CRIS architecture.])
 135         ;;
 136     esac
 137
 138     if test ${this_target} = $target ; then
 139       target_cpu_type=${cpu_type}
 140     elif test ${target_cpu_type} != ${cpu_type} ; then
 141       continue
 142     fi
 143
 144     generic_target=${cpu_type}-${target_vendor}-${target_os}
 145     case ${generic_target} in
 146       i386-*-sco3.2v5*)
 147         if test ${this_target} = $target; then
 148           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 149         fi
 150         ;;
 151
 152       i386-*-msdosdjgpp* \
 153       | i386-*-go32* \
 154       | i386-go32-rtems*)
 155         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 156         ;;
 157
 158       i860-*-*)
 159         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 160         ;;
 161
 162       microblaze*)
 163         ;;
 164
 165 changequote(,)dnl
 166       ppc-*-aix[5-9].*)
 167 changequote([,])dnl
 168         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 169                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 170         ;;
 171       ppc-*-solaris*)
 172         if test ${this_target} = $target; then
 173           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 174                     [Define if default target is PowerPC Solaris.])
 175         fi
 176         if test x${endian} = xbig; then
 177           AC_MSG_ERROR(Solaris must be configured little endian)
 178         fi
 179         ;;
 180
 181       sh*-*-symbianelf*)
 182         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 183         ;;
 184     esac
 185
 186     if test ${this_target} = $target ; then
 187       endian_def=
 188       if test x${endian} = xbig; then
 189         endian_def=1
 190       elif test x${endian} = xlittle; then
 191         endian_def=0
 192       fi
 193       if test x${endian_def} != x; then
 194         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 195                            [Define as 1 if big endian.])
 196       fi
 197     fi
 198
 199 # Other random stuff.
 200
 201     case ${cpu_type} in
 202       mips)
 203         # Set mips_cpu to the name of the default CPU.
 204         case ${target_cpu} in
 205           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 206             mips_cpu=from-abi
 207             ;;
 208           mipsisa32 | mipsisa32el)
 209             mips_cpu=mips32
 210             ;;
 211           mipsisa32r2 | mipsisa32r2el)
 212             mips_cpu=mips32r2
 213             ;;
 214           mipsisa32r3 | mipsisa32r3el)
 215             mips_cpu=mips32r3
 216             ;;
 217           mipsisa32r5 | mipsisa32r5el)
 218             mips_cpu=mips32r5
 219             ;;
 220           mipsisa32r6 | mipsisa32r6el)
 221             mips_cpu=mips32r6
 222             ;;
 223           mipsisa64 | mipsisa64el)
 224             mips_cpu=mips64
 225             ;;
 226           mipsisa64r2 | mipsisa64r2el)
 227             mips_cpu=mips64r2
 228             ;;
 229           mipsisa64r3 | mipsisa64r3el)
 230             mips_cpu=mips64r3
 231             ;;
 232           mipsisa64r5 | mipsisa64r5el)
 233             mips_cpu=mips64r5
 234             ;;
 235           mipsisa64r6 | mipsisa64r6el)
 236             mips_cpu=mips64r6
 237             ;;
 238           mipstx39 | mipstx39el)
 239             mips_cpu=r3900
 240             ;;
 241           mips64vr | mips64vrel)
 242             mips_cpu=vr4100
 243             ;;
 244           mipsisa32r2* | mipsisa64r2*)
 245 changequote(,)dnl
 246             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 247 changequote([,])dnl
 248             ;;
 249           mipsisa32r6* | mipsisa64r6*)
 250 changequote(,)dnl
 251             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 252 changequote([,])dnl
 253             ;;
 254           mips64* | mipsisa64* | mipsisa32*)
 255 changequote(,)dnl
 256             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 257 changequote([,])dnl
 258             ;;
 259           mips*)
 260 changequote(,)dnl
 261             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 262 changequote([,])dnl
 263             ;;
 264           *)
 265             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 266             ;;
 267         esac
 268         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 269         # binaries.  It's a GNU extension that some OSes don't understand.
 270         case ${target} in
 271           *-*-irix*)
 272             use_e_mips_abi_o32=0
 273             ;;
 274           *)
 275             use_e_mips_abi_o32=1
 276             ;;
 277         esac
 278         # Decide whether to generate 32-bit or 64-bit code by default.
 279         # Used to resolve -march=from-abi when an embedded ABI is selected.
 280         case ${target} in
 281           mips64*-*-* | mipsisa64*-*-*)
 282             mips_default_64bit=1
 283             ;;
 284           *)
 285             mips_default_64bit=0
 286             ;;
 287         esac
 288         # Decide which ABI to target by default.
 289         case ${target} in
 290           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* | mips64*-kfreebsd*-gnu)
 291             mips_default_abi=N32_ABI
 292             ;;
 293           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 294             mips_default_abi=O32_ABI
 295             ;;
 296           mips64*-openbsd*)
 297             mips_default_abi=N64_ABI
 298             ;;
 299           *)
 300             mips_default_abi=NO_ABI
 301             ;;
 302         esac
 303         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 304                            [Default CPU for MIPS targets. ])
 305         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 306                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 307         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 308                            [Generate 64-bit code by default on MIPS targets. ])
 309         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 310                            [Choose a default ABI for MIPS targets. ])
 311         ;;
 312     esac
 313
 314     # Do we need the opcodes library?
 315     case ${cpu_type} in
 316       vax | tic30)
 317         ;;
 318
 319       *)
 320         need_opcodes=yes
 321
 322         case "${enable_shared}" in
 323         yes) shared_opcodes=true ;;
 324         *opcodes*) shared_opcodes=true ;;
 325         *) shared_opcodes=false ;;
 326         esac
 327         ;;
 328     esac
 329
 330     # Any other special object files needed ?
 331     case ${cpu_type} in
 332
 333       bfin)
 334         echo ${extra_objects} | grep -s "bfin-parse.o"
 335         if test $? -ne 0 ; then
 336           extra_objects="$extra_objects bfin-parse.o"
 337         fi
 338
 339         echo ${extra_objects} | grep -s "bfin-lex-wrapper.o"
 340         if test $? -ne 0 ; then
 341           extra_objects="$extra_objects bfin-lex-wrapper.o"
 342         fi
 343         ;;
 344
 345       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 346         using_cgen=yes
 347         ;;
 348
 349       m32c)
 350         using_cgen=yes
 351         ;;
 352       frv)
 353         using_cgen=yes
 354         ;;
 355       m68k)
 356         case ${extra_objects} in
 357         *m68k-parse.o*) ;;
 358         *) extra_objects="$extra_objects m68k-parse.o" ;;
 359         esac
 360         ;;
 361
 362       mep)
 363         using_cgen=yes
 364         ;;
 365
 366       mips)
 367         echo ${extra_objects} | grep -s "itbl-parse.o"
 368         if test $? -ne 0 ; then
 369           extra_objects="$extra_objects itbl-parse.o"
 370         fi
 371
 372         echo ${extra_objects} | grep -s "itbl-lex-wrapper.o"
 373         if test $? -ne 0 ; then
 374           extra_objects="$extra_objects itbl-lex-wrapper.o"
 375         fi
 376
 377         echo ${extra_objects} | grep -s "itbl-ops.o"
 378         if test $? -ne 0 ; then
 379           extra_objects="$extra_objects itbl-ops.o"
 380         fi
 381         ;;
 382
 383       mt)
 384         using_cgen=yes
 385         ;;
 386
 387       nds32)
 388         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 389         # based on arch_name.
 390         AC_MSG_CHECKING(for default configuration of --with-arch)
 391         if test "x${with_arch}" != x; then
 392           case ${with_arch} in
 393             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 394               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 395                                  [Define value for nds32_arch_name])
 396               ;;
 397             *)
 398               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 399               ;;
 400           esac
 401         fi
 402         AC_MSG_RESULT($with_arch)
 403
 404         # Decide features one by one.
 405         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 406         if test "x${enable_dx_regs}" == xyes; then
 407           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 408                     [Define value for nds32_dx_regs])
 409         else
 410           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 411                     [Define default value for nds32_dx_regs])
 412         fi
 413         AC_MSG_RESULT($enable_dx_regs)
 414
 415         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 416         if test "x${enable_perf_ext}" == xno; then
 417           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 418                     [Define value for nds32_perf_ext])
 419         else
 420           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 421                     [Define default value for nds32_perf_ext])
 422         fi
 423         AC_MSG_RESULT($enable_perf_ext)
 424
 425         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 426         if test "x${enable_perf_ext2}" == xno; then
 427           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 428                     [Define value for nds32_perf_ext2])
 429         else
 430           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 431                     [Define default value for nds32_perf_ext2])
 432         fi
 433         AC_MSG_RESULT($enable_perf_ext2)
 434
 435         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 436         if test "x${enable_string_ext}" == xno; then
 437           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 438                     [Define value for nds32_string_ext])
 439         else
 440           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 441                     [Define default value for nds32_string_ext])
 442         fi
 443         AC_MSG_RESULT($enable_string_ext)
 444
 445         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 446         if test "x${enable_audio_ext}" == xno; then
 447           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 448                     [Define value for nds32_audio_ext])
 449         else
 450           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 451                     [Define default value for nds32_audio_ext])
 452         fi
 453         AC_MSG_RESULT($enable_audio_ext)
 454         ;;
 455
 456       i386 | s390 | sparc)
 457         if test $this_target = $target ; then
 458           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 459         fi
 460         ;;
 461
 462       rl78)
 463         echo ${extra_objects} | grep -s "rl78-parse.o"
 464         if test $? -ne 0 ; then
 465           extra_objects="$extra_objects rl78-parse.o"
 466         fi
 467         ;;
 468
 469       rx)
 470         echo ${extra_objects} | grep -s "rx-parse.o"
 471         if test $? -ne 0 ; then
 472           extra_objects="$extra_objects rx-parse.o"
 473         fi
 474         ;;
 475
 476       xstormy16)
 477         using_cgen=yes
 478         ;;
 479
 480       xc16x)
 481         using_cgen=yes
 482         ;;
 483
 484       xtensa)
 485         echo ${extra_objects} | grep -s "xtensa-relax.o"
 486         if test $? -ne 0 ; then
 487           extra_objects="$extra_objects xtensa-relax.o"
 488         fi
 489         ;;
 490
 491       *)
 492         ;;
 493     esac
 494
 495     if test $using_cgen = yes ; then
 496         case "x${extra_objects}" in
 497         *cgen.o*) ;;
 498         *) extra_objects="$extra_objects cgen.o" ;;
 499         esac
 500     fi
 501
 502 # See if we really can support this configuration with the emulation code.
 503
 504     if test $this_target = $target ; then
 505       obj_format=$fmt
 506       te_file=$em
 507     fi
 508
 509    case ${te_file} in
 510       vms) extra_objects="$extra_objects te-vms.o" ;;
 511    esac
 512
 513 # From target name and format, produce a list of supported emulations.
 514
 515     case ${generic_target}-${fmt} in
 516       mips-*-*-*)       case "$endian" in
 517                         big)    emulation="mipsbelf mipslelf mipself" ;;
 518                         *)      emulation="mipslelf mipsbelf mipself" ;;
 519                         esac ;;
 520       # i386-pc-pe-coff != i386-pc-coff.
 521       i386-*-pe-coff)   ;;
 522       # Uncommenting the next line will turn on support for i386 AOUT
 523       # for the default linux configuration
 524       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 525       #
 526       i386-*-aout)      emulation="i386aout" ;;
 527       i386-*-coff)      emulation="i386coff" ;;
 528       i386-*-elf)       emulation="i386elf" ;;
 529
 530       # Always all formats.  The first stated emulation becomes the default.
 531       cris-*-*aout*)    emulation="crisaout criself" ;;
 532       cris-*-*)         emulation="criself crisaout" ;;
 533     esac
 534
 535     emulations="$emulations $emulation"
 536
 537 done
 538
 539 # Turn on all targets if possible
 540 if test ${all_targets} = "yes"; then
 541   case ${target_cpu_type} in
 542   i386)
 543     case ${obj_format} in
 544     aout)
 545       emulations="$emulations i386coff i386elf"
 546       ;;
 547     coff)
 548       emulations="$emulations i386aout i386elf"
 549     ;;
 550     elf)
 551       emulations="$emulations i386aout i386coff"
 552       ;;
 553     esac
 554   ;;
 555   x86_64)
 556     case ${obj_format} in
 557     aout)
 558       emulations="$emulations i386coff i386elf"
 559       ;;
 560     coff)
 561       emulations="$emulations i386aout i386elf"
 562     ;;
 563     elf)
 564       emulations="$emulations i386aout i386coff"
 565       ;;
 566     esac
 567   ;;
 568   esac
 569 fi
 570
 571 # PE code has way too many macros tweaking behaviour
 572 case ${te_file} in
 573   pe*) emulations="" ;;
 574 esac
 575
 576 # Assign floating point type.  Most processors with FP support
 577 # IEEE FP.  On those that don't support FP at all, usually IEEE
 578 # is emulated.
 579 case ${target_cpu} in
 580   vax | pdp11 ) atof=vax ;;
 581   *)            atof=ieee ;;
 582 esac
 583
 584 case "${obj_format}" in
 585   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 586 esac
 587
 588 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 589 cgen_cpu_prefix=""
 590 if test $using_cgen = yes ; then
 591   case ${target_cpu} in
 592     or1knd)
 593        cgen_cpu_prefix=or1k ;;
 594     *) cgen_cpu_prefix=${target_cpu} ;;
 595   esac
 596   AC_SUBST(cgen_cpu_prefix)
 597   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 598 fi
 599
 600 dnl
 601 dnl Make sure the desired support files exist.
 602 dnl
 603
 604 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 605   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 606 fi
 607
 608 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 609   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 610 fi
 611
 612 # Some COFF configurations want these random other flags set.
 613 case ${obj_format} in
 614   coff)
 615     case ${target_cpu_type} in
 616       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 617       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 618       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 619       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 620     esac
 621     ;;
 622 esac
 623
 624 # Getting this done right is going to be a bitch.  Each configuration specified
 625 # with --enable-targets=... should be checked for environment, format, cpu
 626 # setting.
 627 #
 628 # For each configuration, the necessary object file support code must be linked
 629 # in.  This might be only one, it might be up to four.  The necessary emulation
 630 # code needs to be provided, too.
 631 #
 632 # And then there's "--enable-targets=all"....
 633 #
 634 # For now, just always do it for MIPS ELF configurations.  Sigh.
 635
 636 formats="${obj_format}"
 637 emfiles=""
 638 EMULATIONS=""
 639 GAS_UNIQ(emulations)
 640 for em in . $emulations ; do
 641   case $em in
 642     .)  continue ;;
 643     mipsbelf | mipslelf | mipself)
 644         fmt=elf   file=mipself ;;
 645     *coff)
 646         fmt=coff  file=$em ;;
 647     *aout)
 648         fmt=aout file=$em ;;
 649     *elf)
 650         fmt=elf file=$em ;;
 651   esac
 652   formats="$formats $fmt"
 653   emfiles="$emfiles e-$file.o"
 654   EMULATIONS="$EMULATIONS &$em,"
 655 done
 656 GAS_UNIQ(formats)
 657 GAS_UNIQ(emfiles)
 658 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 659   for fmt in $formats ; do
 660     case $fmt in
 661       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 662       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 663       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 664       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 665       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 666       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 667       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 668     esac
 669     extra_objects="$extra_objects obj-$fmt.o"
 670   done
 671   obj_format=multi
 672 fi
 673 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 674   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 675   # e-mipself has more than one emulation per file, e-i386* has just one at the
 676   # moment.  If only one emulation is specified, then don't define
 677   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 678   case "${obj_format}${emfiles}" in
 679     multi* | *mipself*)
 680       extra_objects="$extra_objects $emfiles"
 681       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 682   esac
 683 fi
 684 AC_SUBST(extra_objects)
 685 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 686 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 687                    [Default emulation.])
 688
 689 reject_dev_configs=yes
 690
 691 case ${reject_dev_configs}-${dev} in
 692   yes-yes) # Oops.
 693     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 694     ;;
 695 esac
 696
 697 AC_SUBST(target_cpu_type)
 698 AC_SUBST(obj_format)
 699 AC_SUBST(te_file)
 700 AC_SUBST(install_tooldir)
 701 AC_SUBST(atof)
 702 dnl AC_SUBST(emulation)
 703
 704 # do we need the opcodes library?
 705 case "${need_opcodes}" in
 706 yes)
 707   OPCODES_LIB=../opcodes/libopcodes.la
 708   ;;
 709 esac
 710
 711 AC_SUBST(OPCODES_LIB)
 712
 713 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 714 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 715 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 716 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 717 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 718
 719 AC_PROG_YACC
 720 AM_PROG_LEX
 721
 722 ALL_LINGUAS="fr tr es rw id ru fi ja"
 723 ZW_GNU_GETTEXT_SISTER_DIR
 724 AM_PO_SUBDIRS
 725
 726 AM_MAINTAINER_MODE
 727 AM_CONDITIONAL(GENINSRC_NEVER, false)
 728 AC_EXEEXT
 729
 730 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 731 ACX_HEADER_STRING
 732
 733 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 734 # people who are not cross-compiling but are compiling cross-assemblers.
 735 AC_MSG_CHECKING(whether compiling a cross-assembler)
 736 if test "${host}" = "${target}"; then
 737   cross_gas=no
 738 else
 739   cross_gas=yes
 740   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 741 fi
 742 AC_MSG_RESULT($cross_gas)
 743
 744 dnl ansidecl.h will deal with const
 745 dnl AC_C_CONST
 746 AC_FUNC_ALLOCA
 747 AC_C_INLINE
 748
 749 # VMS doesn't have unlink.
 750 AC_CHECK_FUNCS(unlink remove, break)
 751 AC_CHECK_FUNCS(sbrk setlocale)
 752
 753 AM_LC_MESSAGES
 754
 755 # do we need the math library?
 756 case "${need_libm}" in
 757 yes)
 758   LT_LIB_M
 759   AC_SUBST(LIBM)
 760   ;;
 761 esac
 762
 763 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 764 # enough, but on some of those systems, the assert macro relies on requoting
 765 # working properly!
 766 GAS_WORKING_ASSERT
 767
 768 # On some systems, the system header files may not declare malloc, realloc,
 769 # and free.  There are places where gas needs these functions to have been
 770 # declared -- such as when taking their addresses.
 771 gas_test_headers="
 772 #ifdef HAVE_MEMORY_H
 773 #include <memory.h>
 774 #endif
 775 #ifdef HAVE_STRING_H
 776 #include <string.h>
 777 #else
 778 #ifdef HAVE_STRINGS_H
 779 #include <strings.h>
 780 #endif
 781 #endif
 782 #ifdef HAVE_STDLIB_H
 783 #include <stdlib.h>
 784 #endif
 785 #ifdef HAVE_UNISTD_H
 786 #include <unistd.h>
 787 #endif
 788 "
 789
 790 # Does errno.h declare errno, or do we have to add a separate declaration
 791 # for it?
 792 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 793 #ifdef HAVE_ERRNO_H
 794 #include <errno.h>
 795 #endif
 796 ])
 797
 798 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 799 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 800 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 801 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 802 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 803 if test $gas_cv_decl_getopt_unistd_h = yes; then
 804   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 805             [Is the prototype for getopt in <unistd.h> in the expected format?])
 806 fi
 807
 808 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 809 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 810 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 811 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 812 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 813 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 814
 815 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf])
 816
 817 BFD_BINARY_FOPEN
 818
 819 # Link in zlib if we can.  This allows us to write compressed debug sections.
 820 AM_ZLIB
 821
 822 # Support for VMS timestamps via cross compile
 823
 824 if test "$ac_cv_header_time_h" = yes; then
 825   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 826 fi
 827
 828 if test "$ac_cv_header_sys_stat_h" = yes; then
 829     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 830     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 831 fi
 832
 833
 834 dnl Required for html, pdf, install-pdf and install-html targets.
 835 AC_SUBST(datarootdir)
 836 AC_SUBST(docdir)
 837 AC_SUBST(htmldir)
 838 AC_SUBST(pdfdir)
 839
 840 dnl This must come last.
 841
 842 dnl We used to make symlinks to files in the source directory, but now
 843 dnl we just use the right name for .c files, and create .h files in
 844 dnl the build directory which include the right .h file.  Make sure
 845 dnl the old symlinks don't exist, so that a reconfigure in an existing
 846 dnl directory behaves reasonably.
 847
 848 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 849 AC_CONFIG_COMMANDS([default],
 850 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 851  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 852  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 853  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 854  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 855  if test "x$cgen_cpu_prefix" != x ; then
 856    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 857  fi],
 858 [target_cpu_type=${target_cpu_type}
 859  cgen_cpu_prefix=${cgen_cpu_prefix}
 860  obj_format=${obj_format}
 861  te_file=${te_file}])
 862
 863 AC_OUTPUT