gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2019 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-variable -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-error=maybe-uninitialized \
  44 -Wno-mismatched-tags \
  45 -Wno-error=deprecated-register \
  46 -Wsuggest-override \
  47 -Wimplicit-fallthrough=3 \
  48 -Wduplicated-cond \
  49 -Wshadow=local \
  50 -Wdeprecated-copy \
  51 -Wdeprecated-copy-dtor \
  52 -Wredundant-move"
  53
  54 case "${host}" in
  55   *-*-mingw32*)
  56     # Enable -Wno-format by default when using gcc on mingw since many
  57     # GCC versions complain about %I64.
  58     build_warnings="$build_warnings -Wno-format" ;;
  59   *-*-solaris*)
  60     # Solaris 11.4 <python2.7/ceval.h> uses #pragma no_inline that GCC
  61     # doesn't understand.
  62     build_warnings="$build_warnings -Wno-unknown-pragmas"
  63     # Solaris 11 <unistd.h> marks vfork deprecated.
  64     build_warnings="$build_warnings -Wno-deprecated-declarations" ;;
  65   *)
  66     # Note that gcc requires -Wformat for -Wformat-nonliteral to work,
  67     # but there's a special case for this below.
  68     build_warnings="$build_warnings -Wformat-nonliteral" ;;
  69 esac
  70
  71 AC_ARG_ENABLE(build-warnings,
  72 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  73 [case "${enableval}" in
  74   yes)  ;;
  75   no)   build_warnings="-w";;
  76   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  77         build_warnings="${build_warnings} ${t}";;
  78   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  79         build_warnings="${t} ${build_warnings}";;
  80   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  81 esac
  82 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  83   echo "Setting compiler warning flags = $build_warnings" 6>&1
  84 fi])dnl
  85 AC_ARG_ENABLE(gdb-build-warnings,
  86 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  87 [case "${enableval}" in
  88   yes)  ;;
  89   no)   build_warnings="-w";;
  90   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  91         build_warnings="${build_warnings} ${t}";;
  92   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  93         build_warnings="${t} ${build_warnings}";;
  94   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  95 esac
  96 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  97   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  98 fi])dnl
  99
 100 # The set of warnings supported by a C++ compiler is not the same as
 101 # of the C compiler.
 102 AC_LANG_PUSH([C++])
 103
 104 WARN_CFLAGS=""
 105 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 106 then
 107     AC_MSG_CHECKING(compiler warning flags)
 108     # Separate out the -Werror flag as some files just cannot be
 109     # compiled with it enabled.
 110     for w in ${build_warnings}; do
 111         # GCC does not complain about -Wno-unknown-warning.  Invert
 112         # and test -Wunknown-warning instead.
 113         case $w in
 114         -Wno-*)
 115                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
 116         -Wformat-nonliteral)
 117                 # gcc requires -Wformat before -Wformat-nonliteral
 118                 # will work, so stick them together.
 119                 w="-Wformat $w"
 120                 wtest="$w"
 121                 ;;
 122         *)
 123                 wtest=$w ;;
 124         esac
 125
 126         case $w in
 127         -Werr*) WERROR_CFLAGS=-Werror ;;
 128         *)
 129             # Check whether GCC accepts it.
 130             saved_CFLAGS="$CFLAGS"
 131             CFLAGS="$CFLAGS -Werror $wtest"
 132             saved_CXXFLAGS="$CXXFLAGS"
 133             CXXFLAGS="$CXXFLAGS -Werror $wtest"
 134             if test "x$w" = "x-Wunused-variable"; then
 135               # Check for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=38958,
 136               # fixed in GCC 4.9.  This test is derived from the gdb
 137               # source code that triggered this bug in GCC.
 138               AC_TRY_COMPILE(
 139                 [struct scoped_restore_base {};
 140                  struct scoped_restore_tmpl : public scoped_restore_base {
 141                    ~scoped_restore_tmpl() {}
 142                  };],
 143                 [const scoped_restore_base &b = scoped_restore_tmpl();],
 144                 WARN_CFLAGS="${WARN_CFLAGS} $w",)
 145             else
 146               AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 147             fi
 148             CFLAGS="$saved_CFLAGS"
 149             CXXFLAGS="$saved_CXXFLAGS"
 150         esac
 151     done
 152     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 153 fi
 154 AC_SUBST(WARN_CFLAGS)
 155 AC_SUBST(WERROR_CFLAGS)
 156
 157 AC_LANG_POP([C++])
 158 ])