gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-variable -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-error=maybe-uninitialized \
  44 -Wno-mismatched-tags \
  45 -Wno-error=deprecated-register \
  46 -Wsuggest-override \
  47 -Wimplicit-fallthrough=3 \
  48 -Wduplicated-cond"
  49
  50 case "${host}" in
  51   *-*-mingw32*)
  52     # Enable -Wno-format by default when using gcc on mingw since many
  53     # GCC versions complain about %I64.
  54     build_warnings="$build_warnings -Wno-format" ;;
  55   *-*-solaris*)
  56     # Solaris 11.4 <python2.7/ceval.h> uses #pragma no_inline that GCC
  57     # doesn't understand.
  58     build_warnings="$build_warnings -Wno-unknown-pragmas"
  59     # Solaris 11 <unistd.h> marks vfork deprecated.
  60     build_warnings="$build_warnings -Wno-deprecated-declarations" ;;
  61   *)
  62     # Note that gcc requires -Wformat for -Wformat-nonliteral to work,
  63     # but there's a special case for this below.
  64     build_warnings="$build_warnings -Wformat-nonliteral" ;;
  65 esac
  66
  67 AC_ARG_ENABLE(build-warnings,
  68 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  69 [case "${enableval}" in
  70   yes)  ;;
  71   no)   build_warnings="-w";;
  72   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  73         build_warnings="${build_warnings} ${t}";;
  74   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  75         build_warnings="${t} ${build_warnings}";;
  76   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  77 esac
  78 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  79   echo "Setting compiler warning flags = $build_warnings" 6>&1
  80 fi])dnl
  81 AC_ARG_ENABLE(gdb-build-warnings,
  82 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  83 [case "${enableval}" in
  84   yes)  ;;
  85   no)   build_warnings="-w";;
  86   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  87         build_warnings="${build_warnings} ${t}";;
  88   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  89         build_warnings="${t} ${build_warnings}";;
  90   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  91 esac
  92 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  93   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  94 fi])dnl
  95
  96 # The set of warnings supported by a C++ compiler is not the same as
  97 # of the C compiler.
  98 AC_LANG_PUSH([C++])
  99
 100 WARN_CFLAGS=""
 101 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 102 then
 103     AC_MSG_CHECKING(compiler warning flags)
 104     # Separate out the -Werror flag as some files just cannot be
 105     # compiled with it enabled.
 106     for w in ${build_warnings}; do
 107         # GCC does not complain about -Wno-unknown-warning.  Invert
 108         # and test -Wunknown-warning instead.
 109         case $w in
 110         -Wno-*)
 111                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
 112         -Wformat-nonliteral)
 113                 # gcc requires -Wformat before -Wformat-nonliteral
 114                 # will work, so stick them together.
 115                 w="-Wformat $w"
 116                 wtest="$w"
 117                 ;;
 118         *)
 119                 wtest=$w ;;
 120         esac
 121
 122         case $w in
 123         -Werr*) WERROR_CFLAGS=-Werror ;;
 124         *)
 125             # Check whether GCC accepts it.
 126             saved_CFLAGS="$CFLAGS"
 127             CFLAGS="$CFLAGS -Werror $wtest"
 128             saved_CXXFLAGS="$CXXFLAGS"
 129             CXXFLAGS="$CXXFLAGS -Werror $wtest"
 130             if test "x$w" = "x-Wunused-variable"; then
 131               # Check for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=38958,
 132               # fixed in GCC 4.9.  This test is derived from the gdb
 133               # source code that triggered this bug in GCC.
 134               AC_TRY_COMPILE(
 135                 [struct scoped_restore_base {};
 136                  struct scoped_restore_tmpl : public scoped_restore_base {
 137                    ~scoped_restore_tmpl() {}
 138                  };],
 139                 [const scoped_restore_base &b = scoped_restore_tmpl();],
 140                 WARN_CFLAGS="${WARN_CFLAGS} $w",)
 141             else
 142               AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 143             fi
 144             CFLAGS="$saved_CFLAGS"
 145             CXXFLAGS="$saved_CXXFLAGS"
 146         esac
 147     done
 148     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 149 fi
 150 AC_SUBST(WARN_CFLAGS)
 151 AC_SUBST(WERROR_CFLAGS)
 152
 153 AC_LANG_POP([C++])
 154 ])