gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(server.c)
  22 AC_CONFIG_HEADER(config.h:config.in)
  23
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_GNU_SOURCE
  29 AC_SYS_LARGEFILE
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 AC_PROG_INSTALL
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_PROG_RANLIB
  36
  37 AC_ARG_PROGRAM
  38
  39 # We require a C++11 compiler.  Check if one is available, and if
  40 # necessary, set CXX_DIALECT to some -std=xxx switch.
  41 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  42
  43 AC_HEADER_STDC
  44
  45 # Set the 'development' global.
  46 . $srcdir/../../bfd/development.sh
  47
  48 # Enable -lmcheck by default (it provides cheap-enough memory
  49 # mangling), but turn it off for releases.
  50 if $development; then
  51   libmcheck_default=yes
  52 else
  53   libmcheck_default=no
  54 fi
  55 GDB_AC_LIBMCHECK(${libmcheck_default})
  56
  57 if $development; then
  58   srv_selftest_objs="common/selftest.o"
  59   AC_DEFINE(GDB_SELF_TEST, 1,
  60             [Define if self-testing features should be enabled])
  61 fi
  62
  63 ACX_NONCANONICAL_TARGET
  64 ACX_NONCANONICAL_HOST
  65
  66 # Dependency checking.
  67 ZW_CREATE_DEPDIR
  68
  69 # Create sub-directories for objects and dependencies.
  70 CONFIG_SRC_SUBDIR="arch common"
  71 AC_SUBST(CONFIG_SRC_SUBDIR)
  72
  73 AC_CONFIG_COMMANDS([gdbdepdir],[
  74   for subdir in ${CONFIG_SRC_SUBDIR}
  75   do
  76       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  77   done],
  78   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  79
  80 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  81
  82 gnulib_extra_configure_args=
  83 # If large-file support is disabled, make sure gnulib does the same.
  84 if test "$enable_largefile" = no; then
  85 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  86 fi
  87
  88 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  89 # to find the the source subdir to be configured directly under
  90 # gdbserver/.  We need to build gnulib under some other directory not
  91 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  92 # build it in the same directory, when building in the source dir.
  93 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  94                   ["$gnulib_extra_configure_args"])
  95
  96 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  97
  98 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  99                  proc_service.h sys/procfs.h linux/elf.h dnl
 100                  fcntl.h signal.h sys/file.h dnl
 101                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
 102                  netinet/tcp.h arpa/inet.h)
 103 AC_FUNC_FORK
 104 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
 105
 106 GDB_AC_COMMON
 107
 108 # Check the return and argument types of ptrace.
 109 GDB_AC_PTRACE
 110
 111 # Check for UST
 112 ustlibs=""
 113 ustinc=""
 114
 115 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 116                           Equivalent to --with-ust-include=PATH/include
 117                           plus --with-ust-lib=PATH/lib])
 118 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 119 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 120
 121 case $with_ust in
 122   no)
 123     ustlibs=
 124     ustinc=
 125     ;;
 126   "" | yes)
 127     ustlibs=" -lust "
 128     ustinc=""
 129     ;;
 130   *)
 131     ustlibs="-L$with_ust/lib -lust"
 132     ustinc="-I$with_ust/include "
 133     ;;
 134 esac
 135 if test "x$with_ust_include" != x; then
 136   ustinc="-I$with_ust_include "
 137 fi
 138 if test "x$with_ust_lib" != x; then
 139   ustlibs="-L$with_ust_lib -lust"
 140 fi
 141
 142 if test "x$with_ust" != "xno"; then
 143   saved_CFLAGS="$CFLAGS"
 144   CFLAGS="$CFLAGS $ustinc"
 145   AC_MSG_CHECKING([for ust])
 146   AC_TRY_COMPILE([
 147 #define CONFIG_UST_GDB_INTEGRATION
 148 #include <ust/ust.h>
 149   ],[],
 150   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 151   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 152   CFLAGS="$saved_CFLAGS"
 153 fi
 154
 155 # Flags needed for UST
 156 AC_SUBST(ustlibs)
 157 AC_SUBST(ustinc)
 158
 159 AM_GDB_WARNINGS
 160
 161 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 162 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 163 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 164 dnl augment LIBS.
 165 old_LIBS="$LIBS"
 166 LIBS="$LIBS -ldl"
 167 AC_CHECK_FUNCS(dladdr)
 168 LIBS="$old_LIBS"
 169
 170 libiberty_INIT
 171
 172 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 173
 174 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 175
 176 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 177 # Older amd64 Linux's don't have the fs_base and gs_base members of
 178 # `struct user_regs_struct'.
 179 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 180      [], [], [#include <sys/types.h>
 181 #include <sys/user.h>])
 182
 183
 184 AC_CHECK_TYPES(socklen_t, [], [],
 185 [#include <sys/types.h>
 186 #include <sys/socket.h>
 187 ])
 188
 189 case "${target}" in
 190   *-android*)
 191     # Starting with NDK version 9, <elf.h> actually includes definitions
 192     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 193     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 194     # leading to conflicts with the defintions from <linux/elf.h>.
 195     # This makes it impossible for us to include both <elf.h> and
 196     # <linux/elf.h>, which means that, in practice, we do not have
 197     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 198     # Therefore, do not try to auto-detect availability, as it would
 199     # get it wrong on this platform.
 200     ;;
 201   *)
 202     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 203     #include <elf.h>
 204     )
 205 esac
 206
 207 ACX_PKGVERSION([GDB])
 208 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 209 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 210 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 211
 212 # Check for various supplementary target information (beyond the
 213 # triplet) which might affect the choices in configure.srv.
 214 case "${target}" in
 215 changequote(,)dnl
 216   i[34567]86-*-linux*)
 217 changequote([,])dnl
 218     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 219                    [save_CPPFLAGS="$CPPFLAGS"
 220                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 221                     AC_EGREP_CPP([got it], [
 222 #if __x86_64__
 223 got it
 224 #endif
 225                  ], [gdb_cv_i386_is_x86_64=yes],
 226                     [gdb_cv_i386_is_x86_64=no])
 227                     CPPFLAGS="$save_CPPFLAGS"])
 228     ;;
 229
 230   x86_64-*-linux*)
 231     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 232                    [save_CPPFLAGS="$CPPFLAGS"
 233                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 234                     AC_EGREP_CPP([got it], [
 235 #if __x86_64__ && __ILP32__
 236 got it
 237 #endif
 238                  ], [gdb_cv_x86_is_x32=yes],
 239                     [gdb_cv_x86_is_x32=no])
 240                     CPPFLAGS="$save_CPPFLAGS"])
 241     ;;
 242
 243   m68k-*-*)
 244     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 245                    [save_CPPFLAGS="$CPPFLAGS"
 246                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 247                     AC_EGREP_CPP([got it], [
 248 #ifdef __mcoldfire__
 249 got it
 250 #endif
 251                  ], [gdb_cv_m68k_is_coldfire=yes],
 252                     [gdb_cv_m68k_is_coldfire=no])
 253                     CPPFLAGS="$save_CPPFLAGS"])
 254     ;;
 255 esac
 256
 257 . ${srcdir}/configure.srv
 258
 259 # Add in the common host objects.
 260 . ${srcdir}/../common/common.host
 261 srv_host_obs="$common_host_obs"
 262
 263 if test "${srv_mingwce}" = "yes"; then
 264   LIBS="$LIBS -lws2"
 265 elif test "${srv_mingw}" = "yes"; then
 266   LIBS="$LIBS -lws2_32"
 267 elif test "${srv_qnx}" = "yes"; then
 268   LIBS="$LIBS -lsocket"
 269 elif test "${srv_lynxos}" = "yes"; then
 270   LIBS="$LIBS -lnetinet"
 271 fi
 272
 273 if test "${srv_mingw}" = "yes"; then
 274   AC_DEFINE(USE_WIN32API, 1,
 275             [Define if we should use the Windows API, instead of the
 276              POSIX API.  On Windows, we use the Windows API when
 277              building for MinGW, but the POSIX API when building
 278              for Cygwin.])
 279 fi
 280
 281 if test "${srv_linux_usrregs}" = "yes"; then
 282   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 283             [Define if the target supports PTRACE_PEEKUSR for register ]
 284             [access.])
 285 fi
 286
 287 if test "${srv_linux_regsets}" = "yes"; then
 288   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 289             [Define if the target supports register sets.])
 290
 291   AC_MSG_CHECKING(for PTRACE_GETREGS)
 292   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 293   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 294                   [PTRACE_GETREGS;],
 295                   [gdbsrv_cv_have_ptrace_getregs=yes],
 296                   [gdbsrv_cv_have_ptrace_getregs=no])])
 297   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 298   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 299     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 300               [Define if the target supports PTRACE_GETREGS for register ]
 301               [access.])
 302   fi
 303
 304   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 305   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 306   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 307                   [PTRACE_GETFPXREGS;],
 308                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 309                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 310   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 311   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 312     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 313               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 314               [register access.])
 315   fi
 316 fi
 317
 318 if test "${srv_linux_btrace}" = "yes"; then
 319   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 320             [Define if the target supports branch tracing.])
 321 fi
 322
 323 if test "$ac_cv_header_sys_procfs_h" = yes; then
 324   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 325   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 326   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 327   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 328   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 329 fi
 330
 331 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 332 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 333   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 334 fi
 335
 336 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 337 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 338   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 339 fi
 340
 341 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 342 dnl needs it (and gdbreplay doesn't).
 343 old_LIBS="$LIBS"
 344 AC_CHECK_LIB(dl, dlopen)
 345 LIBS="$old_LIBS"
 346
 347 srv_thread_depfiles=
 348 srv_libs=
 349
 350 if test "$srv_linux_thread_db" = "yes"; then
 351   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 352     srv_libs="-ldl"
 353     AC_MSG_CHECKING(for the dynamic export flag)
 354     old_LDFLAGS="$LDFLAGS"
 355     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 356     # supported there.
 357     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 358     LDFLAGS="$LDFLAGS $RDYNAMIC"
 359     AC_TRY_LINK([], [],
 360                 [found="-Wl,--dynamic-list"
 361                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 362                 [RDYNAMIC="-rdynamic"
 363                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 364                  AC_TRY_LINK([], [],
 365                              [found="-rdynamic"],
 366                              [found="no"
 367                               RDYNAMIC=""])])
 368     AC_SUBST(RDYNAMIC)
 369     LDFLAGS="$old_LDFLAGS"
 370     AC_MSG_RESULT($found)
 371   else
 372     srv_libs="-lthread_db"
 373   fi
 374
 375   srv_thread_depfiles="thread-db.o proc-service.o"
 376   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 377   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 378   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 379                   [gdbsrv_cv_have_td_version=yes],
 380                   [gdbsrv_cv_have_td_version=no])])
 381   if test $gdbsrv_cv_have_td_version = yes; then
 382     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 383   fi
 384 fi
 385
 386 AC_ARG_WITH(libthread-db,
 387 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 388 [srv_libthread_db_path="${withval}"
 389   srv_libs="$srv_libthread_db_path"
 390 ])
 391
 392 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 393   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 394 fi
 395
 396 if test "$srv_xmlfiles" != ""; then
 397   srv_xmlbuiltin="xml-builtin.o"
 398   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 399
 400   tmp_xmlfiles=$srv_xmlfiles
 401   srv_xmlfiles=""
 402   for f in $tmp_xmlfiles; do
 403     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 404   done
 405 fi
 406
 407 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs $srv_selftest_objs"
 408 GDBSERVER_LIBS="$srv_libs"
 409
 410 dnl Check whether the target supports __sync_*_compare_and_swap.
 411 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 412                 gdbsrv_cv_have_sync_builtins, [
 413 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 414                 gdbsrv_cv_have_sync_builtins=yes,
 415                 gdbsrv_cv_have_sync_builtins=no)])
 416 if test $gdbsrv_cv_have_sync_builtins = yes; then
 417   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 418     [Define to 1 if the target supports __sync_*_compare_and_swap])
 419 fi
 420
 421 dnl Check for -fvisibility=hidden support in the compiler.
 422 saved_cflags="$CFLAGS"
 423 CFLAGS="$CFLAGS -fvisibility=hidden"
 424 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 425                         [gdbsrv_cv_have_visibility_hidden=yes],
 426                         [gdbsrv_cv_have_visibility_hidden=no])
 427 CFLAGS="$saved_cflags"
 428
 429 dnl Check if we can disable the virtual address space randomization.
 430 dnl The functionality of setarch -R.
 431 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 432 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 433 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 434 #       define ADDR_NO_RANDOMIZE 0x0040000
 435 #      endif
 436        /* Test the flag could be set and stays set.  */
 437        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 438        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 439            return 1])])
 440 AC_RUN_IFELSE([PERSONALITY_TEST],
 441               [gdbsrv_cv_have_personality=true],
 442               [gdbsrv_cv_have_personality=false],
 443               [AC_LINK_IFELSE([PERSONALITY_TEST],
 444                               [gdbsrv_cv_have_personality=true],
 445                               [gdbsrv_cv_have_personality=false])])
 446 if $gdbsrv_cv_have_personality
 447 then
 448     AC_DEFINE([HAVE_PERSONALITY], 1,
 449               [Define if you support the personality syscall.])
 450 fi
 451
 452
 453 IPA_DEPFILES=""
 454 extra_libraries=""
 455
 456 # check whether to enable the inprocess agent
 457 if test "$ipa_obj" != "" \
 458    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 459    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 460    have_ipa=true
 461 else
 462    have_ipa=false
 463 fi
 464
 465 AC_ARG_ENABLE(inprocess-agent,
 466 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 467 [case "$enableval" in
 468   yes) want_ipa=true ;;
 469   no) want_ipa=false ;;
 470   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 471 esac],
 472 [want_ipa=$have_ipa])
 473
 474 if $want_ipa ; then
 475    if $have_ipa ; then
 476      IPA_DEPFILES="$ipa_obj"
 477      extra_libraries="$extra_libraries libinproctrace.so"
 478    else
 479      AC_MSG_ERROR([inprocess agent not supported for this target])
 480    fi
 481 fi
 482
 483 AC_SUBST(GDBSERVER_DEPFILES)
 484 AC_SUBST(GDBSERVER_LIBS)
 485 AC_SUBST(srv_xmlbuiltin)
 486 AC_SUBST(srv_xmlfiles)
 487 AC_SUBST(IPA_DEPFILES)
 488 AC_SUBST(extra_libraries)
 489
 490 GNULIB=build-gnulib-gdbserver/import
 491
 492 GNULIB_STDINT_H=
 493 if test x"$STDINT_H" != x; then
 494   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 495 fi
 496 AC_SUBST(GNULIB_STDINT_H)
 497
 498 AC_CONFIG_FILES([Makefile],
 499 [case x$CONFIG_HEADERS in
 500 xconfig.h:config.in)
 501 echo > stamp-h ;;
 502 esac
 503 ])
 504
 505 AC_OUTPUT