gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl Copyright (C) 2019-2020 Advanced Micro Devices, Inc. All rights reserved.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 3 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  48
  49 dnl List of object files and targets accumulated by configure.
  50
  51 CONFIG_OBS=
  52 CONFIG_DEPS=
  53 CONFIG_SRCS=
  54 ENABLE_CFLAGS=
  55
  56 CONFIG_ALL=
  57 CONFIG_CLEAN=
  58 CONFIG_INSTALL=
  59 CONFIG_UNINSTALL=
  60
  61 dnl Set up for gettext.
  62 ZW_GNU_GETTEXT_SISTER_DIR
  63
  64 localedir='${datadir}/locale'
  65 AC_SUBST(localedir)
  66
  67 if test x"$USE_NLS" = xyes; then
  68    CONFIG_ALL="$CONFIG_ALL all-po"
  69    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  70    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  71    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  72 fi
  73
  74 PACKAGE=gdb
  75 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  76 AC_SUBST(PACKAGE)
  77
  78 # We never need to detect it in this sub-configure.
  79 # But preserve it for config.status --recheck.
  80 AC_ARG_VAR(MAKEINFO,
  81   [Parent configure detects if it is of sufficient version.])
  82 AC_ARG_VAR(MAKEINFOFLAGS,
  83   [Parameters for MAKEINFO.])
  84
  85 MAKEINFO_EXTRA_FLAGS=""
  86 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  87   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  88   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  89     gdb_cv_have_makeinfo_click=yes
  90   else
  91     gdb_cv_have_makeinfo_click=no
  92   fi])
  93 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  94   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  95 fi
  96 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  97
  98 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  99     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 100     [${libdir}/debug])
 101
 102 # We can't pass paths as command line arguments.
 103 # Mingw32 tries to be clever and will convert the paths for us.
 104 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 105 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 106 # This breaks GDB's relocatable path conversions since paths passed in
 107 # config.h would not get so translated, the path prefixes no longer match.
 108 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 109
 110 # GDB's datadir relocation
 111
 112 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 113     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 114     [${datadir}/gdb])
 115
 116 AC_ARG_WITH(relocated-sources,
 117 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 118 [reloc_srcdir="${withval}"
 119  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 120               [Relocated directory for source files. ])
 121 ])
 122
 123 AC_MSG_CHECKING([for default auto-load directory])
 124 AC_ARG_WITH(auto-load-dir,
 125 AS_HELP_STRING([--with-auto-load-dir=PATH],
 126   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 127   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 128 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 129 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 130               [Directories from which to load auto-loaded scripts.])
 131 AC_MSG_RESULT([$with_auto_load_dir])
 132
 133 AC_MSG_CHECKING([for default auto-load safe-path])
 134 AC_ARG_WITH(auto-load-safe-path,
 135 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 136   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 137 AS_HELP_STRING([--without-auto-load-safe-path],
 138                [do not restrict auto-loaded files locations]),
 139     [if test "$with_auto_load_safe_path" = "no"; then
 140      with_auto_load_safe_path="/"
 141      fi],
 142 [with_auto_load_safe_path="$with_auto_load_dir"])
 143 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 144 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 145               [Directories safe to hold auto-loaded files.])
 146 AC_MSG_RESULT([$with_auto_load_safe_path])
 147
 148 AC_CONFIG_SUBDIRS(testsuite)
 149
 150 # Check whether to support alternative target configurations
 151 AC_ARG_ENABLE(targets,
 152 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 153 [case "${enableval}" in
 154   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 155             ;;
 156   no)       enable_targets= ;;
 157   *)        enable_targets=$enableval ;;
 158 esac])
 159
 160 # Check whether to enable 64-bit support on 32-bit hosts
 161 AC_ARG_ENABLE(64-bit-bfd,
 162 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 163 [case "${enableval}" in
 164   yes)  want64=true  ;;
 165   no)   want64=false ;;
 166   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 167 esac],[want64=false])dnl
 168
 169 # Provide defaults for some variables set by the per-host and per-target
 170 # configuration.
 171 gdb_host_obs=posix-hdep.o
 172
 173 if test "${target}" = "${host}"; then
 174   gdb_native=yes
 175 else
 176   gdb_native=no
 177 fi
 178
 179 . $srcdir/configure.host
 180
 181 # Accumulate some settings from configure.tgt over all enabled targets
 182
 183 TARGET_OBS=
 184 all_targets=
 185 HAVE_NATIVE_GCORE_TARGET=
 186
 187 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 188 do
 189   if test "$targ_alias" = "all"; then
 190     all_targets=true
 191   else
 192     # Canonicalize the secondary target names.
 193     result=`$ac_config_sub $targ_alias 2>/dev/null`
 194     if test -n "$result"; then
 195         targ=$result
 196     else
 197         targ=$targ_alias
 198     fi
 199
 200     . ${srcdir}/configure.tgt
 201
 202     AS_IF([test -z "${gdb_target_obs}"],
 203       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 204
 205     # Target-specific object files
 206     for i in ${gdb_target_obs}; do
 207         case " $TARGET_OBS " in
 208         *" ${i} "*) ;;
 209         *)
 210           TARGET_OBS="$TARGET_OBS ${i}"
 211           ;;
 212         esac
 213     done
 214
 215     # Check whether this target needs 64-bit CORE_ADDR
 216     if test x${want64} = xfalse; then
 217       . ${srcdir}/../bfd/config.bfd
 218     fi
 219
 220     # Check whether this target is native and supports gcore.
 221     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 222        && $gdb_have_gcore; then
 223       HAVE_NATIVE_GCORE_TARGET=1
 224     fi
 225   fi
 226 done
 227
 228 if test x${all_targets} = xtrue; then
 229
 230   # We want all 64-bit targets if we either:
 231   #  - run on a 64-bit host  or
 232   #  - already require 64-bit support for some other target  or
 233   #  - the --enable-64-bit-bfd option was supplied
 234   # Otherwise we only support all 32-bit targets.
 235   #
 236   # NOTE: This test must be in sync with the corresponding
 237   #       tests in BFD!
 238
 239   if test x${want64} = xfalse; then
 240     AC_CHECK_SIZEOF(long)
 241     if test "x${ac_cv_sizeof_long}" = "x8"; then
 242       want64=true
 243     fi
 244   fi
 245   if test x${want64} = xtrue; then
 246     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 247   else
 248     TARGET_OBS='$(ALL_TARGET_OBS)'
 249   fi
 250 fi
 251
 252 # ROCm dbgapi support.
 253
 254 AC_ARG_WITH(rocm-dbgapi,
 255 AS_HELP_STRING([--with-rocm-dbgapi=PATH],
 256                [specify prefix directory for installed ROCm-dbgapi package]),,
 257   [with_rocm_dbgapi=/opt/rocm])
 258
 259 save_CPPFLAGS=${CPPFLAGS}
 260 CPPFLAGS="${CPPFLAGS} -I$with_rocm_dbgapi/include"
 261 AC_CHECK_HEADERS(amd-dbgapi.h)
 262 CPPFLAGS=${save_CPPFLAGS}
 263
 264 save_LIBS=${LIBS}
 265 save_LDFLAGS=${LDFLAGS}
 266 LDFLAGS="${LDFLAGS} -L$with_rocm_dbgapi/lib"
 267 AC_CHECK_LIB(rocm-dbgapi,amd_dbgapi_initialize)
 268 LDFLAGS=${save_LDFLAGS}
 269 LIBS=${save_LIBS}
 270
 271 if test x"$ac_cv_header_amd_dbgapi_h" = xyes \
 272     -a x"$ac_cv_lib_rocm_dbgapi_amd_dbgapi_initialize" = xyes; then
 273
 274   if test x"$require_rocm_dbgapi" = xyes -o x"$all_targets" = xtrue; then
 275     TARGET_OBS="$TARGET_OBS amdgcn-rocm-tdep.o rocm-tdep.o solib-rocm.o"
 276   fi
 277
 278   CPPFLAGS="${CPPFLAGS} -I$with_rocm_dbgapi/include"
 279   ROCM_DBGAPI_LIBS="-L$with_rocm_dbgapi/lib -lrocm-dbgapi"
 280   AC_SUBST(ROCM_DBGAPI_LIBS)
 281 else
 282   if test x"$require_rocm_dbgapi" = xyes; then
 283     AC_MSG_ERROR([amdgcn*-*-* requires rocm-dbgapi to be installed, or use \
 284 --with-rocm-dbgapi=PATH])
 285   fi
 286 fi
 287
 288 AC_SUBST(TARGET_OBS)
 289 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 290
 291 # For other settings, only the main target counts.
 292 gdb_sim=
 293 gdb_osabi=
 294 build_gdbserver=
 295 targ=$target; . ${srcdir}/configure.tgt
 296
 297 # Fetch the default architecture and default target vector from BFD.
 298 targ=$target; . $srcdir/../bfd/config.bfd
 299
 300 # We only want the first architecture, so strip off the others if
 301 # there is more than one.
 302 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 303
 304 if test "x$targ_archs" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 306     [Define to BFD's default architecture. ])
 307 fi
 308 if test "x$targ_defvec" != x; then
 309   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 310     [Define to BFD's default target vector. ])
 311 fi
 312
 313 # Enable MI.
 314 AC_ARG_ENABLE(gdbmi,
 315 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 316   [case $enableval in
 317     yes | no)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 321   esac],
 322   [enable_gdbmi=yes])
 323 if test x"$enable_gdbmi" = xyes; then
 324   if test -d "$srcdir/mi"; then
 325     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 326     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 327     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 328     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 329   fi
 330 fi
 331
 332 # Enable TUI.
 333 AC_ARG_ENABLE(tui,
 334 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 335   [case $enableval in
 336     yes | no | auto)
 337       ;;
 338     *)
 339       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 340   esac],enable_tui=auto)
 341
 342 # Enable gdbtk.
 343 AC_ARG_ENABLE(gdbtk,
 344 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 345   [case $enableval in
 346     yes | no)
 347       ;;
 348     *)
 349       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 350   esac],
 351   [if test -d "$srcdir/gdbtk"; then
 352     enable_gdbtk=yes
 353   else
 354     enable_gdbtk=no
 355   fi])
 356 # We unconditionally disable gdbtk tests on selected platforms.
 357 case $host_os in
 358   go32* | windows*)
 359     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 360     enable_gdbtk=no ;;
 361 esac
 362
 363 # Libunwind support for ia64.
 364
 365 AC_ARG_WITH(libunwind-ia64,
 366 AS_HELP_STRING([--with-libunwind-ia64],
 367                [use libunwind frame unwinding for ia64 targets]),,
 368             [with_libunwind_ia64=auto])
 369
 370 # Backward compatibility option.
 371 if test "${with_libunwind+set}" = set; then
 372   if test x"$with_libunwind_ia64" != xauto; then
 373     AC_MSG_ERROR(
 374       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 375   fi
 376   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 377   with_libunwind_ia64="$with_libunwind"
 378 fi
 379
 380 case "$with_libunwind_ia64" in
 381   yes | no)
 382     ;;
 383   auto)
 384     AC_CHECK_HEADERS(libunwind-ia64.h)
 385     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 386     ;;
 387   *)
 388     AC_MSG_ERROR(
 389       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 390     ;;
 391 esac
 392
 393 if test x"$with_libunwind_ia64" = xyes; then
 394   AC_CHECK_HEADERS(libunwind-ia64.h)
 395   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 396     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 397   fi
 398   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 399   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 400   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 401 fi
 402
 403 opt_curses=no
 404 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 405
 406 prefer_curses=no
 407 if test "$opt_curses" = "yes"; then
 408   prefer_curses=yes
 409 fi
 410
 411 # Profiling support.
 412 AC_ARG_ENABLE(profiling,
 413 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 414   [case $enableval in
 415     yes | no)
 416       ;;
 417     *)
 418       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 419   esac],
 420  [enable_profiling=no])
 421
 422 AC_CHECK_FUNCS(monstartup _mcleanup)
 423 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 424 [AC_TRY_LINK(
 425 [#include <stdlib.h>
 426 extern char _etext;
 427 ],
 428 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 429 if test "$ac_cv_var__etext" = yes; then
 430   AC_DEFINE(HAVE__ETEXT, 1,
 431             [Define to 1 if your system has the _etext variable. ])
 432 fi
 433 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 434 [AC_TRY_LINK(
 435 [#include <stdlib.h>
 436 extern char etext;
 437 ],
 438 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 439 if test "$ac_cv_var_etext" = yes; then
 440   AC_DEFINE(HAVE_ETEXT, 1,
 441             [Define to 1 if your system has the etext variable. ])
 442 fi
 443 if test "$enable_profiling" = yes ; then
 444   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 445     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 446   fi
 447   PROFILE_CFLAGS=-pg
 448   OLD_CFLAGS="$CFLAGS"
 449   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 450
 451   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 452     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 453      ac_cv_cc_supports_pg=no)])
 454
 455   if test "$ac_cv_cc_supports_pg" = no; then
 456     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 457   fi
 458
 459   CFLAGS="$OLD_CFLAGS"
 460 fi
 461
 462 CODESIGN_CERT=
 463 AC_ARG_ENABLE([codesign],
 464   AS_HELP_STRING([--enable-codesign=CERT],
 465                  [sign gdb with 'codesign -s CERT']),
 466   [CODESIGN_CERT=$enableval])
 467 AC_SUBST([CODESIGN_CERT])
 468
 469 ACX_PKGVERSION([GDB])
 470 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 471 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 472 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 473
 474 # --------------------- #
 475 # Checks for programs.  #
 476 # --------------------- #
 477
 478 AC_PROG_AWK
 479 AC_PROG_INSTALL
 480 AC_PROG_LN_S
 481 AC_PROG_RANLIB
 482 AC_PROG_YACC
 483
 484 AC_CHECK_TOOL(AR, ar)
 485 AC_CHECK_TOOL(DLLTOOL, dlltool)
 486 AC_CHECK_TOOL(WINDRES, windres)
 487
 488 case $host_os in
 489   gnu*)
 490     # Needed for GNU Hurd hosts.
 491     AC_CHECK_TOOL(MIG, mig)
 492     if test x"$MIG" = x; then
 493       AC_MSG_ERROR([MIG not found but required for $host hosts])
 494     fi
 495     ;;
 496 esac
 497
 498 # ---------------------- #
 499 # Checks for libraries.  #
 500 # ---------------------- #
 501
 502 # We might need to link with -lm; most simulators need it.
 503 AC_CHECK_LIB(m, main)
 504
 505 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 506 AC_SEARCH_LIBS(gethostbyname, nsl)
 507
 508 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 509 AC_SEARCH_LIBS(socketpair, socket)
 510
 511 # Link in zlib if we can.  This allows us to read compressed debug sections.
 512 AM_ZLIB
 513
 514 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 515 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 516 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 517   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 518             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 519
 520 # fbsd-nat.c can also use kinfo_getfile.
 521 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 522   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 523             [Define to 1 if your system has the kinfo_getfile function. ])])
 524
 525 AM_ICONV
 526
 527 # GDB may fork/exec the iconv program to get the list of supported character
 528 # sets.  Allow the user to specify where to find it.
 529 # There are several factors affecting the choice of option name:
 530 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 531 #   the build-time location of libiconv files.
 532 # - The program we need to find is iconv, which comes with glibc.  The user
 533 #   doesn't necessarily have libiconv installed.  Therefore naming this
 534 #   --with-libiconv-foo feels wrong.
 535 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 536 #   defined to work on directories not files (though it really doesn't know
 537 #   the difference).
 538 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 539 #   with --with-libiconv-prefix.
 540 # Putting these together is why the option name is --with-iconv-bin.
 541
 542 AC_ARG_WITH(iconv-bin,
 543 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 544 [iconv_bin="${withval}"
 545  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 546                     [Path of directory of iconv program.])
 547  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 548 ])
 549
 550 # For the TUI, we need enhanced curses functionality.
 551 if test x"$enable_tui" != xno; then
 552   prefer_curses=yes
 553 fi
 554
 555 curses_found=no
 556 if test x"$prefer_curses" = xyes; then
 557   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 558   # curses library because the latter might not provide all the
 559   # functionality we need.  However, this leads to problems on systems
 560   # where the linker searches /usr/local/lib, but the compiler doesn't
 561   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 562   # default installation of ncurses on alpha*-dec-osf* will lead to such
 563   # a situation.
 564   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 565
 566   if test "$ac_cv_search_waddstr" != no; then
 567     curses_found=yes
 568   fi
 569 fi
 570
 571 # Check whether we should enable the TUI, but only do so if we really
 572 # can.
 573 if test x"$enable_tui" != xno; then
 574   if test -d "$srcdir/tui"; then
 575     if test "$curses_found" != no; then
 576       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 577       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 578       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 579       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 580     else
 581       if test x"$enable_tui" = xyes; then
 582         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 583       else
 584         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 585       fi
 586     fi
 587   fi
 588 fi
 589
 590 # Since GDB uses Readline, we need termcap functionality.  In many
 591 # cases this will be provided by the curses library, but some systems
 592 # have a separate termcap library, or no curses library at all.
 593
 594 case $host_os in
 595   cygwin*)
 596     if test -d "$srcdir/libtermcap"; then
 597       LIBS="../libtermcap/libtermcap.a $LIBS"
 598       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 599     fi ;;
 600   go32* | *djgpp*)
 601     ac_cv_search_tgetent="none required"
 602     ;;
 603 esac
 604
 605 # These are the libraries checked by Readline.
 606 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 607
 608 if test "$ac_cv_search_tgetent" = no; then
 609   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 610 fi
 611
 612 AC_ARG_WITH([system-readline],
 613   [AS_HELP_STRING([--with-system-readline],
 614                   [use installed readline library])])
 615
 616 if test "$with_system_readline" = yes; then
 617    AC_CACHE_CHECK([whether system readline is new enough],
 618      [gdb_cv_readline_ok],
 619      [AC_TRY_COMPILE(
 620        [#include <stdio.h>
 621 #include <readline/readline.h>],
 622        [#if RL_VERSION_MAJOR < 7
 623 # error "readline version 7 required"
 624 #endif],
 625     gdb_cv_readline_ok=yes,
 626     gdb_cv_readline_ok=no)])
 627   if test "$gdb_cv_readline_ok" != yes; then
 628     AC_MSG_ERROR([system readline is not new enough])
 629   fi
 630
 631   READLINE=-lreadline
 632   READLINE_DEPS=
 633   READLINE_CFLAGS=
 634   READLINE_TEXI_INCFLAG=
 635 else
 636   READLINE='$(READLINE_DIR)/libreadline.a'
 637   READLINE_DEPS='$(READLINE)'
 638   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 639   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 640 fi
 641 AC_SUBST(READLINE)
 642 AC_SUBST(READLINE_DEPS)
 643 AC_SUBST(READLINE_CFLAGS)
 644 AC_SUBST(READLINE_TEXI_INCFLAG)
 645
 646 # Generate jit-reader.h
 647
 648 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 649 TARGET_PTR=
 650
 651 AC_CHECK_SIZEOF(unsigned long long)
 652 AC_CHECK_SIZEOF(unsigned long)
 653 AC_CHECK_SIZEOF(unsigned __int128)
 654
 655 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 656   TARGET_PTR="unsigned long"
 657 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 658   TARGET_PTR="unsigned long long"
 659 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 660   TARGET_PTR="unsigned __int128"
 661 else
 662   TARGET_PTR="unsigned long"
 663 fi
 664
 665 AC_SUBST(TARGET_PTR)
 666 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 667
 668 AC_SEARCH_LIBS(dlopen, dl)
 669
 670 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 671                 [directory to load the JIT readers from],
 672                 [${libdir}/gdb])
 673
 674 AC_ARG_WITH(expat,
 675   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 676   [], [with_expat=auto])
 677 AC_MSG_CHECKING([whether to use expat])
 678 AC_MSG_RESULT([$with_expat])
 679
 680 if test "${with_expat}" = no; then
 681   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 682   HAVE_LIBEXPAT=no
 683 else
 684   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 685                         [XML_Parser p = XML_ParserCreate (0);])
 686   if test "$HAVE_LIBEXPAT" != yes; then
 687     if test "$with_expat" = yes; then
 688       AC_MSG_ERROR([expat is missing or unusable])
 689     else
 690       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 691     fi
 692   else
 693     save_LIBS=$LIBS
 694     LIBS="$LIBS $LIBEXPAT"
 695     AC_CHECK_FUNCS(XML_StopParser)
 696     LIBS=$save_LIBS
 697   fi
 698 fi
 699
 700 AC_ARG_WITH(mpfr,
 701   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 702   [], [with_mpfr=auto])
 703 AC_MSG_CHECKING([whether to use MPFR])
 704 AC_MSG_RESULT([$with_mpfr])
 705
 706 if test "${with_mpfr}" = no; then
 707   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 708   HAVE_LIBMPFR=no
 709 else
 710   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 711                         [mpfr_exp_t exp; mpfr_t x;
 712                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 713   if test "$HAVE_LIBMPFR" != yes; then
 714     if test "$with_mpfr" = yes; then
 715       AC_MSG_ERROR([MPFR is missing or unusable])
 716     else
 717       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 718     fi
 719   fi
 720 fi
 721
 722 # --------------------- #
 723 # Check for libpython.  #
 724 # --------------------- #
 725
 726 dnl Utility to simplify finding libpython.
 727 dnl $1 = the shell variable to assign the result to
 728 dnl      If libpython is found we store $version here.
 729 dnl $2 = additional flags to add to CPPFLAGS
 730 dnl $3 = additional flags to add to LIBS
 731
 732 AC_DEFUN([AC_TRY_LIBPYTHON],
 733 [
 734   define([have_libpython_var],$1)
 735   new_CPPFLAGS=$2
 736   new_LIBS=$3
 737   AC_MSG_CHECKING([for python])
 738   save_CPPFLAGS=$CPPFLAGS
 739   save_LIBS=$LIBS
 740   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 741   LIBS="$new_LIBS $LIBS"
 742   found_usable_python=no
 743   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 744                                  [[Py_Initialize ();]])],
 745                  [have_libpython_var=yes
 746                   found_usable_python=yes
 747                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 748                   PYTHON_LIBS=$new_LIBS])
 749   CPPFLAGS=$save_CPPFLAGS
 750   LIBS=$save_LIBS
 751   AC_MSG_RESULT([${found_usable_python}])
 752 ])
 753
 754 dnl There are several different values for --with-python:
 755 dnl
 756 dnl no -   Don't include python support.
 757 dnl yes -  Include python support, error if it's missing.
 758 dnl        If we find python in $PATH, use it to fetch configure options,
 759 dnl        otherwise assume the compiler can find it with no help from us.
 760 dnl        Python 2.7 and 2.6 are tried in turn.
 761 dnl auto - Same as "yes", but if python is missing from the system,
 762 dnl        fall back to "no".
 763 dnl /path/to/python/exec-prefix -
 764 dnl        Use the python located in this directory.
 765 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 766 dnl        the compilation parameters.  Otherwise use
 767 dnl        -I/path/to/python/exec-prefix/include,
 768 dnl        -L/path/to/python/exec-prefix/lib.
 769 dnl        Python 2.7 and 2.6 are tried in turn.
 770 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 771 dnl        but is deprecated.
 772 dnl /path/to/python/executable -
 773 dnl        Run python-config.py with this version of python to fetch the
 774 dnl        compilation parameters.
 775 dnl        NOTE: This needn't be the real python executable.
 776 dnl        In a cross-compilation scenario (build != host), this could be
 777 dnl        a shell script that provides what python-config.py provides for
 778 dnl        --ldflags, --includes, --exec-prefix.
 779 dnl python-executable -
 780 dnl        Find python-executable in $PATH, and then handle the same as
 781 dnl        /path/to/python/executable.
 782 dnl
 783 dnl If a python program is specified, it is used to run python-config.py and
 784 dnl is passed --ldflags, --includes, --exec-prefix.
 785
 786 AC_ARG_WITH(python,
 787   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 788   [], [with_python=auto])
 789 AC_MSG_CHECKING([whether to use python])
 790 AC_MSG_RESULT([$with_python])
 791
 792 if test "${with_python}" = no; then
 793   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 794   have_libpython=no
 795 else
 796   case "${with_python}" in
 797   [[\\/]]* | ?:[[\\/]]*)
 798     if test -d "${with_python}"; then
 799       # Assume the python binary is ${with_python}/bin/python.
 800       python_prog="${with_python}/bin/python"
 801       python_prefix=
 802       # If python does not exit ${with_python}/bin, then try in
 803       # ${with_python}.  On Windows/MinGW, this is where the Python
 804       # executable is.
 805       if test ! -x "${python_prog}"; then
 806         python_prog="${with_python}/python"
 807         python_prefix=
 808       fi
 809       if test ! -x "${python_prog}"; then
 810         # Fall back to gdb 7.0/7.1 behaviour.
 811         python_prog=missing
 812         python_prefix=${with_python}
 813       fi
 814     elif test -x "${with_python}"; then
 815       # While we can't run python compiled for $host (unless host == build),
 816       # the user could write a script that provides the needed information,
 817       # so we support that.
 818       python_prog=${with_python}
 819       python_prefix=
 820     else
 821       AC_ERROR(invalid value for --with-python)
 822     fi
 823     ;;
 824   */*)
 825     # Disallow --with-python=foo/bar.
 826     AC_ERROR(invalid value for --with-python)
 827     ;;
 828   *)
 829     # The user has either specified auto, yes, or the name of the python
 830     # program assumed to be in $PATH.
 831     python_prefix=
 832     case "${with_python}" in
 833     yes | auto)
 834       if test "${build}" = "${host}"; then
 835         AC_PATH_PROG(python_prog_path, python, missing)
 836         if test "${python_prog_path}" = missing; then
 837           python_prog=missing
 838         else
 839           python_prog=${python_prog_path}
 840         fi
 841       else
 842         # Not much we can do except assume the cross-compiler will find the
 843         # right files.
 844         python_prog=missing
 845       fi
 846       ;;
 847     *)
 848       # While we can't run python compiled for $host (unless host == build),
 849       # the user could write a script that provides the needed information,
 850       # so we support that.
 851       python_prog="${with_python}"
 852       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 853       if test "${python_prog_path}" = missing; then
 854         AC_ERROR(unable to find python program ${python_prog})
 855       fi
 856       ;;
 857     esac
 858   esac
 859
 860   if test "${python_prog}" != missing; then
 861     # We have a python program to use, but it may be too old.
 862     # Don't flag an error for --with-python=auto (the default).
 863     have_python_config=yes
 864     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 865     if test $? != 0; then
 866       have_python_config=failed
 867       if test "${with_python}" != auto; then
 868         AC_ERROR(failure running python-config --includes)
 869       fi
 870     fi
 871     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 872     if test $? != 0; then
 873       have_python_config=failed
 874       if test "${with_python}" != auto; then
 875         AC_ERROR(failure running python-config --ldflags)
 876       fi
 877     fi
 878     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 879     if test $? != 0; then
 880       have_python_config=failed
 881       if test "${with_python}" != auto; then
 882         AC_ERROR(failure running python-config --exec-prefix)
 883       fi
 884     fi
 885   else
 886     # We do not have a python executable we can use to determine where
 887     # to find the Python headers and libs.  We cannot guess the include
 888     # path from the python_prefix either, because that include path
 889     # depends on the Python version.  So, there is nothing much we can
 890     # do except assume that the compiler will be able to find those files.
 891     python_includes=
 892     python_libs=
 893     have_python_config=no
 894   fi
 895
 896   # If we have python-config, only try the configuration it provides.
 897   # Otherwise fallback on the old way of trying different versions of
 898   # python in turn.
 899
 900   have_libpython=no
 901   if test "${have_python_config}" = yes; then
 902     AC_TRY_LIBPYTHON(have_libpython,
 903                      ${python_includes}, ${python_libs})
 904   elif test "${have_python_config}" != failed; then
 905     if test "${have_libpython}" = no; then
 906       AC_TRY_LIBPYTHON(have_libpython,
 907                        ${python_includes}, "-lpython2.7 ${python_libs}")
 908     fi
 909     if test "${have_libpython}" = no; then
 910       AC_TRY_LIBPYTHON(have_libpython,
 911                        ${python_includes}, "-lpython2.6 ${python_libs}")
 912     fi
 913   fi
 914
 915   if test "${have_libpython}" = no; then
 916     case "${with_python}" in
 917     yes)
 918       AC_MSG_ERROR([python is missing or unusable])
 919       ;;
 920     auto)
 921       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 922       ;;
 923     *)
 924       AC_MSG_ERROR([no usable python found at ${with_python}])
 925       ;;
 926     esac
 927   else
 928     if test -n "${python_prefix}"; then
 929       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 930                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 931       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 932     fi
 933   fi
 934 fi
 935
 936 if test "${have_libpython}" != no; then
 937   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 938   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 939   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 940   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 941   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 942   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 943
 944   # Flags needed to compile Python code (taken from python-config --cflags).
 945   # We cannot call python-config directly because it will output whatever was
 946   # used when compiling the Python interpreter itself, including flags which
 947   # would make the python-related objects be compiled differently from the
 948   # rest of GDB (e.g., -O2 and -fPIC).
 949   if test "${GCC}" = yes; then
 950     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 951     # Python headers recommend -DNDEBUG, but it's unclear if that just
 952     # refers to building Python itself.  In release mode, though, it
 953     # doesn't hurt for the Python code in gdb to follow.
 954     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 955   fi
 956
 957   if test "x${tentative_python_cflags}" != x; then
 958     AC_MSG_CHECKING(compiler flags for python code)
 959     for flag in ${tentative_python_cflags}; do
 960       # Check that the compiler accepts it
 961       saved_CFLAGS="$CFLAGS"
 962       CFLAGS="$CFLAGS $flag"
 963       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 964       CFLAGS="$saved_CFLAGS"
 965     done
 966     AC_MSG_RESULT(${PYTHON_CFLAGS})
 967   fi
 968
 969   # On x64 Windows, Python's include headers, and pyconfig.h in
 970   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 971   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 972   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 973   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 974   # The issue was reported to the Python community, but still isn't
 975   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 976
 977   case "$gdb_host" in
 978     mingw64)
 979            if test "${GCC}" = yes; then
 980              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 981            fi
 982            ;;
 983   esac
 984 else
 985   # Even if Python support is not compiled in, we need to have this file
 986   # included so that the "python" command, et.al., still exists.
 987   CONFIG_OBS="$CONFIG_OBS python/python.o"
 988   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 989 fi
 990
 991 # Work around Python http://bugs.python.org/issue10112.  See also
 992 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 993 # no effect.  Note that the only test after this that uses Python is
 994 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 995 # run without -export-dynamic too.
 996 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 997
 998 AC_SUBST(PYTHON_CFLAGS)
 999 AC_SUBST(PYTHON_CPPFLAGS)
1000 AC_SUBST(PYTHON_LIBS)
1001 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1002
1003 # -------------------- #
1004 # Check for libguile.  #
1005 # -------------------- #
1006
1007 dnl Utility to simplify finding libguile.
1008 dnl $1 = pkg-config-program
1009 dnl $2 = space-separate list of guile versions to try
1010 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1011 dnl $4 = the shell variable to assign the result to
1012 dnl      If libguile is found we store "yes" here.
1013
1014 AC_DEFUN([AC_TRY_LIBGUILE],
1015 [
1016   pkg_config=$1
1017   guile_version_list=$2
1018   flag_errors=$3
1019   define([have_libguile_var],$4)
1020   found_usable_guile=checking
1021   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1022   for guile_version in ${guile_version_list}; do
1023     ${pkg_config} --exists ${guile_version} 2>/dev/null
1024     if test $? != 0; then
1025       continue
1026     fi
1027     dnl pkg-config says the package exists, so if we get an error now,
1028     dnl that's bad.
1029     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1030     if test $? != 0; then
1031       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1032     fi
1033     new_LIBS=`${pkg_config} --libs ${guile_version}`
1034     if test $? != 0; then
1035       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1036     fi
1037     dnl If we get this far, great.
1038     found_usable_guile=${guile_version}
1039     break
1040   done
1041   if test "${found_usable_guile}" = "checking"; then
1042     if test "${flag_errors}" = "yes"; then
1043       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1044     else
1045       found_usable_guile=no
1046     fi
1047   fi
1048   dnl One final sanity check.
1049   dnl The user could have said --with-guile=python-2.7.
1050   if test "${found_usable_guile}" != no; then
1051     save_CPPFLAGS=$CPPFLAGS
1052     save_LIBS=$LIBS
1053     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1054     LIBS="$LIBS $new_LIBS"
1055     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1056                                    [[scm_init_guile ();]])],
1057                    [have_libguile_var=yes
1058                     GUILE_CPPFLAGS=$new_CPPFLAGS
1059                     GUILE_LIBS=$new_LIBS],
1060                    [found_usable_guile=no])
1061     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1062     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1063       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1064                 [Define if Guile supports manual finalization.])
1065     )
1066     CPPFLAGS=$save_CPPFLAGS
1067     LIBS=$save_LIBS
1068     if test "${found_usable_guile}" = no; then
1069       if test "${flag_errors}" = yes; then
1070         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1071       fi
1072     fi
1073   fi
1074   AC_MSG_RESULT([${found_usable_guile}])
1075 ])
1076
1077 dnl There are several different values for --with-guile:
1078 dnl
1079 dnl no -   Don't include guile support.
1080 dnl yes -  Include guile support, error if it's missing.
1081 dnl        The pkg-config program must be in $PATH.
1082 dnl auto - Same as "yes", but if guile is missing from the system,
1083 dnl        fall back to "no".
1084 dnl guile-version [guile-version-choice-2 ...] -
1085 dnl        A space-separated list of guile package versions to try.
1086 dnl        These are passed to pkg-config as-is.
1087 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1088 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1089 dnl /path/to/pkg-config -
1090 dnl        Use this pkg-config program.
1091 dnl        NOTE: This needn't be the "real" pkg-config program.
1092 dnl        It could be a shell script.  It is invoked as:
1093 dnl        pkg-config --exists $version
1094 dnl        pkg-config --cflags $version
1095 dnl        pkg-config --libs $version
1096 dnl        pkg-config --variable guild $version
1097 dnl        The script will be called with $version having each value in
1098 dnl        $try_guile_versions until --exists indicates success.
1099
1100 AC_ARG_WITH(guile,
1101   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1102   [], [with_guile=auto])
1103 AC_MSG_CHECKING([whether to use guile])
1104 AC_MSG_RESULT([$with_guile])
1105
1106 dnl We check guile with pkg-config.
1107 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1108
1109 try_guile_versions="guile-2.0"
1110 have_libguile=no
1111 case "${with_guile}" in
1112 no)
1113   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1114   ;;
1115 auto)
1116   if test "${pkg_config_prog_path}" = "missing"; then
1117     AC_MSG_WARN([pkg-config not found, guile support disabled])
1118   else
1119     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1120   fi
1121   ;;
1122 yes)
1123   if test "${pkg_config_prog_path}" = "missing"; then
1124     AC_MSG_ERROR([pkg-config not found])
1125   fi
1126   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1127   ;;
1128 [[\\/]]* | ?:[[\\/]]*)
1129   if test -x "${with_guile}"; then
1130     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1131   else
1132     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1133   fi
1134   ;;
1135 "" | */*)
1136   # Disallow --with=guile="" and --with-guile=foo/bar.
1137   AC_MSG_ERROR([invalid value for --with-guile])
1138   ;;
1139 *)
1140   # A space separate list of guile versions to try, in order.
1141   if test "${pkg_config_prog_path}" = "missing"; then
1142     AC_MSG_ERROR([pkg-config not found])
1143   fi
1144   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1145   ;;
1146 esac
1147
1148 if test "${have_libguile}" != no; then
1149   dnl Get the name of the 'guild' program.
1150   case "${with_guile}" in
1151   [[\\/]]* | ?:[[\\/]]*)
1152     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1153     ;;
1154   *)
1155     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1156     ;;
1157   esac
1158
1159   dnl Make sure guild can handle this host.
1160   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1161   dnl If not, disable guile support.
1162   if test "$ac_cv_guild_ok" = no; then
1163     have_libguile=no
1164     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1165   fi
1166 fi
1167
1168 if test "${have_libguile}" != no; then
1169   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1170   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1171   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1172   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1173   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1174   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1175
1176   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1177   save_LIBS="$LIBS"
1178   save_CPPFLAGS="$CPPFLAGS"
1179   LIBS="$GUILE_LIBS"
1180   CPPFLAGS="$GUILE_CPPFLAGS"
1181   AC_CHECK_FUNCS([scm_new_smob])
1182   LIBS="$save_LIBS"
1183   CPPFLAGS="$save_CPPFLAGS"
1184 else
1185   # Even if Guile support is not compiled in, we need to have these files
1186   # included.
1187   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1188   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1189 fi
1190 AC_SUBST(GUILE_CPPFLAGS)
1191 AC_SUBST(GUILE_LIBS)
1192 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1193
1194 # ---------------------------- #
1195 # Check for source highlight.  #
1196 # ---------------------------- #
1197
1198 SRCHIGH_LIBS=
1199 SRCHIGH_CFLAGS=
1200
1201 AC_ARG_ENABLE(source-highlight,
1202   AS_HELP_STRING([--enable-source-highlight],
1203     [enable source-highlight for source listings]),
1204   [case "${enableval}" in
1205   yes)  enable_source_highlight=yes ;;
1206   no)   enable_source_highlight=no  ;;
1207   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1208 esac],
1209 [enable_source_highlight=auto])
1210
1211 if test "${enable_source_highlight}" != "no"; then
1212   AC_MSG_CHECKING([for the source-highlight library])
1213   if test "${pkg_config_prog_path}" = "missing"; then
1214     AC_MSG_RESULT([no - pkg-config not found])
1215     if test "${enable_source_highlight}" = "yes"; then
1216       AC_MSG_ERROR([pkg-config was not found in your system])
1217     fi
1218   else
1219     case "$LDFLAGS" in
1220       *static-libstdc*)
1221         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1222 either use --disable-source-highlight or dnl
1223 --without-static-standard-libraries])
1224         ;;
1225     esac
1226
1227     if ${pkg_config_prog_path} --exists source-highlight; then
1228       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1229       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1230       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1231                 [Define to 1 if the source-highlight library is available])
1232       AC_MSG_RESULT([yes])
1233     else
1234       AC_MSG_RESULT([no])
1235       if test "${enable_source_highlight}" = "yes"; then
1236         AC_MSG_ERROR([source-highlight was not found in your system])
1237       fi
1238     fi
1239   fi
1240 fi
1241 AC_SUBST(SRCHIGH_LIBS)
1242 AC_SUBST(SRCHIGH_CFLAGS)
1243
1244 AC_ARG_WITH(intel_pt,
1245   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1246   [], [with_intel_pt=auto])
1247 AC_MSG_CHECKING([whether to use intel pt])
1248 AC_MSG_RESULT([$with_intel_pt])
1249
1250 if test "${with_intel_pt}" = no; then
1251   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1252   HAVE_LIBIPT=no
1253 else
1254   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1255 #include <linux/perf_event.h>
1256 #ifndef PERF_ATTR_SIZE_VER5
1257 # error
1258 #endif
1259   ]])], [perf_event=yes], [perf_event=no])
1260   if test "$perf_event" != yes; then
1261     if test "$with_intel_pt" = yes; then
1262       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1263     else
1264       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1265     fi
1266   fi
1267
1268   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1269   if test "$HAVE_LIBIPT" != yes; then
1270     if test "$with_intel_pt" = yes; then
1271       AC_MSG_ERROR([libipt is missing or unusable])
1272     else
1273       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1274     fi
1275   else
1276     save_LIBS=$LIBS
1277     LIBS="$LIBS $LIBIPT"
1278     AC_CHECK_FUNCS(pt_insn_event)
1279     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1280                      [#include <intel-pt.h>])
1281     LIBS=$save_LIBS
1282   fi
1283 fi
1284
1285 # ------------------------- #
1286 # Checks for header files.  #
1287 # ------------------------- #
1288
1289 AC_HEADER_STDC
1290 # elf_hp.h is for HP/UX 64-bit shared library support.
1291 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1292                   thread_db.h linux/elf.h \
1293                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1294                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1295                   sys/reg.h sys/debugreg.h sys/select.h \
1296                   termios.h elf_hp.h])
1297 AC_CHECK_HEADERS(sys/user.h, [], [],
1298 [#if HAVE_SYS_PARAM_H
1299 # include <sys/param.h>
1300 #endif
1301 ])
1302
1303 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1304 AC_CHECK_HEADERS(term.h, [], [],
1305 [#if HAVE_CURSES_H
1306 # include <curses.h>
1307 #endif
1308 ])
1309
1310 # ------------------------- #
1311 # Checks for declarations.  #
1312 # ------------------------- #
1313
1314 libiberty_INIT
1315
1316 AC_CHECK_DECLS([snprintf])
1317 AM_LC_MESSAGES
1318
1319 # ----------------------- #
1320 # Checks for structures.  #
1321 # ----------------------- #
1322
1323 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1324
1325 # ------------------ #
1326 # Checks for types.  #
1327 # ------------------ #
1328
1329 AC_CHECK_TYPES(socklen_t, [], [],
1330 [#include <sys/types.h>
1331 #include <sys/socket.h>
1332 ])
1333
1334 # ------------------------------------- #
1335 # Checks for compiler characteristics.  #
1336 # ------------------------------------- #
1337
1338 AC_C_CONST
1339 AC_C_INLINE
1340 AC_C_BIGENDIAN
1341
1342 # ------------------------------ #
1343 # Checks for library functions.  #
1344 # ------------------------------ #
1345
1346 AC_FUNC_MMAP
1347 AC_FUNC_VFORK
1348 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1349                 pipe poll pread pread64 pwrite resize_term \
1350                 sbrk getpgid setpgid setpgrp setsid \
1351                 sigaction sigsetmask socketpair \
1352                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1353                 setrlimit getrlimit posix_madvise waitpid \
1354                 ptrace64 sigaltstack setns use_default_colors])
1355 AM_LANGINFO_CODESET
1356 GDB_AC_COMMON
1357
1358 # Check the return and argument types of ptrace.
1359 GDB_AC_PTRACE
1360
1361 dnl AC_FUNC_SETPGRP does not work when cross compiling
1362 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1363 if test "$cross_compiling" = no; then
1364   AC_FUNC_SETPGRP
1365 else
1366   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1367     [AC_TRY_COMPILE([
1368 #include <unistd.h>
1369 ], [
1370   if (setpgrp(1,1) == -1)
1371     exit (0);
1372   else
1373     exit (1);
1374 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1375 if test "$ac_cv_func_setpgrp_void" = yes; then
1376   AC_DEFINE(SETPGRP_VOID, 1)
1377 fi
1378 fi
1379
1380 # Assume we'll default to using the included libiberty regex.
1381 gdb_use_included_regex=yes
1382
1383 # However, if the system regex is GNU regex, then default to *not*
1384 # using the included regex.
1385 AC_CACHE_CHECK(
1386   [for GNU regex],
1387   [gdb_cv_have_gnu_regex],
1388   [AC_TRY_COMPILE(
1389     [#include <gnu-versions.h>],
1390     [#define REGEX_INTERFACE_VERSION 1
1391 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1392 # error "Version mismatch"
1393 #endif],
1394     gdb_cv_have_gnu_regex=yes,
1395     gdb_cv_have_gnu_regex=no)])
1396 if test "$gdb_cv_have_gnu_regex" = yes; then
1397   gdb_use_included_regex=no
1398 fi
1399
1400 AC_ARG_WITH(included-regex,
1401   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1402   gdb_with_regex=$withval,
1403   gdb_with_regex=$gdb_use_included_regex)
1404 if test "$gdb_with_regex" = yes; then
1405   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1406     [Define to 1 if the regex included in libiberty should be used.])
1407 fi
1408
1409 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1410 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1411 [#include <sys/param.h>
1412 #include <sys/proc.h>
1413 ])
1414
1415 # See if <sys/lwp.h> defines `struct lwp`.
1416 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1417 [AC_TRY_COMPILE([#include <sys/param.h>
1418 #define _KMEMUSER
1419 #include <sys/lwp.h>], [struct lwp l;],
1420 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1421 if test "$gdb_cv_struct_lwp" = yes; then
1422   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1423             [Define to 1 if your system has struct lwp.])
1424 fi
1425
1426 # See if <machine/reg.h> degines `struct reg'.
1427 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1428 [AC_TRY_COMPILE([#include <sys/types.h>
1429 #include <machine/reg.h>], [struct reg r;],
1430 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1431 if test "$gdb_cv_struct_reg" = yes; then
1432   AC_DEFINE(HAVE_STRUCT_REG, 1,
1433             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1434 fi
1435
1436 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1437 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1438 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1439                  [#include <sys/types.h>
1440 #include <machine/reg.h>])
1441
1442 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1443 # Older amd64 Linux's don't have the fs_base and gs_base members of
1444 # `struct user_regs_struct'.
1445 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1446      [], [], [#include <sys/types.h>
1447 #include <sys/user.h>])
1448
1449 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1450 AC_MSG_CHECKING(for PTRACE_GETREGS)
1451 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1452 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1453                 [PTRACE_GETREGS;],
1454                 [gdb_cv_have_ptrace_getregs=yes],
1455                 [gdb_cv_have_ptrace_getregs=no])])
1456 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1457 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1458   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1459   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1460 fi
1461
1462 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1463 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1464 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1465 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1466                 [PTRACE_GETFPXREGS;],
1467                 [gdb_cv_have_ptrace_getfpxregs=yes],
1468                 [gdb_cv_have_ptrace_getfpxregs=no])])
1469 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1470 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1471   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1472   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1473 fi
1474
1475 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1476 AC_MSG_CHECKING(for PT_GETDBREGS)
1477 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1478 [AC_TRY_COMPILE([#include <sys/types.h>
1479 #include <sys/ptrace.h>],
1480                 [PT_GETDBREGS;],
1481                 [gdb_cv_have_pt_getdbregs=yes],
1482                 [gdb_cv_have_pt_getdbregs=no])])
1483 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1484 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1485   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1486   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1487 fi
1488
1489 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1490 AC_MSG_CHECKING(for PT_GETXMMREGS)
1491 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1492 [AC_TRY_COMPILE([#include <sys/types.h>
1493 #include <sys/ptrace.h>],
1494                 [PT_GETXMMREGS;],
1495                 [gdb_cv_have_pt_getxmmregs=yes],
1496                 [gdb_cv_have_pt_getxmmregs=no])])
1497 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1498 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1499   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1500   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1501 fi
1502
1503 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1504 # Older FreeBSD versions don't have the pl_tdname member of
1505 # `struct ptrace_lwpinfo'.
1506 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1507                  [#include <sys/ptrace.h>])
1508
1509 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1510 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1511 # FreeBSD 10.3.
1512 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1513                  [#include <sys/ptrace.h>])
1514
1515 if test "$ac_cv_header_sys_procfs_h" = yes; then
1516   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1517   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1518   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1519   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1520   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1521   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1522   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1523   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
1524 fi
1525
1526 # Check if the compiler supports the `long long' type.
1527
1528 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1529                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1530 [[extern long long foo;]],
1531 [[switch (foo & 2) { case 0: return 1; }]])],
1532                                   gdb_cv_c_long_long=yes,
1533                                   gdb_cv_c_long_long=no)])
1534 if test "$gdb_cv_c_long_long" != yes; then
1535   # libdecnumber requires long long.
1536   AC_MSG_ERROR([Compiler must support long long for GDB.])
1537 fi
1538
1539 # Check if the compiler and runtime support printing long longs.
1540
1541 AC_CACHE_CHECK([for long long support in printf],
1542                gdb_cv_printf_has_long_long,
1543                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1544 [[char buf[32];
1545   long long l = 0;
1546   l = (l << 16) + 0x0123;
1547   l = (l << 16) + 0x4567;
1548   l = (l << 16) + 0x89ab;
1549   l = (l << 16) + 0xcdef;
1550   sprintf (buf, "0x%016llx", l);
1551   return (strcmp ("0x0123456789abcdef", buf));]])],
1552                               gdb_cv_printf_has_long_long=yes,
1553                               gdb_cv_printf_has_long_long=no,
1554                               gdb_cv_printf_has_long_long=no)])
1555 if test "$gdb_cv_printf_has_long_long" = yes; then
1556   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1557             [Define to 1 if the "%ll" format works to print long longs.])
1558 fi
1559
1560 # Check if the compiler and runtime support printing decfloats.
1561
1562 AC_CACHE_CHECK([for decfloat support in printf],
1563                gdb_cv_printf_has_decfloat,
1564                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1565 [[char buf[64];
1566   _Decimal32 d32 = 1.2345df;
1567   _Decimal64 d64 = 1.2345dd;
1568   _Decimal128 d128 = 1.2345dl;
1569   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1570   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1571                               gdb_cv_printf_has_decfloat=yes,
1572                               gdb_cv_printf_has_decfloat=no,
1573                               gdb_cv_printf_has_decfloat=no)])
1574 if test "$gdb_cv_printf_has_decfloat" = yes; then
1575   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1576             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1577 fi
1578
1579 # Check if the compiler supports the `long double' type.  We can't use
1580 # AC_C_LONG_DOUBLE because that one does additional checks on the
1581 # constants defined in <float.h> that fail on some systems,
1582 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1583
1584 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1585                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1586                                   gdb_cv_c_long_double=yes,
1587                                   gdb_cv_c_long_double=no)])
1588 if test "$gdb_cv_c_long_double" = yes; then
1589   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1590            [Define to 1 if the compiler supports long double.])
1591 fi
1592
1593 # Check if the compiler and runtime support printing long doubles.
1594
1595 AC_CACHE_CHECK([for long double support in printf],
1596                gdb_cv_printf_has_long_double,
1597                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1598 [[char buf[16];
1599   long double f = 3.141592653;
1600   sprintf (buf, "%Lg", f);
1601   return (strncmp ("3.14159", buf, 7));]])],
1602                               gdb_cv_printf_has_long_double=yes,
1603                               gdb_cv_printf_has_long_double=no,
1604                               gdb_cv_printf_has_long_double=no)])
1605 if test "$gdb_cv_printf_has_long_double" = yes; then
1606   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1607             [Define to 1 if the "%Lg" format works to print long doubles.])
1608 fi
1609
1610 # Check if the compiler and runtime support scanning long doubles.
1611
1612 AC_CACHE_CHECK([for long double support in scanf],
1613                gdb_cv_scanf_has_long_double,
1614                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1615 [[#include <stdio.h>]],
1616 [[char *buf = "3.141592653";
1617   long double f = 0;
1618   sscanf (buf, "%Lg", &f);
1619   return !(f > 3.14159 && f < 3.14160);]])],
1620                               gdb_cv_scanf_has_long_double=yes,
1621                               gdb_cv_scanf_has_long_double=no,
1622                               gdb_cv_scanf_has_long_double=no)])
1623 if test "$gdb_cv_scanf_has_long_double" = yes; then
1624   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1625             [Define to 1 if the "%Lg" format works to scan long doubles.])
1626 fi
1627
1628 case ${host_os} in
1629 aix*)
1630   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1631     SAVE_LDFLAGS=$LDFLAGS
1632
1633     case $GCC in
1634     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1635     *) gdb_cv_bigtoc=-bbigtoc ;;
1636     esac
1637
1638     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1639     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1640     LDFLAGS="${SAVE_LDFLAGS}"
1641   ])
1642   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1643   ;;
1644 esac
1645
1646 AC_MSG_CHECKING(for the dynamic export flag)
1647 dynamic_list=false
1648 if test "${gdb_native}" = yes; then
1649    # The dynamically loaded libthread_db needs access to symbols in the gdb
1650    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1651    # may not be supported there.
1652    old_LDFLAGS="$LDFLAGS"
1653    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1654    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1655    LDFLAGS="$LDFLAGS $RDYNAMIC"
1656    if test "${have_libpython}" = no; then
1657      AC_TRY_LINK([], [], [dynamic_list=true])
1658    else
1659      # Workaround http://bugs.python.org/issue4434 where static
1660      # libpythonX.Y.a would get its symbols required for
1661      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1662      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1663
1664      # Note the workaround for Python
1665      # http://bugs.python.org/issue10112 earlier has removed
1666      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1667      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1668      # always pass.
1669      old_CFLAGS="$CFLAGS"
1670      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1671      old_LIBS="$LIBS"
1672      LIBS="$LIBS $PYTHON_LIBS"
1673      old_CPPFLAGS="$CPPFLAGS"
1674      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1675      AC_RUN_IFELSE(
1676        [AC_LANG_PROGRAM(
1677          [#include "Python.h"],
1678          [int err;
1679           Py_Initialize ();
1680           err = PyRun_SimpleString ("import itertools\n");
1681           Py_Finalize ();
1682           return err == 0 ? 0 : 1;])],
1683        [dynamic_list=true], [], [true])
1684      LIBS="$old_LIBS"
1685      CFLAGS="$old_CFLAGS"
1686      CPPFLAGS="$old_CPPFLAGS"
1687    fi
1688    LDFLAGS="$old_LDFLAGS"
1689 fi
1690 if $dynamic_list; then
1691   found="-Wl,--dynamic-list"
1692   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1693 else
1694   found="-rdynamic"
1695   RDYNAMIC="-rdynamic"
1696 fi
1697 AC_SUBST(RDYNAMIC)
1698 AC_MSG_RESULT($found)
1699
1700 dnl For certain native configurations, we need to check whether thread
1701 dnl support can be built in or not.
1702 dnl
1703 dnl Note that we only want this if we are both native (host == target),
1704 dnl and not doing a canadian cross build (build == host).
1705
1706 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1707    case ${host_os} in
1708    aix*)
1709       AC_MSG_CHECKING(for AiX thread debugging library)
1710       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1711                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1712                                    [#ifndef PTHDB_VERSION_3
1713                                     #error
1714                                     #endif],
1715                                    gdb_cv_have_aix_thread_debug=yes,
1716                                    gdb_cv_have_aix_thread_debug=no)])
1717       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1718       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1719          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1720          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1721          LIBS="$LIBS -lpthdebug"
1722
1723          # Older versions of AIX do not provide the declaration for
1724          # the getthrds function (it appears that it was introduced
1725          # with AIX 6.x).
1726          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1727       fi
1728       ;;
1729    esac
1730    AC_SUBST(CONFIG_LDFLAGS)
1731 fi
1732
1733 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1734 dnl other error codes.
1735 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1736    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1737                   gdb_cv_thread_db_h_has_td_notalloc,
1738      AC_TRY_COMPILE(
1739        [#include <thread_db.h>],
1740        [int i = TD_NOTALLOC;],
1741        gdb_cv_thread_db_h_has_td_notalloc=yes,
1742        gdb_cv_thread_db_h_has_td_notalloc=no
1743      )
1744    )
1745    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1746                   gdb_cv_thread_db_h_has_td_version,
1747      AC_TRY_COMPILE(
1748        [#include <thread_db.h>],
1749        [int i = TD_VERSION;],
1750        gdb_cv_thread_db_h_has_td_version=yes,
1751        gdb_cv_thread_db_h_has_td_version=no
1752      )
1753    )
1754    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1755                   gdb_cv_thread_db_h_has_td_notls,
1756      AC_TRY_COMPILE(
1757        [#include <thread_db.h>],
1758        [int i = TD_NOTLS;],
1759        gdb_cv_thread_db_h_has_td_notls=yes,
1760        gdb_cv_thread_db_h_has_td_notls=no
1761      )
1762    )
1763 fi
1764 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1765   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1766             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1767 fi
1768 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1769   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1770             [Define if <thread_db.h> has the TD_VERSION error code.])
1771 fi
1772 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1773   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1774             [Define if <thread_db.h> has the TD_NOTLS error code.])
1775 fi
1776
1777 dnl Check if we can disable the virtual address space randomization.
1778 dnl The functionality of setarch -R.
1779 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1780 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1781 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1782 #       define ADDR_NO_RANDOMIZE 0x0040000
1783 #      endif
1784        /* Test the flag could be set and stays set.  */
1785        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1786        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1787            return 1])])
1788 AC_RUN_IFELSE([PERSONALITY_TEST],
1789               [have_personality=true],
1790               [have_personality=false],
1791               [AC_LINK_IFELSE([PERSONALITY_TEST],
1792                               [have_personality=true],
1793                               [have_personality=false])])
1794 if $have_personality
1795 then
1796     AC_DEFINE([HAVE_PERSONALITY], 1,
1797               [Define if you support the personality syscall.])
1798 fi
1799
1800 dnl Set the host's .gdbinit filename.
1801 case $host_os in
1802   go32* | *djgpp*)
1803     gdbinit=gdb.ini
1804     ;;
1805   *)
1806     gdbinit=.gdbinit
1807     ;;
1808 esac
1809 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1810
1811 dnl Handle optional features that can be enabled.
1812
1813 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1814 # except that the argument to --with-sysroot is optional.
1815 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1816 if test "x$with_sysroot" = xyes; then
1817   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1818 fi
1819 AC_ARG_WITH(sysroot,
1820   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1821                  [search for usr/lib et al within DIR]),
1822   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1823 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1824               [search for usr/lib et al within DIR])
1825 AC_SUBST(TARGET_SYSTEM_ROOT)
1826 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1827
1828 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1829     [automatically load a system-wide gdbinit file],
1830     [])
1831 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1832     [automatically load system-wide gdbinit files from this directory],
1833     [])
1834
1835 AM_GDB_WARNINGS
1836 AM_GDB_UBSAN
1837
1838 # In the Cygwin environment, we need some additional flags.
1839 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1840 [AC_EGREP_CPP(^lose$, [
1841 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1842 lose
1843 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1844
1845
1846 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1847 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1848 case ${host} in
1849   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1850   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1851   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1852   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1853 esac
1854 AC_SUBST(SER_HARDWIRE)
1855
1856 # libreadline needs libuser32.a in a cygwin environment
1857 WIN32LIBS=
1858 if test x"$gdb_cv_os_cygwin" = xyes; then
1859     WIN32LIBS="-luser32"
1860     case "${target}" in
1861         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1862         ;;
1863     esac
1864 fi
1865
1866 # The ser-tcp.c module requires sockets.
1867 case ${host} in
1868   *mingw32*)
1869     AC_DEFINE(USE_WIN32API, 1,
1870               [Define if we should use the Windows API, instead of the
1871                POSIX API.  On Windows, we use the Windows API when
1872                building for MinGW, but the POSIX API when building
1873                for Cygwin.])
1874     WIN32LIBS="$WIN32LIBS -lws2_32"
1875     ;;
1876 esac
1877 AC_SUBST(WIN32LIBS)
1878
1879 # Add ELF support to GDB, but only if BFD includes ELF support.
1880 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1881                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1882 if test "$gdb_cv_var_elf" = yes; then
1883   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1884   AC_DEFINE(HAVE_ELF, 1,
1885             [Define if ELF support should be included.])
1886   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1887   if test "$plugins" = "yes"; then
1888     AC_SEARCH_LIBS(dlopen, dl)
1889   fi
1890 fi
1891
1892 # Add macho support to GDB, but only if BFD includes it.
1893 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1894                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1895 if test "$gdb_cv_var_macho" = yes; then
1896   CONFIG_OBS="$CONFIG_OBS machoread.o"
1897 fi
1898
1899 # Add any host-specific objects to GDB.
1900 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1901
1902 # If building on ELF, look for lzma support for embedded compressed debug info.
1903 if test "$gdb_cv_var_elf" = yes; then
1904   AC_ARG_WITH(lzma,
1905     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1906     [], [with_lzma=auto])
1907   AC_MSG_CHECKING([whether to use lzma])
1908   AC_MSG_RESULT([$with_lzma])
1909
1910   if test "${with_lzma}" != no; then
1911     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1912                           [lzma_index_iter iter;
1913                            lzma_index_iter_init (&iter, 0);
1914                            lzma_mf_is_supported (LZMA_MF_HC3);])
1915     if test "$HAVE_LIBLZMA" != yes; then
1916       if test "$with_lzma" = yes; then
1917         AC_MSG_ERROR([missing liblzma for --with-lzma])
1918       fi
1919     fi
1920   fi
1921 fi
1922
1923 LIBGUI="../libgui/src/libgui.a"
1924 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1925 AC_SUBST(LIBGUI)
1926 AC_SUBST(GUI_CFLAGS_X)
1927
1928 WIN32LDAPP=
1929 AC_SUBST(WIN32LIBS)
1930 AC_SUBST(WIN32LDAPP)
1931
1932 case "${host}" in
1933 *-*-cygwin* | *-*-mingw* )
1934     configdir="win"
1935     ;;
1936 *)
1937     configdir="unix"
1938     ;;
1939 esac
1940
1941 GDBTKLIBS=
1942 if test "${enable_gdbtk}" = "yes"; then
1943
1944     # Gdbtk must have an absolute path to srcdir in order to run
1945     # properly when not installed.
1946     here=`pwd`
1947     cd ${srcdir}
1948     GDBTK_SRC_DIR=`pwd`
1949     cd $here
1950
1951     SC_PATH_TCLCONFIG
1952
1953     # If $no_tk is nonempty, then we can't do Tk, and there is no
1954     # point to doing Tcl.
1955     SC_PATH_TKCONFIG
1956
1957     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1958         SC_LOAD_TCLCONFIG
1959
1960         # Check for in-tree tcl
1961         here=`pwd`
1962         cd ${srcdir}/..
1963         topdir=`pwd`
1964         cd ${here}
1965
1966         intree="no"
1967         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1968           intree="yes"
1969         fi
1970
1971         # Find Tcl private headers
1972         if test x"${intree}" = xno; then
1973           CY_AC_TCL_PRIVATE_HEADERS
1974           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1975           TCL_LIBRARY="${TCL_LIB_SPEC}"
1976           TCL_DEPS=""
1977         else
1978           # If building tcl in the same src tree, private headers
1979           # are not needed, but we need to be sure to use the right
1980           # headers library
1981           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1982           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1983           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1984         fi
1985         AC_SUBST(TCL_INCLUDE)
1986         AC_SUBST(TCL_LIBRARY)
1987         AC_SUBST(TCL_DEPS)
1988
1989         SC_LOAD_TKCONFIG
1990
1991         # Check for in-tree Tk
1992         intree="no"
1993         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1994           intree="yes"
1995         fi
1996
1997         # Find Tk private headers
1998         if test x"${intree}" = xno; then
1999           CY_AC_TK_PRIVATE_HEADERS
2000           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2001           TK_LIBRARY=${TK_LIB_SPEC}
2002           TK_DEPS=""
2003         else
2004           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2005           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2006           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2007         fi
2008         AC_SUBST(TK_INCLUDE)
2009         AC_SUBST(TK_LIBRARY)
2010         AC_SUBST(TK_DEPS)
2011         AC_SUBST(TK_XINCLUDES)
2012
2013         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2014
2015         # Include some libraries that Tcl and Tk want.
2016         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2017         # Yes, the ordering seems wrong here.  But it isn't.
2018         # TK_LIBS is the list of libraries that need to be linked
2019         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2020         # were in LIBS then any link tests after this point would
2021         # try to include things like `$(LIBGUI)', which wouldn't work.
2022         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2023
2024         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2025         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2026         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2027         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2028         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2029         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2030         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2031
2032         if test x"$gdb_cv_os_cygwin" = xyes; then
2033           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2034           WIN32LDAPP="-Wl,--subsystem,console"
2035           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2036         fi
2037
2038         AC_CONFIG_SUBDIRS(gdbtk)
2039     fi
2040 fi
2041
2042 AC_SUBST(X_CFLAGS)
2043 AC_SUBST(X_LDFLAGS)
2044 AC_SUBST(X_LIBS)
2045 AC_SUBST(GDBTKLIBS)
2046 AC_SUBST(GDBTK_CFLAGS)
2047 AC_SUBST(GDBTK_SRC_DIR)
2048
2049 AC_PATH_X
2050
2051 # Unlike the sim directory, whether a simulator is linked is controlled by
2052 # presence of a gdb_sim definition in the target configure.tgt entry.
2053 # This code just checks for a few cases where we'd like to ignore those
2054 # definitions, even when they're present in the '.mt' file.  These cases
2055 # are when --disable-sim is specified, or if the simulator directory is
2056 # not part of the source tree.
2057 #
2058 AC_ARG_ENABLE(sim,
2059 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2060 [echo "enable_sim = $enable_sim";
2061  echo "enableval = ${enableval}";
2062  case "${enableval}" in
2063   yes) ignore_sim=false ;;
2064   no)  ignore_sim=true ;;
2065   *)   ignore_sim=false ;;
2066  esac],
2067 [ignore_sim=false])
2068
2069 if test ! -d "${srcdir}/../sim"; then
2070   ignore_sim=true
2071 fi
2072
2073 SIM=
2074 SIM_OBS=
2075 if test "${ignore_sim}" = "false"; then
2076   if test x"${gdb_sim}" != x ; then
2077     SIM="${gdb_sim}"
2078     SIM_OBS="remote-sim.o"
2079     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2080
2081     # Some tdep code should only be compiled in when the ppc sim is
2082     # built.  PR sim/13418.
2083     case $target in
2084       powerpc*-*-*)
2085         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2086         ;;
2087     esac
2088   fi
2089 fi
2090 AC_SUBST(SIM)
2091 AC_SUBST(SIM_OBS)
2092
2093 AC_SUBST(ENABLE_CFLAGS)
2094 AC_SUBST(PROFILE_CFLAGS)
2095
2096 AC_SUBST(CONFIG_OBS)
2097 AC_SUBST(CONFIG_DEPS)
2098 AC_SUBST(CONFIG_SRCS)
2099 AC_SUBST(CONFIG_ALL)
2100 AC_SUBST(CONFIG_CLEAN)
2101 AC_SUBST(CONFIG_INSTALL)
2102 AC_SUBST(CONFIG_UNINSTALL)
2103
2104 # List of host floatformats.
2105 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2106 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2107 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2108
2109 # target_subdir is used by the testsuite to find the target libraries.
2110 target_subdir=
2111 if test "${host}" != "${target}"; then
2112     target_subdir="${target_alias}/"
2113 fi
2114 AC_SUBST(target_subdir)
2115
2116 # Import nat definitions.
2117 nat_makefile_frag=/dev/null
2118 if test "${gdb_native}" = "yes"; then
2119   . ${srcdir}/configure.nat
2120   nativefile=$NAT_FILE
2121 fi
2122
2123 AC_SUBST(NAT_FILE)
2124 AC_SUBST(NATDEPFILES)
2125 AC_SUBST(NAT_CDEPS)
2126 AC_SUBST(LOADLIBES)
2127 AC_SUBST(MH_CFLAGS)
2128 AC_SUBST(XM_CLIBS)
2129 AC_SUBST(NAT_GENERATED_FILES)
2130 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2131 AC_SUBST_FILE(nat_makefile_frag)
2132
2133 if test x"${gdb_osabi}" != x ; then
2134     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2135                        [Define to the default OS ABI for this configuration.])
2136 fi
2137
2138 AC_ARG_ENABLE(gdbserver,
2139 AS_HELP_STRING([--enable-gdbserver],
2140                [automatically build gdbserver (yes/no/auto, default is auto)]),
2141 [case "${enableval}" in
2142   yes| no|auto) ;;
2143   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2144 esac],[enable_gdbserver=auto])
2145
2146 # We only build gdbserver automatically in a native configuration, and
2147 # only if the user did not explicitly disable its build.
2148 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2149   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2150   if test "x$build_gdbserver" = xyes; then
2151     AC_MSG_RESULT(yes)
2152     AC_CONFIG_SUBDIRS(gdbserver)
2153     gdbserver_build_enabled=yes
2154   else
2155     AC_MSG_RESULT(no)
2156   fi
2157 fi
2158
2159 # If the user explicitly request the gdbserver to be built, verify that
2160 # we were in fact able to enable it.
2161 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2162   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2163 fi
2164
2165 # Check for babeltrace and babeltrace-ctf
2166 AC_ARG_WITH(babeltrace,
2167   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2168   [], [with_babeltrace=auto])
2169 AC_MSG_CHECKING([whether to use babeltrace])
2170 AC_MSG_RESULT([$with_babeltrace])
2171
2172 if test "x$with_babeltrace" = "xno"; then
2173   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2174 else
2175   # Append -Werror to CFLAGS so that configure can catch the warning
2176   # "assignment from incompatible pointer type", which is related to
2177   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2178   # in GDB, while babeltrace 1.0.3 is broken.
2179   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2180   # safe to save and restore CFLAGS here.
2181   saved_CFLAGS=$CFLAGS
2182   CFLAGS="$CFLAGS -Werror"
2183   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2184                         [#include <babeltrace/babeltrace.h>
2185                          #include <babeltrace/ctf/events.h>
2186                          #include <babeltrace/ctf/iterator.h>],
2187                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2188                         struct bt_ctf_event *event = NULL;
2189                         const struct bt_definition *scope;
2190
2191                         pos->type = BT_SEEK_BEGIN;
2192                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2193                         scope = bt_ctf_get_top_level_scope (event,
2194                                                            BT_STREAM_EVENT_HEADER);
2195                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2196                         ])
2197   CFLAGS=$saved_CFLAGS
2198
2199   if test "$HAVE_LIBBABELTRACE" != yes; then
2200      if test "$with_babeltrace" = yes; then
2201        AC_MSG_ERROR([babeltrace is missing or unusable])
2202      else
2203        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2204      fi
2205   fi
2206 fi
2207
2208 # Check for xxhash
2209 AC_ARG_WITH(xxhash,
2210   AC_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2211   [], [with_xxhash=auto])
2212
2213 if test "x$with_xxhash" != "xno"; then
2214   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2215                         [#include <xxhash.h>],
2216                         [XXH32("foo", 3, 0);
2217                         ])
2218   if test "$HAVE_LIBXXHASH" != yes; then
2219     if test "$with_xxhash" = yes; then
2220       AC_MSG_ERROR([xxhash is missing or unusable])
2221     fi
2222   fi
2223   if test "x$with_xxhash" = "xauto"; then
2224     with_xxhash="$HAVE_LIBXXHASH"
2225   fi
2226 fi
2227
2228 AC_MSG_CHECKING([whether to use xxhash])
2229 AC_MSG_RESULT([$with_xxhash])
2230
2231 NM_H=
2232 rm -f nm.h
2233 if test "${nativefile}" != ""; then
2234     case "${nativefile}" in
2235       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2236       * ) GDB_NM_FILE="${nativefile}"
2237     esac
2238     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2239                     [GDB_NM_FILE=$GDB_NM_FILE])
2240     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2241     NM_H=nm.h
2242 fi
2243 AC_SUBST(GDB_NM_FILE)
2244 AC_SUBST(NM_H)
2245
2246 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2247 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2248 if test "x$USE_MAINTAINER_MODE" = xyes; then
2249   if test "${XSLTPROC}" = missing; then
2250     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2251   fi
2252 fi
2253 AC_SUBST(XSLTPROC)
2254
2255 dnl Check for exe extension set on certain hosts (e.g. Win32)
2256 AC_EXEEXT
2257
2258 dnl  Detect the character set used by this host.
2259 dnl  At the moment, we just assume it's UTF-8.
2260 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2261           [Define to be a string naming the default host character set.])
2262
2263 GDB_AC_SELFTEST([
2264   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) gdbsupport/selftest.o selftest-arch.o"
2265   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) gdbsupport/selftest.c selftest-arch.c"
2266 ])
2267
2268 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2269 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2270 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2271 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2272
2273 AC_OUTPUT