gas/testsuite/gas/all/gas.exp

   1 #
   2 # These tests should be valid on all targets.
   3 #
   4
   5 # I think currently all targets fail this one when listings are enabled.
   6 gas_test "p2425.s" ""   "" "pcrel values in assignment"
   7
   8 # p1480.s uses a ".space" directive which for most assemblers means
   9 # "allocate some space".  On the PA it means "switch into this space".
  10 #
  11 # Therefore this test (as it is currently written) is completely bogus
  12 # for any PA target.  Do not bother trying to run it and just claim
  13 # it fails.
  14 #
  15 # The C54x uses ".space" to allocate bits, and requires absolute expressions;
  16 # The ".space" directive is taken care of in the C54x-specific tests, so fail
  17 #  here
  18 #
  19 # The test also doesn't work on mep targets, since they use RELC, and it
  20 # will avoid simplifying the expression since it conservatively assumes
  21 # ugly expressions can be saved until link-time.
  22 if { [istarget hppa*-*-*] || [istarget *c54x*-*-*] || [istarget mep*-*-*]} then {
  23     setup_xfail *-*-*
  24     fail "simplifiable double subtraction"
  25 } else {
  26     gas_test "p1480.s" "" "-a>" "simplifiable double subtraction"
  27 }
  28
  29 # No floating point support in assembly code for CRIS and Z80.
  30 if { ![istarget cris-*-*] && ![istarget crisv32-*-*]
  31      && ![istarget z80-*-*] } then {
  32     gas_test "float.s" ""   "" "simple FP constants"
  33 }
  34
  35 # This test is meaningless for the PA; the difference of two undefined
  36 # symbols is something that is (and must be) supported on the PA.
  37 # The same is true for alpha-vms
  38 #
  39 # The MN10300 port supports link time relaxation which in turn allows
  40 # for link time resolution of the differneces of two symbols which are
  41 # undefined at assembly time.  Hence this test will not pass for the
  42 # MN10300.  The same thing is true for the RX port as well.
  43 if { ![istarget hppa*-*-*]
  44      && ![istarget alpha*-*-*vms*]
  45      && ![istarget rx-*-*]
  46      && ![istarget mn10300-*-*]
  47      && ![istarget am3*-*-*] } then {
  48     gas_test_error "diff1.s" "" "difference of two undefined symbols"
  49 }
  50
  51 gas_test_error "equiv1.s" "" ".equiv for symbol already set to another one"
  52 gas_test_error "equiv2.s" "" ".equiv for symbol already set to an expression"
  53
  54 # .equ works differently on some targets.
  55 case $target_triplet in {
  56     { hppa*-*-* } { }
  57     { *c54x*-*-* } { }
  58     default {
  59         gas_test "equ-ok.s" "" "" ".equ for symbol already set"
  60         gas_test_error "equ-bad.s" "" ".equ for symbol already set through .eqv"
  61     }
  62 }
  63
  64 gas_test "eqv-ok.s" "" "" ".eqv support"
  65 gas_test_error "eqv-bad.s" "" ".eqv for symbol already set"
  66
  67 if { ![istarget "bfin-*-*"] } then {
  68     gas_test "assign-ok.s" "" "" "== assignment support"
  69 }
  70 gas_test_error "assign-bad.s" "" "== assignment for symbol already set"
  71
  72 # .equ works differently on some targets.
  73 # linkrelax-ing prevents most forward references from working.
  74 case $target_triplet in {
  75     { *c54x*-*-* } { }
  76     { cr16*-*-* } { }
  77     { crx*-*-* } { }
  78     { h8300*-*-* } { }
  79     { hppa*-*-* } { }
  80     { mep-*-* } { }
  81     { mn10\[23\]00*-*-* } { }
  82     default {
  83         # Some targets don't manage to resolve BFD_RELOC_8 for constants.
  84         setup_xfail "alpha*-*-*" "*c30*-*-*" "*c4x*-*-*" \
  85             "d\[13\]0v*-*-*" "i860-*-*" "mips*-*-*" "msp430-*-*" \
  86             "pdp11-*-*" "xtensa*-*-*"
  87         run_dump_test forward
  88     }
  89 }
  90
  91 # aout relocs are often weird, so is mep and mips-ecoff. don't bother testing
  92 # som doesn't use a .text section
  93 # mmix doesn't like .L1:
  94 # ti addresses aren't octets.
  95 if { ![is_aout_format] } {
  96     case $target_triplet in {
  97         { hppa*64*-*-* } {
  98             run_dump_test fwdexp
  99         }
 100         { hppa*-*-hpux* } { }
 101         { mep-*-* } { }
 102         { mips*-*-ecoff* } { }
 103         { mmix-*-* } { }
 104         { tic30*-*-* } { }
 105         { tic4x*-*-* } { }
 106         { tic54x*-*-* } { }
 107         default {
 108             run_dump_test fwdexp
 109         }
 110     }
 111 }
 112
 113 # .set works differently on some targets.
 114 # most of the tests won't work on targets that set linkrelax.
 115 # 4 octet bytes confuse address matching on ti targets.
 116 # pdp11 gets unexpected reloc types.
 117 case $target_triplet in {
 118     { alpha*-*-* } { }
 119     { cr16*-*-* } { }
 120     { crx*-*-* } { }
 121     { h8300-*-* } { }
 122     { mips*-*-* } { }
 123     { mn10200-*-* } { }
 124     { mn10300-*-* } { }
 125     { pdp11-*-* } { }
 126     { tic30*-*-* } { }
 127     { tic4x*-*-* } { }
 128     { tic54x*-*-* } { }
 129     { xtensa*-*-* } { }
 130     { z80-*-* } { }
 131     default {
 132         run_dump_test redef
 133         # These targets fail redef2 because they disallow redefined
 134         # symbols on relocs.
 135         setup_xfail "m68hc1*-*-*" "m6811-*-*" "m6812-*-*"
 136         setup_xfail "rx-*-*" "vax*-*-*" "xgate*-*-*" "z8k-*-*"
 137         run_dump_test redef2
 138         setup_xfail "m68hc1*-*-*" "m6811-*-*" "m6812-*-*"
 139         setup_xfail "rx-*-*" "vax*-*-*" "xgate*-*-*" "z8k-*-*"
 140         # rs6000-aix disallows redefinition via .comm.
 141         setup_xfail "*-*-aix*"
 142         # SOM uses a different syntax for .comm
 143         setup_xfail "hppa*-*-hpux*"
 144         # These targets fail redef3 because section contents for the
 145         # word referencing the .comm sym is not zero and/or its reloc
 146         # has a non-zero addend.  Relaxing the test would hide real
 147         # failures such as or32-elf.
 148         setup_xfail "bfin-*-*" "i\[3-7\]86-*-*coff" \
 149             "i\[3-7\]86-*-*pe" "i\[3-7\]86-*-go32*" \
 150             "i\[3-7\]86-*-cygwin*" "i\[3-7\]86-*-mingw*" "x86_64-*-mingw*"
 151         run_dump_test redef3
 152         gas_test_error "redef4.s" "" ".set for symbol already used as label"
 153         gas_test_error "redef5.s" "" ".set for symbol already defined through .comm"
 154     }
 155 }
 156
 157 proc do_comment {} {
 158     set testname "comment.s: comments in listings"
 159     set x1 0
 160     set x2 0
 161     set x3 0
 162     set white {[ \t]*}
 163     gas_start "comment.s" "-al"
 164     while 1 {
 165 # Apparently CRLF is received when using ptys for subprocesses; hence the
 166 # \r\n for line 3.
 167         expect {
 168             -re "^ +1\[ \t\]+# This\[^\n\]*\n"          { set x1 1 }
 169             -re "^ +2\[ \t\]+# correctly\[^\n\]*\n"     { set x2 1 }
 170             -re "^ +3\[ \t\]+/. C comments too. ./\r?\r?\n" { set x3 1 }
 171             -re "\[^\n\]*\n"                            { }
 172             timeout                             { perror "timeout\n"; break }
 173             eof                                 { break }
 174         }
 175     }
 176     gas_finish
 177     if [all_ones $x1 $x2 $x3] then { pass $testname } else { fail $testname }
 178 }
 179
 180 # m32c pads out sections, even empty ones.
 181 case $target_triplet in {
 182     { m32c-*-* } { }
 183     default {
 184         do_comment
 185     }
 186 }
 187
 188 # This test checks the output of the -ag switch. It must detect at least
 189 # the name of the input file, output file, and options passed.
 190 proc general_info_section {} {
 191     set testname "general info section in listings"
 192     set x1 0
 193     set x2 0
 194     set x3 0
 195     set white {[ \t]*}
 196     gas_start "comment.s" "-agn"
 197     while 1 {
 198         expect {
 199             -re "^ \[^\n\]*\t: .*\-agn\[^\n\]*\n"                { set x1 1 }
 200             -re "^ \[^\n\]*\t: \[^\n\]*comment\.s\[^\n\]*\n"   { set x2 1 }
 201             -re "^ \[^\n\]*\t: a\.out\[^\n\]*\n"               { set x3 1 }
 202             -re "\[^\n\]*\n"     { }
 203             timeout              { perror "timeout\n"; break }
 204             eof                  { break }
 205         }
 206     }
 207     gas_finish
 208     if [all_ones $x1 $x2 $x3] then { pass $testname } else { fail $testname }
 209 }
 210
 211 general_info_section
 212
 213 #
 214 # Test x930509a -- correct assembly of differences involving forward
 215 # references.
 216 #
 217
 218 proc do_930509a {} {
 219     set testname "difference between forward references"
 220     set x 0
 221     gas_start "x930509.s" "-al"
 222     while 1 {
 223 # We need to accomodate both byte orders here.
 224 # If ".long" means an 8-byte value on some target someday, this test will have
 225 # to be fixed.
 226         expect {
 227             -re "^ +1 .... 00 ?00 ?00 ?00" { fail $testname; set x 1 }
 228             -re "^ +1 .... 04 ?00 ?00 ?00" { pass $testname; set x 1 }
 229             -re "^ +1 .... 00 ?00 ?00 ?04" { pass $testname; set x 1 }
 230             -re "\[^\n\]*\n" { }
 231             timeout { perror "timeout\n"; break }
 232             eof { break }
 233         }
 234     }
 235     gas_finish
 236     if !$x then { fail $testname }
 237 }
 238
 239 # This test is meaningless for the PA and CR16/CRX: the difference of two
 240 # symbols cannot be resolved by the assembler.
 241 # C54x assembler (for compatibility) does not allow differences between
 242 # forward references.
 243 # C30 counts a four byte offset as a difference of one.
 244 if { ![istarget hppa*-*-*] &&
 245      ![istarget cr16*-*-*] &&
 246      ![istarget  crx*-*-*] &&
 247      ![istarget *c30*-*-*] &&
 248      ![istarget *c4x*-*-*] &&
 249      ![istarget *c54x*-*-*] } then {
 250     # the vax fails because VMS can apparently actually handle this
 251     # case in relocs, so gas doesn't handle it itself.
 252     # mn10300 emits two relocs to handle the difference of two symbols.
 253     setup_xfail "mn10300*-*-*" "vax*-*-vms*"
 254     do_930509a
 255 }
 256
 257 # ".struct" and ".align" have different meanings on c54x
 258 # These directives are done in the c54x-specific tests instead
 259 case $target_triplet in {
 260     { hppa*-*-* } { }
 261     { *c4x*-*-* } { }
 262     { *c54x*-*-* } { }
 263     default {
 264         run_dump_test struct
 265         run_dump_test align
 266         run_dump_test align2
 267     }
 268 }
 269
 270 # '<' and '>' appear to have special meanings on the excluded targets
 271 case $target_triplet in {
 272     { frv-*-* } { }
 273     { hppa*-*-* } { }
 274     { m32r-*-* } { }
 275     { mmix-*-* } { }
 276     { *c4x*-*-* } { }
 277     { *c54x*-*-* } { }
 278     { bfin-*-* } { }
 279     default {
 280         run_dump_test altmacro
 281         # The second test is valid only when '!' is not a comment
 282         # character (it is allowed to be a line comment character).
 283         if [string match "" [lindex [gas_run excl.s "-o /dev/null" ""] 0]] {
 284             run_dump_test altmac2
 285             # Similarly this test does not work when ! is a line seperator.
 286             run_dump_test eval
 287         }
 288     }
 289 }
 290
 291 # This test is for any COFF target.
 292 # We omit the ARM toolchains because they define locals to
 293 #  start with '.', which eliminates .eos, .text etc from the output.
 294 # Omit c54x, since .tag and .def mean something different on that target
 295 if {   ([istarget *-*-coff*] && ![istarget arm*-*-coff] && ![istarget *c4x*-*-coff] && ![istarget *c54x*-*-coff]) \
 296      ||([istarget *-*-pe*] && ![istarget arm*-*-pe*]) \
 297      || [istarget i*86-*-aix*] \
 298      || [istarget i*86-*-sco*] \
 299      || [istarget i*86-*-isc*] \
 300      || [istarget i*86-*-go32*] \
 301      || [istarget i*86-*-cygwin*] \
 302      || [istarget x86_64-*-mingw*] \
 303      || [istarget i*86-*-*nt] \
 304      || [istarget i*86-*-interix*] \
 305      || ([istarget i960-*-vxworks5.*] && ![istarget i960-*-vxworks5.0*]) } {
 306     run_dump_test cofftag
 307 }
 308
 309 # Test omitting conditionals from listings.
 310 proc test_cond {} {
 311     global comp_output
 312     global srcdir
 313     global subdir
 314
 315     set testname "conditional listings"
 316     gas_run cond.s "-alc" ">dump.out"
 317     if ![string match "" $comp_output] {
 318         send_log "$comp_output\n"
 319         fail $testname
 320     } else {
 321         if { [regexp_diff dump.out $srcdir/$subdir/cond.l] } {
 322             fail $testname
 323         } else {
 324             pass $testname
 325         }
 326     }
 327 }
 328
 329 # This test is not suitable for the PA for various reasons
 330 # not limited to the fact that it depends on specific section
 331 # names appearing in the output file.
 332 # again, p2align doesn't work on c54x target
 333 case $target_triplet in {
 334     { hppa*-*-* } { }
 335     { *c4x*-*-* } { }
 336     { *c54x*-*-* } { }
 337     { rx-*-* } { }
 338     default {
 339         test_cond
 340         remote_download host "$srcdir/$subdir/incbin.dat"
 341         run_dump_test incbin
 342     }
 343 }
 344
 345 if {  ([istarget "i*86-*-*pe*"] && ![istarget "i*86-*-openbsd*"]) \
 346     || [istarget "i*86-*-cygwin*"] \
 347     || [istarget "i*86-*-mingw32*"] } {
 348   gas_test "fastcall.s" ""   "" "fastcall labels"
 349 }
 350
 351 if { ![istarget "bfin-*-*"] } then {
 352     run_dump_test assign
 353 }
 354 run_dump_test sleb128
 355
 356 # .byte is 32 bits on tic4x, and .p2align isn't supported on tic54x
 357 # .space is different on hppa*-hpux.
 358 # MeP put bytes into packets.
 359 if { ![istarget "tic4x*-*-*"] && ![istarget "tic54x*-*-*"] && ![istarget "hppa*-*-hpux*"] && ![istarget "mep*-*-*"] } {
 360     run_dump_test relax
 361 }
 362
 363 # powerpc and s390 allow a string argument to .byte
 364 if { ![istarget "powerpc*-*-*"] && ![istarget "rs6000*-*-*"] && ![istarget "s390*-*-*"] } {
 365     run_dump_test byte
 366 }
 367
 368 # .quad is 16 bytes on i960.
 369 if { ![istarget "i960-*-*"] } {
 370     run_dump_test quad
 371 }
 372
 373 # som doesn't use .data section.
 374 case $target_triplet in {
 375     { hppa*64*-*-* } {
 376         run_dump_test octa
 377     }
 378     { hppa*-*-hpux* } { }
 379     default {
 380         run_dump_test octa
 381     }
 382 }
 383
 384 # .set works differently on some targets.
 385 case $target_triplet in {
 386     { alpha*-*-* } { }
 387     { mips*-*-* } { }
 388     { *c54x*-*-* } { }
 389     { z80-*-* } { }
 390     default {
 391         run_dump_test weakref1
 392         run_dump_test weakref1g
 393         run_dump_test weakref1l
 394         run_dump_test weakref1u
 395         run_dump_test weakref1w
 396     }
 397 }
 398 gas_test_error "weakref2.s" "" "e: would close weakref loop: e => a => b => c => d => e"
 399 gas_test_error "weakref3.s" "" "a: would close weakref loop: a => b => c => d => e => a"
 400 gas_test_error "weakref4.s" "" "is already defined"
 401
 402 run_dump_test string
 403 run_dump_test rept
 404
 405 load_lib gas-dg.exp
 406 dg-init
 407 dg-runtest [lsort [glob -nocomplain $srcdir/$subdir/err-*.s $srcdir/$subdir/warn-*.s]] "" ""
 408 dg-finish