gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2019 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 dnl List of object files and targets accumulated by configure.
  49
  50 CONFIG_OBS=
  51 CONFIG_DEPS=
  52 CONFIG_SRCS=
  53 ENABLE_CFLAGS=
  54
  55 CONFIG_ALL=
  56 CONFIG_CLEAN=
  57 CONFIG_INSTALL=
  58 CONFIG_UNINSTALL=
  59
  60 dnl Set up for gettext.
  61 ZW_GNU_GETTEXT_SISTER_DIR
  62
  63 localedir='${datadir}/locale'
  64 AC_SUBST(localedir)
  65
  66 if test x"$USE_NLS" = xyes; then
  67    CONFIG_ALL="$CONFIG_ALL all-po"
  68    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  69    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  70    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  71 fi
  72
  73 PACKAGE=gdb
  74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  75 AC_SUBST(PACKAGE)
  76
  77 # We never need to detect it in this sub-configure.
  78 # But preserve it for config.status --recheck.
  79 AC_ARG_VAR(MAKEINFO,
  80   [Parent configure detects if it is of sufficient version.])
  81 AC_ARG_VAR(MAKEINFOFLAGS,
  82   [Parameters for MAKEINFO.])
  83
  84 MAKEINFO_EXTRA_FLAGS=""
  85 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  86   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  87   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  88     gdb_cv_have_makeinfo_click=yes
  89   else
  90     gdb_cv_have_makeinfo_click=no
  91   fi])
  92 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  93   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  94 fi
  95 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  96
  97 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  98     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  99     [${libdir}/debug])
 100
 101 # We can't pass paths as command line arguments.
 102 # Mingw32 tries to be clever and will convert the paths for us.
 103 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 104 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 105 # This breaks GDB's relocatable path conversions since paths passed in
 106 # config.h would not get so translated, the path prefixes no longer match.
 107 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 108
 109 # GDB's datadir relocation
 110
 111 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 112     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 113     [${datadir}/gdb])
 114
 115 AC_ARG_WITH(relocated-sources,
 116 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 117 [reloc_srcdir="${withval}"
 118  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 119               [Relocated directory for source files. ])
 120 ])
 121
 122 AC_MSG_CHECKING([for default auto-load directory])
 123 AC_ARG_WITH(auto-load-dir,
 124 AS_HELP_STRING([--with-auto-load-dir=PATH],
 125   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 126   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 127 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 128 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 129               [Directories from which to load auto-loaded scripts.])
 130 AC_MSG_RESULT([$with_auto_load_dir])
 131
 132 AC_MSG_CHECKING([for default auto-load safe-path])
 133 AC_ARG_WITH(auto-load-safe-path,
 134 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 135   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 136 AS_HELP_STRING([--without-auto-load-safe-path],
 137                [do not restrict auto-loaded files locations]),
 138     [if test "$with_auto_load_safe_path" = "no"; then
 139      with_auto_load_safe_path="/"
 140      fi],
 141 [with_auto_load_safe_path="$with_auto_load_dir"])
 142 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 143 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 144               [Directories safe to hold auto-loaded files.])
 145 AC_MSG_RESULT([$with_auto_load_safe_path])
 146
 147 AC_CONFIG_SUBDIRS(testsuite)
 148
 149 # Check whether to support alternative target configurations
 150 AC_ARG_ENABLE(targets,
 151 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 152 [case "${enableval}" in
 153   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 154             ;;
 155   no)       enable_targets= ;;
 156   *)        enable_targets=$enableval ;;
 157 esac])
 158
 159 # Check whether to enable 64-bit support on 32-bit hosts
 160 AC_ARG_ENABLE(64-bit-bfd,
 161 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 162 [case "${enableval}" in
 163   yes)  want64=true  ;;
 164   no)   want64=false ;;
 165   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 166 esac],[want64=false])dnl
 167
 168 # Provide defaults for some variables set by the per-host and per-target
 169 # configuration.
 170 gdb_host_obs=posix-hdep.o
 171
 172 if test "${target}" = "${host}"; then
 173   gdb_native=yes
 174 else
 175   gdb_native=no
 176 fi
 177
 178 . $srcdir/configure.host
 179
 180 # Add in the common host objects.
 181 . $srcdir/gdbsupport/common.host
 182 gdb_host_obs="$gdb_host_obs $common_host_obs"
 183
 184 # Accumulate some settings from configure.tgt over all enabled targets
 185
 186 TARGET_OBS=
 187 all_targets=
 188 HAVE_NATIVE_GCORE_TARGET=
 189
 190 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 191 do
 192   if test "$targ_alias" = "all"; then
 193     all_targets=true
 194   else
 195     # Canonicalize the secondary target names.
 196     result=`$ac_config_sub $targ_alias 2>/dev/null`
 197     if test -n "$result"; then
 198         targ=$result
 199     else
 200         targ=$targ_alias
 201     fi
 202
 203     . ${srcdir}/configure.tgt
 204
 205     AS_IF([test -z "${gdb_target_obs}"],
 206       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 207
 208     # Target-specific object files
 209     for i in ${gdb_target_obs}; do
 210         case " $TARGET_OBS " in
 211         *" ${i} "*) ;;
 212         *)
 213           TARGET_OBS="$TARGET_OBS ${i}"
 214           ;;
 215         esac
 216     done
 217
 218     # Check whether this target needs 64-bit CORE_ADDR
 219     if test x${want64} = xfalse; then
 220       . ${srcdir}/../bfd/config.bfd
 221     fi
 222
 223     # Check whether this target is native and supports gcore.
 224     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 225        && $gdb_have_gcore; then
 226       HAVE_NATIVE_GCORE_TARGET=1
 227     fi
 228   fi
 229 done
 230
 231 if test x${all_targets} = xtrue; then
 232
 233   # We want all 64-bit targets if we either:
 234   #  - run on a 64-bit host  or
 235   #  - already require 64-bit support for some other target  or
 236   #  - the --enable-64-bit-bfd option was supplied
 237   # Otherwise we only support all 32-bit targets.
 238   #
 239   # NOTE: This test must be in sync with the corresponding
 240   #       tests in BFD!
 241
 242   if test x${want64} = xfalse; then
 243     AC_CHECK_SIZEOF(long)
 244     if test "x${ac_cv_sizeof_long}" = "x8"; then
 245       want64=true
 246     fi
 247   fi
 248   if test x${want64} = xtrue; then
 249     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 250   else
 251     TARGET_OBS='$(ALL_TARGET_OBS)'
 252   fi
 253 fi
 254
 255 AC_SUBST(TARGET_OBS)
 256 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 257
 258 # For other settings, only the main target counts.
 259 gdb_sim=
 260 gdb_osabi=
 261 build_gdbserver=
 262 targ=$target; . ${srcdir}/configure.tgt
 263
 264 # Fetch the default architecture and default target vector from BFD.
 265 targ=$target; . $srcdir/../bfd/config.bfd
 266
 267 # We only want the first architecture, so strip off the others if
 268 # there is more than one.
 269 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 270
 271 if test "x$targ_archs" != x; then
 272   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 273     [Define to BFD's default architecture. ])
 274 fi
 275 if test "x$targ_defvec" != x; then
 276   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 277     [Define to BFD's default target vector. ])
 278 fi
 279
 280 # Enable MI.
 281 AC_ARG_ENABLE(gdbmi,
 282 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 283   [case $enableval in
 284     yes | no)
 285       ;;
 286     *)
 287       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 288   esac],
 289   [enable_gdbmi=yes])
 290 if test x"$enable_gdbmi" = xyes; then
 291   if test -d $srcdir/mi; then
 292     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 293     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 294     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 295     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 296   fi
 297 fi
 298
 299 # Enable TUI.
 300 AC_ARG_ENABLE(tui,
 301 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 302   [case $enableval in
 303     yes | no | auto)
 304       ;;
 305     *)
 306       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 307   esac],enable_tui=auto)
 308
 309 # Enable gdbtk.
 310 AC_ARG_ENABLE(gdbtk,
 311 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 312   [case $enableval in
 313     yes | no)
 314       ;;
 315     *)
 316       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 317   esac],
 318   [if test -d $srcdir/gdbtk; then
 319     enable_gdbtk=yes
 320   else
 321     enable_gdbtk=no
 322   fi])
 323 # We unconditionally disable gdbtk tests on selected platforms.
 324 case $host_os in
 325   go32* | windows*)
 326     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 327     enable_gdbtk=no ;;
 328 esac
 329
 330 # Libunwind support for ia64.
 331
 332 AC_ARG_WITH(libunwind-ia64,
 333 AS_HELP_STRING([--with-libunwind-ia64],
 334                [use libunwind frame unwinding for ia64 targets]),,
 335             [with_libunwind_ia64=auto])
 336
 337 # Backward compatibility option.
 338 if test "${with_libunwind+set}" = set; then
 339   if test x"$with_libunwind_ia64" != xauto; then
 340     AC_MSG_ERROR(
 341       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 342   fi
 343   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 344   with_libunwind_ia64="$with_libunwind"
 345 fi
 346
 347 case "$with_libunwind_ia64" in
 348   yes | no)
 349     ;;
 350   auto)
 351     AC_CHECK_HEADERS(libunwind-ia64.h)
 352     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 353     ;;
 354   *)
 355     AC_MSG_ERROR(
 356       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 357     ;;
 358 esac
 359
 360 if test x"$with_libunwind_ia64" = xyes; then
 361   AC_CHECK_HEADERS(libunwind-ia64.h)
 362   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 363     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 364   fi
 365   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 366   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 367   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 368 fi
 369
 370 opt_curses=no
 371 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 372
 373 prefer_curses=no
 374 if test "$opt_curses" = "yes"; then
 375   prefer_curses=yes
 376 fi
 377
 378 # Profiling support.
 379 AC_ARG_ENABLE(profiling,
 380 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 381   [case $enableval in
 382     yes | no)
 383       ;;
 384     *)
 385       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 386   esac],
 387  [enable_profiling=no])
 388
 389 AC_CHECK_FUNCS(monstartup _mcleanup)
 390 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 391 [AC_TRY_LINK(
 392 [#include <stdlib.h>
 393 extern char _etext;
 394 ],
 395 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 396 if test $ac_cv_var__etext = yes; then
 397   AC_DEFINE(HAVE__ETEXT, 1,
 398             [Define to 1 if your system has the _etext variable. ])
 399 fi
 400 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 401 [AC_TRY_LINK(
 402 [#include <stdlib.h>
 403 extern char etext;
 404 ],
 405 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 406 if test $ac_cv_var_etext = yes; then
 407   AC_DEFINE(HAVE_ETEXT, 1,
 408             [Define to 1 if your system has the etext variable. ])
 409 fi
 410 if test "$enable_profiling" = yes ; then
 411   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 412     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 413   fi
 414   PROFILE_CFLAGS=-pg
 415   OLD_CFLAGS="$CFLAGS"
 416   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 417
 418   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 419     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 420      ac_cv_cc_supports_pg=no)])
 421
 422   if test $ac_cv_cc_supports_pg = no; then
 423     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 424   fi
 425
 426   CFLAGS="$OLD_CFLAGS"
 427 fi
 428
 429 CODESIGN_CERT=
 430 AC_ARG_ENABLE([codesign],
 431   AS_HELP_STRING([--enable-codesign=CERT],
 432                  [sign gdb with 'codesign -s CERT']),
 433   [CODESIGN_CERT=$enableval])
 434 AC_SUBST([CODESIGN_CERT])
 435
 436 ACX_PKGVERSION([GDB])
 437 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 438 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 439 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 440
 441 # --------------------- #
 442 # Checks for programs.  #
 443 # --------------------- #
 444
 445 AC_PROG_AWK
 446 AC_PROG_INSTALL
 447 AC_PROG_LN_S
 448 AC_PROG_RANLIB
 449 AC_PROG_YACC
 450
 451 AC_CHECK_TOOL(AR, ar)
 452 AC_CHECK_TOOL(DLLTOOL, dlltool)
 453 AC_CHECK_TOOL(WINDRES, windres)
 454
 455 case $host_os in
 456   gnu*)
 457     # Needed for GNU Hurd hosts.
 458     AC_CHECK_TOOL(MIG, mig)
 459     if test x"$MIG" = x; then
 460       AC_MSG_ERROR([MIG not found but required for $host hosts])
 461     fi
 462     ;;
 463 esac
 464
 465 # ---------------------- #
 466 # Checks for libraries.  #
 467 # ---------------------- #
 468
 469 # We might need to link with -lm; most simulators need it.
 470 AC_CHECK_LIB(m, main)
 471
 472 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 473 AC_SEARCH_LIBS(gethostbyname, nsl)
 474
 475 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 476 AC_SEARCH_LIBS(socketpair, socket)
 477
 478 # Link in zlib if we can.  This allows us to read compressed debug sections.
 479 AM_ZLIB
 480
 481 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 482 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 483 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 484   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 485             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 486
 487 # fbsd-nat.c can also use kinfo_getfile.
 488 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 489   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 490             [Define to 1 if your system has the kinfo_getfile function. ])])
 491
 492 AM_ICONV
 493
 494 # GDB may fork/exec the iconv program to get the list of supported character
 495 # sets.  Allow the user to specify where to find it.
 496 # There are several factors affecting the choice of option name:
 497 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 498 #   the build-time location of libiconv files.
 499 # - The program we need to find is iconv, which comes with glibc.  The user
 500 #   doesn't necessarily have libiconv installed.  Therefore naming this
 501 #   --with-libiconv-foo feels wrong.
 502 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 503 #   defined to work on directories not files (though it really doesn't know
 504 #   the difference).
 505 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 506 #   with --with-libiconv-prefix.
 507 # Putting these together is why the option name is --with-iconv-bin.
 508
 509 AC_ARG_WITH(iconv-bin,
 510 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 511 [iconv_bin="${withval}"
 512  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 513                     [Path of directory of iconv program.])
 514  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 515 ])
 516
 517 # For the TUI, we need enhanced curses functionality.
 518 if test x"$enable_tui" != xno; then
 519   prefer_curses=yes
 520 fi
 521
 522 curses_found=no
 523 if test x"$prefer_curses" = xyes; then
 524   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 525   # curses library because the latter might not provide all the
 526   # functionality we need.  However, this leads to problems on systems
 527   # where the linker searches /usr/local/lib, but the compiler doesn't
 528   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 529   # default installation of ncurses on alpha*-dec-osf* will lead to such
 530   # a situation.
 531   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 532
 533   if test "$ac_cv_search_waddstr" != no; then
 534     curses_found=yes
 535   fi
 536 fi
 537
 538 # Check whether we should enable the TUI, but only do so if we really
 539 # can.
 540 if test x"$enable_tui" != xno; then
 541   if test -d $srcdir/tui; then
 542     if test "$curses_found" != no; then
 543       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 544       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 545       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 546       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 547     else
 548       if test x"$enable_tui" = xyes; then
 549         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 550       else
 551         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 552       fi
 553     fi
 554   fi
 555 fi
 556
 557 # Since GDB uses Readline, we need termcap functionality.  In many
 558 # cases this will be provided by the curses library, but some systems
 559 # have a separate termcap library, or no curses library at all.
 560
 561 case $host_os in
 562   cygwin*)
 563     if test -d $srcdir/libtermcap; then
 564       LIBS="../libtermcap/libtermcap.a $LIBS"
 565       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 566     fi ;;
 567   go32* | *djgpp*)
 568     ac_cv_search_tgetent="none required"
 569     ;;
 570 esac
 571
 572 # These are the libraries checked by Readline.
 573 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 574
 575 if test "$ac_cv_search_tgetent" = no; then
 576   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 577 fi
 578
 579 AC_ARG_WITH([system-readline],
 580   [AS_HELP_STRING([--with-system-readline],
 581                   [use installed readline library])])
 582
 583 if test "$with_system_readline" = yes; then
 584    AC_CACHE_CHECK([whether system readline is new enough],
 585      [gdb_cv_readline_ok],
 586      [AC_TRY_COMPILE(
 587        [#include <stdio.h>
 588 #include <readline/readline.h>],
 589        [#if RL_VERSION_MAJOR < 7
 590 # error "readline version 7 required"
 591 #endif],
 592     gdb_cv_readline_ok=yes,
 593     gdb_cv_readline_ok=no)])
 594   if test "$gdb_cv_readline_ok" != yes; then
 595     AC_MSG_ERROR([system readline is not new enough])
 596   fi
 597
 598   READLINE=-lreadline
 599   READLINE_DEPS=
 600   READLINE_CFLAGS=
 601   READLINE_TEXI_INCFLAG=
 602 else
 603   READLINE='$(READLINE_DIR)/libreadline.a'
 604   READLINE_DEPS='$(READLINE)'
 605   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 606   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 607 fi
 608 AC_SUBST(READLINE)
 609 AC_SUBST(READLINE_DEPS)
 610 AC_SUBST(READLINE_CFLAGS)
 611 AC_SUBST(READLINE_TEXI_INCFLAG)
 612
 613 # Generate jit-reader.h
 614
 615 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 616 TARGET_PTR=
 617
 618 AC_CHECK_SIZEOF(unsigned long long)
 619 AC_CHECK_SIZEOF(unsigned long)
 620 AC_CHECK_SIZEOF(unsigned __int128)
 621
 622 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 623   TARGET_PTR="unsigned long"
 624 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 625   TARGET_PTR="unsigned long long"
 626 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 627   TARGET_PTR="unsigned __int128"
 628 else
 629   TARGET_PTR="unsigned long"
 630 fi
 631
 632 AC_SUBST(TARGET_PTR)
 633 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 634
 635 AC_SEARCH_LIBS(dlopen, dl)
 636
 637 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 638                 [directory to load the JIT readers from],
 639                 [${libdir}/gdb])
 640
 641 AC_ARG_WITH(expat,
 642   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 643   [], [with_expat=auto])
 644 AC_MSG_CHECKING([whether to use expat])
 645 AC_MSG_RESULT([$with_expat])
 646
 647 if test "${with_expat}" = no; then
 648   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 649   HAVE_LIBEXPAT=no
 650 else
 651   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 652                         [XML_Parser p = XML_ParserCreate (0);])
 653   if test "$HAVE_LIBEXPAT" != yes; then
 654     if test "$with_expat" = yes; then
 655       AC_MSG_ERROR([expat is missing or unusable])
 656     else
 657       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 658     fi
 659   else
 660     save_LIBS=$LIBS
 661     LIBS="$LIBS $LIBEXPAT"
 662     AC_CHECK_FUNCS(XML_StopParser)
 663     LIBS=$save_LIBS
 664   fi
 665 fi
 666
 667 AC_ARG_WITH(mpfr,
 668   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 669   [], [with_mpfr=auto])
 670 AC_MSG_CHECKING([whether to use MPFR])
 671 AC_MSG_RESULT([$with_mpfr])
 672
 673 if test "${with_mpfr}" = no; then
 674   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 675   HAVE_LIBMPFR=no
 676 else
 677   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 678                         [mpfr_exp_t exp; mpfr_t x;
 679                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 680   if test "$HAVE_LIBMPFR" != yes; then
 681     if test "$with_mpfr" = yes; then
 682       AC_MSG_ERROR([MPFR is missing or unusable])
 683     else
 684       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 685     fi
 686   fi
 687 fi
 688
 689 # --------------------- #
 690 # Check for libpython.  #
 691 # --------------------- #
 692
 693 dnl Utility to simplify finding libpython.
 694 dnl $1 = the shell variable to assign the result to
 695 dnl      If libpython is found we store $version here.
 696 dnl $2 = additional flags to add to CPPFLAGS
 697 dnl $3 = additional flags to add to LIBS
 698
 699 AC_DEFUN([AC_TRY_LIBPYTHON],
 700 [
 701   define([have_libpython_var],$1)
 702   new_CPPFLAGS=$2
 703   new_LIBS=$3
 704   AC_MSG_CHECKING([for python])
 705   save_CPPFLAGS=$CPPFLAGS
 706   save_LIBS=$LIBS
 707   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 708   LIBS="$new_LIBS $LIBS"
 709   found_usable_python=no
 710   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 711                                  [[Py_Initialize ();]])],
 712                  [have_libpython_var=yes
 713                   found_usable_python=yes
 714                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 715                   PYTHON_LIBS=$new_LIBS])
 716   CPPFLAGS=$save_CPPFLAGS
 717   LIBS=$save_LIBS
 718   AC_MSG_RESULT([${found_usable_python}])
 719 ])
 720
 721 dnl There are several different values for --with-python:
 722 dnl
 723 dnl no -   Don't include python support.
 724 dnl yes -  Include python support, error if it's missing.
 725 dnl        If we find python in $PATH, use it to fetch configure options,
 726 dnl        otherwise assume the compiler can find it with no help from us.
 727 dnl        Python 2.7 and 2.6 are tried in turn.
 728 dnl auto - Same as "yes", but if python is missing from the system,
 729 dnl        fall back to "no".
 730 dnl /path/to/python/exec-prefix -
 731 dnl        Use the python located in this directory.
 732 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 733 dnl        the compilation parameters.  Otherwise use
 734 dnl        -I/path/to/python/exec-prefix/include,
 735 dnl        -L/path/to/python/exec-prefix/lib.
 736 dnl        Python 2.7 and 2.6 are tried in turn.
 737 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 738 dnl        but is deprecated.
 739 dnl /path/to/python/executable -
 740 dnl        Run python-config.py with this version of python to fetch the
 741 dnl        compilation parameters.
 742 dnl        NOTE: This needn't be the real python executable.
 743 dnl        In a cross-compilation scenario (build != host), this could be
 744 dnl        a shell script that provides what python-config.py provides for
 745 dnl        --ldflags, --includes, --exec-prefix.
 746 dnl python-executable -
 747 dnl        Find python-executable in $PATH, and then handle the same as
 748 dnl        /path/to/python/executable.
 749 dnl
 750 dnl If a python program is specified, it is used to run python-config.py and
 751 dnl is passed --ldflags, --includes, --exec-prefix.
 752
 753 AC_ARG_WITH(python,
 754   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 755   [], [with_python=auto])
 756 AC_MSG_CHECKING([whether to use python])
 757 AC_MSG_RESULT([$with_python])
 758
 759 if test "${with_python}" = no; then
 760   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 761   have_libpython=no
 762 else
 763   case "${with_python}" in
 764   [[\\/]]* | ?:[[\\/]]*)
 765     if test -d ${with_python}; then
 766       # Assume the python binary is ${with_python}/bin/python.
 767       python_prog="${with_python}/bin/python"
 768       python_prefix=
 769       # If python does not exit ${with_python}/bin, then try in
 770       # ${with_python}.  On Windows/MinGW, this is where the Python
 771       # executable is.
 772       if test ! -x "${python_prog}"; then
 773         python_prog="${with_python}/python"
 774         python_prefix=
 775       fi
 776       if test ! -x "${python_prog}"; then
 777         # Fall back to gdb 7.0/7.1 behaviour.
 778         python_prog=missing
 779         python_prefix=${with_python}
 780       fi
 781     elif test -x "${with_python}"; then
 782       # While we can't run python compiled for $host (unless host == build),
 783       # the user could write a script that provides the needed information,
 784       # so we support that.
 785       python_prog=${with_python}
 786       python_prefix=
 787     else
 788       AC_ERROR(invalid value for --with-python)
 789     fi
 790     ;;
 791   */*)
 792     # Disallow --with-python=foo/bar.
 793     AC_ERROR(invalid value for --with-python)
 794     ;;
 795   *)
 796     # The user has either specified auto, yes, or the name of the python
 797     # program assumed to be in $PATH.
 798     python_prefix=
 799     case "${with_python}" in
 800     yes | auto)
 801       if test ${build} = ${host}; then
 802         AC_PATH_PROG(python_prog_path, python, missing)
 803         if test "${python_prog_path}" = missing; then
 804           python_prog=missing
 805         else
 806           python_prog=${python_prog_path}
 807         fi
 808       else
 809         # Not much we can do except assume the cross-compiler will find the
 810         # right files.
 811         python_prog=missing
 812       fi
 813       ;;
 814     *)
 815       # While we can't run python compiled for $host (unless host == build),
 816       # the user could write a script that provides the needed information,
 817       # so we support that.
 818       python_prog="${with_python}"
 819       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 820       if test "${python_prog_path}" = missing; then
 821         AC_ERROR(unable to find python program ${python_prog})
 822       fi
 823       ;;
 824     esac
 825   esac
 826
 827   if test "${python_prog}" != missing; then
 828     # We have a python program to use, but it may be too old.
 829     # Don't flag an error for --with-python=auto (the default).
 830     have_python_config=yes
 831     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 832     if test $? != 0; then
 833       have_python_config=failed
 834       if test "${with_python}" != auto; then
 835         AC_ERROR(failure running python-config --includes)
 836       fi
 837     fi
 838     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 839     if test $? != 0; then
 840       have_python_config=failed
 841       if test "${with_python}" != auto; then
 842         AC_ERROR(failure running python-config --ldflags)
 843       fi
 844     fi
 845     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 846     if test $? != 0; then
 847       have_python_config=failed
 848       if test "${with_python}" != auto; then
 849         AC_ERROR(failure running python-config --exec-prefix)
 850       fi
 851     fi
 852   else
 853     # We do not have a python executable we can use to determine where
 854     # to find the Python headers and libs.  We cannot guess the include
 855     # path from the python_prefix either, because that include path
 856     # depends on the Python version.  So, there is nothing much we can
 857     # do except assume that the compiler will be able to find those files.
 858     python_includes=
 859     python_libs=
 860     have_python_config=no
 861   fi
 862
 863   # If we have python-config, only try the configuration it provides.
 864   # Otherwise fallback on the old way of trying different versions of
 865   # python in turn.
 866
 867   have_libpython=no
 868   if test "${have_python_config}" = yes; then
 869     AC_TRY_LIBPYTHON(have_libpython,
 870                      ${python_includes}, ${python_libs})
 871   elif test "${have_python_config}" != failed; then
 872     if test "${have_libpython}" = no; then
 873       AC_TRY_LIBPYTHON(have_libpython,
 874                        ${python_includes}, "-lpython2.7 ${python_libs}")
 875     fi
 876     if test "${have_libpython}" = no; then
 877       AC_TRY_LIBPYTHON(have_libpython,
 878                        ${python_includes}, "-lpython2.6 ${python_libs}")
 879     fi
 880   fi
 881
 882   if test "${have_libpython}" = no; then
 883     case "${with_python}" in
 884     yes)
 885       AC_MSG_ERROR([python is missing or unusable])
 886       ;;
 887     auto)
 888       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 889       ;;
 890     *)
 891       AC_MSG_ERROR([no usable python found at ${with_python}])
 892       ;;
 893     esac
 894   else
 895     if test -n "${python_prefix}"; then
 896       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 897                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 898       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 899     fi
 900   fi
 901 fi
 902
 903 if test "${have_libpython}" != no; then
 904   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 905   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 906   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 907   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 908   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 909   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 910
 911   # Flags needed to compile Python code (taken from python-config --cflags).
 912   # We cannot call python-config directly because it will output whatever was
 913   # used when compiling the Python interpreter itself, including flags which
 914   # would make the python-related objects be compiled differently from the
 915   # rest of GDB (e.g., -O2 and -fPIC).
 916   if test "${GCC}" = yes; then
 917     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 918     # Python headers recommend -DNDEBUG, but it's unclear if that just
 919     # refers to building Python itself.  In release mode, though, it
 920     # doesn't hurt for the Python code in gdb to follow.
 921     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 922   fi
 923
 924   if test "x${tentative_python_cflags}" != x; then
 925     AC_MSG_CHECKING(compiler flags for python code)
 926     for flag in ${tentative_python_cflags}; do
 927       # Check that the compiler accepts it
 928       saved_CFLAGS="$CFLAGS"
 929       CFLAGS="$CFLAGS $flag"
 930       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 931       CFLAGS="$saved_CFLAGS"
 932     done
 933     AC_MSG_RESULT(${PYTHON_CFLAGS})
 934   fi
 935
 936   # On x64 Windows, Python's include headers, and pyconfig.h in
 937   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 938   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 939   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 940   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 941   # The issue was reported to the Python community, but still isn't
 942   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 943
 944   case "$gdb_host" in
 945     mingw64)
 946            if test "${GCC}" = yes; then
 947              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 948            fi
 949            ;;
 950   esac
 951 else
 952   # Even if Python support is not compiled in, we need to have this file
 953   # included so that the "python" command, et.al., still exists.
 954   CONFIG_OBS="$CONFIG_OBS python/python.o"
 955   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 956 fi
 957
 958 # Work around Python http://bugs.python.org/issue10112.  See also
 959 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 960 # no effect.  Note that the only test after this that uses Python is
 961 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 962 # run without -export-dynamic too.
 963 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 964
 965 AC_SUBST(PYTHON_CFLAGS)
 966 AC_SUBST(PYTHON_CPPFLAGS)
 967 AC_SUBST(PYTHON_LIBS)
 968 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
 969
 970 # -------------------- #
 971 # Check for libguile.  #
 972 # -------------------- #
 973
 974 dnl Utility to simplify finding libguile.
 975 dnl $1 = pkg-config-program
 976 dnl $2 = space-separate list of guile versions to try
 977 dnl $3 = yes|no, indicating whether to flag errors or ignore them
 978 dnl $4 = the shell variable to assign the result to
 979 dnl      If libguile is found we store "yes" here.
 980
 981 AC_DEFUN([AC_TRY_LIBGUILE],
 982 [
 983   pkg_config=$1
 984   guile_version_list=$2
 985   flag_errors=$3
 986   define([have_libguile_var],$4)
 987   found_usable_guile=checking
 988   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
 989   for guile_version in ${guile_version_list}; do
 990     ${pkg_config} --exists ${guile_version} 2>/dev/null
 991     if test $? != 0; then
 992       continue
 993     fi
 994     dnl pkg-config says the package exists, so if we get an error now,
 995     dnl that's bad.
 996     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
 997     if test $? != 0; then
 998       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
 999     fi
1000     new_LIBS=`${pkg_config} --libs ${guile_version}`
1001     if test $? != 0; then
1002       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1003     fi
1004     dnl If we get this far, great.
1005     found_usable_guile=${guile_version}
1006     break
1007   done
1008   if test "${found_usable_guile}" = "checking"; then
1009     if test "${flag_errors}" = "yes"; then
1010       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1011     else
1012       found_usable_guile=no
1013     fi
1014   fi
1015   dnl One final sanity check.
1016   dnl The user could have said --with-guile=python-2.7.
1017   if test "${found_usable_guile}" != no; then
1018     save_CPPFLAGS=$CPPFLAGS
1019     save_LIBS=$LIBS
1020     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1021     LIBS="$LIBS $new_LIBS"
1022     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1023                                    [[scm_init_guile ();]])],
1024                    [have_libguile_var=yes
1025                     GUILE_CPPFLAGS=$new_CPPFLAGS
1026                     GUILE_LIBS=$new_LIBS],
1027                    [found_usable_guile=no])
1028     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1029     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1030       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1031                 [Define if Guile supports manual finalization.])
1032     )
1033     CPPFLAGS=$save_CPPFLAGS
1034     LIBS=$save_LIBS
1035     if test "${found_usable_guile}" = no; then
1036       if test "${flag_errors}" = yes; then
1037         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1038       fi
1039     fi
1040   fi
1041   AC_MSG_RESULT([${found_usable_guile}])
1042 ])
1043
1044 dnl There are several different values for --with-guile:
1045 dnl
1046 dnl no -   Don't include guile support.
1047 dnl yes -  Include guile support, error if it's missing.
1048 dnl        The pkg-config program must be in $PATH.
1049 dnl auto - Same as "yes", but if guile is missing from the system,
1050 dnl        fall back to "no".
1051 dnl guile-version [guile-version-choice-2 ...] -
1052 dnl        A space-separated list of guile package versions to try.
1053 dnl        These are passed to pkg-config as-is.
1054 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1055 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1056 dnl /path/to/pkg-config -
1057 dnl        Use this pkg-config program.
1058 dnl        NOTE: This needn't be the "real" pkg-config program.
1059 dnl        It could be a shell script.  It is invoked as:
1060 dnl        pkg-config --exists $version
1061 dnl        pkg-config --cflags $version
1062 dnl        pkg-config --libs $version
1063 dnl        pkg-config --variable guild $version
1064 dnl        The script will be called with $version having each value in
1065 dnl        $try_guile_versions until --exists indicates success.
1066
1067 AC_ARG_WITH(guile,
1068   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1069   [], [with_guile=auto])
1070 AC_MSG_CHECKING([whether to use guile])
1071 AC_MSG_RESULT([$with_guile])
1072
1073 dnl We check guile with pkg-config.
1074 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1075
1076 try_guile_versions="guile-2.0"
1077 have_libguile=no
1078 case "${with_guile}" in
1079 no)
1080   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1081   ;;
1082 auto)
1083   if test "${pkg_config_prog_path}" = "missing"; then
1084     AC_MSG_WARN([pkg-config not found, guile support disabled])
1085   else
1086     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1087   fi
1088   ;;
1089 yes)
1090   if test "${pkg_config_prog_path}" = "missing"; then
1091     AC_MSG_ERROR([pkg-config not found])
1092   fi
1093   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1094   ;;
1095 [[\\/]]* | ?:[[\\/]]*)
1096   if test -x "${with_guile}"; then
1097     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1098   else
1099     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1100   fi
1101   ;;
1102 "" | */*)
1103   # Disallow --with=guile="" and --with-guile=foo/bar.
1104   AC_MSG_ERROR([invalid value for --with-guile])
1105   ;;
1106 *)
1107   # A space separate list of guile versions to try, in order.
1108   if test "${pkg_config_prog_path}" = "missing"; then
1109     AC_MSG_ERROR([pkg-config not found])
1110   fi
1111   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1112   ;;
1113 esac
1114
1115 if test "${have_libguile}" != no; then
1116   dnl Get the name of the 'guild' program.
1117   case "${with_guile}" in
1118   [[\\/]]* | ?:[[\\/]]*)
1119     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1120     ;;
1121   *)
1122     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1123     ;;
1124   esac
1125
1126   dnl Make sure guild can handle this host.
1127   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1128   dnl If not, disable guile support.
1129   if test "$ac_cv_guild_ok" = no; then
1130     have_libguile=no
1131     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1132   fi
1133 fi
1134
1135 if test "${have_libguile}" != no; then
1136   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1137   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1138   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1139   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1140   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1141   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1142
1143   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1144   save_LIBS="$LIBS"
1145   save_CPPFLAGS="$CPPFLAGS"
1146   LIBS="$GUILE_LIBS"
1147   CPPFLAGS="$GUILE_CPPFLAGS"
1148   AC_CHECK_FUNCS([scm_new_smob])
1149   LIBS="$save_LIBS"
1150   CPPFLAGS="$save_CPPFLAGS"
1151 else
1152   # Even if Guile support is not compiled in, we need to have these files
1153   # included.
1154   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1155   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1156 fi
1157 AC_SUBST(GUILE_CPPFLAGS)
1158 AC_SUBST(GUILE_LIBS)
1159 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1160
1161 # ---------------------------- #
1162 # Check for source highlight.  #
1163 # ---------------------------- #
1164
1165 SRCHIGH_LIBS=
1166 SRCHIGH_CFLAGS=
1167
1168 AC_ARG_ENABLE(source-highlight,
1169   AS_HELP_STRING([--enable-source-highlight],
1170     [enable source-highlight for source listings]),
1171   [case "${enableval}" in
1172   yes)  enable_source_highlight=yes ;;
1173   no)   enable_source_highlight=no  ;;
1174   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1175 esac],
1176 [enable_source_highlight=auto])
1177
1178 if test "${enable_source_highlight}" != "no"; then
1179   AC_MSG_CHECKING([for the source-highlight library])
1180   if test "${pkg_config_prog_path}" = "missing"; then
1181     AC_MSG_RESULT([no - pkg-config not found])
1182     if test "${enable_source_highlight}" = "yes"; then
1183       AC_MSG_ERROR([pkg-config was not found in your system])
1184     fi
1185   else
1186     case "$LDFLAGS" in
1187       *static-libstdc*)
1188         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1189 either use --disable-source-highlight or dnl
1190 --without-static-standard-libraries])
1191         ;;
1192     esac
1193
1194     if ${pkg_config_prog_path} --exists source-highlight; then
1195       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1196       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1197       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1198                 [Define to 1 if the source-highlight library is available])
1199       AC_MSG_RESULT([yes])
1200     else
1201       AC_MSG_RESULT([no])
1202       if test "${enable_source_highlight}" = "yes"; then
1203         AC_MSG_ERROR([source-highlight was not found in your system])
1204       fi
1205     fi
1206   fi
1207 fi
1208 AC_SUBST(SRCHIGH_LIBS)
1209 AC_SUBST(SRCHIGH_CFLAGS)
1210
1211 AC_ARG_WITH(intel_pt,
1212   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1213   [], [with_intel_pt=auto])
1214 AC_MSG_CHECKING([whether to use intel pt])
1215 AC_MSG_RESULT([$with_intel_pt])
1216
1217 if test "${with_intel_pt}" = no; then
1218   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1219   HAVE_LIBIPT=no
1220 else
1221   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1222 #include <linux/perf_event.h>
1223 #ifndef PERF_ATTR_SIZE_VER5
1224 # error
1225 #endif
1226   ]])], [perf_event=yes], [perf_event=no])
1227   if test "$perf_event" != yes; then
1228     if test "$with_intel_pt" = yes; then
1229       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1230     else
1231       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1232     fi
1233   fi
1234
1235   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1236   if test "$HAVE_LIBIPT" != yes; then
1237     if test "$with_intel_pt" = yes; then
1238       AC_MSG_ERROR([libipt is missing or unusable])
1239     else
1240       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1241     fi
1242   else
1243     save_LIBS=$LIBS
1244     LIBS="$LIBS $LIBIPT"
1245     AC_CHECK_FUNCS(pt_insn_event)
1246     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1247                      [#include <intel-pt.h>])
1248     LIBS=$save_LIBS
1249   fi
1250 fi
1251
1252 # ------------------------- #
1253 # Checks for header files.  #
1254 # ------------------------- #
1255
1256 AC_HEADER_STDC
1257 # elf_hp.h is for HP/UX 64-bit shared library support.
1258 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1259                   thread_db.h linux/elf.h \
1260                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1261                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1262                   sys/reg.h sys/debugreg.h sys/select.h \
1263                   termios.h elf_hp.h])
1264 AC_CHECK_HEADERS(sys/user.h, [], [],
1265 [#if HAVE_SYS_PARAM_H
1266 # include <sys/param.h>
1267 #endif
1268 ])
1269
1270 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1271 AC_CHECK_HEADERS(term.h, [], [],
1272 [#if HAVE_CURSES_H
1273 # include <curses.h>
1274 #endif
1275 ])
1276
1277 # ------------------------- #
1278 # Checks for declarations.  #
1279 # ------------------------- #
1280
1281 libiberty_INIT
1282
1283 AC_CHECK_DECLS([snprintf])
1284 AM_LC_MESSAGES
1285
1286 # ----------------------- #
1287 # Checks for structures.  #
1288 # ----------------------- #
1289
1290 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1291
1292 # ------------------ #
1293 # Checks for types.  #
1294 # ------------------ #
1295
1296 AC_CHECK_TYPES(socklen_t, [], [],
1297 [#include <sys/types.h>
1298 #include <sys/socket.h>
1299 ])
1300
1301 # ------------------------------------- #
1302 # Checks for compiler characteristics.  #
1303 # ------------------------------------- #
1304
1305 AC_C_CONST
1306 AC_C_INLINE
1307 AC_C_BIGENDIAN
1308
1309 # ------------------------------ #
1310 # Checks for library functions.  #
1311 # ------------------------------ #
1312
1313 AC_FUNC_MMAP
1314 AC_FUNC_VFORK
1315 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1316                 pipe poll pread pread64 pwrite resize_term \
1317                 sbrk getpgid setpgid setpgrp setsid \
1318                 sigaction sigsetmask socketpair \
1319                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1320                 setrlimit getrlimit posix_madvise waitpid \
1321                 ptrace64 sigaltstack setns use_default_colors])
1322 AM_LANGINFO_CODESET
1323 GDB_AC_COMMON
1324
1325 # Check the return and argument types of ptrace.
1326 GDB_AC_PTRACE
1327
1328 dnl AC_FUNC_SETPGRP does not work when cross compiling
1329 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1330 if test "$cross_compiling" = no; then
1331   AC_FUNC_SETPGRP
1332 else
1333   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1334     [AC_TRY_COMPILE([
1335 #include <unistd.h>
1336 ], [
1337   if (setpgrp(1,1) == -1)
1338     exit (0);
1339   else
1340     exit (1);
1341 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1342 if test $ac_cv_func_setpgrp_void = yes; then
1343   AC_DEFINE(SETPGRP_VOID, 1)
1344 fi
1345 fi
1346
1347 # Assume we'll default to using the included libiberty regex.
1348 gdb_use_included_regex=yes
1349
1350 # However, if the system regex is GNU regex, then default to *not*
1351 # using the included regex.
1352 AC_CACHE_CHECK(
1353   [for GNU regex],
1354   [gdb_cv_have_gnu_regex],
1355   [AC_TRY_COMPILE(
1356     [#include <gnu-versions.h>],
1357     [#define REGEX_INTERFACE_VERSION 1
1358 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1359 # error "Version mismatch"
1360 #endif],
1361     gdb_cv_have_gnu_regex=yes,
1362     gdb_cv_have_gnu_regex=no)])
1363 if test $gdb_cv_have_gnu_regex = yes; then
1364   gdb_use_included_regex=no
1365 fi
1366
1367 AC_ARG_WITH(included-regex,
1368   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1369   gdb_with_regex=$withval,
1370   gdb_with_regex=$gdb_use_included_regex)
1371 if test "$gdb_with_regex" = yes; then
1372   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1373     [Define to 1 if the regex included in libiberty should be used.])
1374 fi
1375
1376 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1377 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1378 [#include <sys/param.h>
1379 #include <sys/proc.h>
1380 ])
1381
1382 # See if <sys/lwp.h> defines `struct lwp`.
1383 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1384 [AC_TRY_COMPILE([#include <sys/param.h>
1385 #define _KMEMUSER
1386 #include <sys/lwp.h>], [struct lwp l;],
1387 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1388 if test $gdb_cv_struct_lwp = yes; then
1389   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1390             [Define to 1 if your system has struct lwp.])
1391 fi
1392
1393 # See if <machine/reg.h> degines `struct reg'.
1394 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1395 [AC_TRY_COMPILE([#include <sys/types.h>
1396 #include <machine/reg.h>], [struct reg r;],
1397 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1398 if test $gdb_cv_struct_reg = yes; then
1399   AC_DEFINE(HAVE_STRUCT_REG, 1,
1400             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1401 fi
1402
1403 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1404 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1405 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1406                  [#include <sys/types.h>
1407 #include <machine/reg.h>])
1408
1409 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1410 # Older amd64 Linux's don't have the fs_base and gs_base members of
1411 # `struct user_regs_struct'.
1412 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1413      [], [], [#include <sys/types.h>
1414 #include <sys/user.h>])
1415
1416 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1417 AC_MSG_CHECKING(for PTRACE_GETREGS)
1418 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1419 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1420                 [PTRACE_GETREGS;],
1421                 [gdb_cv_have_ptrace_getregs=yes],
1422                 [gdb_cv_have_ptrace_getregs=no])])
1423 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1424 if test $gdb_cv_have_ptrace_getregs = yes; then
1425   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1426   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1427 fi
1428
1429 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1430 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1431 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1432 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1433                 [PTRACE_GETFPXREGS;],
1434                 [gdb_cv_have_ptrace_getfpxregs=yes],
1435                 [gdb_cv_have_ptrace_getfpxregs=no])])
1436 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1437 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1438   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1439   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1440 fi
1441
1442 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1443 AC_MSG_CHECKING(for PT_GETDBREGS)
1444 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1445 [AC_TRY_COMPILE([#include <sys/types.h>
1446 #include <sys/ptrace.h>],
1447                 [PT_GETDBREGS;],
1448                 [gdb_cv_have_pt_getdbregs=yes],
1449                 [gdb_cv_have_pt_getdbregs=no])])
1450 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1451 if test $gdb_cv_have_pt_getdbregs = yes; then
1452   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1453   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1454 fi
1455
1456 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1457 AC_MSG_CHECKING(for PT_GETXMMREGS)
1458 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1459 [AC_TRY_COMPILE([#include <sys/types.h>
1460 #include <sys/ptrace.h>],
1461                 [PT_GETXMMREGS;],
1462                 [gdb_cv_have_pt_getxmmregs=yes],
1463                 [gdb_cv_have_pt_getxmmregs=no])])
1464 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1465 if test $gdb_cv_have_pt_getxmmregs = yes; then
1466   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1467   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1468 fi
1469
1470 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1471 # Older FreeBSD versions don't have the pl_tdname member of
1472 # `struct ptrace_lwpinfo'.
1473 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1474                  [#include <sys/ptrace.h>])
1475
1476 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1477 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1478 # FreeBSD 10.3.
1479 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1480                  [#include <sys/ptrace.h>])
1481
1482 if test "$ac_cv_header_sys_procfs_h" = yes; then
1483   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1484   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1485   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1486   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1487   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1488   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1489   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1490   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
1491 fi
1492
1493 # Check if the compiler supports the `long long' type.
1494
1495 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1496                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1497 [[extern long long foo;]],
1498 [[switch (foo & 2) { case 0: return 1; }]])],
1499                                   gdb_cv_c_long_long=yes,
1500                                   gdb_cv_c_long_long=no)])
1501 if test $gdb_cv_c_long_long != yes; then
1502   # libdecnumber requires long long.
1503   AC_MSG_ERROR([Compiler must support long long for GDB.])
1504 fi
1505
1506 # Check if the compiler and runtime support printing long longs.
1507
1508 AC_CACHE_CHECK([for long long support in printf],
1509                gdb_cv_printf_has_long_long,
1510                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1511 [[char buf[32];
1512   long long l = 0;
1513   l = (l << 16) + 0x0123;
1514   l = (l << 16) + 0x4567;
1515   l = (l << 16) + 0x89ab;
1516   l = (l << 16) + 0xcdef;
1517   sprintf (buf, "0x%016llx", l);
1518   return (strcmp ("0x0123456789abcdef", buf));]])],
1519                               gdb_cv_printf_has_long_long=yes,
1520                               gdb_cv_printf_has_long_long=no,
1521                               gdb_cv_printf_has_long_long=no)])
1522 if test $gdb_cv_printf_has_long_long = yes; then
1523   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1524             [Define to 1 if the "%ll" format works to print long longs.])
1525 fi
1526
1527 # Check if the compiler and runtime support printing decfloats.
1528
1529 AC_CACHE_CHECK([for decfloat support in printf],
1530                gdb_cv_printf_has_decfloat,
1531                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1532 [[char buf[64];
1533   _Decimal32 d32 = 1.2345df;
1534   _Decimal64 d64 = 1.2345dd;
1535   _Decimal128 d128 = 1.2345dl;
1536   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1537   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1538                               gdb_cv_printf_has_decfloat=yes,
1539                               gdb_cv_printf_has_decfloat=no,
1540                               gdb_cv_printf_has_decfloat=no)])
1541 if test $gdb_cv_printf_has_decfloat = yes; then
1542   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1543             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1544 fi
1545
1546 # Check if the compiler supports the `long double' type.  We can't use
1547 # AC_C_LONG_DOUBLE because that one does additional checks on the
1548 # constants defined in <float.h> that fail on some systems,
1549 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1550
1551 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1552                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1553                                   gdb_cv_c_long_double=yes,
1554                                   gdb_cv_c_long_double=no)])
1555 if test $gdb_cv_c_long_double = yes; then
1556   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1557            [Define to 1 if the compiler supports long double.])
1558 fi
1559
1560 # Check if the compiler and runtime support printing long doubles.
1561
1562 AC_CACHE_CHECK([for long double support in printf],
1563                gdb_cv_printf_has_long_double,
1564                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1565 [[char buf[16];
1566   long double f = 3.141592653;
1567   sprintf (buf, "%Lg", f);
1568   return (strncmp ("3.14159", buf, 7));]])],
1569                               gdb_cv_printf_has_long_double=yes,
1570                               gdb_cv_printf_has_long_double=no,
1571                               gdb_cv_printf_has_long_double=no)])
1572 if test $gdb_cv_printf_has_long_double = yes; then
1573   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1574             [Define to 1 if the "%Lg" format works to print long doubles.])
1575 fi
1576
1577 # Check if the compiler and runtime support scanning long doubles.
1578
1579 AC_CACHE_CHECK([for long double support in scanf],
1580                gdb_cv_scanf_has_long_double,
1581                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1582 [[#include <stdio.h>]],
1583 [[char *buf = "3.141592653";
1584   long double f = 0;
1585   sscanf (buf, "%Lg", &f);
1586   return !(f > 3.14159 && f < 3.14160);]])],
1587                               gdb_cv_scanf_has_long_double=yes,
1588                               gdb_cv_scanf_has_long_double=no,
1589                               gdb_cv_scanf_has_long_double=no)])
1590 if test $gdb_cv_scanf_has_long_double = yes; then
1591   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1592             [Define to 1 if the "%Lg" format works to scan long doubles.])
1593 fi
1594
1595 case ${host_os} in
1596 aix*)
1597   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1598     SAVE_LDFLAGS=$LDFLAGS
1599
1600     case $GCC in
1601     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1602     *) gdb_cv_bigtoc=-bbigtoc ;;
1603     esac
1604
1605     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1606     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1607     LDFLAGS="${SAVE_LDFLAGS}"
1608   ])
1609   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1610   ;;
1611 esac
1612
1613 AC_MSG_CHECKING(for the dynamic export flag)
1614 dynamic_list=false
1615 if test "${gdb_native}" = yes; then
1616    # The dynamically loaded libthread_db needs access to symbols in the gdb
1617    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1618    # may not be supported there.
1619    old_LDFLAGS="$LDFLAGS"
1620    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1621    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1622    LDFLAGS="$LDFLAGS $RDYNAMIC"
1623    if test "${have_libpython}" = no; then
1624      AC_TRY_LINK([], [], [dynamic_list=true])
1625    else
1626      # Workaround http://bugs.python.org/issue4434 where static
1627      # libpythonX.Y.a would get its symbols required for
1628      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1629      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1630
1631      # Note the workaround for Python
1632      # http://bugs.python.org/issue10112 earlier has removed
1633      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1634      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1635      # always pass.
1636      old_CFLAGS="$CFLAGS"
1637      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1638      old_LIBS="$LIBS"
1639      LIBS="$LIBS $PYTHON_LIBS"
1640      old_CPPFLAGS="$CPPFLAGS"
1641      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1642      AC_RUN_IFELSE(
1643        [AC_LANG_PROGRAM(
1644          [#include "Python.h"],
1645          [int err;
1646           Py_Initialize ();
1647           err = PyRun_SimpleString ("import itertools\n");
1648           Py_Finalize ();
1649           return err == 0 ? 0 : 1;])],
1650        [dynamic_list=true], [], [true])
1651      LIBS="$old_LIBS"
1652      CFLAGS="$old_CFLAGS"
1653      CPPFLAGS="$old_CPPFLAGS"
1654    fi
1655    LDFLAGS="$old_LDFLAGS"
1656 fi
1657 if $dynamic_list; then
1658   found="-Wl,--dynamic-list"
1659   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1660 else
1661   found="-rdynamic"
1662   RDYNAMIC="-rdynamic"
1663 fi
1664 AC_SUBST(RDYNAMIC)
1665 AC_MSG_RESULT($found)
1666
1667 dnl For certain native configurations, we need to check whether thread
1668 dnl support can be built in or not.
1669 dnl
1670 dnl Note that we only want this if we are both native (host == target),
1671 dnl and not doing a canadian cross build (build == host).
1672
1673 if test ${build} = ${host} -a ${host} = ${target} ; then
1674    case ${host_os} in
1675    aix*)
1676       AC_MSG_CHECKING(for AiX thread debugging library)
1677       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1678                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1679                                    [#ifndef PTHDB_VERSION_3
1680                                     #error
1681                                     #endif],
1682                                    gdb_cv_have_aix_thread_debug=yes,
1683                                    gdb_cv_have_aix_thread_debug=no)])
1684       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1685       if test $gdb_cv_have_aix_thread_debug = yes; then
1686          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1687          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1688          LIBS="$LIBS -lpthdebug"
1689
1690          # Older versions of AIX do not provide the declaration for
1691          # the getthrds function (it appears that it was introduced
1692          # with AIX 6.x).
1693          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1694       fi
1695       ;;
1696    esac
1697    AC_SUBST(CONFIG_LDFLAGS)
1698 fi
1699
1700 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1701 dnl other error codes.
1702 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1703    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1704                   gdb_cv_thread_db_h_has_td_notalloc,
1705      AC_TRY_COMPILE(
1706        [#include <thread_db.h>],
1707        [int i = TD_NOTALLOC;],
1708        gdb_cv_thread_db_h_has_td_notalloc=yes,
1709        gdb_cv_thread_db_h_has_td_notalloc=no
1710      )
1711    )
1712    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1713                   gdb_cv_thread_db_h_has_td_version,
1714      AC_TRY_COMPILE(
1715        [#include <thread_db.h>],
1716        [int i = TD_VERSION;],
1717        gdb_cv_thread_db_h_has_td_version=yes,
1718        gdb_cv_thread_db_h_has_td_version=no
1719      )
1720    )
1721    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1722                   gdb_cv_thread_db_h_has_td_notls,
1723      AC_TRY_COMPILE(
1724        [#include <thread_db.h>],
1725        [int i = TD_NOTLS;],
1726        gdb_cv_thread_db_h_has_td_notls=yes,
1727        gdb_cv_thread_db_h_has_td_notls=no
1728      )
1729    )
1730 fi
1731 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1732   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1733             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1734 fi
1735 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1736   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1737             [Define if <thread_db.h> has the TD_VERSION error code.])
1738 fi
1739 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1740   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1741             [Define if <thread_db.h> has the TD_NOTLS error code.])
1742 fi
1743
1744 dnl Check if we can disable the virtual address space randomization.
1745 dnl The functionality of setarch -R.
1746 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1747 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1748 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1749 #       define ADDR_NO_RANDOMIZE 0x0040000
1750 #      endif
1751        /* Test the flag could be set and stays set.  */
1752        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1753        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1754            return 1])])
1755 AC_RUN_IFELSE([PERSONALITY_TEST],
1756               [have_personality=true],
1757               [have_personality=false],
1758               [AC_LINK_IFELSE([PERSONALITY_TEST],
1759                               [have_personality=true],
1760                               [have_personality=false])])
1761 if $have_personality
1762 then
1763     AC_DEFINE([HAVE_PERSONALITY], 1,
1764               [Define if you support the personality syscall.])
1765 fi
1766
1767 dnl Set the host's .gdbinit filename.
1768 case $host_os in
1769   go32* | *djgpp*)
1770     gdbinit=gdb.ini
1771     ;;
1772   *)
1773     gdbinit=.gdbinit
1774     ;;
1775 esac
1776 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1777
1778 dnl Handle optional features that can be enabled.
1779
1780 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1781 # except that the argument to --with-sysroot is optional.
1782 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1783 if test "x$with_sysroot" = xyes; then
1784   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1785 fi
1786 AC_ARG_WITH(sysroot,
1787   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1788                  [search for usr/lib et al within DIR]),
1789   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1790 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1791               [search for usr/lib et al within DIR])
1792 AC_SUBST(TARGET_SYSTEM_ROOT)
1793 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1794
1795 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1796     [automatically load a system-wide gdbinit file],
1797     [])
1798 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1799     [automatically load system-wide gdbinit files from this directory],
1800     [])
1801
1802 AM_GDB_WARNINGS
1803 AM_GDB_UBSAN
1804
1805 # In the Cygwin environment, we need some additional flags.
1806 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1807 [AC_EGREP_CPP(^lose$, [
1808 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1809 lose
1810 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1811
1812
1813 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1814 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1815 case ${host} in
1816   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1817   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1818   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1819   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1820 esac
1821 AC_SUBST(SER_HARDWIRE)
1822
1823 # libreadline needs libuser32.a in a cygwin environment
1824 WIN32LIBS=
1825 if test x$gdb_cv_os_cygwin = xyes; then
1826     WIN32LIBS="-luser32"
1827     case "${target}" in
1828         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1829         ;;
1830     esac
1831 fi
1832
1833 # The ser-tcp.c module requires sockets.
1834 case ${host} in
1835   *mingw32*)
1836     AC_DEFINE(USE_WIN32API, 1,
1837               [Define if we should use the Windows API, instead of the
1838                POSIX API.  On Windows, we use the Windows API when
1839                building for MinGW, but the POSIX API when building
1840                for Cygwin.])
1841     WIN32LIBS="$WIN32LIBS -lws2_32"
1842     ;;
1843 esac
1844 AC_SUBST(WIN32LIBS)
1845
1846 # Add ELF support to GDB, but only if BFD includes ELF support.
1847 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1848                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1849 if test $gdb_cv_var_elf = yes; then
1850   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1851   AC_DEFINE(HAVE_ELF, 1,
1852             [Define if ELF support should be included.])
1853   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1854   if test "$plugins" = "yes"; then
1855     AC_SEARCH_LIBS(dlopen, dl)
1856   fi
1857 fi
1858
1859 # Add macho support to GDB, but only if BFD includes it.
1860 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1861                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1862 if test $gdb_cv_var_macho = yes; then
1863   CONFIG_OBS="$CONFIG_OBS machoread.o"
1864 fi
1865
1866 # Add any host-specific objects to GDB.
1867 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1868
1869 # If building on ELF, look for lzma support for embedded compressed debug info.
1870 if test $gdb_cv_var_elf = yes; then
1871   AC_ARG_WITH(lzma,
1872     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1873     [], [with_lzma=auto])
1874   AC_MSG_CHECKING([whether to use lzma])
1875   AC_MSG_RESULT([$with_lzma])
1876
1877   if test "${with_lzma}" != no; then
1878     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1879                           [lzma_index_iter iter;
1880                            lzma_index_iter_init (&iter, 0);
1881                            lzma_mf_is_supported (LZMA_MF_HC3);])
1882     if test "$HAVE_LIBLZMA" != yes; then
1883       if test "$with_lzma" = yes; then
1884         AC_MSG_ERROR([missing liblzma for --with-lzma])
1885       fi
1886     fi
1887   fi
1888 fi
1889
1890 LIBGUI="../libgui/src/libgui.a"
1891 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1892 AC_SUBST(LIBGUI)
1893 AC_SUBST(GUI_CFLAGS_X)
1894
1895 WIN32LDAPP=
1896 AC_SUBST(WIN32LIBS)
1897 AC_SUBST(WIN32LDAPP)
1898
1899 case "${host}" in
1900 *-*-cygwin* | *-*-mingw* )
1901     configdir="win"
1902     ;;
1903 *)
1904     configdir="unix"
1905     ;;
1906 esac
1907
1908 GDBTKLIBS=
1909 if test "${enable_gdbtk}" = "yes"; then
1910
1911     # Gdbtk must have an absolute path to srcdir in order to run
1912     # properly when not installed.
1913     here=`pwd`
1914     cd ${srcdir}
1915     GDBTK_SRC_DIR=`pwd`
1916     cd $here
1917
1918     SC_PATH_TCLCONFIG
1919
1920     # If $no_tk is nonempty, then we can't do Tk, and there is no
1921     # point to doing Tcl.
1922     SC_PATH_TKCONFIG
1923
1924     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1925         SC_LOAD_TCLCONFIG
1926
1927         # Check for in-tree tcl
1928         here=`pwd`
1929         cd ${srcdir}/..
1930         topdir=`pwd`
1931         cd ${here}
1932
1933         intree="no"
1934         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1935           intree="yes"
1936         fi
1937
1938         # Find Tcl private headers
1939         if test x"${intree}" = xno; then
1940           CY_AC_TCL_PRIVATE_HEADERS
1941           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1942           TCL_LIBRARY="${TCL_LIB_SPEC}"
1943           TCL_DEPS=""
1944         else
1945           # If building tcl in the same src tree, private headers
1946           # are not needed, but we need to be sure to use the right
1947           # headers library
1948           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1949           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1950           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1951         fi
1952         AC_SUBST(TCL_INCLUDE)
1953         AC_SUBST(TCL_LIBRARY)
1954         AC_SUBST(TCL_DEPS)
1955
1956         SC_LOAD_TKCONFIG
1957
1958         # Check for in-tree Tk
1959         intree="no"
1960         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1961           intree="yes"
1962         fi
1963
1964         # Find Tk private headers
1965         if test x"${intree}" = xno; then
1966           CY_AC_TK_PRIVATE_HEADERS
1967           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1968           TK_LIBRARY=${TK_LIB_SPEC}
1969           TK_DEPS=""
1970         else
1971           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1972           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1973           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1974         fi
1975         AC_SUBST(TK_INCLUDE)
1976         AC_SUBST(TK_LIBRARY)
1977         AC_SUBST(TK_DEPS)
1978         AC_SUBST(TK_XINCLUDES)
1979
1980         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1981
1982         # Include some libraries that Tcl and Tk want.
1983         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1984         # Yes, the ordering seems wrong here.  But it isn't.
1985         # TK_LIBS is the list of libraries that need to be linked
1986         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1987         # were in LIBS then any link tests after this point would
1988         # try to include things like `$(LIBGUI)', which wouldn't work.
1989         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1990
1991         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1992         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1993         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1994         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1995         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1996         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1997         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1998
1999         if test x$gdb_cv_os_cygwin = xyes; then
2000           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2001           WIN32LDAPP="-Wl,--subsystem,console"
2002           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2003         fi
2004
2005         AC_CONFIG_SUBDIRS(gdbtk)
2006     fi
2007 fi
2008
2009 AC_SUBST(X_CFLAGS)
2010 AC_SUBST(X_LDFLAGS)
2011 AC_SUBST(X_LIBS)
2012 AC_SUBST(GDBTKLIBS)
2013 AC_SUBST(GDBTK_CFLAGS)
2014 AC_SUBST(GDBTK_SRC_DIR)
2015
2016 AC_PATH_X
2017
2018 # Unlike the sim directory, whether a simulator is linked is controlled by
2019 # presence of a gdb_sim definition in the target configure.tgt entry.
2020 # This code just checks for a few cases where we'd like to ignore those
2021 # definitions, even when they're present in the '.mt' file.  These cases
2022 # are when --disable-sim is specified, or if the simulator directory is
2023 # not part of the source tree.
2024 #
2025 AC_ARG_ENABLE(sim,
2026 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2027 [echo "enable_sim = $enable_sim";
2028  echo "enableval = ${enableval}";
2029  case "${enableval}" in
2030   yes) ignore_sim=false ;;
2031   no)  ignore_sim=true ;;
2032   *)   ignore_sim=false ;;
2033  esac],
2034 [ignore_sim=false])
2035
2036 if test ! -d "${srcdir}/../sim"; then
2037   ignore_sim=true
2038 fi
2039
2040 SIM=
2041 SIM_OBS=
2042 if test "${ignore_sim}" = "false"; then
2043   if test x"${gdb_sim}" != x ; then
2044     SIM="${gdb_sim}"
2045     SIM_OBS="remote-sim.o"
2046     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2047
2048     # Some tdep code should only be compiled in when the ppc sim is
2049     # built.  PR sim/13418.
2050     case $target in
2051       powerpc*-*-*)
2052         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2053         ;;
2054     esac
2055   fi
2056 fi
2057 AC_SUBST(SIM)
2058 AC_SUBST(SIM_OBS)
2059
2060 AC_SUBST(ENABLE_CFLAGS)
2061 AC_SUBST(PROFILE_CFLAGS)
2062
2063 AC_SUBST(CONFIG_OBS)
2064 AC_SUBST(CONFIG_DEPS)
2065 AC_SUBST(CONFIG_SRCS)
2066 AC_SUBST(CONFIG_ALL)
2067 AC_SUBST(CONFIG_CLEAN)
2068 AC_SUBST(CONFIG_INSTALL)
2069 AC_SUBST(CONFIG_UNINSTALL)
2070
2071 # List of host floatformats.
2072 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2073 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2074 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2075
2076 # target_subdir is used by the testsuite to find the target libraries.
2077 target_subdir=
2078 if test "${host}" != "${target}"; then
2079     target_subdir="${target_alias}/"
2080 fi
2081 AC_SUBST(target_subdir)
2082
2083 # Import nat definitions.
2084 nat_makefile_frag=/dev/null
2085 if test "${gdb_native}" = "yes"; then
2086   . ${srcdir}/configure.nat
2087   nativefile=$NAT_FILE
2088 fi
2089
2090 AC_SUBST(NAT_FILE)
2091 AC_SUBST(NATDEPFILES)
2092 AC_SUBST(NAT_CDEPS)
2093 AC_SUBST(LOADLIBES)
2094 AC_SUBST(MH_CFLAGS)
2095 AC_SUBST(XM_CLIBS)
2096 AC_SUBST(NAT_GENERATED_FILES)
2097 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2098 AC_SUBST_FILE(nat_makefile_frag)
2099
2100 if test x"${gdb_osabi}" != x ; then
2101     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2102                        [Define to the default OS ABI for this configuration.])
2103 fi
2104
2105 AC_ARG_ENABLE(gdbserver,
2106 AS_HELP_STRING([--enable-gdbserver],
2107                [automatically build gdbserver (yes/no/auto, default is auto)]),
2108 [case "${enableval}" in
2109   yes| no|auto) ;;
2110   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2111 esac],[enable_gdbserver=auto])
2112
2113 # We only build gdbserver automatically in a native configuration, and
2114 # only if the user did not explicitly disable its build.
2115 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2116   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2117   if test "x$build_gdbserver" = xyes; then
2118     AC_MSG_RESULT(yes)
2119     AC_CONFIG_SUBDIRS(gdbserver)
2120     gdbserver_build_enabled=yes
2121   else
2122     AC_MSG_RESULT(no)
2123   fi
2124 fi
2125
2126 # If the user explicitly request the gdbserver to be built, verify that
2127 # we were in fact able to enable it.
2128 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2129   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2130 fi
2131
2132 # Check for babeltrace and babeltrace-ctf
2133 AC_ARG_WITH(babeltrace,
2134   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2135   [], [with_babeltrace=auto])
2136 AC_MSG_CHECKING([whether to use babeltrace])
2137 AC_MSG_RESULT([$with_babeltrace])
2138
2139 if test "x$with_babeltrace" = "xno"; then
2140   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2141 else
2142   # Append -Werror to CFLAGS so that configure can catch the warning
2143   # "assignment from incompatible pointer type", which is related to
2144   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2145   # in GDB, while babeltrace 1.0.3 is broken.
2146   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2147   # safe to save and restore CFLAGS here.
2148   saved_CFLAGS=$CFLAGS
2149   CFLAGS="$CFLAGS -Werror"
2150   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2151                         [#include <babeltrace/babeltrace.h>
2152                          #include <babeltrace/ctf/events.h>
2153                          #include <babeltrace/ctf/iterator.h>],
2154                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2155                         struct bt_ctf_event *event = NULL;
2156                         const struct bt_definition *scope;
2157
2158                         pos->type = BT_SEEK_BEGIN;
2159                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2160                         scope = bt_ctf_get_top_level_scope (event,
2161                                                            BT_STREAM_EVENT_HEADER);
2162                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2163                         ])
2164   CFLAGS=$saved_CFLAGS
2165
2166   if test "$HAVE_LIBBABELTRACE" != yes; then
2167      if test "$with_babeltrace" = yes; then
2168        AC_MSG_ERROR([babeltrace is missing or unusable])
2169      else
2170        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2171      fi
2172   fi
2173 fi
2174
2175 # Check for xxhash
2176 AC_ARG_WITH(xxhash,
2177   AC_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2178   [], [with_xxhash=auto])
2179
2180 if test "x$with_xxhash" != "xno"; then
2181   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2182                         [#include <xxhash.h>],
2183                         [XXH32("foo", 3, 0);
2184                         ])
2185   if test "$HAVE_LIBXXHASH" != yes; then
2186     if test "$with_xxhash" = yes; then
2187       AC_MSG_ERROR([xxhash is missing or unusable])
2188     fi
2189   fi
2190   if test "x$with_xxhash" = "xauto"; then
2191     with_xxhash="$HAVE_LIBXXHASH"
2192   fi
2193 fi
2194
2195 AC_MSG_CHECKING([whether to use xxhash])
2196 AC_MSG_RESULT([$with_xxhash])
2197
2198 NM_H=
2199 rm -f nm.h
2200 if test "${nativefile}" != ""; then
2201     case "${nativefile}" in
2202       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2203       * ) GDB_NM_FILE="${nativefile}"
2204     esac
2205     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2206                     [GDB_NM_FILE=$GDB_NM_FILE])
2207     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2208     NM_H=nm.h
2209 fi
2210 AC_SUBST(GDB_NM_FILE)
2211 AC_SUBST(NM_H)
2212
2213 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2214 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2215 if test "x$USE_MAINTAINER_MODE" = xyes; then
2216   if test "${XSLTPROC}" = missing; then
2217     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2218   fi
2219 fi
2220 AC_SUBST(XSLTPROC)
2221
2222 dnl Check for exe extension set on certain hosts (e.g. Win32)
2223 AC_EXEEXT
2224
2225 dnl  Detect the character set used by this host.
2226 dnl  At the moment, we just assume it's UTF-8.
2227 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2228           [Define to be a string naming the default host character set.])
2229
2230 GDB_AC_SELFTEST([
2231   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) gdbsupport/selftest.o selftest-arch.o"
2232   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) gdbsupport/selftest.c selftest-arch.c"
2233 ])
2234
2235 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2236 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2237 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2238 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2239
2240 AC_OUTPUT