gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(server.c)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_GNU_SOURCE
  29 AC_SYS_LARGEFILE
  30 AM_PROG_INSTALL_STRIP
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_PROG_RANLIB
  37
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 AC_HEADER_STDC
  45
  46 # Set the 'development' global.
  47 . $srcdir/../../bfd/development.sh
  48
  49 GDB_AC_SELFTEST([
  50   srv_selftest_objs="gdbsupport/selftest.o"
  51 ])
  52
  53 ACX_NONCANONICAL_TARGET
  54 ACX_NONCANONICAL_HOST
  55
  56 # Dependency checking.
  57 ZW_CREATE_DEPDIR
  58
  59 # Create sub-directories for objects and dependencies.
  60 CONFIG_SRC_SUBDIR="arch gdbsupport nat target"
  61 AC_SUBST(CONFIG_SRC_SUBDIR)
  62
  63 AC_CONFIG_COMMANDS([gdbdepdir],[
  64   for subdir in ${CONFIG_SRC_SUBDIR}
  65   do
  66       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  67   done],
  68   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  69
  70 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  71
  72 gnulib_extra_configure_args=
  73 # If large-file support is disabled, make sure gnulib does the same.
  74 if test "$enable_largefile" = no; then
  75 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  76 fi
  77
  78 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  79 # to find the the source subdir to be configured directly under
  80 # gdbserver/.  We need to build gnulib under some other directory not
  81 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  82 # build it in the same directory, when building in the source dir.
  83 ACX_CONFIGURE_DIR(["../../gnulib"], ["build-gnulib-gdbserver"],
  84                   ["$gnulib_extra_configure_args"])
  85
  86 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  87
  88 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  89                  sys/procfs.h linux/elf.h dnl
  90                  fcntl.h signal.h sys/file.h dnl
  91                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  92                  netinet/tcp.h arpa/inet.h)
  93 AC_FUNC_FORK
  94 AC_CHECK_FUNCS(pread pwrite pread64)
  95
  96 GDB_AC_COMMON
  97
  98 # Check the return and argument types of ptrace.
  99 GDB_AC_PTRACE
 100
 101 # Check for UST
 102 ustlibs=""
 103 ustinc=""
 104
 105 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 106                           Equivalent to --with-ust-include=PATH/include
 107                           plus --with-ust-lib=PATH/lib])
 108 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 109 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 110
 111 case $with_ust in
 112   no)
 113     ustlibs=
 114     ustinc=
 115     ;;
 116   "" | yes)
 117     ustlibs=" -lust "
 118     ustinc=""
 119     ;;
 120   *)
 121     ustlibs="-L$with_ust/lib -lust"
 122     ustinc="-I$with_ust/include "
 123     ;;
 124 esac
 125 if test "x$with_ust_include" != x; then
 126   ustinc="-I$with_ust_include "
 127 fi
 128 if test "x$with_ust_lib" != x; then
 129   ustlibs="-L$with_ust_lib -lust"
 130 fi
 131
 132 if test "x$with_ust" != "xno"; then
 133   saved_CFLAGS="$CFLAGS"
 134   CFLAGS="$CFLAGS $ustinc"
 135   AC_MSG_CHECKING([for ust])
 136   AC_TRY_COMPILE([
 137 #define CONFIG_UST_GDB_INTEGRATION
 138 #include <ust/ust.h>
 139   ],[],
 140   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 141   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 142   CFLAGS="$saved_CFLAGS"
 143 fi
 144
 145 # Flags needed for UST
 146 AC_SUBST(ustlibs)
 147 AC_SUBST(ustinc)
 148
 149 AM_GDB_WARNINGS
 150
 151 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 152 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 153 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 154 dnl augment LIBS.
 155 old_LIBS="$LIBS"
 156 LIBS="$LIBS -ldl"
 157 AC_CHECK_FUNCS(dladdr)
 158 LIBS="$old_LIBS"
 159
 160 libiberty_INIT
 161
 162 AC_CHECK_DECLS([perror, vasprintf, vsnprintf])
 163
 164 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 165 # Older amd64 Linux's don't have the fs_base and gs_base members of
 166 # `struct user_regs_struct'.
 167 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 168      [], [], [#include <sys/types.h>
 169 #include <sys/user.h>])
 170
 171
 172 AC_CHECK_TYPES(socklen_t, [], [],
 173 [#include <sys/types.h>
 174 #include <sys/socket.h>
 175 ])
 176
 177 case "${target}" in
 178   *-android*)
 179     # Starting with NDK version 9, <elf.h> actually includes definitions
 180     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 181     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 182     # leading to conflicts with the defintions from <linux/elf.h>.
 183     # This makes it impossible for us to include both <elf.h> and
 184     # <linux/elf.h>, which means that, in practice, we do not have
 185     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 186     # Therefore, do not try to auto-detect availability, as it would
 187     # get it wrong on this platform.
 188     ;;
 189   *)
 190     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 191     #include <elf.h>
 192     )
 193 esac
 194
 195 ACX_PKGVERSION([GDB])
 196 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 197 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 198 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 199
 200 # Check for various supplementary target information (beyond the
 201 # triplet) which might affect the choices in configure.srv.
 202 case "${target}" in
 203 changequote(,)dnl
 204   i[34567]86-*-linux*)
 205 changequote([,])dnl
 206     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 207                    [save_CPPFLAGS="$CPPFLAGS"
 208                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 209                     AC_EGREP_CPP([got it], [
 210 #if __x86_64__
 211 got it
 212 #endif
 213                  ], [gdb_cv_i386_is_x86_64=yes],
 214                     [gdb_cv_i386_is_x86_64=no])
 215                     CPPFLAGS="$save_CPPFLAGS"])
 216     ;;
 217
 218   x86_64-*-linux*)
 219     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 220                    [save_CPPFLAGS="$CPPFLAGS"
 221                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 222                     AC_EGREP_CPP([got it], [
 223 #if __x86_64__ && __ILP32__
 224 got it
 225 #endif
 226                  ], [gdb_cv_x86_is_x32=yes],
 227                     [gdb_cv_x86_is_x32=no])
 228                     CPPFLAGS="$save_CPPFLAGS"])
 229     ;;
 230
 231   m68k-*-*)
 232     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 233                    [save_CPPFLAGS="$CPPFLAGS"
 234                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 235                     AC_EGREP_CPP([got it], [
 236 #ifdef __mcoldfire__
 237 got it
 238 #endif
 239                  ], [gdb_cv_m68k_is_coldfire=yes],
 240                     [gdb_cv_m68k_is_coldfire=no])
 241                     CPPFLAGS="$save_CPPFLAGS"])
 242     ;;
 243 esac
 244
 245 . ${srcdir}/configure.srv
 246
 247 if test "${srv_mingwce}" = "yes"; then
 248   LIBS="$LIBS -lws2"
 249 elif test "${srv_mingw}" = "yes"; then
 250   # WIN32APILIBS is set by GDB_AC_COMMON.
 251   LIBS="$LIBS $WIN32APILIBS"
 252 elif test "${srv_qnx}" = "yes"; then
 253   LIBS="$LIBS -lsocket"
 254 elif test "${srv_lynxos}" = "yes"; then
 255   LIBS="$LIBS -lnetinet"
 256 fi
 257
 258 if test "${srv_linux_usrregs}" = "yes"; then
 259   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 260             [Define if the target supports PTRACE_PEEKUSR for register ]
 261             [access.])
 262 fi
 263
 264 if test "${srv_linux_regsets}" = "yes"; then
 265   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 266             [Define if the target supports register sets.])
 267
 268   AC_MSG_CHECKING(for PTRACE_GETREGS)
 269   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 270   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 271                   [PTRACE_GETREGS;],
 272                   [gdbsrv_cv_have_ptrace_getregs=yes],
 273                   [gdbsrv_cv_have_ptrace_getregs=no])])
 274   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 275   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 276     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 277               [Define if the target supports PTRACE_GETREGS for register ]
 278               [access.])
 279   fi
 280
 281   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 282   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 283   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 284                   [PTRACE_GETFPXREGS;],
 285                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 286                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 287   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 288   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 289     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 290               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 291               [register access.])
 292   fi
 293 fi
 294
 295 if test "${srv_linux_btrace}" = "yes"; then
 296   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 297             [Define if the target supports branch tracing.])
 298 fi
 299
 300 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 301 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 302   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 303 fi
 304
 305 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 306 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 307   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 308 fi
 309
 310 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 311 dnl needs it (and gdbreplay doesn't).
 312 old_LIBS="$LIBS"
 313 AC_CHECK_LIB(dl, dlopen)
 314 LIBS="$old_LIBS"
 315
 316 srv_thread_depfiles=
 317 srv_libs=
 318
 319 if test "$srv_linux_thread_db" = "yes"; then
 320   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 321     srv_libs="-ldl"
 322     AC_MSG_CHECKING(for the dynamic export flag)
 323     old_LDFLAGS="$LDFLAGS"
 324     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 325     # supported there.
 326     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 327     LDFLAGS="$LDFLAGS $RDYNAMIC"
 328     AC_TRY_LINK([], [],
 329                 [found="-Wl,--dynamic-list"
 330                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 331                 [RDYNAMIC="-rdynamic"
 332                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 333                  AC_TRY_LINK([], [],
 334                              [found="-rdynamic"],
 335                              [found="no"
 336                               RDYNAMIC=""])])
 337     AC_SUBST(RDYNAMIC)
 338     LDFLAGS="$old_LDFLAGS"
 339     AC_MSG_RESULT($found)
 340   else
 341     srv_libs="-lthread_db"
 342   fi
 343
 344   srv_thread_depfiles="thread-db.o proc-service.o"
 345   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 346   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 347   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 348                   [gdbsrv_cv_have_td_version=yes],
 349                   [gdbsrv_cv_have_td_version=no])])
 350   if test "$gdbsrv_cv_have_td_version" = yes; then
 351     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 352   fi
 353 fi
 354
 355 AC_ARG_WITH(libthread-db,
 356 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 357 [srv_libthread_db_path="${withval}"
 358   srv_libs="$srv_libthread_db_path"
 359 ])
 360
 361 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 362   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 363 fi
 364
 365 if test "$srv_xmlfiles" != ""; then
 366   srv_xmlbuiltin="xml-builtin.o"
 367   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 368
 369   tmp_xmlfiles=$srv_xmlfiles
 370   srv_xmlfiles=""
 371   for f in $tmp_xmlfiles; do
 372     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 373   done
 374 fi
 375
 376 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_selftest_objs"
 377 GDBSERVER_LIBS="$srv_libs"
 378
 379 dnl Check whether the target supports __sync_*_compare_and_swap.
 380 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 381                 gdbsrv_cv_have_sync_builtins, [
 382 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 383                 gdbsrv_cv_have_sync_builtins=yes,
 384                 gdbsrv_cv_have_sync_builtins=no)])
 385 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
 386   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 387     [Define to 1 if the target supports __sync_*_compare_and_swap])
 388 fi
 389
 390 dnl Check for -fvisibility=hidden support in the compiler.
 391 saved_cflags="$CFLAGS"
 392 CFLAGS="$CFLAGS -fvisibility=hidden"
 393 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 394                         [gdbsrv_cv_have_visibility_hidden=yes],
 395                         [gdbsrv_cv_have_visibility_hidden=no])
 396 CFLAGS="$saved_cflags"
 397
 398 IPA_DEPFILES=""
 399 extra_libraries=""
 400
 401 # check whether to enable the inprocess agent
 402 if test "$ipa_obj" != "" \
 403    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 404    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 405    have_ipa=true
 406 else
 407    have_ipa=false
 408 fi
 409
 410 AC_ARG_ENABLE(inprocess-agent,
 411 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 412 [case "$enableval" in
 413   yes) want_ipa=true ;;
 414   no) want_ipa=false ;;
 415   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 416 esac],
 417 [want_ipa=$have_ipa])
 418
 419 if $want_ipa ; then
 420    if $have_ipa ; then
 421      IPA_DEPFILES="$ipa_obj"
 422      extra_libraries="$extra_libraries libinproctrace.so"
 423    else
 424      AC_MSG_ERROR([inprocess agent not supported for this target])
 425    fi
 426 fi
 427
 428 AC_SUBST(GDBSERVER_DEPFILES)
 429 AC_SUBST(GDBSERVER_LIBS)
 430 AC_SUBST(srv_xmlbuiltin)
 431 AC_SUBST(srv_xmlfiles)
 432 AC_SUBST(IPA_DEPFILES)
 433 AC_SUBST(extra_libraries)
 434
 435 GNULIB=build-gnulib-gdbserver/import
 436
 437 GNULIB_STDINT_H=
 438 if test x"$STDINT_H" != x; then
 439   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 440 fi
 441 AC_SUBST(GNULIB_STDINT_H)
 442
 443 AC_CONFIG_FILES([Makefile])
 444
 445 AC_OUTPUT