gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_USE_SYSTEM_EXTENSIONS
  28 ACX_LARGEFILE
  29 AM_PROG_CC_STDC
  30
  31 AC_CONFIG_AUX_DIR(..)
  32 AC_CANONICAL_SYSTEM
  33 AC_ARG_PROGRAM
  34
  35 # Dependency checking.
  36 ZW_CREATE_DEPDIR
  37 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  38
  39 # Check for the 'make' the user wants to use.
  40 AC_CHECK_PROGS(MAKE, make)
  41 MAKE_IS_GNU=
  42 case "`$MAKE --version 2>&1 | sed 1q`" in
  43   *GNU*)
  44     MAKE_IS_GNU=yes
  45     ;;
  46 esac
  47 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  48 AC_PROG_MAKE_SET
  49
  50 # Configure gnulib.  We need to build gnulib under some other
  51 # directory not "gnulib", to avoid the problem of both GDB and
  52 # GDBserver wanting to build it in the same directory, when building
  53 # in the source dir.
  54 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  55
  56 dnl List of object files and targets accumulated by configure.
  57
  58 CONFIG_OBS=
  59 CONFIG_DEPS=
  60 CONFIG_SRCS=
  61 ENABLE_CFLAGS=
  62
  63 CONFIG_ALL=
  64 CONFIG_CLEAN=
  65 CONFIG_INSTALL=
  66 CONFIG_UNINSTALL=
  67
  68 dnl Set up for gettext.
  69 ZW_GNU_GETTEXT_SISTER_DIR
  70
  71 localedir='${datadir}/locale'
  72 AC_SUBST(localedir)
  73
  74 if test x"$USE_NLS" = xyes; then
  75    CONFIG_ALL="$CONFIG_ALL all-po"
  76    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  77    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  78    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  79 fi
  80
  81 GNULIB=build-gnulib/import
  82
  83 # For Makefile dependencies.
  84 GNULIB_STDINT_H=
  85 if test x"$STDINT_H" != x; then
  86   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  87 fi
  88 AC_SUBST(GNULIB_STDINT_H)
  89
  90 PACKAGE=gdb
  91 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  92 AC_SUBST(PACKAGE)
  93
  94 # We never need to detect it in this sub-configure.
  95 # But preserve it for config.status --recheck.
  96 AC_ARG_VAR(MAKEINFO,
  97   [Parent configure detects if it is of sufficient version.])
  98 AC_ARG_VAR(MAKEINFOFLAGS,
  99   [Parameters for MAKEINFO.])
 100
 101 MAKEINFO_EXTRA_FLAGS=""
 102 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 103   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 104   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 105     gdb_cv_have_makeinfo_click=yes
 106   else
 107     gdb_cv_have_makeinfo_click=no
 108   fi])
 109 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 110   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 111 fi
 112 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 113
 114 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 115     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 116     [${libdir}/debug])
 117
 118 # We can't pass paths as command line arguments.
 119 # Mingw32 tries to be clever and will convert the paths for us.
 120 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 121 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 122 # This breaks GDB's relocatable path conversions since paths passed in
 123 # config.h would not get so translated, the path prefixes no longer match.
 124 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 125
 126 # GDB's datadir relocation
 127
 128 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 129     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 130     [${datadir}/gdb])
 131
 132 AC_ARG_WITH(relocated-sources,
 133 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 134 [reloc_srcdir="${withval}"
 135  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 136               [Relocated directory for source files. ])
 137 ])
 138
 139 AC_MSG_CHECKING([for default auto-load safe-path])
 140 AC_ARG_WITH(auto-load-safe-path,
 141 AS_HELP_STRING([--with-auto-load-safe-path=PATH], [directories safe to hold auto-loaded files])
 142 AS_HELP_STRING([--without-auto-load-safe-path], [do not restrict auto-loaded files locations]),
 143 [if test "$with_auto_load_safe_path" = "no"; then
 144    with_auto_load_safe_path=""
 145  fi],
 146 [with_auto_load_safe_path="$prefix"])
 147 AC_DEFINE_DIR(DEFAULT_AUTO_LOAD_SAFE_PATH, with_auto_load_safe_path,
 148               [Directories safe to hold auto-loaded files.])
 149 AC_MSG_RESULT([$with_auto_load_safe_path])
 150
 151 AC_CONFIG_SUBDIRS(testsuite)
 152
 153 # Check whether to support alternative target configurations
 154 AC_ARG_ENABLE(targets,
 155 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 156 [case "${enableval}" in
 157   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 158             ;;
 159   no)       enable_targets= ;;
 160   *)        enable_targets=$enableval ;;
 161 esac])
 162
 163 # Check whether to enable 64-bit support on 32-bit hosts
 164 AC_ARG_ENABLE(64-bit-bfd,
 165 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 166 [case "${enableval}" in
 167   yes)  want64=true  ;;
 168   no)   want64=false ;;
 169   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 170 esac],[want64=false])dnl
 171
 172 # Provide defaults for some variables set by the per-host and per-target
 173 # configuration.
 174 gdb_host_obs=posix-hdep.o
 175
 176 if test "${target}" = "${host}"; then
 177   gdb_native=yes
 178 else
 179   gdb_native=no
 180 fi
 181
 182 . $srcdir/configure.host
 183
 184 # Accumulate some settings from configure.tgt over all enabled targets
 185
 186 TARGET_OBS=
 187 all_targets=
 188
 189 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 190 do
 191   if test "$targ_alias" = "all"; then
 192     all_targets=true
 193   else
 194     # Canonicalize the secondary target names.
 195     result=`$ac_config_sub $targ_alias 2>/dev/null`
 196     if test -n "$result"; then
 197         targ=$result
 198     else
 199         targ=$targ_alias
 200     fi
 201
 202     . ${srcdir}/configure.tgt
 203
 204     AS_IF([test -z "${gdb_target_obs}"],
 205       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 206
 207     # Target-specific object files
 208     for i in ${gdb_target_obs}; do
 209         case " $TARGET_OBS " in
 210         *" ${i} "*) ;;
 211         *)
 212           TARGET_OBS="$TARGET_OBS ${i}"
 213           ;;
 214         esac
 215     done
 216
 217     # Check whether this target needs 64-bit CORE_ADDR
 218     if test x${want64} = xfalse; then
 219       . ${srcdir}/../bfd/config.bfd
 220     fi
 221   fi
 222 done
 223
 224 if test x${all_targets} = xtrue; then
 225
 226   # We want all 64-bit targets if we either:
 227   #  - run on a 64-bit host  or
 228   #  - already require 64-bit support for some other target  or
 229   #  - the --enable-64-bit-bfd option was supplied
 230   # Otherwise we only support all 32-bit targets.
 231   #
 232   # NOTE: This test must be in sync with the corresponding
 233   #       tests in BFD!
 234
 235   if test x${want64} = xfalse; then
 236     AC_CHECK_SIZEOF(long)
 237     if test "x${ac_cv_sizeof_long}" = "x8"; then
 238       want64=true
 239     fi
 240   fi
 241   if test x${want64} = xtrue; then
 242     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 243   else
 244     TARGET_OBS='$(ALL_TARGET_OBS)'
 245   fi
 246 fi
 247
 248 AC_SUBST(TARGET_OBS)
 249
 250 # For other settings, only the main target counts.
 251 gdb_sim=
 252 gdb_osabi=
 253 build_gdbserver=
 254 targ=$target; . ${srcdir}/configure.tgt
 255
 256 # Fetch the default architecture and default target vector from BFD.
 257 targ=$target; . $srcdir/../bfd/config.bfd
 258
 259 # We only want the first architecture, so strip off the others if
 260 # there is more than one.
 261 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 262
 263 if test "x$targ_archs" != x; then
 264   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 265     [Define to BFD's default architecture. ])
 266 fi
 267 if test "x$targ_defvec" != x; then
 268   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 269     [Define to BFD's default target vector. ])
 270 fi
 271
 272 # The CLI cannot be disabled yet, but may be in the future.
 273
 274 # Enable CLI.
 275 AC_ARG_ENABLE(gdbcli,
 276 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 277   [case $enableval in
 278     yes)
 279       ;;
 280     no)
 281       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 282     *)
 283       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 284   esac],
 285   [enable_gdbcli=yes])
 286 if test x"$enable_gdbcli" = xyes; then
 287   if test -d $srcdir/cli; then
 288     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 289     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 290     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 291     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 292   fi
 293 fi
 294
 295 # Enable MI.
 296 AC_ARG_ENABLE(gdbmi,
 297 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 298   [case $enableval in
 299     yes | no)
 300       ;;
 301     *)
 302       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 303   esac],
 304   [enable_gdbmi=yes])
 305 if test x"$enable_gdbmi" = xyes; then
 306   if test -d $srcdir/mi; then
 307     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 308     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 309     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 310     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 311   fi
 312 fi
 313
 314 # Enable TUI.
 315 AC_ARG_ENABLE(tui,
 316 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 317   [case $enableval in
 318     yes | no | auto)
 319       ;;
 320     *)
 321       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 322   esac],enable_tui=auto)
 323
 324 # Enable gdbtk.
 325 AC_ARG_ENABLE(gdbtk,
 326 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 327   [case $enableval in
 328     yes | no)
 329       ;;
 330     *)
 331       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 332   esac],
 333   [if test -d $srcdir/gdbtk; then
 334     enable_gdbtk=yes
 335   else
 336     enable_gdbtk=no
 337   fi])
 338 # We unconditionally disable gdbtk tests on selected platforms.
 339 case $host_os in
 340   go32* | windows*)
 341     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 342     enable_gdbtk=no ;;
 343 esac
 344
 345 # Libunwind support for ia64.
 346
 347 AC_ARG_WITH(libunwind-ia64,
 348 AS_HELP_STRING([--with-libunwind-ia64],
 349                [use libunwind frame unwinding for ia64 targets]),,
 350             [with_libunwind_ia64=auto])
 351
 352 # Backward compatibility option.
 353 if test "${with_libunwind+set}" = set; then
 354   if test x"$with_libunwind_ia64" != xauto; then
 355     AC_MSG_ERROR(
 356       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 357   fi
 358   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 359   with_libunwind_ia64="$with_libunwind"
 360 fi
 361
 362 case "$with_libunwind_ia64" in
 363   yes | no)
 364     ;;
 365   auto)
 366     AC_CHECK_HEADERS(libunwind-ia64.h)
 367     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 368     ;;
 369   *)
 370     AC_MSG_ERROR(
 371       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 372     ;;
 373 esac
 374
 375 if test x"$with_libunwind_ia64" = xyes; then
 376   AC_CHECK_HEADERS(libunwind-ia64.h)
 377   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 378     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 379   fi
 380   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 381   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 382   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 383 fi
 384
 385 opt_curses=no
 386 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 387
 388 prefer_curses=no
 389 if test "$opt_curses" = "yes"; then
 390   prefer_curses=yes
 391 fi
 392
 393 # Profiling support.
 394 AC_ARG_ENABLE(profiling,
 395 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 396   [case $enableval in
 397     yes | no)
 398       ;;
 399     *)
 400       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 401   esac],
 402  [enable_profiling=no])
 403
 404 AC_CHECK_FUNCS(monstartup _mcleanup)
 405 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 406 [AC_TRY_LINK(
 407 [#include <stdlib.h>
 408 extern char _etext;
 409 ],
 410 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 411 if test $ac_cv_var__etext = yes; then
 412   AC_DEFINE(HAVE__ETEXT, 1,
 413             [Define to 1 if your system has the _etext variable. ])
 414 fi
 415 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 416 [AC_TRY_LINK(
 417 [#include <stdlib.h>
 418 extern char etext;
 419 ],
 420 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 421 if test $ac_cv_var_etext = yes; then
 422   AC_DEFINE(HAVE_ETEXT, 1,
 423             [Define to 1 if your system has the etext variable. ])
 424 fi
 425 if test "$enable_profiling" = yes ; then
 426   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 427     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 428   fi
 429   PROFILE_CFLAGS=-pg
 430   OLD_CFLAGS="$CFLAGS"
 431   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 432
 433   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 434     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 435      ac_cv_cc_supports_pg=no)])
 436
 437   if test $ac_cv_cc_supports_pg = no; then
 438     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 439   fi
 440
 441   CFLAGS="$OLD_CFLAGS"
 442 fi
 443
 444 ACX_PKGVERSION([GDB])
 445 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 446 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 447 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 448
 449 # --------------------- #
 450 # Checks for programs.  #
 451 # --------------------- #
 452
 453 AC_PROG_AWK
 454 AC_PROG_INSTALL
 455 AC_PROG_LN_S
 456 AC_PROG_RANLIB
 457 AC_PROG_YACC
 458
 459 AC_CHECK_TOOL(AR, ar)
 460 AC_CHECK_TOOL(DLLTOOL, dlltool)
 461 AC_CHECK_TOOL(WINDRES, windres)
 462
 463 # Needed for GNU/Hurd.
 464 AC_CHECK_TOOL(MIG, mig)
 465
 466 # ---------------------- #
 467 # Checks for libraries.  #
 468 # ---------------------- #
 469
 470 # We might need to link with -lm; most simulators need it.
 471 AC_CHECK_LIB(m, main)
 472
 473 # We need to link with -lw to get `wctype' on Solaris before Solaris
 474 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 475 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 476 # is known to have this problem).  Therefore we avoid libw if we can.
 477 AC_CHECK_FUNC(wctype, [],
 478   [AC_CHECK_LIB(w, wctype)])
 479
 480 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 481 AC_SEARCH_LIBS(gethostbyname, nsl)
 482
 483 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 484 AC_SEARCH_LIBS(socketpair, socket)
 485
 486 # Link in zlib if we can.  This allows us to read compressed debug sections.
 487 AM_ZLIB
 488
 489 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 490 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 491
 492 AM_ICONV
 493
 494 # GDB may fork/exec the iconv program to get the list of supported character
 495 # sets.  Allow the user to specify where to find it.
 496 # There are several factors affecting the choice of option name:
 497 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 498 #   the build-time location of libiconv files.
 499 # - The program we need to find is iconv, which comes with glibc.  The user
 500 #   doesn't necessarily have libiconv installed.  Therefore naming this
 501 #   --with-libiconv-foo feels wrong.
 502 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 503 #   defined to work on directories not files (though it really doesn't know
 504 #   the difference).
 505 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 506 #   with --with-libiconv-prefix.
 507 # Putting these together is why the option name is --with-iconv-bin.
 508
 509 AC_ARG_WITH(iconv-bin,
 510 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 511 [iconv_bin="${withval}"
 512  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 513                     [Path of directory of iconv program.])
 514  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 515 ])
 516
 517 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 518 # There is a very specific comment in /usr/include/curses.h explaining that
 519 # termcap routines built into libcurses must not be used.
 520 #
 521 # The symptoms we observed so far is GDB unexpectedly changing
 522 # the terminal settings when tgetent is called - this is particularly
 523 # visible as the output is missing carriage returns, and so rapidly
 524 # becomes very hard to read.
 525 #
 526 # The readline configure script has already decided that libtermcap
 527 # was enough for its purposes, and so decided to build readline using
 528 # libtermcap.  Since the TUI mode requires curses, building GDB with
 529 # TUI enabled results in both libraries to be used at the same time,
 530 # which is not allowed.  This basically means that GDB with TUI is
 531 # broken on alpha-osf.
 532
 533 case $host_os in
 534   osf* )
 535     if test x"$enable_tui" = xyes; then
 536       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 537     fi
 538     if test x"$enable_tui" = xauto; then
 539       enable_tui=no
 540     fi
 541     ;;
 542 esac
 543
 544 # For the TUI, we need enhanced curses functionality.
 545 if test x"$enable_tui" != xno; then
 546   prefer_curses=yes
 547 fi
 548
 549 curses_found=no
 550 if test x"$prefer_curses" = xyes; then
 551   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 552   # curses library because the latter might not provide all the
 553   # functionality we need.  However, this leads to problems on systems
 554   # where the linker searches /usr/local/lib, but the compiler doesn't
 555   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 556   # default installation of ncurses on alpha*-dec-osf* will lead to such
 557   # a situation.
 558   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 559
 560   if test "$ac_cv_search_waddstr" != no; then
 561     curses_found=yes
 562   fi
 563 fi
 564
 565 # Check whether we should enable the TUI, but only do so if we really
 566 # can.
 567 if test x"$enable_tui" != xno; then
 568   if test -d $srcdir/tui; then
 569     if test "$curses_found" != no; then
 570       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 571       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 572       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 573       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 574     else
 575       if test x"$enable_tui" = xyes; then
 576         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 577       else
 578         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 579       fi
 580     fi
 581   fi
 582 fi
 583
 584 # Since GDB uses Readline, we need termcap functionality.  In many
 585 # cases this will be provided by the curses library, but some systems
 586 # have a seperate termcap library, or no curses library at all.
 587
 588 case $host_os in
 589   cygwin*)
 590     if test -d $srcdir/libtermcap; then
 591       LIBS="../libtermcap/libtermcap.a $LIBS"
 592       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 593     fi ;;
 594   go32* | *djgpp*)
 595     ac_cv_search_tgetent="none required"
 596     ;;
 597   *mingw32*)
 598     ac_cv_search_tgetent="none required"
 599     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 600     ;;
 601 esac
 602
 603 # These are the libraries checked by Readline.
 604 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 605
 606 if test "$ac_cv_search_tgetent" = no; then
 607   AC_MSG_ERROR([no termcap library found])
 608 fi
 609
 610 AC_ARG_WITH([system-readline],
 611   [AS_HELP_STRING([--with-system-readline],
 612                   [use installed readline library])])
 613
 614 if test "$with_system_readline" = yes; then
 615   READLINE=-lreadline
 616   READLINE_DEPS=
 617   READLINE_CFLAGS=
 618   READLINE_TEXI_INCFLAG=
 619 else
 620   READLINE='$(READLINE_DIR)/libreadline.a'
 621   READLINE_DEPS='$(READLINE)'
 622   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 623   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 624 fi
 625 AC_SUBST(READLINE)
 626 AC_SUBST(READLINE_DEPS)
 627 AC_SUBST(READLINE_CFLAGS)
 628 AC_SUBST(READLINE_TEXI_INCFLAG)
 629
 630 # Generate jit-reader.h
 631
 632 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 633 TARGET_PTR=
 634
 635 AC_CHECK_SIZEOF(unsigned long long)
 636 AC_CHECK_SIZEOF(unsigned long)
 637 AC_CHECK_SIZEOF(unsigned __int128)
 638
 639 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 640   TARGET_PTR="unsigned long"
 641 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 642   TARGET_PTR="unsigned long long"
 643 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 644   TARGET_PTR="unsigned __int128"
 645 else
 646   TARGET_PTR="unsigned long"
 647 fi
 648
 649 AC_SUBST(TARGET_PTR)
 650 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 651
 652 AC_SEARCH_LIBS(dlopen, dl)
 653
 654 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 655                 [directory to load the JIT readers from],
 656                 [${libdir}/gdb])
 657
 658 AC_ARG_WITH(expat,
 659   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 660   [], [with_expat=auto])
 661 AC_MSG_CHECKING([whether to use expat])
 662 AC_MSG_RESULT([$with_expat])
 663
 664 if test "${with_expat}" = no; then
 665   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 666   HAVE_LIBEXPAT=no
 667 else
 668   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 669                         [XML_Parser p = XML_ParserCreate (0);])
 670   if test "$HAVE_LIBEXPAT" != yes; then
 671     if test "$with_expat" = yes; then
 672       AC_MSG_ERROR([expat is missing or unusable])
 673     else
 674       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 675     fi
 676   else
 677     save_LIBS=$LIBS
 678     LIBS="$LIBS $LIBEXPAT"
 679     AC_CHECK_FUNCS(XML_StopParser)
 680     LIBS=$save_LIBS
 681   fi
 682 fi
 683
 684 dnl Utility to simplify finding libpython.
 685 dnl $1 = pythonX.Y
 686 dnl $2 = the shell variable to assign the result to
 687 dnl      If libpython is found we store $version here.
 688 dnl $3 = additional flags to add to CPPFLAGS
 689 dnl $4 = additional flags to add to LIBS
 690
 691 AC_DEFUN([AC_TRY_LIBPYTHON],
 692 [
 693   version=$1
 694   define([have_libpython_var],$2)
 695   new_CPPFLAGS=$3
 696   new_LIBS=$4
 697   AC_MSG_CHECKING([for ${version}])
 698   save_CPPFLAGS=$CPPFLAGS
 699   save_LIBS=$LIBS
 700   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 701   LIBS="$LIBS $new_LIBS"
 702   found_usable_python=no
 703   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 704                                  [[Py_Initialize ();]]),
 705                  [have_libpython_var=${version}
 706                   found_usable_python=yes
 707                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 708                   PYTHON_LIBS=$new_LIBS])
 709   CPPFLAGS=$save_CPPFLAGS
 710   LIBS=$save_LIBS
 711   AC_MSG_RESULT([${found_usable_python}])
 712 ])
 713
 714 dnl There are several different values for --with-python:
 715 dnl
 716 dnl no -   Don't include python support.
 717 dnl yes -  Include python support, error if it's missing.
 718 dnl        If we find python in $PATH, use it to fetch configure options,
 719 dnl        otherwise assume the compiler can find it with no help from us.
 720 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 721 dnl auto - Same as "yes", but if python is missing from the system,
 722 dnl        fall back to "no".
 723 dnl /path/to/python/exec-prefix -
 724 dnl        Use the python located in this directory.
 725 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 726 dnl        the compilation parameters.  Otherwise use
 727 dnl        -I/path/to/python/exec-prefix/include,
 728 dnl        -L/path/to/python/exec-prefix/lib.
 729 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 730 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 731 dnl        but is deprecated.
 732 dnl /path/to/python/executable -
 733 dnl        Run python-config.py with this version of python to fetch the
 734 dnl        compilation parameters.
 735 dnl        NOTE: This needn't be the real python executable.
 736 dnl        In a cross-compilation scenario (build != host), this could be
 737 dnl        a shell script that provides what python-config.py provides for
 738 dnl        --ldflags, --includes, --exec-prefix.
 739 dnl python-executable -
 740 dnl        Find python-executable in $PATH, and then handle the same as
 741 dnl        /path/to/python/executable.
 742 dnl
 743 dnl If a python program is specified, it is used to run python-config.py and
 744 dnl is passed --ldflags, --includes, --exec-prefix.
 745
 746 AC_ARG_WITH(python,
 747   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 748   [], [with_python=auto])
 749 AC_MSG_CHECKING([whether to use python])
 750 AC_MSG_RESULT([$with_python])
 751
 752 if test "${with_python}" = no; then
 753   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 754   have_libpython=no
 755 else
 756   case "${with_python}" in
 757   [[\\/]]* | ?:[[\\/]]*)
 758     if test -d ${with_python}; then
 759       # Assume the python binary is ${with_python}/bin/python.
 760       python_prog="${with_python}/bin/python"
 761       python_prefix=
 762       # If python does not exit ${with_python}/bin, then try in
 763       # ${with_python}.  On Windows/MinGW, this is where the Python
 764       # executable is.
 765       if test ! -x "${python_prog}"; then
 766         python_prog="${with_python}/python"
 767         python_prefix=
 768       fi
 769       if test ! -x "${python_prog}"; then
 770         # Fall back to gdb 7.0/7.1 behaviour.
 771         python_prog=missing
 772         python_prefix=${with_python}
 773       fi
 774     elif test -x "${with_python}"; then
 775       # While we can't run python compiled for $host (unless host == build),
 776       # the user could write a script that provides the needed information,
 777       # so we support that.
 778       python_prog=${with_python}
 779       python_prefix=
 780     else
 781       AC_ERROR(invalid value for --with-python)
 782     fi
 783     ;;
 784   */*)
 785     # Disallow --with-python=foo/bar.
 786     AC_ERROR(invalid value for --with-python)
 787     ;;
 788   *)
 789     # The user has either specified auto, yes, or the name of the python
 790     # program assumed to be in $PATH.
 791     python_prefix=
 792     case "${with_python}" in
 793     yes | auto)
 794       if test ${build} = ${host}; then
 795         AC_PATH_PROG(python_prog_path, python, missing)
 796         if test "${python_prog_path}" = missing; then
 797           python_prog=missing
 798         else
 799           python_prog=${python_prog_path}
 800         fi
 801       else
 802         # Not much we can do except assume the cross-compiler will find the
 803         # right files.
 804         python_prog=missing
 805       fi
 806       ;;
 807     *)
 808       # While we can't run python compiled for $host (unless host == build),
 809       # the user could write a script that provides the needed information,
 810       # so we support that.
 811       python_prog="${with_python}"
 812       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 813       if test "${python_prog_path}" = missing; then
 814         AC_ERROR(unable to find python program ${python_prog})
 815       fi
 816       ;;
 817     esac
 818   esac
 819
 820   if test "${python_prog}" != missing; then
 821     # We have a python program to use, but it may be too old.
 822     # Don't flag an error for --with-python=auto (the default).
 823     have_python_config=yes
 824     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 825     if test $? != 0; then
 826       have_python_config=failed
 827       if test "${with_python}" != auto; then
 828         AC_ERROR(failure running python-config --includes)
 829       fi
 830     fi
 831     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 832     if test $? != 0; then
 833       have_python_config=failed
 834       if test "${with_python}" != auto; then
 835         AC_ERROR(failure running python-config --ldflags)
 836       fi
 837     fi
 838     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 839     if test $? != 0; then
 840       have_python_config=failed
 841       if test "${with_python}" != auto; then
 842         AC_ERROR(failure running python-config --exec-prefix)
 843       fi
 844     fi
 845   else
 846     # We do not have a python executable we can use to determine where
 847     # to find the Python headers and libs.  We cannot guess the include
 848     # path from the python_prefix either, because that include path
 849     # depends on the Python version.  So, there is nothing much we can
 850     # do except assume that the compiler will be able to find those files.
 851     python_includes=
 852     python_libs=
 853     have_python_config=no
 854   fi
 855
 856   # If we have python-config, only try the configuration it provides.
 857   # Otherwise fallback on the old way of trying different versions of
 858   # python in turn.
 859
 860   have_libpython=no
 861   if test "${have_python_config}" = yes; then
 862     # Determine the Python version by extracting "-lpython<version>"
 863     # part of the python_libs. <version> is usually X.Y with X and Y
 864     # being decimal numbers, but can also be XY (seen on Windows).
 865     #
 866     # The extraction is performed using sed with a regular expression.
 867     # Initially, the regexp used was using the '?' quantifier to make
 868     # the dot in the version number optional.  Unfortunately, this
 869     # does not work with non-GNU versions of sed because, because of
 870     # what looks like a limitation (the '?' quantifier does not work
 871     # with back-references).  We work around this limitation by using
 872     # the '*' quantifier instead.  It means that, in theory, we might
 873     # match unexpected version strings such as "-lpython2..7", but
 874     # this seems unlikely in practice.  And even if that happens,
 875     # an error will be triggered later on, when checking that version
 876     # number.
 877     python_version=`echo " ${python_libs} " \
 878                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 879     case "${python_version}" in
 880     python*)
 881       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 882                        ${python_includes}, ${python_libs})
 883       ;;
 884     *)
 885       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 886       ;;
 887     esac
 888   elif test "${have_python_config}" != failed; then
 889     if test "${have_libpython}" = no; then
 890       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 891                        ${python_includes}, "${python_libs} -lpython2.7")
 892     fi
 893     if test "${have_libpython}" = no; then
 894       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 895                        ${python_includes}, "${python_libs} -lpython2.6")
 896     fi
 897     if test ${have_libpython} = no; then
 898       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 899                        ${python_includes}, "${python_libs} -lpython2.5")
 900     fi
 901     if test ${have_libpython} = no; then
 902       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 903                        ${python_includes}, "${python_libs} -lpython2.4")
 904     fi
 905   fi
 906   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 907     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 908   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 909     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 910   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 911     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 912   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 913     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 914   fi
 915
 916   if test "${have_libpython}" = no; then
 917     case "${with_python}" in
 918     yes)
 919       AC_MSG_ERROR([python is missing or unusable])
 920       ;;
 921     auto)
 922       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 923       ;;
 924     *)
 925       AC_MSG_ERROR([no usable python found at ${with_python}])
 926       ;;
 927     esac
 928   else
 929     if test -n "${python_prefix}"; then
 930       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 931                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 932       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 933     fi
 934   fi
 935 fi
 936
 937 if test "${have_libpython}" != no; then
 938   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 939   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 940   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 941   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 942   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 943   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 944
 945   # Flags needed to compile Python code (taken from python-config --cflags).
 946   # We cannot call python-config directly because it will output whatever was
 947   # used when compiling the Python interpreter itself, including flags which
 948   # would make the python-related objects be compiled differently from the
 949   # rest of GDB (e.g., -O2 and -fPIC).
 950   if test "${GCC}" = yes; then
 951     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 952   fi
 953
 954   if test "x${tentative_python_cflags}" != x; then
 955     AC_MSG_CHECKING(compiler flags for python code)
 956     for flag in ${tentative_python_cflags}; do
 957       # Check that the compiler accepts it
 958       saved_CFLAGS="$CFLAGS"
 959       CFLAGS="$CFLAGS $flag"
 960       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 961       CFLAGS="$saved_CFLAGS"
 962     done
 963     AC_MSG_RESULT(${PYTHON_CFLAGS})
 964   fi
 965
 966   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 967   #    #if _SGIAPI
 968   #    #define siginfo __siginfo
 969   #    #endif
 970   # The problem is that including Python causes some XOPEN macros to be
 971   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 972   # to false.  So, we work around this issue by defining siginfo ourself
 973   # though the command-line.
 974   case "$gdb_host" in
 975     irix*) if test "${GCC}" = yes; then
 976              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 977            fi
 978            ;;
 979   esac
 980 else
 981   # Even if Python support is not compiled in, we need to have these files
 982   # included.
 983   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 984   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 985         python/py-prettyprint.c python/py-auto-load.c"
 986 fi
 987 AC_SUBST(PYTHON_CFLAGS)
 988 AC_SUBST(PYTHON_CPPFLAGS)
 989 AC_SUBST(PYTHON_LIBS)
 990
 991 # ------------------------- #
 992 # Checks for header files.  #
 993 # ------------------------- #
 994
 995 AC_HEADER_DIRENT
 996 AC_HEADER_STAT
 997 AC_HEADER_STDC
 998 # elf_hp.h is for HP/UX 64-bit shared library support.
 999 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
1000 # unconditionally, so what's the point in checking these?
1001 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1002                   thread_db.h gnu/libc-version.h signal.h stddef.h \
1003                   stdlib.h string.h memory.h strings.h sys/fault.h \
1004                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1005                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1006                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1007                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1008                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1009                   dlfcn.h sys/socket.h sys/un.h])
1010 AC_CHECK_HEADERS(link.h, [], [],
1011 [#if HAVE_SYS_TYPES_H
1012 # include <sys/types.h>
1013 #endif
1014 #if HAVE_NLIST_H
1015 # include <nlist.h>
1016 #endif
1017 ])
1018 AC_CHECK_HEADERS(sys/proc.h, [], [],
1019 [#if HAVE_SYS_PARAM_H
1020 # include <sys/param.h>
1021 #endif
1022 ])
1023 AC_CHECK_HEADERS(sys/user.h, [], [],
1024 [#if HAVE_SYS_PARAM_H
1025 # include <sys/param.h>
1026 #endif
1027 ])
1028
1029 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1030 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1031 # think that we don't have <curses.h> if we're using GCC.
1032 case $host_os in
1033   solaris2.[[789]])
1034     if test "$GCC" = yes; then
1035       AC_DEFINE(_MSE_INT_H, 1,
1036         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1037    Solaris 2.[789] when using GCC. ])
1038     fi ;;
1039 esac
1040 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1041 AC_CHECK_HEADERS(term.h, [], [],
1042 [#if HAVE_CURSES_H
1043 # include <curses.h>
1044 #endif
1045 ])
1046
1047 # ------------------------- #
1048 # Checks for declarations.  #
1049 # ------------------------- #
1050
1051 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1052                 snprintf, vsnprintf])
1053 AM_LC_MESSAGES
1054
1055 # ----------------------- #
1056 # Checks for structures.  #
1057 # ----------------------- #
1058
1059 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1060
1061 # ------------------ #
1062 # Checks for types.  #
1063 # ------------------ #
1064
1065 AC_TYPE_SIGNAL
1066 AC_CHECK_TYPES(socklen_t, [], [],
1067 [#include <sys/types.h>
1068 #include <sys/socket.h>
1069 ])
1070
1071 # ------------------------------------- #
1072 # Checks for compiler characteristics.  #
1073 # ------------------------------------- #
1074
1075 AC_C_CONST
1076 AC_C_INLINE
1077 AC_C_BIGENDIAN
1078
1079 # ------------------------------ #
1080 # Checks for library functions.  #
1081 # ------------------------------ #
1082
1083 AC_FUNC_ALLOCA
1084 AC_FUNC_MMAP
1085 AC_FUNC_VFORK
1086 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1087                 pipe poll pread pread64 pwrite readlink resize_term \
1088                 sbrk setpgid setpgrp setsid \
1089                 sigaction sigprocmask sigsetmask socketpair syscall \
1090                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1091                 setrlimit getrlimit posix_madvise waitpid lstat])
1092 AM_LANGINFO_CODESET
1093
1094 # Check the return and argument types of ptrace.  No canned test for
1095 # this, so roll our own.
1096 gdb_ptrace_headers='
1097 #if HAVE_SYS_TYPES_H
1098 # include <sys/types.h>
1099 #endif
1100 #if HAVE_SYS_PTRACE_H
1101 # include <sys/ptrace.h>
1102 #endif
1103 #if HAVE_UNISTD_H
1104 # include <unistd.h>
1105 #endif
1106 '
1107 # There is no point in checking if we don't have a prototype.
1108 AC_CHECK_DECLS(ptrace, [], [
1109   : ${gdb_cv_func_ptrace_ret='int'}
1110   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1111 ], $gdb_ptrace_headers)
1112 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1113 # empty argument list, so check for that explicitly.
1114 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1115   AC_TRY_COMPILE($gdb_ptrace_headers,
1116     [extern long ptrace (enum __ptrace_request, ...);],
1117     gdb_cv_func_ptrace_ret='long',
1118     AC_TRY_COMPILE($gdb_ptrace_headers,
1119       [extern int ptrace ();],
1120       gdb_cv_func_ptrace_ret='int',
1121       gdb_cv_func_ptrace_ret='long')))
1122 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1123   [Define as the return type of ptrace.])
1124 # Check argument types.
1125 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1126   AC_TRY_COMPILE($gdb_ptrace_headers,
1127     [extern long ptrace (enum __ptrace_request, ...);],
1128     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1129 for gdb_arg1 in 'int' 'long'; do
1130  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1131   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1132    for gdb_arg4 in 'int' 'long'; do
1133      AC_TRY_COMPILE($gdb_ptrace_headers, [
1134 extern $gdb_cv_func_ptrace_ret
1135   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1136 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1137     break 4;])
1138     for gdb_arg5 in 'int *' 'int' 'long'; do
1139      AC_TRY_COMPILE($gdb_ptrace_headers, [
1140 extern $gdb_cv_func_ptrace_ret
1141   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1142 ], [
1143 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1144     break 5;])
1145     done
1146    done
1147   done
1148  done
1149 done
1150 # Provide a safe default value.
1151 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1152 ])])
1153 ac_save_IFS=$IFS; IFS=','
1154 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1155 IFS=$ac_save_IFS
1156 shift
1157 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1158   [Define to the type of arg 3 for ptrace.])
1159 if test -n "$[5]"; then
1160   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1161     [Define to the type of arg 5 for ptrace.])
1162 fi
1163
1164 dnl AC_FUNC_SETPGRP does not work when cross compiling
1165 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1166 if test "$cross_compiling" = no; then
1167   AC_FUNC_SETPGRP
1168 else
1169   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1170     [AC_TRY_COMPILE([
1171 #include <unistd.h>
1172 ], [
1173   if (setpgrp(1,1) == -1)
1174     exit (0);
1175   else
1176     exit (1);
1177 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1178 if test $ac_cv_func_setpgrp_void = yes; then
1179   AC_DEFINE(SETPGRP_VOID, 1)
1180 fi
1181 fi
1182
1183 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1184 # since sigsetjmp might only be defined as a macro.
1185 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1186 [AC_TRY_COMPILE([
1187 #include <setjmp.h>
1188 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1189 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1190 if test $gdb_cv_func_sigsetjmp = yes; then
1191   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1192 fi
1193
1194 # Assume we'll default to using the included libiberty regex.
1195 gdb_use_included_regex=yes
1196
1197 # However, if the system regex is GNU regex, then default to *not*
1198 # using the included regex.
1199 AC_CACHE_CHECK(
1200   [for GNU regex],
1201   [gdb_cv_have_gnu_regex],
1202   [AC_TRY_COMPILE(
1203     [#include <gnu-versions.h>],
1204     [#define REGEX_INTERFACE_VERSION 1
1205 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1206 # error "Version mismatch"
1207 #endif],
1208     gdb_cv_have_gnu_regex=yes,
1209     gdb_cv_have_gnu_regex=no)])
1210 if test $gdb_cv_have_gnu_regex = yes; then
1211   gdb_use_included_regex=no
1212 fi
1213
1214 AC_ARG_WITH(included-regex,
1215   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1216   gdb_with_regex=$withval,
1217   gdb_with_regex=$gdb_use_included_regex)
1218 if test "$gdb_with_regex" = yes; then
1219   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1220     [Define to 1 if the regex included in libiberty should be used.])
1221 fi
1222
1223 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1224 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1225 [#include <sys/param.h>
1226 #include <sys/proc.h>
1227 ])
1228
1229 # See if <sys/lwp.h> defines `struct lwp`.
1230 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1231 [AC_TRY_COMPILE([#include <sys/param.h>
1232 #include <sys/lwp.h>], [struct lwp l;],
1233 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1234 if test $gdb_cv_struct_lwp = yes; then
1235   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1236             [Define to 1 if your system has struct lwp.])
1237 fi
1238
1239 # See if <machine/reg.h> degines `struct reg'.
1240 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1241 [AC_TRY_COMPILE([#include <sys/types.h>
1242 #include <machine/reg.h>], [struct reg r;],
1243 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1244 if test $gdb_cv_struct_reg = yes; then
1245   AC_DEFINE(HAVE_STRUCT_REG, 1,
1246             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1247 fi
1248
1249 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1250 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1251 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1252                  [#include <machine/reg.h>])
1253
1254 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1255 AC_MSG_CHECKING(for PTRACE_GETREGS)
1256 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1257 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1258                 [PTRACE_GETREGS;],
1259                 [gdb_cv_have_ptrace_getregs=yes],
1260                 [gdb_cv_have_ptrace_getregs=no])])
1261 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1262 if test $gdb_cv_have_ptrace_getregs = yes; then
1263   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1264   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1265 fi
1266
1267 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1268 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1269 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1270 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1271                 [PTRACE_GETFPXREGS;],
1272                 [gdb_cv_have_ptrace_getfpxregs=yes],
1273                 [gdb_cv_have_ptrace_getfpxregs=no])])
1274 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1275 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1276   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1277   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1278 fi
1279
1280 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1281 AC_MSG_CHECKING(for PT_GETDBREGS)
1282 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1283 [AC_TRY_COMPILE([#include <sys/types.h>
1284 #include <sys/ptrace.h>],
1285                 [PT_GETDBREGS;],
1286                 [gdb_cv_have_pt_getdbregs=yes],
1287                 [gdb_cv_have_pt_getdbregs=no])])
1288 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1289 if test $gdb_cv_have_pt_getdbregs = yes; then
1290   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1291   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1292 fi
1293
1294 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1295 AC_MSG_CHECKING(for PT_GETXMMREGS)
1296 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1297 [AC_TRY_COMPILE([#include <sys/types.h>
1298 #include <sys/ptrace.h>],
1299                 [PT_GETXMMREGS;],
1300                 [gdb_cv_have_pt_getxmmregs=yes],
1301                 [gdb_cv_have_pt_getxmmregs=no])])
1302 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1303 if test $gdb_cv_have_pt_getxmmregs = yes; then
1304   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1305   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1306 fi
1307
1308 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1309
1310 if test "${target}" = "${host}"; then
1311   case "${host}" in
1312   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1313       AC_DEFINE(NEW_PROC_API, 1,
1314       [Define if you want to use new multi-fd /proc interface
1315        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1316       ;;
1317   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1318       AC_DEFINE(NEW_PROC_API, 1,
1319       [Define if you want to use new multi-fd /proc interface
1320        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1321       ;;
1322   mips-sgi-irix5*)
1323       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1324       AC_DEFINE([_KMEMUSER], 1,
1325       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1326        around a <sys/proc.h> problem on IRIX 5.])
1327       ;;
1328   esac
1329 fi
1330
1331 if test "$ac_cv_header_sys_procfs_h" = yes; then
1332   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1333   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1334   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1335   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1336   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1337   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1338   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1339   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1340   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1341   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1342   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1343   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1344   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1345   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1346
1347
1348   dnl Check for broken prfpregset_t type
1349
1350   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1351   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1352   dnl instead of the struct itself).  We detect this here, and work
1353   dnl around it in gdb_proc_service.h.
1354
1355   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1356     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1357     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1358       [AC_TRY_RUN([#include <sys/procfs.h>
1359        int main ()
1360        {
1361          if (sizeof (prfpregset_t) == sizeof (void *))
1362            return 1;
1363          return 0;
1364        }],
1365        gdb_cv_prfpregset_t_broken=no,
1366        gdb_cv_prfpregset_t_broken=yes,
1367        gdb_cv_prfpregset_t_broken=yes)])
1368     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1369     if test $gdb_cv_prfpregset_t_broken = yes; then
1370       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1371       [Define if the prfpregset_t type is broken.])
1372     fi
1373   fi
1374
1375   dnl Check for PIOCSET ioctl entry
1376
1377   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1378   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1379   [AC_TRY_COMPILE([#include <unistd.h>
1380 #include <sys/types.h>
1381 #include <sys/procfs.h>
1382 ], [
1383     int dummy;;
1384     dummy = ioctl(0, PIOCSET, &dummy);
1385   ],
1386   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1387   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1388   if test $gdb_cv_have_procfs_piocset = yes; then
1389     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1390     [Define if ioctl argument PIOCSET is available.])
1391   fi
1392 fi
1393
1394 dnl For native ports (host == target), check to see what kind of
1395 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1396 if test ${host} = ${target} ; then
1397   dnl Check for struct link_map with l_ members which are indicative
1398   dnl of SVR4-like shared libraries
1399
1400   AC_MSG_CHECKING(for member l_addr in struct link_map)
1401   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1402     [AC_TRY_COMPILE([#include <link.h>],
1403                     [struct link_map lm; (void) lm.l_addr;],
1404                     gdb_cv_have_struct_link_map_with_l_members=yes,
1405                     gdb_cv_have_struct_link_map_with_l_members=no)])
1406   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1407   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1408     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1409     [Define if <link.h> exists and defines struct link_map which has
1410      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1411      SVR4-like systems.)])
1412   fi
1413
1414   dnl Check for struct link_map with lm_ members which are indicative
1415   dnl of SunOS-like shared libraries
1416
1417   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1418   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1419     [AC_TRY_COMPILE([#include <sys/types.h>
1420 #include <link.h>],
1421                     [struct link_map lm; (void) lm.lm_addr;],
1422                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1423                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1424   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1425   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1426     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1427     [Define if <link.h> exists and defines struct link_map which has
1428      members with an ``lm_'' prefix.  (For SunOS.)])
1429   fi
1430
1431   dnl Check for struct so_map with som_ members which are found on
1432   dnl some *BSD systems.
1433
1434   AC_MSG_CHECKING(for member som_addr in struct so_map)
1435   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1436     [AC_TRY_COMPILE([#include <sys/types.h>
1437 #ifdef HAVE_NLIST_H
1438 #include <nlist.h>
1439 #endif
1440 #include <link.h>],
1441                     [struct so_map lm; (void) lm.som_addr;],
1442                     gdb_cv_have_struct_so_map_with_som_members=yes,
1443                     gdb_cv_have_struct_so_map_with_som_members=no)])
1444   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1445   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1446     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1447     [Define if <link.h> exists and defines a struct so_map which has
1448      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1449   fi
1450
1451   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1452   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1453
1454   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1455   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1456     [AC_TRY_COMPILE([#define _SYSCALL32
1457 #include <sys/link.h>], [struct link_map32 l;],
1458      gdb_cv_have_struct_link_map32=yes,
1459      gdb_cv_have_struct_link_map32=no)])
1460   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1461   if test $gdb_cv_have_struct_link_map32 = yes; then
1462     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1463     [Define if <sys/link.h> has struct link_map32])
1464     AC_DEFINE(_SYSCALL32, 1,
1465     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1466   fi
1467 fi
1468
1469 # Check if the compiler supports the `long long' type.
1470
1471 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1472                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1473 [[extern long long foo;]],
1474 [[switch (foo & 2) { case 0: return 1; }]])],
1475                                   gdb_cv_c_long_long=yes,
1476                                   gdb_cv_c_long_long=no)])
1477 if test $gdb_cv_c_long_long = yes; then
1478   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1479             [Define to 1 if the compiler supports long long.])
1480 fi
1481
1482 # Check if the compiler and runtime support printing long longs.
1483
1484 AC_CACHE_CHECK([for long long support in printf],
1485                gdb_cv_printf_has_long_long,
1486                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1487 [[char buf[32];
1488   long long l = 0;
1489   l = (l << 16) + 0x0123;
1490   l = (l << 16) + 0x4567;
1491   l = (l << 16) + 0x89ab;
1492   l = (l << 16) + 0xcdef;
1493   sprintf (buf, "0x%016llx", l);
1494   return (strcmp ("0x0123456789abcdef", buf));]])],
1495                               gdb_cv_printf_has_long_long=yes,
1496                               gdb_cv_printf_has_long_long=no,
1497                               gdb_cv_printf_has_long_long=no)])
1498 if test $gdb_cv_printf_has_long_long = yes; then
1499   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1500             [Define to 1 if the "%ll" format works to print long longs.])
1501 fi
1502
1503 # Check if the compiler and runtime support printing decfloats.
1504
1505 AC_CACHE_CHECK([for decfloat support in printf],
1506                gdb_cv_printf_has_decfloat,
1507                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1508 [[char buf[64];
1509   _Decimal32 d32 = 1.2345df;
1510   _Decimal64 d64 = 1.2345dd;
1511   _Decimal128 d128 = 1.2345dl;
1512   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1513   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1514                               gdb_cv_printf_has_decfloat=yes,
1515                               gdb_cv_printf_has_decfloat=no,
1516                               gdb_cv_printf_has_decfloat=no)])
1517 if test $gdb_cv_printf_has_decfloat = yes; then
1518   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1519             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1520 fi
1521
1522 # Check if the compiler supports the `long double' type.  We can't use
1523 # AC_C_LONG_DOUBLE because that one does additional checks on the
1524 # constants defined in <float.h> that fail on some systems,
1525 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1526
1527 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1528                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1529                                   gdb_cv_c_long_double=yes,
1530                                   gdb_cv_c_long_double=no)])
1531 if test $gdb_cv_c_long_double = yes; then
1532   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1533            [Define to 1 if the compiler supports long double.])
1534 fi
1535
1536 # Check if the compiler and runtime support printing long doubles.
1537
1538 AC_CACHE_CHECK([for long double support in printf],
1539                gdb_cv_printf_has_long_double,
1540                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1541 [[char buf[16];
1542   long double f = 3.141592653;
1543   sprintf (buf, "%Lg", f);
1544   return (strncmp ("3.14159", buf, 7));]])],
1545                               gdb_cv_printf_has_long_double=yes,
1546                               gdb_cv_printf_has_long_double=no,
1547                               gdb_cv_printf_has_long_double=no)])
1548 if test $gdb_cv_printf_has_long_double = yes; then
1549   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1550             [Define to 1 if the "%Lg" format works to print long doubles.])
1551 fi
1552
1553 # Check if the compiler and runtime support scanning long doubles.
1554
1555 AC_CACHE_CHECK([for long double support in scanf],
1556                gdb_cv_scanf_has_long_double,
1557                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1558 [[#include <stdio.h>]],
1559 [[char *buf = "3.141592653";
1560   long double f = 0;
1561   sscanf (buf, "%Lg", &f);
1562   return !(f > 3.14159 && f < 3.14160);]])],
1563                               gdb_cv_scanf_has_long_double=yes,
1564                               gdb_cv_scanf_has_long_double=no,
1565                               gdb_cv_scanf_has_long_double=no)])
1566 if test $gdb_cv_scanf_has_long_double = yes; then
1567   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1568             [Define to 1 if the "%Lg" format works to scan long doubles.])
1569 fi
1570
1571 case ${host_os} in
1572 aix*)
1573   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1574     SAVE_LDFLAGS=$LDFLAGS
1575
1576     case $GCC in
1577     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1578     *) gdb_cv_bigtoc=-bbigtoc ;;
1579     esac
1580
1581     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1582     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1583     LDFLAGS="${SAVE_LDFLAGS}"
1584   ])
1585   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1586   ;;
1587 esac
1588
1589 AC_MSG_CHECKING(for the dynamic export flag)
1590 dynamic_list=false
1591 if test "${gdb_native}" = yes; then
1592    # The dynamically loaded libthread_db needs access to symbols in the gdb
1593    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1594    # may not be supported there.
1595    old_LDFLAGS="$LDFLAGS"
1596    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1597    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1598    LDFLAGS="$LDFLAGS $RDYNAMIC"
1599    if test "${have_libpython}" = no; then
1600      AC_TRY_LINK([], [], [dynamic_list=true])
1601    else
1602      # Workaround http://bugs.python.org/issue4434 where static
1603      # libpythonX.Y.a would get its symbols required for
1604      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1605      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1606      old_CFLAGS="$CFLAGS"
1607      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1608      AC_RUN_IFELSE(
1609        AC_LANG_PROGRAM(
1610          [#include "]${have_libpython}[/Python.h"],
1611          [int err;
1612           Py_Initialize ();
1613           err = PyRun_SimpleString ("import itertools\n");
1614           Py_Finalize ();
1615           return err == 0 ? 0 : 1;]),
1616        [dynamic_list=true], [], [true])
1617      CFLAGS="$old_CFLAGS"
1618    fi
1619    LDFLAGS="$old_LDFLAGS"
1620 fi
1621 if $dynamic_list; then
1622   found="-Wl,--dynamic-list"
1623   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1624 else
1625   found="-rdynamic"
1626   RDYNAMIC="-rdynamic"
1627 fi
1628 AC_SUBST(RDYNAMIC)
1629 AC_MSG_RESULT($found)
1630
1631 dnl For certain native configurations, we need to check whether thread
1632 dnl support can be built in or not.
1633 dnl
1634 dnl Note that we only want this if we are both native (host == target),
1635 dnl and not doing a canadian cross build (build == host).
1636
1637 if test ${build} = ${host} -a ${host} = ${target} ; then
1638    case ${host_os} in
1639    solaris*)
1640       # See if thread_db library is around for Solaris thread debugging.
1641       # Note that we must explicitly test for version 1 of the library
1642       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1643       # the same API.
1644       AC_MSG_CHECKING(for Solaris thread debugging library)
1645       if test -f /usr/lib/libthread_db.so.1 ; then
1646          AC_MSG_RESULT(yes)
1647          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1648          [Define if using Solaris thread debugging.])
1649          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1650          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1651          AC_CHECK_LIB(dl, dlopen)
1652          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1653          # Sun randomly tweaked the prototypes in <proc_service.h>
1654          # at one point.
1655          AC_MSG_CHECKING(if <proc_service.h> is old)
1656          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1657             AC_TRY_COMPILE([
1658                 #include <proc_service.h>
1659                 ps_err_e ps_pdwrite
1660                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1661             ],, gdb_cv_proc_service_is_old=no,
1662                 gdb_cv_proc_service_is_old=yes)
1663          ])
1664          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1665          if test $gdb_cv_proc_service_is_old = yes; then
1666             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1667             [Define if <proc_service.h> on solaris uses int instead of
1668              size_t, and assorted other type changes.])
1669          fi
1670       else
1671          AC_MSG_RESULT(no)
1672       fi
1673       ;;
1674    aix*)
1675       AC_MSG_CHECKING(for AiX thread debugging library)
1676       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1677                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1678                                    [#ifndef PTHDB_VERSION_3
1679                                     #error
1680                                     #endif],
1681                                    gdb_cv_have_aix_thread_debug=yes,
1682                                    gdb_cv_have_aix_thread_debug=no)])
1683       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1684       if test $gdb_cv_have_aix_thread_debug = yes; then
1685          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1686          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1687          LIBS="$LIBS -lpthdebug"
1688
1689          # Older versions of AIX do not provide the declaration for
1690          # the getthrds function (it appears that it was introduced
1691          # with AIX 6.x).
1692          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1693       fi
1694       ;;
1695    esac
1696    AC_SUBST(CONFIG_LDFLAGS)
1697 fi
1698
1699 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1700 dnl other error codes.
1701 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1702    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1703                   gdb_cv_thread_db_h_has_td_notalloc,
1704      AC_TRY_COMPILE(
1705        [#include <thread_db.h>],
1706        [int i = TD_NOTALLOC;],
1707        gdb_cv_thread_db_h_has_td_notalloc=yes,
1708        gdb_cv_thread_db_h_has_td_notalloc=no
1709      )
1710    )
1711    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1712                   gdb_cv_thread_db_h_has_td_version,
1713      AC_TRY_COMPILE(
1714        [#include <thread_db.h>],
1715        [int i = TD_VERSION;],
1716        gdb_cv_thread_db_h_has_td_version=yes,
1717        gdb_cv_thread_db_h_has_td_version=no
1718      )
1719    )
1720    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1721                   gdb_cv_thread_db_h_has_td_notls,
1722      AC_TRY_COMPILE(
1723        [#include <thread_db.h>],
1724        [int i = TD_NOTLS;],
1725        gdb_cv_thread_db_h_has_td_notls=yes,
1726        gdb_cv_thread_db_h_has_td_notls=no
1727      )
1728    )
1729 fi
1730 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1731   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1732             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1733 fi
1734 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1735   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1736             [Define if <thread_db.h> has the TD_VERSION error code.])
1737 fi
1738 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1739   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1740             [Define if <thread_db.h> has the TD_NOTLS error code.])
1741 fi
1742
1743 dnl See if we have a sys/syscall header file that has __NR_tkill.
1744 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1745    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1746                   gdb_cv_sys_syscall_h_has_tkill,
1747      AC_TRY_COMPILE(
1748        [#include <sys/syscall.h>],
1749        [int i = __NR_tkill;],
1750        gdb_cv_sys_syscall_h_has_tkill=yes,
1751        gdb_cv_sys_syscall_h_has_tkill=no
1752      )
1753    )
1754 fi
1755 dnl See if we can issue tkill syscall.
1756 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1757   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1758 fi
1759
1760 dnl Check if we can disable the virtual address space randomization.
1761 dnl The functionality of setarch -R.
1762 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1763 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1764 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1765 #       define ADDR_NO_RANDOMIZE 0x0040000
1766 #      endif
1767        /* Test the flag could be set and stays set.  */
1768        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1769        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1770            return 1])])
1771 AC_RUN_IFELSE([PERSONALITY_TEST],
1772               [have_personality=true],
1773               [have_personality=false],
1774               [AC_LINK_IFELSE([PERSONALITY_TEST],
1775                               [have_personality=true],
1776                               [have_personality=false])])
1777 if $have_personality
1778 then
1779     AC_DEFINE([HAVE_PERSONALITY], 1,
1780               [Define if you support the personality syscall.])
1781 fi
1782
1783 dnl Handle optional features that can be enabled.
1784
1785 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1786 # except that the argument to --with-sysroot is optional.
1787 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1788 if test "x$with_sysroot" = xyes; then
1789   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1790 fi
1791 AC_ARG_WITH(sysroot,
1792   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1793                  [search for usr/lib et al within DIR]),
1794   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1795 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1796               [search for usr/lib et al within DIR])
1797 AC_SUBST(TARGET_SYSTEM_ROOT)
1798 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1799
1800 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1801     [automatically load a system-wide gdbinit file],
1802     [])
1803
1804 AC_ARG_ENABLE(werror,
1805   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1806   [case "${enableval}" in
1807      yes | y) ERROR_ON_WARNING="yes" ;;
1808      no | n)  ERROR_ON_WARNING="no" ;;
1809      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1810    esac])
1811
1812 # Enable -Werror by default when using gcc
1813 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1814     ERROR_ON_WARNING=yes
1815 fi
1816
1817 WERROR_CFLAGS=""
1818 if test "${ERROR_ON_WARNING}" = yes ; then
1819     WERROR_CFLAGS="-Werror"
1820 fi
1821
1822 # The entries after -Wno-pointer-sign are disabled warnings which may
1823 # be enabled in the future, which can not currently be used to build
1824 # GDB.
1825 # NOTE: If you change this list, remember to update
1826 # gdb/doc/gdbint.texinfo.
1827 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1828 -Wformat-nonliteral -Wno-pointer-sign \
1829 -Wno-unused -Wunused-value -Wunused-function \
1830 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes"
1831
1832 # Enable -Wno-format by default when using gcc on mingw since many
1833 # GCC versions complain about %I64.
1834 case "${host}" in
1835   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1836 esac
1837
1838 AC_ARG_ENABLE(build-warnings,
1839 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1840 [case "${enableval}" in
1841   yes)  ;;
1842   no)   build_warnings="-w";;
1843   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1844         build_warnings="${build_warnings} ${t}";;
1845   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1846         build_warnings="${t} ${build_warnings}";;
1847   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1848 esac
1849 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1850   echo "Setting compiler warning flags = $build_warnings" 6>&1
1851 fi])dnl
1852 AC_ARG_ENABLE(gdb-build-warnings,
1853 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1854 [case "${enableval}" in
1855   yes)  ;;
1856   no)   build_warnings="-w";;
1857   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1858         build_warnings="${build_warnings} ${t}";;
1859   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1860         build_warnings="${t} ${build_warnings}";;
1861   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1862 esac
1863 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1864   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1865 fi])dnl
1866 WARN_CFLAGS=""
1867 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1868 then
1869     AC_MSG_CHECKING(compiler warning flags)
1870     # Separate out the -Werror flag as some files just cannot be
1871     # compiled with it enabled.
1872     for w in ${build_warnings}; do
1873         case $w in
1874         -Werr*) WERROR_CFLAGS=-Werror ;;
1875         *) # Check that GCC accepts it
1876             saved_CFLAGS="$CFLAGS"
1877             CFLAGS="$CFLAGS $w"
1878             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1879             CFLAGS="$saved_CFLAGS"
1880         esac
1881     done
1882     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1883 fi
1884 AC_SUBST(WARN_CFLAGS)
1885 AC_SUBST(WERROR_CFLAGS)
1886
1887 # In the Cygwin environment, we need some additional flags.
1888 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1889 [AC_EGREP_CPP(lose, [
1890 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1891 lose
1892 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1893
1894
1895 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1896 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1897 case ${host} in
1898   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1899   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1900   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1901 esac
1902 AC_SUBST(SER_HARDWIRE)
1903
1904 # libreadline needs libuser32.a in a cygwin environment
1905 WIN32LIBS=
1906 if test x$gdb_cv_os_cygwin = xyes; then
1907     WIN32LIBS="-luser32"
1908     case "${target}" in
1909         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1910         ;;
1911     esac
1912 fi
1913
1914 # The ser-tcp.c module requires sockets.
1915 case ${host} in
1916   *mingw32*)
1917     AC_DEFINE(USE_WIN32API, 1,
1918               [Define if we should use the Windows API, instead of the
1919                POSIX API.  On Windows, we use the Windows API when
1920                building for MinGW, but the POSIX API when building
1921                for Cygwin.])
1922     WIN32LIBS="$WIN32LIBS -lws2_32"
1923     ;;
1924 esac
1925 AC_SUBST(WIN32LIBS)
1926
1927 # Add ELF support to GDB, but only if BFD includes ELF support.
1928 OLD_CFLAGS=$CFLAGS
1929 OLD_LDFLAGS=$LDFLAGS
1930 OLD_LIBS=$LIBS
1931 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1932 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1933 # always want our bfd.
1934 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1935 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1936 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1937 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1938 if test "$plugins" = "yes"; then
1939   LIBS="-ldl $LIBS"
1940 fi
1941 LIBS="-lbfd -liberty $intl $LIBS"
1942 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1943 [AC_TRY_LINK(
1944 [#include <stdlib.h>
1945 #include "bfd.h"
1946 #include "elf-bfd.h"
1947 ],
1948 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1949 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1950 if test $gdb_cv_var_elf = yes; then
1951   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
1952   AC_DEFINE(HAVE_ELF, 1,
1953             [Define if ELF support should be included.])
1954   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1955   if test "$plugins" = "yes"; then
1956     OLD_LIBS="-ldl $OLD_LIBS"
1957   fi
1958 fi
1959 CFLAGS=$OLD_CFLAGS
1960 LDFLAGS=$OLD_LDFLAGS
1961 LIBS=$OLD_LIBS
1962
1963 # Add any host-specific objects to GDB.
1964 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1965
1966 LIBGUI="../libgui/src/libgui.a"
1967 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1968 AC_SUBST(LIBGUI)
1969 AC_SUBST(GUI_CFLAGS_X)
1970
1971 WIN32LDAPP=
1972 AC_SUBST(WIN32LIBS)
1973 AC_SUBST(WIN32LDAPP)
1974
1975 case "${host}" in
1976 *-*-cygwin* | *-*-mingw* )
1977     configdir="win"
1978     ;;
1979 *)
1980     configdir="unix"
1981     ;;
1982 esac
1983
1984 GDBTKLIBS=
1985 if test "${enable_gdbtk}" = "yes"; then
1986
1987     # Gdbtk must have an absolute path to srcdir in order to run
1988     # properly when not installed.
1989     here=`pwd`
1990     cd ${srcdir}
1991     GDBTK_SRC_DIR=`pwd`
1992     cd $here
1993
1994     SC_PATH_TCLCONFIG
1995
1996     # If $no_tk is nonempty, then we can't do Tk, and there is no
1997     # point to doing Tcl.
1998     SC_PATH_TKCONFIG
1999
2000     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2001         SC_LOAD_TCLCONFIG
2002
2003         # Check for in-tree tcl
2004         here=`pwd`
2005         cd ${srcdir}/..
2006         topdir=`pwd`
2007         cd ${here}
2008
2009         intree="no"
2010         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2011           intree="yes"
2012         fi
2013
2014         # Find Tcl private headers
2015         if test x"${intree}" = xno; then
2016           CY_AC_TCL_PRIVATE_HEADERS
2017           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2018           TCL_LIBRARY="${TCL_LIB_SPEC}"
2019           TCL_DEPS=""
2020         else
2021           # If building tcl in the same src tree, private headers
2022           # are not needed, but we need to be sure to use the right
2023           # headers library
2024           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2025           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2026           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2027         fi
2028         AC_SUBST(TCL_INCLUDE)
2029         AC_SUBST(TCL_LIBRARY)
2030         AC_SUBST(TCL_DEPS)
2031
2032         SC_LOAD_TKCONFIG
2033
2034         # Check for in-tree Tk
2035         intree="no"
2036         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2037           intree="yes"
2038         fi
2039
2040         # Find Tk private headers
2041         if test x"${intree}" = xno; then
2042           CY_AC_TK_PRIVATE_HEADERS
2043           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2044           TK_LIBRARY=${TK_LIB_SPEC}
2045           TK_DEPS=""
2046         else
2047           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2048           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2049           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2050         fi
2051         AC_SUBST(TK_INCLUDE)
2052         AC_SUBST(TK_LIBRARY)
2053         AC_SUBST(TK_DEPS)
2054         AC_SUBST(TK_XINCLUDES)
2055
2056         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2057
2058         # Include some libraries that Tcl and Tk want.
2059         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2060         # Yes, the ordering seems wrong here.  But it isn't.
2061         # TK_LIBS is the list of libraries that need to be linked
2062         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2063         # were in LIBS then any link tests after this point would
2064         # try to include things like `$(LIBGUI)', which wouldn't work.
2065         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2066
2067         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2068         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2069         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2070         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2071         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2072         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2073         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2074
2075         if test x$gdb_cv_os_cygwin = xyes; then
2076           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2077           WIN32LDAPP="-Wl,--subsystem,console"
2078           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2079         fi
2080
2081         AC_CONFIG_SUBDIRS(gdbtk)
2082     fi
2083 fi
2084
2085 AC_SUBST(X_CFLAGS)
2086 AC_SUBST(X_LDFLAGS)
2087 AC_SUBST(X_LIBS)
2088 AC_SUBST(GDBTKLIBS)
2089 AC_SUBST(GDBTK_CFLAGS)
2090 AC_SUBST(GDBTK_SRC_DIR)
2091
2092 AC_PATH_X
2093
2094 # Unlike the sim directory, whether a simulator is linked is controlled by
2095 # presence of a gdb_sim definition in the target configure.tgt entry.
2096 # This code just checks for a few cases where we'd like to ignore those
2097 # definitions, even when they're present in the '.mt' file.  These cases
2098 # are when --disable-sim is specified, or if the simulator directory is
2099 # not part of the source tree.
2100 #
2101 AC_ARG_ENABLE(sim,
2102 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2103 [echo "enable_sim = $enable_sim";
2104  echo "enableval = ${enableval}";
2105  case "${enableval}" in
2106   yes) ignore_sim=false ;;
2107   no)  ignore_sim=true ;;
2108   *)   ignore_sim=false ;;
2109  esac],
2110 [ignore_sim=false])
2111
2112 if test ! -d "${srcdir}/../sim"; then
2113   ignore_sim=true
2114 fi
2115
2116 SIM=
2117 SIM_OBS=
2118 if test "${ignore_sim}" = "false"; then
2119   if test x"${gdb_sim}" != x ; then
2120     SIM="${gdb_sim}"
2121     SIM_OBS="remote-sim.o"
2122     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2123   fi
2124 fi
2125 AC_SUBST(SIM)
2126 AC_SUBST(SIM_OBS)
2127
2128 AC_SUBST(ENABLE_CFLAGS)
2129 AC_SUBST(PROFILE_CFLAGS)
2130
2131 AC_SUBST(CONFIG_OBS)
2132 AC_SUBST(CONFIG_DEPS)
2133 AC_SUBST(CONFIG_SRCS)
2134 AC_SUBST(CONFIG_ALL)
2135 AC_SUBST(CONFIG_CLEAN)
2136 AC_SUBST(CONFIG_INSTALL)
2137 AC_SUBST(CONFIG_UNINSTALL)
2138
2139 # List of host floatformats.
2140 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2141 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2142 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2143
2144 # target_subdir is used by the testsuite to find the target libraries.
2145 target_subdir=
2146 if test "${host}" != "${target}"; then
2147     target_subdir="${target_alias}/"
2148 fi
2149 AC_SUBST(target_subdir)
2150
2151 frags=
2152 if test "${gdb_native}" = "yes"; then
2153   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2154   if test ! -f ${host_makefile_frag}; then
2155     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2156   fi
2157   frags="$frags $host_makefile_frag"
2158 else
2159   host_makefile_frag=/dev/null
2160 fi
2161
2162 AC_SUBST_FILE(host_makefile_frag)
2163 AC_SUBST(frags)
2164
2165 changequote(,)dnl
2166 if test "${gdb_native}" = "yes"; then
2167 # We pick this up from the host configuration file (.mh) because we
2168 # do not have a native configuration Makefile fragment.
2169 nativefile=`sed -n '
2170 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2171 ' ${host_makefile_frag}`
2172 fi
2173 changequote([,])
2174
2175 if test x"${gdb_osabi}" != x ; then
2176     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2177                        [Define to the default OS ABI for this configuration.])
2178 fi
2179
2180 # Enable multi-ice-gdb-server.
2181 AC_ARG_ENABLE(multi-ice,
2182 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2183   [case $enableval in
2184     yes | no)
2185       ;;
2186     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2187   esac])
2188 if test "x$enable_multi_ice" = xyes; then
2189    AC_CONFIG_SUBDIRS(multi-ice)
2190 fi
2191
2192 AC_ARG_ENABLE(gdbserver,
2193 AS_HELP_STRING([--enable-gdbserver],
2194                [automatically build gdbserver (yes/no/auto, default is auto)]),
2195 [case "${enableval}" in
2196   yes| no|auto) ;;
2197   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2198 esac],[enable_gdbserver=auto])
2199
2200 # We only build gdbserver automatically in a native configuration, and
2201 # only if the user did not explicitly disable its build.
2202 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2203   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2204   if test "x$build_gdbserver" = xyes; then
2205     AC_MSG_RESULT(yes)
2206     AC_CONFIG_SUBDIRS(gdbserver)
2207     gdbserver_build_enabled=yes
2208   else
2209     AC_MSG_RESULT(no)
2210   fi
2211 fi
2212
2213 # If the user explicitly request the gdbserver to be built, verify that
2214 # we were in fact able to enable it.
2215 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2216   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2217 fi
2218
2219 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2220 # to an empty version.
2221
2222 files=
2223 links=
2224
2225 rm -f nm.h
2226 if test "${nativefile}" != ""; then
2227     case "${nativefile}" in
2228       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2229       * ) GDB_NM_FILE="${nativefile}"
2230     esac
2231     files="${files} ${GDB_NM_FILE}"
2232     links="${links} nm.h"
2233     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2234 fi
2235 AC_SUBST(GDB_NM_FILE)
2236
2237 AC_LINK_FILES($files, $links)
2238
2239 dnl Check for exe extension set on certain hosts (e.g. Win32)
2240 AC_EXEEXT
2241
2242 dnl  Detect the character set used by this host.
2243 dnl  At the moment, we just assume it's UTF-8.
2244 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2245           [Define to be a string naming the default host character set.])
2246
2247 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2248 [
2249 case x$CONFIG_HEADERS in
2250 xconfig.h:config.in)
2251 echo > stamp-h ;;
2252 esac
2253 ])
2254
2255 exit 0