gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  48
  49 gnulib_extra_configure_args=
  50 # If large-file support is disabled, make sure gnulib does the same.
  51 if test "$enable_largefile" = no; then
  52 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  53 fi
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  60                   ["$gnulib_extra_configure_args"])
  61
  62 dnl List of object files and targets accumulated by configure.
  63
  64 CONFIG_OBS=
  65 CONFIG_DEPS=
  66 CONFIG_SRCS=
  67 ENABLE_CFLAGS=
  68
  69 CONFIG_ALL=
  70 CONFIG_CLEAN=
  71 CONFIG_INSTALL=
  72 CONFIG_UNINSTALL=
  73
  74 dnl Set up for gettext.
  75 ZW_GNU_GETTEXT_SISTER_DIR
  76
  77 localedir='${datadir}/locale'
  78 AC_SUBST(localedir)
  79
  80 if test x"$USE_NLS" = xyes; then
  81    CONFIG_ALL="$CONFIG_ALL all-po"
  82    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  83    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  84    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  85 fi
  86
  87 GNULIB=build-gnulib/import
  88
  89 # For Makefile dependencies.
  90 GNULIB_STDINT_H=
  91 if test x"$STDINT_H" != x; then
  92   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  93 fi
  94 AC_SUBST(GNULIB_STDINT_H)
  95
  96 PACKAGE=gdb
  97 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  98 AC_SUBST(PACKAGE)
  99
 100 # We never need to detect it in this sub-configure.
 101 # But preserve it for config.status --recheck.
 102 AC_ARG_VAR(MAKEINFO,
 103   [Parent configure detects if it is of sufficient version.])
 104 AC_ARG_VAR(MAKEINFOFLAGS,
 105   [Parameters for MAKEINFO.])
 106
 107 MAKEINFO_EXTRA_FLAGS=""
 108 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 109   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 110   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 111     gdb_cv_have_makeinfo_click=yes
 112   else
 113     gdb_cv_have_makeinfo_click=no
 114   fi])
 115 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 116   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 117 fi
 118 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 119
 120 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 121     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 122     [${libdir}/debug])
 123
 124 # We can't pass paths as command line arguments.
 125 # Mingw32 tries to be clever and will convert the paths for us.
 126 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 127 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 128 # This breaks GDB's relocatable path conversions since paths passed in
 129 # config.h would not get so translated, the path prefixes no longer match.
 130 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 131
 132 # GDB's datadir relocation
 133
 134 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 135     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 136     [${datadir}/gdb])
 137
 138 AC_ARG_WITH(relocated-sources,
 139 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 140 [reloc_srcdir="${withval}"
 141  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 142               [Relocated directory for source files. ])
 143 ])
 144
 145 AC_MSG_CHECKING([for default auto-load directory])
 146 AC_ARG_WITH(auto-load-dir,
 147 AS_HELP_STRING([--with-auto-load-dir=PATH],
 148   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 149   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 150 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 151 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 152               [Directories from which to load auto-loaded scripts.])
 153 AC_MSG_RESULT([$with_auto_load_dir])
 154
 155 AC_MSG_CHECKING([for default auto-load safe-path])
 156 AC_ARG_WITH(auto-load-safe-path,
 157 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 158   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 159 AS_HELP_STRING([--without-auto-load-safe-path],
 160                [do not restrict auto-loaded files locations]),
 161     [if test "$with_auto_load_safe_path" = "no"; then
 162      with_auto_load_safe_path="/"
 163      fi],
 164 [with_auto_load_safe_path="$with_auto_load_dir"])
 165 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 166 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 167               [Directories safe to hold auto-loaded files.])
 168 AC_MSG_RESULT([$with_auto_load_safe_path])
 169
 170 AC_CONFIG_SUBDIRS(testsuite)
 171
 172 # Check whether to support alternative target configurations
 173 AC_ARG_ENABLE(targets,
 174 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 175 [case "${enableval}" in
 176   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 177             ;;
 178   no)       enable_targets= ;;
 179   *)        enable_targets=$enableval ;;
 180 esac])
 181
 182 # Check whether to enable 64-bit support on 32-bit hosts
 183 AC_ARG_ENABLE(64-bit-bfd,
 184 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 185 [case "${enableval}" in
 186   yes)  want64=true  ;;
 187   no)   want64=false ;;
 188   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 189 esac],[want64=false])dnl
 190
 191 # Provide defaults for some variables set by the per-host and per-target
 192 # configuration.
 193 gdb_host_obs=posix-hdep.o
 194
 195 if test "${target}" = "${host}"; then
 196   gdb_native=yes
 197 else
 198   gdb_native=no
 199 fi
 200
 201 . $srcdir/configure.host
 202
 203 # Add in the common host objects.
 204 . $srcdir/common/common.host
 205 gdb_host_obs="$gdb_host_obs $common_host_obs"
 206
 207 # Accumulate some settings from configure.tgt over all enabled targets
 208
 209 TARGET_OBS=
 210 all_targets=
 211 HAVE_NATIVE_GCORE_TARGET=
 212
 213 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 214 do
 215   if test "$targ_alias" = "all"; then
 216     all_targets=true
 217   else
 218     # Canonicalize the secondary target names.
 219     result=`$ac_config_sub $targ_alias 2>/dev/null`
 220     if test -n "$result"; then
 221         targ=$result
 222     else
 223         targ=$targ_alias
 224     fi
 225
 226     . ${srcdir}/configure.tgt
 227
 228     AS_IF([test -z "${gdb_target_obs}"],
 229       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 230
 231     # Target-specific object files
 232     for i in ${gdb_target_obs}; do
 233         case " $TARGET_OBS " in
 234         *" ${i} "*) ;;
 235         *)
 236           TARGET_OBS="$TARGET_OBS ${i}"
 237           ;;
 238         esac
 239     done
 240
 241     # Check whether this target needs 64-bit CORE_ADDR
 242     if test x${want64} = xfalse; then
 243       . ${srcdir}/../bfd/config.bfd
 244     fi
 245
 246     # Check whether this target is native and supports gcore.
 247     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 248        && $gdb_have_gcore; then
 249       HAVE_NATIVE_GCORE_TARGET=1
 250     fi
 251   fi
 252 done
 253
 254 if test x${all_targets} = xtrue; then
 255
 256   # We want all 64-bit targets if we either:
 257   #  - run on a 64-bit host  or
 258   #  - already require 64-bit support for some other target  or
 259   #  - the --enable-64-bit-bfd option was supplied
 260   # Otherwise we only support all 32-bit targets.
 261   #
 262   # NOTE: This test must be in sync with the corresponding
 263   #       tests in BFD!
 264
 265   if test x${want64} = xfalse; then
 266     AC_CHECK_SIZEOF(long)
 267     if test "x${ac_cv_sizeof_long}" = "x8"; then
 268       want64=true
 269     fi
 270   fi
 271   if test x${want64} = xtrue; then
 272     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 273   else
 274     TARGET_OBS='$(ALL_TARGET_OBS)'
 275   fi
 276 fi
 277
 278 AC_SUBST(TARGET_OBS)
 279 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 280
 281 # For other settings, only the main target counts.
 282 gdb_sim=
 283 gdb_osabi=
 284 build_gdbserver=
 285 targ=$target; . ${srcdir}/configure.tgt
 286
 287 # Fetch the default architecture and default target vector from BFD.
 288 targ=$target; . $srcdir/../bfd/config.bfd
 289
 290 # We only want the first architecture, so strip off the others if
 291 # there is more than one.
 292 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 293
 294 if test "x$targ_archs" != x; then
 295   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 296     [Define to BFD's default architecture. ])
 297 fi
 298 if test "x$targ_defvec" != x; then
 299   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 300     [Define to BFD's default target vector. ])
 301 fi
 302
 303 # The CLI cannot be disabled yet, but may be in the future.
 304
 305 # Enable CLI.
 306 AC_ARG_ENABLE(gdbcli,
 307 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 308   [case $enableval in
 309     yes)
 310       ;;
 311     no)
 312       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 313     *)
 314       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 315   esac],
 316   [enable_gdbcli=yes])
 317 if test x"$enable_gdbcli" = xyes; then
 318   if test -d $srcdir/cli; then
 319     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 320     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 321     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 322     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 323   fi
 324 fi
 325
 326 # Enable MI.
 327 AC_ARG_ENABLE(gdbmi,
 328 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 329   [case $enableval in
 330     yes | no)
 331       ;;
 332     *)
 333       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 334   esac],
 335   [enable_gdbmi=yes])
 336 if test x"$enable_gdbmi" = xyes; then
 337   if test -d $srcdir/mi; then
 338     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 339     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 340     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 341     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 342   fi
 343 fi
 344
 345 # Enable TUI.
 346 AC_ARG_ENABLE(tui,
 347 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 348   [case $enableval in
 349     yes | no | auto)
 350       ;;
 351     *)
 352       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 353   esac],enable_tui=auto)
 354
 355 # Enable gdbtk.
 356 AC_ARG_ENABLE(gdbtk,
 357 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 358   [case $enableval in
 359     yes | no)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 363   esac],
 364   [if test -d $srcdir/gdbtk; then
 365     enable_gdbtk=yes
 366   else
 367     enable_gdbtk=no
 368   fi])
 369 # We unconditionally disable gdbtk tests on selected platforms.
 370 case $host_os in
 371   go32* | windows*)
 372     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 373     enable_gdbtk=no ;;
 374 esac
 375
 376 # Libunwind support for ia64.
 377
 378 AC_ARG_WITH(libunwind-ia64,
 379 AS_HELP_STRING([--with-libunwind-ia64],
 380                [use libunwind frame unwinding for ia64 targets]),,
 381             [with_libunwind_ia64=auto])
 382
 383 # Backward compatibility option.
 384 if test "${with_libunwind+set}" = set; then
 385   if test x"$with_libunwind_ia64" != xauto; then
 386     AC_MSG_ERROR(
 387       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 388   fi
 389   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 390   with_libunwind_ia64="$with_libunwind"
 391 fi
 392
 393 case "$with_libunwind_ia64" in
 394   yes | no)
 395     ;;
 396   auto)
 397     AC_CHECK_HEADERS(libunwind-ia64.h)
 398     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 399     ;;
 400   *)
 401     AC_MSG_ERROR(
 402       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 403     ;;
 404 esac
 405
 406 if test x"$with_libunwind_ia64" = xyes; then
 407   AC_CHECK_HEADERS(libunwind-ia64.h)
 408   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 409     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 410   fi
 411   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 412   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 413   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 414 fi
 415
 416 opt_curses=no
 417 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 418
 419 prefer_curses=no
 420 if test "$opt_curses" = "yes"; then
 421   prefer_curses=yes
 422 fi
 423
 424 # Profiling support.
 425 AC_ARG_ENABLE(profiling,
 426 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 427   [case $enableval in
 428     yes | no)
 429       ;;
 430     *)
 431       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 432   esac],
 433  [enable_profiling=no])
 434
 435 AC_CHECK_FUNCS(monstartup _mcleanup)
 436 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 437 [AC_TRY_LINK(
 438 [#include <stdlib.h>
 439 extern char _etext;
 440 ],
 441 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 442 if test $ac_cv_var__etext = yes; then
 443   AC_DEFINE(HAVE__ETEXT, 1,
 444             [Define to 1 if your system has the _etext variable. ])
 445 fi
 446 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char etext;
 450 ],
 451 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 452 if test $ac_cv_var_etext = yes; then
 453   AC_DEFINE(HAVE_ETEXT, 1,
 454             [Define to 1 if your system has the etext variable. ])
 455 fi
 456 if test "$enable_profiling" = yes ; then
 457   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 458     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 459   fi
 460   PROFILE_CFLAGS=-pg
 461   OLD_CFLAGS="$CFLAGS"
 462   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 463
 464   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 465     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 466      ac_cv_cc_supports_pg=no)])
 467
 468   if test $ac_cv_cc_supports_pg = no; then
 469     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 470   fi
 471
 472   CFLAGS="$OLD_CFLAGS"
 473 fi
 474
 475 ACX_PKGVERSION([GDB])
 476 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 477 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 478 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 479
 480 # --------------------- #
 481 # Checks for programs.  #
 482 # --------------------- #
 483
 484 AC_PROG_AWK
 485 AC_PROG_INSTALL
 486 AC_PROG_LN_S
 487 AC_PROG_RANLIB
 488 AC_PROG_YACC
 489
 490 AC_CHECK_TOOL(AR, ar)
 491 AC_CHECK_TOOL(DLLTOOL, dlltool)
 492 AC_CHECK_TOOL(WINDRES, windres)
 493
 494 case $host_os in
 495   gnu*)
 496     # Needed for GNU Hurd hosts.
 497     AC_CHECK_TOOL(MIG, mig)
 498     if test x"$MIG" = x; then
 499       AC_MSG_ERROR([MIG not found but required for $host hosts])
 500     fi
 501     ;;
 502 esac
 503
 504 # ---------------------- #
 505 # Checks for libraries.  #
 506 # ---------------------- #
 507
 508 # We might need to link with -lm; most simulators need it.
 509 AC_CHECK_LIB(m, main)
 510
 511 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 512 AC_SEARCH_LIBS(gethostbyname, nsl)
 513
 514 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 515 AC_SEARCH_LIBS(socketpair, socket)
 516
 517 # Link in zlib if we can.  This allows us to read compressed debug sections.
 518 AM_ZLIB
 519
 520 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 521 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 522 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 523   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 524             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 525
 526 # fbsd-nat.c can also use kinfo_getfile.
 527 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 528   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 529             [Define to 1 if your system has the kinfo_getfile function. ])])
 530
 531 AM_ICONV
 532
 533 # GDB may fork/exec the iconv program to get the list of supported character
 534 # sets.  Allow the user to specify where to find it.
 535 # There are several factors affecting the choice of option name:
 536 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 537 #   the build-time location of libiconv files.
 538 # - The program we need to find is iconv, which comes with glibc.  The user
 539 #   doesn't necessarily have libiconv installed.  Therefore naming this
 540 #   --with-libiconv-foo feels wrong.
 541 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 542 #   defined to work on directories not files (though it really doesn't know
 543 #   the difference).
 544 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 545 #   with --with-libiconv-prefix.
 546 # Putting these together is why the option name is --with-iconv-bin.
 547
 548 AC_ARG_WITH(iconv-bin,
 549 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 550 [iconv_bin="${withval}"
 551  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 552                     [Path of directory of iconv program.])
 553  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 554 ])
 555
 556 # For the TUI, we need enhanced curses functionality.
 557 if test x"$enable_tui" != xno; then
 558   prefer_curses=yes
 559 fi
 560
 561 curses_found=no
 562 if test x"$prefer_curses" = xyes; then
 563   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 564   # curses library because the latter might not provide all the
 565   # functionality we need.  However, this leads to problems on systems
 566   # where the linker searches /usr/local/lib, but the compiler doesn't
 567   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 568   # default installation of ncurses on alpha*-dec-osf* will lead to such
 569   # a situation.
 570   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 571
 572   if test "$ac_cv_search_waddstr" != no; then
 573     curses_found=yes
 574   fi
 575 fi
 576
 577 # Check whether we should enable the TUI, but only do so if we really
 578 # can.
 579 if test x"$enable_tui" != xno; then
 580   if test -d $srcdir/tui; then
 581     if test "$curses_found" != no; then
 582       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 583       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 584       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 585       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 586     else
 587       if test x"$enable_tui" = xyes; then
 588         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 589       else
 590         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 591       fi
 592     fi
 593   fi
 594 fi
 595
 596 # Since GDB uses Readline, we need termcap functionality.  In many
 597 # cases this will be provided by the curses library, but some systems
 598 # have a separate termcap library, or no curses library at all.
 599
 600 case $host_os in
 601   cygwin*)
 602     if test -d $srcdir/libtermcap; then
 603       LIBS="../libtermcap/libtermcap.a $LIBS"
 604       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 605     fi ;;
 606   go32* | *djgpp*)
 607     ac_cv_search_tgetent="none required"
 608     ;;
 609 esac
 610
 611 # These are the libraries checked by Readline.
 612 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncursesw ncurses])
 613
 614 if test "$ac_cv_search_tgetent" = no; then
 615   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 616 fi
 617
 618 AC_ARG_WITH([system-readline],
 619   [AS_HELP_STRING([--with-system-readline],
 620                   [use installed readline library])])
 621
 622 if test "$with_system_readline" = yes; then
 623   READLINE=-lreadline
 624   READLINE_DEPS=
 625   READLINE_CFLAGS=
 626   READLINE_TEXI_INCFLAG=
 627 else
 628   READLINE='$(READLINE_DIR)/libreadline.a'
 629   READLINE_DEPS='$(READLINE)'
 630   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 631   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 632 fi
 633 AC_SUBST(READLINE)
 634 AC_SUBST(READLINE_DEPS)
 635 AC_SUBST(READLINE_CFLAGS)
 636 AC_SUBST(READLINE_TEXI_INCFLAG)
 637
 638 # Generate jit-reader.h
 639
 640 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 641 TARGET_PTR=
 642
 643 AC_CHECK_SIZEOF(unsigned long long)
 644 AC_CHECK_SIZEOF(unsigned long)
 645 AC_CHECK_SIZEOF(unsigned __int128)
 646
 647 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 648   TARGET_PTR="unsigned long"
 649 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 650   TARGET_PTR="unsigned long long"
 651 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 652   TARGET_PTR="unsigned __int128"
 653 else
 654   TARGET_PTR="unsigned long"
 655 fi
 656
 657 AC_SUBST(TARGET_PTR)
 658 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 659
 660 AC_SEARCH_LIBS(dlopen, dl)
 661
 662 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 663                 [directory to load the JIT readers from],
 664                 [${libdir}/gdb])
 665
 666 AC_ARG_WITH(expat,
 667   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 668   [], [with_expat=auto])
 669 AC_MSG_CHECKING([whether to use expat])
 670 AC_MSG_RESULT([$with_expat])
 671
 672 if test "${with_expat}" = no; then
 673   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 674   HAVE_LIBEXPAT=no
 675 else
 676   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 677                         [XML_Parser p = XML_ParserCreate (0);])
 678   if test "$HAVE_LIBEXPAT" != yes; then
 679     if test "$with_expat" = yes; then
 680       AC_MSG_ERROR([expat is missing or unusable])
 681     else
 682       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 683     fi
 684   else
 685     save_LIBS=$LIBS
 686     LIBS="$LIBS $LIBEXPAT"
 687     AC_CHECK_FUNCS(XML_StopParser)
 688     LIBS=$save_LIBS
 689   fi
 690 fi
 691
 692 AC_ARG_WITH(mpfr,
 693   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 694   [], [with_mpfr=auto])
 695 AC_MSG_CHECKING([whether to use MPFR])
 696 AC_MSG_RESULT([$with_mpfr])
 697
 698 if test "${with_mpfr}" = no; then
 699   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 700   HAVE_LIBMPFR=no
 701 else
 702   AC_LIB_HAVE_LINKFLAGS([mpfr], [], [#include <mpfr.h>],
 703                         [mpfr_exp_t exp; mpfr_t x;
 704                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 705   if test "$HAVE_LIBMPFR" != yes; then
 706     if test "$with_mpfr" = yes; then
 707       AC_MSG_ERROR([MPFR is missing or unusable])
 708     else
 709       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 710     fi
 711   fi
 712 fi
 713
 714 # --------------------- #
 715 # Check for libpython.  #
 716 # --------------------- #
 717
 718 dnl Utility to simplify finding libpython.
 719 dnl $1 = pythonX.Y
 720 dnl $2 = the shell variable to assign the result to
 721 dnl      If libpython is found we store $version here.
 722 dnl $3 = additional flags to add to CPPFLAGS
 723 dnl $4 = additional flags to add to LIBS
 724
 725 AC_DEFUN([AC_TRY_LIBPYTHON],
 726 [
 727   version=$1
 728   define([have_libpython_var],$2)
 729   new_CPPFLAGS=$3
 730   new_LIBS=$4
 731   AC_MSG_CHECKING([for ${version}])
 732   save_CPPFLAGS=$CPPFLAGS
 733   save_LIBS=$LIBS
 734   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 735   LIBS="$LIBS $new_LIBS"
 736   found_usable_python=no
 737   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 738                                  [[Py_Initialize ();]]),
 739                  [have_libpython_var=${version}
 740                   found_usable_python=yes
 741                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 742                   PYTHON_LIBS=$new_LIBS])
 743   CPPFLAGS=$save_CPPFLAGS
 744   LIBS=$save_LIBS
 745   AC_MSG_RESULT([${found_usable_python}])
 746 ])
 747
 748 dnl There are several different values for --with-python:
 749 dnl
 750 dnl no -   Don't include python support.
 751 dnl yes -  Include python support, error if it's missing.
 752 dnl        If we find python in $PATH, use it to fetch configure options,
 753 dnl        otherwise assume the compiler can find it with no help from us.
 754 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 755 dnl auto - Same as "yes", but if python is missing from the system,
 756 dnl        fall back to "no".
 757 dnl /path/to/python/exec-prefix -
 758 dnl        Use the python located in this directory.
 759 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 760 dnl        the compilation parameters.  Otherwise use
 761 dnl        -I/path/to/python/exec-prefix/include,
 762 dnl        -L/path/to/python/exec-prefix/lib.
 763 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 764 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 765 dnl        but is deprecated.
 766 dnl /path/to/python/executable -
 767 dnl        Run python-config.py with this version of python to fetch the
 768 dnl        compilation parameters.
 769 dnl        NOTE: This needn't be the real python executable.
 770 dnl        In a cross-compilation scenario (build != host), this could be
 771 dnl        a shell script that provides what python-config.py provides for
 772 dnl        --ldflags, --includes, --exec-prefix.
 773 dnl python-executable -
 774 dnl        Find python-executable in $PATH, and then handle the same as
 775 dnl        /path/to/python/executable.
 776 dnl
 777 dnl If a python program is specified, it is used to run python-config.py and
 778 dnl is passed --ldflags, --includes, --exec-prefix.
 779
 780 AC_ARG_WITH(python,
 781   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 782   [], [with_python=auto])
 783 AC_MSG_CHECKING([whether to use python])
 784 AC_MSG_RESULT([$with_python])
 785
 786 if test "${with_python}" = no; then
 787   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 788   have_libpython=no
 789 else
 790   case "${with_python}" in
 791   [[\\/]]* | ?:[[\\/]]*)
 792     if test -d ${with_python}; then
 793       # Assume the python binary is ${with_python}/bin/python.
 794       python_prog="${with_python}/bin/python"
 795       python_prefix=
 796       # If python does not exit ${with_python}/bin, then try in
 797       # ${with_python}.  On Windows/MinGW, this is where the Python
 798       # executable is.
 799       if test ! -x "${python_prog}"; then
 800         python_prog="${with_python}/python"
 801         python_prefix=
 802       fi
 803       if test ! -x "${python_prog}"; then
 804         # Fall back to gdb 7.0/7.1 behaviour.
 805         python_prog=missing
 806         python_prefix=${with_python}
 807       fi
 808     elif test -x "${with_python}"; then
 809       # While we can't run python compiled for $host (unless host == build),
 810       # the user could write a script that provides the needed information,
 811       # so we support that.
 812       python_prog=${with_python}
 813       python_prefix=
 814     else
 815       AC_ERROR(invalid value for --with-python)
 816     fi
 817     ;;
 818   */*)
 819     # Disallow --with-python=foo/bar.
 820     AC_ERROR(invalid value for --with-python)
 821     ;;
 822   *)
 823     # The user has either specified auto, yes, or the name of the python
 824     # program assumed to be in $PATH.
 825     python_prefix=
 826     case "${with_python}" in
 827     yes | auto)
 828       if test ${build} = ${host}; then
 829         AC_PATH_PROG(python_prog_path, python, missing)
 830         if test "${python_prog_path}" = missing; then
 831           python_prog=missing
 832         else
 833           python_prog=${python_prog_path}
 834         fi
 835       else
 836         # Not much we can do except assume the cross-compiler will find the
 837         # right files.
 838         python_prog=missing
 839       fi
 840       ;;
 841     *)
 842       # While we can't run python compiled for $host (unless host == build),
 843       # the user could write a script that provides the needed information,
 844       # so we support that.
 845       python_prog="${with_python}"
 846       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 847       if test "${python_prog_path}" = missing; then
 848         AC_ERROR(unable to find python program ${python_prog})
 849       fi
 850       ;;
 851     esac
 852   esac
 853
 854   if test "${python_prog}" != missing; then
 855     # We have a python program to use, but it may be too old.
 856     # Don't flag an error for --with-python=auto (the default).
 857     have_python_config=yes
 858     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 859     if test $? != 0; then
 860       have_python_config=failed
 861       if test "${with_python}" != auto; then
 862         AC_ERROR(failure running python-config --includes)
 863       fi
 864     fi
 865     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 866     if test $? != 0; then
 867       have_python_config=failed
 868       if test "${with_python}" != auto; then
 869         AC_ERROR(failure running python-config --ldflags)
 870       fi
 871     fi
 872     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 873     if test $? != 0; then
 874       have_python_config=failed
 875       if test "${with_python}" != auto; then
 876         AC_ERROR(failure running python-config --exec-prefix)
 877       fi
 878     fi
 879   else
 880     # We do not have a python executable we can use to determine where
 881     # to find the Python headers and libs.  We cannot guess the include
 882     # path from the python_prefix either, because that include path
 883     # depends on the Python version.  So, there is nothing much we can
 884     # do except assume that the compiler will be able to find those files.
 885     python_includes=
 886     python_libs=
 887     have_python_config=no
 888   fi
 889
 890   # If we have python-config, only try the configuration it provides.
 891   # Otherwise fallback on the old way of trying different versions of
 892   # python in turn.
 893
 894   have_libpython=no
 895   if test "${have_python_config}" = yes; then
 896     # Determine the Python version by extracting "-lpython<version>"
 897     # part of the python_libs. <version> is usually X.Y with X and Y
 898     # being decimal numbers, but can also be XY (seen on Windows).
 899     #
 900     # The extraction is performed using sed with a regular expression.
 901     # Initially, the regexp used was using the '?' quantifier to make
 902     # the dot in the version number optional.  Unfortunately, this
 903     # does not work with non-GNU versions of sed because, because of
 904     # what looks like a limitation (the '?' quantifier does not work
 905     # with back-references).  We work around this limitation by using
 906     # the '*' quantifier instead.  It means that, in theory, we might
 907     # match unexpected version strings such as "-lpython2..7", but
 908     # this seems unlikely in practice.  And even if that happens,
 909     # an error will be triggered later on, when checking that version
 910     # number.
 911     python_version=`echo " ${python_libs} " \
 912                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 913     case "${python_version}" in
 914     python*)
 915       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 916                        ${python_includes}, ${python_libs})
 917       ;;
 918     *)
 919       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 920       ;;
 921     esac
 922   elif test "${have_python_config}" != failed; then
 923     if test "${have_libpython}" = no; then
 924       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 925                        ${python_includes}, "${python_libs} -lpython2.7")
 926     fi
 927     if test "${have_libpython}" = no; then
 928       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 929                        ${python_includes}, "${python_libs} -lpython2.6")
 930     fi
 931     if test ${have_libpython} = no; then
 932       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 933                        ${python_includes}, "${python_libs} -lpython2.5")
 934     fi
 935     if test ${have_libpython} = no; then
 936       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 937                        ${python_includes}, "${python_libs} -lpython2.4")
 938     fi
 939   fi
 940   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 941     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 942   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 943     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 944   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 945     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 946   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 947     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 948   fi
 949
 950   if test "${have_libpython}" = no; then
 951     case "${with_python}" in
 952     yes)
 953       AC_MSG_ERROR([python is missing or unusable])
 954       ;;
 955     auto)
 956       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 957       ;;
 958     *)
 959       AC_MSG_ERROR([no usable python found at ${with_python}])
 960       ;;
 961     esac
 962   else
 963     if test -n "${python_prefix}"; then
 964       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 965                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 966       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 967     fi
 968   fi
 969 fi
 970
 971 if test "${have_libpython}" != no; then
 972   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 973   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 974   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 975   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 976   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 977   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 978
 979   # Flags needed to compile Python code (taken from python-config --cflags).
 980   # We cannot call python-config directly because it will output whatever was
 981   # used when compiling the Python interpreter itself, including flags which
 982   # would make the python-related objects be compiled differently from the
 983   # rest of GDB (e.g., -O2 and -fPIC).
 984   if test "${GCC}" = yes; then
 985     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 986   fi
 987
 988   if test "x${tentative_python_cflags}" != x; then
 989     AC_MSG_CHECKING(compiler flags for python code)
 990     for flag in ${tentative_python_cflags}; do
 991       # Check that the compiler accepts it
 992       saved_CFLAGS="$CFLAGS"
 993       CFLAGS="$CFLAGS $flag"
 994       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 995       CFLAGS="$saved_CFLAGS"
 996     done
 997     AC_MSG_RESULT(${PYTHON_CFLAGS})
 998   fi
 999
1000   # On x64 Windows, Python's include headers, and pyconfig.h in
1001   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1002   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1003   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1004   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1005   # The issue was reported to the Python community, but still isn't
1006   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1007
1008   case "$gdb_host" in
1009     mingw64)
1010            if test "${GCC}" = yes; then
1011              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1012            fi
1013            ;;
1014   esac
1015
1016   # Note that "python -m threading" cannot be used to check for
1017   # threading support due to a bug in Python 2.7.3
1018   # (http://bugs.python.org/issue15567).
1019   AC_MSG_CHECKING(whether python supports threads)
1020   saved_CPPFLAGS="${CPPFLAGS}"
1021   CPPFLAGS="${PYTHON_CPPFLAGS}"
1022   # Note that the test is reversed so that python_has_threads=yes on
1023   # unexpected failures.
1024   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1025 #include <Python.h>
1026 #ifdef WITH_THREAD
1027 # error
1028 #endif
1029   ]]), [python_has_threads=no], [python_has_threads=yes])
1030   AC_MSG_RESULT(${python_has_threads})
1031   CPPFLAGS="${saved_CPPFLAGS}"
1032 else
1033   # Even if Python support is not compiled in, we need to have this file
1034   # included so that the "python" command, et.al., still exists.
1035   CONFIG_OBS="$CONFIG_OBS python/python.o"
1036   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1037 fi
1038
1039 # Work around Python http://bugs.python.org/issue10112.  See also
1040 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1041 # no effect.  Note that the only test after this that uses Python is
1042 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1043 # run without -export-dynamic too.
1044 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1045
1046 AC_SUBST(PYTHON_CFLAGS)
1047 AC_SUBST(PYTHON_CPPFLAGS)
1048 AC_SUBST(PYTHON_LIBS)
1049 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1050
1051 # -------------------- #
1052 # Check for libguile.  #
1053 # -------------------- #
1054
1055 dnl Utility to simplify finding libguile.
1056 dnl $1 = pkg-config-program
1057 dnl $2 = space-separate list of guile versions to try
1058 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1059 dnl $4 = the shell variable to assign the result to
1060 dnl      If libguile is found we store "yes" here.
1061
1062 AC_DEFUN([AC_TRY_LIBGUILE],
1063 [
1064   pkg_config=$1
1065   guile_version_list=$2
1066   flag_errors=$3
1067   define([have_libguile_var],$4)
1068   found_usable_guile=checking
1069   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1070   for guile_version in ${guile_version_list}; do
1071     ${pkg_config} --exists ${guile_version} 2>/dev/null
1072     if test $? != 0; then
1073       continue
1074     fi
1075     dnl pkg-config says the package exists, so if we get an error now,
1076     dnl that's bad.
1077     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1078     if test $? != 0; then
1079       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1080     fi
1081     new_LIBS=`${pkg_config} --libs ${guile_version}`
1082     if test $? != 0; then
1083       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1084     fi
1085     dnl If we get this far, great.
1086     found_usable_guile=${guile_version}
1087     break
1088   done
1089   if test "${found_usable_guile}" = "checking"; then
1090     if test "${flag_errors}" = "yes"; then
1091       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1092     else
1093       found_usable_guile=no
1094     fi
1095   fi
1096   dnl One final sanity check.
1097   dnl The user could have said --with-guile=python-2.7.
1098   if test "${found_usable_guile}" != no; then
1099     save_CPPFLAGS=$CPPFLAGS
1100     save_LIBS=$LIBS
1101     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1102     LIBS="$LIBS $new_LIBS"
1103     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1104                                    [[scm_init_guile ();]]),
1105                    [have_libguile_var=yes
1106                     GUILE_CPPFLAGS=$new_CPPFLAGS
1107                     GUILE_LIBS=$new_LIBS],
1108                    [found_usable_guile=no])
1109     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1110     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1111       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1112                 [Define if Guile supports manual finalization.])
1113     )
1114     CPPFLAGS=$save_CPPFLAGS
1115     LIBS=$save_LIBS
1116     if test "${found_usable_guile}" = no; then
1117       if test "${flag_errors}" = yes; then
1118         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1119       fi
1120     fi
1121   fi
1122   AC_MSG_RESULT([${found_usable_guile}])
1123 ])
1124
1125 dnl There are several different values for --with-guile:
1126 dnl
1127 dnl no -   Don't include guile support.
1128 dnl yes -  Include guile support, error if it's missing.
1129 dnl        The pkg-config program must be in $PATH.
1130 dnl auto - Same as "yes", but if guile is missing from the system,
1131 dnl        fall back to "no".
1132 dnl guile-version [guile-version-choice-2 ...] -
1133 dnl        A space-separated list of guile package versions to try.
1134 dnl        These are passed to pkg-config as-is.
1135 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1136 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1137 dnl /path/to/pkg-config -
1138 dnl        Use this pkg-config program.
1139 dnl        NOTE: This needn't be the "real" pkg-config program.
1140 dnl        It could be a shell script.  It is invoked as:
1141 dnl        pkg-config --exists $version
1142 dnl        pkg-config --cflags $version
1143 dnl        pkg-config --libs $version
1144 dnl        pkg-config --variable guild $version
1145 dnl        The script will be called with $version having each value in
1146 dnl        $try_guile_versions until --exists indicates success.
1147
1148 AC_ARG_WITH(guile,
1149   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1150   [], [with_guile=auto])
1151 AC_MSG_CHECKING([whether to use guile])
1152 AC_MSG_RESULT([$with_guile])
1153
1154 dnl We check guile with pkg-config.
1155 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1156
1157 try_guile_versions="guile-2.0"
1158 have_libguile=no
1159 case "${with_guile}" in
1160 no)
1161   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1162   ;;
1163 auto)
1164   if test "${pkg_config_prog_path}" = "missing"; then
1165     AC_MSG_WARN([pkg-config not found, guile support disabled])
1166   else
1167     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1168   fi
1169   ;;
1170 yes)
1171   if test "${pkg_config_prog_path}" = "missing"; then
1172     AC_MSG_ERROR([pkg-config not found])
1173   fi
1174   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1175   ;;
1176 [[\\/]]* | ?:[[\\/]]*)
1177   if test -x "${with_guile}"; then
1178     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1179   else
1180     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1181   fi
1182   ;;
1183 "" | */*)
1184   # Disallow --with=guile="" and --with-guile=foo/bar.
1185   AC_MSG_ERROR([invalid value for --with-guile])
1186   ;;
1187 *)
1188   # A space separate list of guile versions to try, in order.
1189   if test "${pkg_config_prog_path}" = "missing"; then
1190     AC_MSG_ERROR([pkg-config not found])
1191   fi
1192   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1193   ;;
1194 esac
1195
1196 if test "${have_libguile}" != no; then
1197   dnl Get the name of the 'guild' program.
1198   case "${with_guile}" in
1199   [[\\/]]* | ?:[[\\/]]*)
1200     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1201     ;;
1202   *)
1203     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1204     ;;
1205   esac
1206
1207   dnl Make sure guild can handle this host.
1208   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1209   dnl If not, disable guile support.
1210   if test "$ac_cv_guild_ok" = no; then
1211     have_libguile=no
1212     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1213   fi
1214 fi
1215
1216 if test "${have_libguile}" != no; then
1217   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1218   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1219   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1220   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1221   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1222   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1223
1224   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1225   save_LIBS="$LIBS"
1226   save_CPPFLAGS="$CPPFLAGS"
1227   LIBS="$GUILE_LIBS"
1228   CPPFLAGS="$GUILE_CPPFLAGS"
1229   AC_CHECK_FUNCS([scm_new_smob])
1230   LIBS="$save_LIBS"
1231   CPPFLAGS="$save_CPPFLAGS"
1232 else
1233   # Even if Guile support is not compiled in, we need to have these files
1234   # included.
1235   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1236   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1237 fi
1238 AC_SUBST(GUILE_CPPFLAGS)
1239 AC_SUBST(GUILE_LIBS)
1240 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1241
1242 # --------------------- #
1243 # Check for libmcheck.  #
1244 # --------------------- #
1245
1246 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1247 # but turn it off if Python is enabled with threads, since -lmcheck is
1248 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1249 # and for releases.
1250 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1251    && $development; then
1252   libmcheck_default=yes
1253 else
1254   libmcheck_default=no
1255 fi
1256 GDB_AC_LIBMCHECK(${libmcheck_default})
1257
1258 if test "$ENABLE_LIBMCHECK" = "yes" \
1259         -a "${have_libpython}" != "no" \
1260         -a "${python_has_threads}" = "yes" ; then
1261   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1262 fi
1263
1264 AC_ARG_WITH(intel_pt,
1265   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1266   [], [with_intel_pt=auto])
1267 AC_MSG_CHECKING([whether to use intel pt])
1268 AC_MSG_RESULT([$with_intel_pt])
1269
1270 if test "${with_intel_pt}" = no; then
1271   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1272   HAVE_LIBIPT=no
1273 else
1274   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1275 #include <linux/perf_event.h>
1276 #ifndef PERF_ATTR_SIZE_VER5
1277 # error
1278 #endif
1279   ]]), [perf_event=yes], [perf_event=no])
1280   if test "$perf_event" != yes; then
1281     if test "$with_intel_pt" = yes; then
1282       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1283     else
1284       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1285     fi
1286   fi
1287
1288   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1289   if test "$HAVE_LIBIPT" != yes; then
1290     if test "$with_intel_pt" = yes; then
1291       AC_MSG_ERROR([libipt is missing or unusable])
1292     else
1293       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1294     fi
1295   else
1296     save_LIBS=$LIBS
1297     LIBS="$LIBS $LIBIPT"
1298     AC_CHECK_FUNCS(pt_insn_event)
1299     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1300                      [#include <intel-pt.h>])
1301     LIBS=$save_LIBS
1302   fi
1303 fi
1304
1305 # ------------------------- #
1306 # Checks for header files.  #
1307 # ------------------------- #
1308
1309 AC_HEADER_STDC
1310 # elf_hp.h is for HP/UX 64-bit shared library support.
1311 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1312                   thread_db.h \
1313                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1314                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1315                   sys/reg.h sys/debugreg.h sys/select.h \
1316                   termios.h elf_hp.h \
1317                   dlfcn.h])
1318 AC_CHECK_HEADERS(sys/user.h, [], [],
1319 [#if HAVE_SYS_PARAM_H
1320 # include <sys/param.h>
1321 #endif
1322 ])
1323
1324 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1325 AC_CHECK_HEADERS(term.h, [], [],
1326 [#if HAVE_CURSES_H
1327 # include <curses.h>
1328 #endif
1329 ])
1330
1331 # ------------------------- #
1332 # Checks for declarations.  #
1333 # ------------------------- #
1334
1335 libiberty_INIT
1336
1337 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1338 AM_LC_MESSAGES
1339
1340 # ----------------------- #
1341 # Checks for structures.  #
1342 # ----------------------- #
1343
1344 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1345
1346 # ------------------ #
1347 # Checks for types.  #
1348 # ------------------ #
1349
1350 AC_CHECK_TYPES(socklen_t, [], [],
1351 [#include <sys/types.h>
1352 #include <sys/socket.h>
1353 ])
1354
1355 # ------------------------------------- #
1356 # Checks for compiler characteristics.  #
1357 # ------------------------------------- #
1358
1359 AC_C_CONST
1360 AC_C_INLINE
1361 AC_C_BIGENDIAN
1362
1363 # ------------------------------ #
1364 # Checks for library functions.  #
1365 # ------------------------------ #
1366
1367 AC_FUNC_MMAP
1368 AC_FUNC_VFORK
1369 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1370                 pipe poll pread pread64 pwrite resize_term \
1371                 sbrk getpgid setpgid setpgrp setsid \
1372                 sigaction sigprocmask sigsetmask socketpair \
1373                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1374                 setrlimit getrlimit posix_madvise waitpid \
1375                 ptrace64 sigaltstack mkdtemp setns])
1376 AM_LANGINFO_CODESET
1377 GDB_AC_COMMON
1378
1379 # Check the return and argument types of ptrace.
1380 GDB_AC_PTRACE
1381
1382 dnl AC_FUNC_SETPGRP does not work when cross compiling
1383 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1384 if test "$cross_compiling" = no; then
1385   AC_FUNC_SETPGRP
1386 else
1387   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1388     [AC_TRY_COMPILE([
1389 #include <unistd.h>
1390 ], [
1391   if (setpgrp(1,1) == -1)
1392     exit (0);
1393   else
1394     exit (1);
1395 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1396 if test $ac_cv_func_setpgrp_void = yes; then
1397   AC_DEFINE(SETPGRP_VOID, 1)
1398 fi
1399 fi
1400
1401 # Assume we'll default to using the included libiberty regex.
1402 gdb_use_included_regex=yes
1403
1404 # However, if the system regex is GNU regex, then default to *not*
1405 # using the included regex.
1406 AC_CACHE_CHECK(
1407   [for GNU regex],
1408   [gdb_cv_have_gnu_regex],
1409   [AC_TRY_COMPILE(
1410     [#include <gnu-versions.h>],
1411     [#define REGEX_INTERFACE_VERSION 1
1412 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1413 # error "Version mismatch"
1414 #endif],
1415     gdb_cv_have_gnu_regex=yes,
1416     gdb_cv_have_gnu_regex=no)])
1417 if test $gdb_cv_have_gnu_regex = yes; then
1418   gdb_use_included_regex=no
1419 fi
1420
1421 AC_ARG_WITH(included-regex,
1422   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1423   gdb_with_regex=$withval,
1424   gdb_with_regex=$gdb_use_included_regex)
1425 if test "$gdb_with_regex" = yes; then
1426   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1427     [Define to 1 if the regex included in libiberty should be used.])
1428 fi
1429
1430 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1431 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1432 [#include <sys/param.h>
1433 #include <sys/proc.h>
1434 ])
1435
1436 # See if <sys/lwp.h> defines `struct lwp`.
1437 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1438 [AC_TRY_COMPILE([#include <sys/param.h>
1439 #define _KMEMUSER
1440 #include <sys/lwp.h>], [struct lwp l;],
1441 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1442 if test $gdb_cv_struct_lwp = yes; then
1443   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1444             [Define to 1 if your system has struct lwp.])
1445 fi
1446
1447 # See if <machine/reg.h> degines `struct reg'.
1448 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1449 [AC_TRY_COMPILE([#include <sys/types.h>
1450 #include <machine/reg.h>], [struct reg r;],
1451 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1452 if test $gdb_cv_struct_reg = yes; then
1453   AC_DEFINE(HAVE_STRUCT_REG, 1,
1454             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1455 fi
1456
1457 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1458 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1459 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1460                  [#include <sys/types.h>
1461 #include <machine/reg.h>])
1462
1463 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1464 # Older amd64 Linux's don't have the fs_base and gs_base members of
1465 # `struct user_regs_struct'.
1466 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1467      [], [], [#include <sys/types.h>
1468 #include <sys/user.h>])
1469
1470 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1471 AC_MSG_CHECKING(for PTRACE_GETREGS)
1472 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1473 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1474                 [PTRACE_GETREGS;],
1475                 [gdb_cv_have_ptrace_getregs=yes],
1476                 [gdb_cv_have_ptrace_getregs=no])])
1477 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1478 if test $gdb_cv_have_ptrace_getregs = yes; then
1479   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1480   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1481 fi
1482
1483 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1484 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1485 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1486 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1487                 [PTRACE_GETFPXREGS;],
1488                 [gdb_cv_have_ptrace_getfpxregs=yes],
1489                 [gdb_cv_have_ptrace_getfpxregs=no])])
1490 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1491 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1492   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1493   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1494 fi
1495
1496 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1497 AC_MSG_CHECKING(for PT_GETDBREGS)
1498 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1499 [AC_TRY_COMPILE([#include <sys/types.h>
1500 #include <sys/ptrace.h>],
1501                 [PT_GETDBREGS;],
1502                 [gdb_cv_have_pt_getdbregs=yes],
1503                 [gdb_cv_have_pt_getdbregs=no])])
1504 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1505 if test $gdb_cv_have_pt_getdbregs = yes; then
1506   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1507   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1508 fi
1509
1510 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1511 AC_MSG_CHECKING(for PT_GETXMMREGS)
1512 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1513 [AC_TRY_COMPILE([#include <sys/types.h>
1514 #include <sys/ptrace.h>],
1515                 [PT_GETXMMREGS;],
1516                 [gdb_cv_have_pt_getxmmregs=yes],
1517                 [gdb_cv_have_pt_getxmmregs=no])])
1518 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1519 if test $gdb_cv_have_pt_getxmmregs = yes; then
1520   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1521   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1522 fi
1523
1524 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1525 # Older FreeBSD versions don't have the pl_tdname member of
1526 # `struct ptrace_lwpinfo'.
1527 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1528                  [#include <sys/ptrace.h>])
1529
1530 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1531 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1532 # FreeBSD 10.3.
1533 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1534                  [#include <sys/ptrace.h>])
1535
1536 if test "$ac_cv_header_sys_procfs_h" = yes; then
1537   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1538   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1539   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1540   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1541   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1542   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1543   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1544
1545   dnl Check for broken prfpregset_t type
1546
1547   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1548   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1549   dnl instead of the struct itself).  We detect this here, and work
1550   dnl around it in gdb_proc_service.h.
1551
1552   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1553     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1554     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1555       [AC_TRY_RUN([#include <sys/procfs.h>
1556        int main ()
1557        {
1558          if (sizeof (prfpregset_t) == sizeof (void *))
1559            return 1;
1560          return 0;
1561        }],
1562        gdb_cv_prfpregset_t_broken=no,
1563        gdb_cv_prfpregset_t_broken=yes,
1564        gdb_cv_prfpregset_t_broken=yes)])
1565     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1566     if test $gdb_cv_prfpregset_t_broken = yes; then
1567       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1568       [Define if the prfpregset_t type is broken.])
1569     fi
1570   fi
1571 fi
1572
1573 # Check if the compiler supports the `long long' type.
1574
1575 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1576                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1577 [[extern long long foo;]],
1578 [[switch (foo & 2) { case 0: return 1; }]])],
1579                                   gdb_cv_c_long_long=yes,
1580                                   gdb_cv_c_long_long=no)])
1581 if test $gdb_cv_c_long_long != yes; then
1582   # libdecnumber requires long long.
1583   AC_MSG_ERROR([Compiler must support long long for GDB.])
1584 fi
1585
1586 # Check if the compiler and runtime support printing long longs.
1587
1588 AC_CACHE_CHECK([for long long support in printf],
1589                gdb_cv_printf_has_long_long,
1590                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1591 [[char buf[32];
1592   long long l = 0;
1593   l = (l << 16) + 0x0123;
1594   l = (l << 16) + 0x4567;
1595   l = (l << 16) + 0x89ab;
1596   l = (l << 16) + 0xcdef;
1597   sprintf (buf, "0x%016llx", l);
1598   return (strcmp ("0x0123456789abcdef", buf));]])],
1599                               gdb_cv_printf_has_long_long=yes,
1600                               gdb_cv_printf_has_long_long=no,
1601                               gdb_cv_printf_has_long_long=no)])
1602 if test $gdb_cv_printf_has_long_long = yes; then
1603   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1604             [Define to 1 if the "%ll" format works to print long longs.])
1605 fi
1606
1607 # Check if the compiler and runtime support printing decfloats.
1608
1609 AC_CACHE_CHECK([for decfloat support in printf],
1610                gdb_cv_printf_has_decfloat,
1611                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1612 [[char buf[64];
1613   _Decimal32 d32 = 1.2345df;
1614   _Decimal64 d64 = 1.2345dd;
1615   _Decimal128 d128 = 1.2345dl;
1616   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1617   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1618                               gdb_cv_printf_has_decfloat=yes,
1619                               gdb_cv_printf_has_decfloat=no,
1620                               gdb_cv_printf_has_decfloat=no)])
1621 if test $gdb_cv_printf_has_decfloat = yes; then
1622   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1623             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1624 fi
1625
1626 # Check if the compiler supports the `long double' type.  We can't use
1627 # AC_C_LONG_DOUBLE because that one does additional checks on the
1628 # constants defined in <float.h> that fail on some systems,
1629 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1630
1631 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1632                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1633                                   gdb_cv_c_long_double=yes,
1634                                   gdb_cv_c_long_double=no)])
1635 if test $gdb_cv_c_long_double = yes; then
1636   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1637            [Define to 1 if the compiler supports long double.])
1638 fi
1639
1640 # Check if the compiler and runtime support printing long doubles.
1641
1642 AC_CACHE_CHECK([for long double support in printf],
1643                gdb_cv_printf_has_long_double,
1644                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1645 [[char buf[16];
1646   long double f = 3.141592653;
1647   sprintf (buf, "%Lg", f);
1648   return (strncmp ("3.14159", buf, 7));]])],
1649                               gdb_cv_printf_has_long_double=yes,
1650                               gdb_cv_printf_has_long_double=no,
1651                               gdb_cv_printf_has_long_double=no)])
1652 if test $gdb_cv_printf_has_long_double = yes; then
1653   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1654             [Define to 1 if the "%Lg" format works to print long doubles.])
1655 fi
1656
1657 # Check if the compiler and runtime support scanning long doubles.
1658
1659 AC_CACHE_CHECK([for long double support in scanf],
1660                gdb_cv_scanf_has_long_double,
1661                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1662 [[#include <stdio.h>]],
1663 [[char *buf = "3.141592653";
1664   long double f = 0;
1665   sscanf (buf, "%Lg", &f);
1666   return !(f > 3.14159 && f < 3.14160);]])],
1667                               gdb_cv_scanf_has_long_double=yes,
1668                               gdb_cv_scanf_has_long_double=no,
1669                               gdb_cv_scanf_has_long_double=no)])
1670 if test $gdb_cv_scanf_has_long_double = yes; then
1671   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1672             [Define to 1 if the "%Lg" format works to scan long doubles.])
1673 fi
1674
1675 case ${host_os} in
1676 aix*)
1677   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1678     SAVE_LDFLAGS=$LDFLAGS
1679
1680     case $GCC in
1681     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1682     *) gdb_cv_bigtoc=-bbigtoc ;;
1683     esac
1684
1685     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1686     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1687     LDFLAGS="${SAVE_LDFLAGS}"
1688   ])
1689   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1690   ;;
1691 esac
1692
1693 AC_MSG_CHECKING(for the dynamic export flag)
1694 dynamic_list=false
1695 if test "${gdb_native}" = yes; then
1696    # The dynamically loaded libthread_db needs access to symbols in the gdb
1697    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1698    # may not be supported there.
1699    old_LDFLAGS="$LDFLAGS"
1700    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1701    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1702    LDFLAGS="$LDFLAGS $RDYNAMIC"
1703    if test "${have_libpython}" = no; then
1704      AC_TRY_LINK([], [], [dynamic_list=true])
1705    else
1706      # Workaround http://bugs.python.org/issue4434 where static
1707      # libpythonX.Y.a would get its symbols required for
1708      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1709      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1710
1711      # Note the workaround for Python
1712      # http://bugs.python.org/issue10112 earlier has removed
1713      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1714      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1715      # always pass.
1716      old_CFLAGS="$CFLAGS"
1717      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1718      old_LIBS="$LIBS"
1719      LIBS="$LIBS $PYTHON_LIBS"
1720      old_CPPFLAGS="$CPPFLAGS"
1721      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1722      AC_RUN_IFELSE(
1723        AC_LANG_PROGRAM(
1724          [#include "Python.h"],
1725          [int err;
1726           Py_Initialize ();
1727           err = PyRun_SimpleString ("import itertools\n");
1728           Py_Finalize ();
1729           return err == 0 ? 0 : 1;]),
1730        [dynamic_list=true], [], [true])
1731      LIBS="$old_LIBS"
1732      CFLAGS="$old_CFLAGS"
1733      CPPFLAGS="$old_CPPFLAGS"
1734    fi
1735    LDFLAGS="$old_LDFLAGS"
1736 fi
1737 if $dynamic_list; then
1738   found="-Wl,--dynamic-list"
1739   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1740 else
1741   found="-rdynamic"
1742   RDYNAMIC="-rdynamic"
1743 fi
1744 AC_SUBST(RDYNAMIC)
1745 AC_MSG_RESULT($found)
1746
1747 dnl For certain native configurations, we need to check whether thread
1748 dnl support can be built in or not.
1749 dnl
1750 dnl Note that we only want this if we are both native (host == target),
1751 dnl and not doing a canadian cross build (build == host).
1752
1753 if test ${build} = ${host} -a ${host} = ${target} ; then
1754    case ${host_os} in
1755    aix*)
1756       AC_MSG_CHECKING(for AiX thread debugging library)
1757       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1758                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1759                                    [#ifndef PTHDB_VERSION_3
1760                                     #error
1761                                     #endif],
1762                                    gdb_cv_have_aix_thread_debug=yes,
1763                                    gdb_cv_have_aix_thread_debug=no)])
1764       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1765       if test $gdb_cv_have_aix_thread_debug = yes; then
1766          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1767          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1768          LIBS="$LIBS -lpthdebug"
1769
1770          # Older versions of AIX do not provide the declaration for
1771          # the getthrds function (it appears that it was introduced
1772          # with AIX 6.x).
1773          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1774       fi
1775       ;;
1776    esac
1777    AC_SUBST(CONFIG_LDFLAGS)
1778 fi
1779
1780 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1781 dnl other error codes.
1782 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1783    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1784                   gdb_cv_thread_db_h_has_td_notalloc,
1785      AC_TRY_COMPILE(
1786        [#include <thread_db.h>],
1787        [int i = TD_NOTALLOC;],
1788        gdb_cv_thread_db_h_has_td_notalloc=yes,
1789        gdb_cv_thread_db_h_has_td_notalloc=no
1790      )
1791    )
1792    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1793                   gdb_cv_thread_db_h_has_td_version,
1794      AC_TRY_COMPILE(
1795        [#include <thread_db.h>],
1796        [int i = TD_VERSION;],
1797        gdb_cv_thread_db_h_has_td_version=yes,
1798        gdb_cv_thread_db_h_has_td_version=no
1799      )
1800    )
1801    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1802                   gdb_cv_thread_db_h_has_td_notls,
1803      AC_TRY_COMPILE(
1804        [#include <thread_db.h>],
1805        [int i = TD_NOTLS;],
1806        gdb_cv_thread_db_h_has_td_notls=yes,
1807        gdb_cv_thread_db_h_has_td_notls=no
1808      )
1809    )
1810 fi
1811 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1812   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1813             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1814 fi
1815 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1816   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1817             [Define if <thread_db.h> has the TD_VERSION error code.])
1818 fi
1819 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1820   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1821             [Define if <thread_db.h> has the TD_NOTLS error code.])
1822 fi
1823
1824 dnl Check if we can disable the virtual address space randomization.
1825 dnl The functionality of setarch -R.
1826 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1827 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1828 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1829 #       define ADDR_NO_RANDOMIZE 0x0040000
1830 #      endif
1831        /* Test the flag could be set and stays set.  */
1832        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1833        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1834            return 1])])
1835 AC_RUN_IFELSE([PERSONALITY_TEST],
1836               [have_personality=true],
1837               [have_personality=false],
1838               [AC_LINK_IFELSE([PERSONALITY_TEST],
1839                               [have_personality=true],
1840                               [have_personality=false])])
1841 if $have_personality
1842 then
1843     AC_DEFINE([HAVE_PERSONALITY], 1,
1844               [Define if you support the personality syscall.])
1845 fi
1846
1847 dnl Set the host's .gdbinit filename.
1848 case $host_os in
1849   go32* | *djgpp*)
1850     gdbinit=gdb.ini
1851     ;;
1852   *)
1853     gdbinit=.gdbinit
1854     ;;
1855 esac
1856 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1857
1858 dnl Handle optional features that can be enabled.
1859
1860 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1861 # except that the argument to --with-sysroot is optional.
1862 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1863 if test "x$with_sysroot" = xyes; then
1864   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1865 fi
1866 AC_ARG_WITH(sysroot,
1867   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1868                  [search for usr/lib et al within DIR]),
1869   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1870 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1871               [search for usr/lib et al within DIR])
1872 AC_SUBST(TARGET_SYSTEM_ROOT)
1873 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1874
1875 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1876     [automatically load a system-wide gdbinit file],
1877     [])
1878
1879 AM_GDB_WARNINGS
1880
1881 # In the Cygwin environment, we need some additional flags.
1882 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1883 [AC_EGREP_CPP(^lose$, [
1884 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1885 lose
1886 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1887
1888
1889 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1890 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1891 case ${host} in
1892   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1893   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1894   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1895 esac
1896 AC_SUBST(SER_HARDWIRE)
1897
1898 # libreadline needs libuser32.a in a cygwin environment
1899 WIN32LIBS=
1900 if test x$gdb_cv_os_cygwin = xyes; then
1901     WIN32LIBS="-luser32"
1902     case "${target}" in
1903         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1904         ;;
1905     esac
1906 fi
1907
1908 # The ser-tcp.c module requires sockets.
1909 case ${host} in
1910   *mingw32*)
1911     AC_DEFINE(USE_WIN32API, 1,
1912               [Define if we should use the Windows API, instead of the
1913                POSIX API.  On Windows, we use the Windows API when
1914                building for MinGW, but the POSIX API when building
1915                for Cygwin.])
1916     WIN32LIBS="$WIN32LIBS -lws2_32"
1917     ;;
1918 esac
1919 AC_SUBST(WIN32LIBS)
1920
1921 # Add ELF support to GDB, but only if BFD includes ELF support.
1922 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1923                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1924 if test $gdb_cv_var_elf = yes; then
1925   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1926   AC_DEFINE(HAVE_ELF, 1,
1927             [Define if ELF support should be included.])
1928   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1929   if test "$plugins" = "yes"; then
1930     AC_SEARCH_LIBS(dlopen, dl)
1931   fi
1932 fi
1933
1934 # Add macho support to GDB, but only if BFD includes it.
1935 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1936                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1937 if test $gdb_cv_var_macho = yes; then
1938   CONFIG_OBS="$CONFIG_OBS machoread.o"
1939 fi
1940
1941 # Add any host-specific objects to GDB.
1942 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1943
1944 # If building on ELF, look for lzma support for embedded compressed debug info.
1945 if test $gdb_cv_var_elf = yes; then
1946   AC_ARG_WITH(lzma,
1947     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1948     [], [with_lzma=auto])
1949   AC_MSG_CHECKING([whether to use lzma])
1950   AC_MSG_RESULT([$with_lzma])
1951
1952   if test "${with_lzma}" != no; then
1953     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1954                           [lzma_index_iter iter;
1955                            lzma_index_iter_init (&iter, 0);
1956                            lzma_mf_is_supported (LZMA_MF_HC3);])
1957     if test "$HAVE_LIBLZMA" != yes; then
1958       if test "$with_lzma" = yes; then
1959         AC_MSG_ERROR([missing liblzma for --with-lzma])
1960       fi
1961     fi
1962   fi
1963 fi
1964
1965 LIBGUI="../libgui/src/libgui.a"
1966 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1967 AC_SUBST(LIBGUI)
1968 AC_SUBST(GUI_CFLAGS_X)
1969
1970 WIN32LDAPP=
1971 AC_SUBST(WIN32LIBS)
1972 AC_SUBST(WIN32LDAPP)
1973
1974 case "${host}" in
1975 *-*-cygwin* | *-*-mingw* )
1976     configdir="win"
1977     ;;
1978 *)
1979     configdir="unix"
1980     ;;
1981 esac
1982
1983 GDBTKLIBS=
1984 if test "${enable_gdbtk}" = "yes"; then
1985
1986     # Gdbtk must have an absolute path to srcdir in order to run
1987     # properly when not installed.
1988     here=`pwd`
1989     cd ${srcdir}
1990     GDBTK_SRC_DIR=`pwd`
1991     cd $here
1992
1993     SC_PATH_TCLCONFIG
1994
1995     # If $no_tk is nonempty, then we can't do Tk, and there is no
1996     # point to doing Tcl.
1997     SC_PATH_TKCONFIG
1998
1999     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2000         SC_LOAD_TCLCONFIG
2001
2002         # Check for in-tree tcl
2003         here=`pwd`
2004         cd ${srcdir}/..
2005         topdir=`pwd`
2006         cd ${here}
2007
2008         intree="no"
2009         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2010           intree="yes"
2011         fi
2012
2013         # Find Tcl private headers
2014         if test x"${intree}" = xno; then
2015           CY_AC_TCL_PRIVATE_HEADERS
2016           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2017           TCL_LIBRARY="${TCL_LIB_SPEC}"
2018           TCL_DEPS=""
2019         else
2020           # If building tcl in the same src tree, private headers
2021           # are not needed, but we need to be sure to use the right
2022           # headers library
2023           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2024           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2025           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2026         fi
2027         AC_SUBST(TCL_INCLUDE)
2028         AC_SUBST(TCL_LIBRARY)
2029         AC_SUBST(TCL_DEPS)
2030
2031         SC_LOAD_TKCONFIG
2032
2033         # Check for in-tree Tk
2034         intree="no"
2035         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2036           intree="yes"
2037         fi
2038
2039         # Find Tk private headers
2040         if test x"${intree}" = xno; then
2041           CY_AC_TK_PRIVATE_HEADERS
2042           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2043           TK_LIBRARY=${TK_LIB_SPEC}
2044           TK_DEPS=""
2045         else
2046           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2047           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2048           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2049         fi
2050         AC_SUBST(TK_INCLUDE)
2051         AC_SUBST(TK_LIBRARY)
2052         AC_SUBST(TK_DEPS)
2053         AC_SUBST(TK_XINCLUDES)
2054
2055         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2056
2057         # Include some libraries that Tcl and Tk want.
2058         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2059         # Yes, the ordering seems wrong here.  But it isn't.
2060         # TK_LIBS is the list of libraries that need to be linked
2061         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2062         # were in LIBS then any link tests after this point would
2063         # try to include things like `$(LIBGUI)', which wouldn't work.
2064         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2065
2066         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2067         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2068         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2069         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2070         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2071         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2072         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2073
2074         if test x$gdb_cv_os_cygwin = xyes; then
2075           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2076           WIN32LDAPP="-Wl,--subsystem,console"
2077           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2078         fi
2079
2080         AC_CONFIG_SUBDIRS(gdbtk)
2081     fi
2082 fi
2083
2084 AC_SUBST(X_CFLAGS)
2085 AC_SUBST(X_LDFLAGS)
2086 AC_SUBST(X_LIBS)
2087 AC_SUBST(GDBTKLIBS)
2088 AC_SUBST(GDBTK_CFLAGS)
2089 AC_SUBST(GDBTK_SRC_DIR)
2090
2091 AC_PATH_X
2092
2093 # Unlike the sim directory, whether a simulator is linked is controlled by
2094 # presence of a gdb_sim definition in the target configure.tgt entry.
2095 # This code just checks for a few cases where we'd like to ignore those
2096 # definitions, even when they're present in the '.mt' file.  These cases
2097 # are when --disable-sim is specified, or if the simulator directory is
2098 # not part of the source tree.
2099 #
2100 AC_ARG_ENABLE(sim,
2101 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2102 [echo "enable_sim = $enable_sim";
2103  echo "enableval = ${enableval}";
2104  case "${enableval}" in
2105   yes) ignore_sim=false ;;
2106   no)  ignore_sim=true ;;
2107   *)   ignore_sim=false ;;
2108  esac],
2109 [ignore_sim=false])
2110
2111 if test ! -d "${srcdir}/../sim"; then
2112   ignore_sim=true
2113 fi
2114
2115 SIM=
2116 SIM_OBS=
2117 if test "${ignore_sim}" = "false"; then
2118   if test x"${gdb_sim}" != x ; then
2119     SIM="${gdb_sim}"
2120     SIM_OBS="remote-sim.o"
2121     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2122
2123     # Some tdep code should only be compiled in when the ppc sim is
2124     # built.  PR sim/13418.
2125     case $target in
2126       powerpc*-*-*)
2127         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2128         ;;
2129     esac
2130   fi
2131 fi
2132 AC_SUBST(SIM)
2133 AC_SUBST(SIM_OBS)
2134
2135 AC_SUBST(ENABLE_CFLAGS)
2136 AC_SUBST(PROFILE_CFLAGS)
2137
2138 AC_SUBST(CONFIG_OBS)
2139 AC_SUBST(CONFIG_DEPS)
2140 AC_SUBST(CONFIG_SRCS)
2141 AC_SUBST(CONFIG_ALL)
2142 AC_SUBST(CONFIG_CLEAN)
2143 AC_SUBST(CONFIG_INSTALL)
2144 AC_SUBST(CONFIG_UNINSTALL)
2145
2146 # List of host floatformats.
2147 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2148 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2149 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2150
2151 # target_subdir is used by the testsuite to find the target libraries.
2152 target_subdir=
2153 if test "${host}" != "${target}"; then
2154     target_subdir="${target_alias}/"
2155 fi
2156 AC_SUBST(target_subdir)
2157
2158 # Import nat definitions.
2159 nat_makefile_frag=/dev/null
2160 if test "${gdb_native}" = "yes"; then
2161   . ${srcdir}/configure.nat
2162   nativefile=$NAT_FILE
2163 fi
2164
2165 AC_SUBST(NAT_FILE)
2166 AC_SUBST(NATDEPFILES)
2167 AC_SUBST(NAT_CDEPS)
2168 AC_SUBST(LOADLIBES)
2169 AC_SUBST(MH_CFLAGS)
2170 AC_SUBST(XM_CLIBS)
2171 AC_SUBST(NAT_GENERATED_FILES)
2172 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2173 AC_SUBST_FILE(nat_makefile_frag)
2174
2175 if test x"${gdb_osabi}" != x ; then
2176     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2177                        [Define to the default OS ABI for this configuration.])
2178 fi
2179
2180 # Enable multi-ice-gdb-server.
2181 AC_ARG_ENABLE(multi-ice,
2182 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2183   [case $enableval in
2184     yes | no)
2185       ;;
2186     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2187   esac])
2188 if test "x$enable_multi_ice" = xyes; then
2189    AC_CONFIG_SUBDIRS(multi-ice)
2190 fi
2191
2192 AC_ARG_ENABLE(gdbserver,
2193 AS_HELP_STRING([--enable-gdbserver],
2194                [automatically build gdbserver (yes/no/auto, default is auto)]),
2195 [case "${enableval}" in
2196   yes| no|auto) ;;
2197   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2198 esac],[enable_gdbserver=auto])
2199
2200 # We only build gdbserver automatically in a native configuration, and
2201 # only if the user did not explicitly disable its build.
2202 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2203   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2204   if test "x$build_gdbserver" = xyes; then
2205     AC_MSG_RESULT(yes)
2206     AC_CONFIG_SUBDIRS(gdbserver)
2207     gdbserver_build_enabled=yes
2208   else
2209     AC_MSG_RESULT(no)
2210   fi
2211 fi
2212
2213 # If the user explicitly request the gdbserver to be built, verify that
2214 # we were in fact able to enable it.
2215 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2216   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2217 fi
2218
2219 # Check for babeltrace and babeltrace-ctf
2220 AC_ARG_WITH(babeltrace,
2221   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2222   [], [with_babeltrace=auto])
2223 AC_MSG_CHECKING([whether to use babeltrace])
2224 AC_MSG_RESULT([$with_babeltrace])
2225
2226 if test "x$with_babeltrace" = "xno"; then
2227   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2228 else
2229   # Append -Werror to CFLAGS so that configure can catch the warning
2230   # "assignment from incompatible pointer type", which is related to
2231   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2232   # in GDB, while babeltrace 1.0.3 is broken.
2233   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2234   # safe to save and restore CFLAGS here.
2235   saved_CFLAGS=$CFLAGS
2236   CFLAGS="$CFLAGS -Werror"
2237   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2238                         [#include <babeltrace/babeltrace.h>
2239                          #include <babeltrace/ctf/events.h>
2240                          #include <babeltrace/ctf/iterator.h>],
2241                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2242                         struct bt_ctf_event *event = NULL;
2243                         const struct bt_definition *scope;
2244
2245                         pos->type = BT_SEEK_BEGIN;
2246                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2247                         scope = bt_ctf_get_top_level_scope (event,
2248                                                            BT_STREAM_EVENT_HEADER);
2249                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2250                         ])
2251   CFLAGS=$saved_CFLAGS
2252
2253   if test "$HAVE_LIBBABELTRACE" != yes; then
2254      if test "$with_babeltrace" = yes; then
2255        AC_MSG_ERROR([babeltrace is missing or unusable])
2256      else
2257        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2258      fi
2259   fi
2260 fi
2261
2262 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2263 # empty version.
2264
2265 files=
2266 links=
2267
2268 rm -f nm.h
2269 if test "${nativefile}" != ""; then
2270     case "${nativefile}" in
2271       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2272       * ) GDB_NM_FILE="${nativefile}"
2273     esac
2274     files="${files} ${GDB_NM_FILE}"
2275     links="${links} nm.h"
2276     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2277 fi
2278 AC_SUBST(GDB_NM_FILE)
2279
2280 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2281 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2282 if test "x$USE_MAINTAINER_MODE" = xyes; then
2283   if test "${XSLTPROC}" = missing; then
2284     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2285   fi
2286 fi
2287 AC_SUBST(XSLTPROC)
2288
2289 AC_LINK_FILES($files, $links)
2290
2291 dnl Check for exe extension set on certain hosts (e.g. Win32)
2292 AC_EXEEXT
2293
2294 dnl  Detect the character set used by this host.
2295 dnl  At the moment, we just assume it's UTF-8.
2296 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2297           [Define to be a string naming the default host character set.])
2298
2299 if $development; then
2300   AC_DEFINE(GDB_SELF_TEST, 1,
2301             [Define if self-testing features should be enabled])
2302   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) selftest.o selftest-arch.o"
2303   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) common/selftest.c selftest-arch.c"
2304 fi
2305
2306 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2307 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2308 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2309 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2310 [
2311 case x$CONFIG_HEADERS in
2312 xconfig.h:config.in)
2313 echo > stamp-h ;;
2314 esac
2315 ])
2316
2317 AC_OUTPUT