gdb: better handling of 'S' packets
[deliverable/binutils-gdb.git] / gdb / testsuite / gdb.server / stop-reply-no-thread-multi.exp
1 # This testcase is part of GDB, the GNU debugger.
2 #
3 # Copyright 2021 Free Software Foundation, Inc.
4 #
5 # This program is free software; you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 3 of the License, or
8 # (at your option) any later version.
9 #
10 # This program is distributed in the hope that it will be useful,
11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
13 # GNU General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License
16 # along with this program. If not, see <http://www.gnu.org/licenses/>.
17
18 # Test how GDB handles the case where a target either doesn't use 'T'
19 # packets at all or doesn't include a thread-id in a 'T' packet, AND,
20 # where the test program contains multiple threads.
21 #
22 # In general if multiple threads are executing and the target doesn't
23 # include a thread-id in its stop response then GDB will not be able
24 # to correctly figure out which thread the stop applies to.
25 #
26 # However, this test covers a very specific case, there are multiple
27 # threads but only a single thread is actually executing. So, when
28 # the stop comes from the target, without a thread-id, GDB should be
29 # able to correctly figure out which thread has stopped.
30
31 load_lib gdbserver-support.exp
32
33 if { [skip_gdbserver_tests] } {
34 verbose "skipping gdbserver tests"
35 return -1
36 }
37
38 standard_testfile
39 if { [build_executable "failed to prepare" $testfile $srcfile {debug pthreads}] == -1 } {
40 return -1
41 }
42
43 # Run the tests with different features of GDBserver disabled.
44 proc run_test { disable_feature } {
45 global binfile gdb_prompt decimal hex
46
47 clean_restart ${binfile}
48
49 # Make sure we're disconnected, in case we're testing with an
50 # extended-remote board, therefore already connected.
51 gdb_test "disconnect" ".*"
52
53 set packet_arg ""
54 if { $disable_feature != "" } {
55 set packet_arg "--disable-packet=${disable_feature}"
56 }
57 set res [gdbserver_start $packet_arg $binfile]
58 set gdbserver_protocol [lindex $res 0]
59 set gdbserver_gdbport [lindex $res 1]
60
61 # Disable XML-based thread listing, and multi-process extensions.
62 gdb_test_no_output "set remote threads-packet off"
63 gdb_test_no_output "set remote multiprocess-feature-packet off"
64
65 set res [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
66 if ![gdb_assert {$res == 0} "connect"] {
67 return
68 }
69
70 # There should be only one thread listed at this point.
71 gdb_test_multiple "info threads" "" {
72 -re "2 Thread.*$gdb_prompt $" {
73 fail $gdb_test_name
74 }
75 -re "has terminated.*$gdb_prompt $" {
76 fail $gdb_test_name
77 }
78 -re "\\\* 1\[\t \]*Thread\[^\r\n\]*\r\n$gdb_prompt $" {
79 pass $gdb_test_name
80 }
81 }
82
83 gdb_breakpoint "unlock_worker"
84 gdb_continue_to_breakpoint "run to unlock_worker"
85
86 # There should be two threads at this point with thread 1 selected.
87 gdb_test "info threads" \
88 "\\\* 1\[\t \]*Thread\[^\r\n\]*\r\n 2\[\t \]*Thread\[^\r\n\]*" \
89 "second thread should now exist"
90
91 # Switch threads.
92 gdb_test "thread 2" ".*" "switch to second thread"
93
94 # Now turn on scheduler-locking so that when we step thread 2 only
95 # that one thread will be set running.
96 gdb_test_no_output "set scheduler-locking on"
97
98 # Single step thread 2. Only the one thread will step. When the
99 # thread stops, if the stop packet doesn't include a thread-id
100 # then GDB should still understand which thread stopped.
101 gdb_test_multiple "stepi" "" {
102 -re -wrap "Thread 1 received signal SIGTRAP.*" {
103 fail $gdb_test_name
104 }
105 -re -wrap "$hex.*$decimal.*while \\(worker_blocked\\).*" {
106 pass $gdb_test_name
107 }
108 }
109
110 # Check that thread 2 is still selected.
111 gdb_test "info threads" \
112 " 1\[\t \]*Thread\[^\r\n\]*\r\n\\\* 2\[\t \]*Thread\[^\r\n\]*" \
113 "second thread should still be selected after stepi"
114
115 # Turn scheduler locking off again so that when we continue all
116 # threads will be set running.
117 gdb_test_no_output "set scheduler-locking off"
118
119 # Continue until exit. The server sends a 'W' with no PID.
120 # Bad GDB gave an error like below when target is nonstop:
121 # (gdb) c
122 # Continuing.
123 # No process or thread specified in stop reply: W00
124 gdb_continue_to_end "" continue 1
125 }
126
127 # Disable different features within gdbserver:
128 #
129 # Tthread: Start GDBserver, with ";thread:NNN" in T stop replies disabled,
130 # emulating old gdbservers when debugging single-threaded programs.
131 #
132 # T: Start GDBserver with the entire 'T' stop reply packet disabled,
133 # GDBserver will instead send the 'S' stop reply.
134 foreach_with_prefix to_disable { "" Tthread T } {
135 run_test $to_disable
136 }
This page took 0.032856 seconds and 4 git commands to generate.