gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-narrowing -Wno-error=maybe-uninitialized \
  44 -Wno-mismatched-tags \
  45 -Wno-error=deprecated-register \
  46 -Wsuggest-override"
  47
  48 case "${host}" in
  49   *-*-mingw32*)
  50     # Enable -Wno-format by default when using gcc on mingw since many
  51     # GCC versions complain about %I64.
  52     build_warnings="$build_warnings -Wno-format" ;;
  53   *-*-solaris*)
  54     # Solaris 11.4 <python2.7/ceval.h> uses #pragma no_inline that GCC
  55     # doesn't understand.
  56     build_warnings="$build_warnings -Wno-unknown-pragmas"
  57     # Solaris 11 <unistd.h> marks vfork deprecated.
  58     build_warnings="$build_warnings -Wno-deprecated-declarations" ;;
  59   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
  60 esac
  61
  62 AC_ARG_ENABLE(build-warnings,
  63 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  64 [case "${enableval}" in
  65   yes)  ;;
  66   no)   build_warnings="-w";;
  67   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  68         build_warnings="${build_warnings} ${t}";;
  69   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  70         build_warnings="${t} ${build_warnings}";;
  71   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  72 esac
  73 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  74   echo "Setting compiler warning flags = $build_warnings" 6>&1
  75 fi])dnl
  76 AC_ARG_ENABLE(gdb-build-warnings,
  77 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  78 [case "${enableval}" in
  79   yes)  ;;
  80   no)   build_warnings="-w";;
  81   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  82         build_warnings="${build_warnings} ${t}";;
  83   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  84         build_warnings="${t} ${build_warnings}";;
  85   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  86 esac
  87 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  88   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  89 fi])dnl
  90
  91 # The set of warnings supported by a C++ compiler is not the same as
  92 # of the C compiler.
  93 AC_LANG_PUSH([C++])
  94
  95 WARN_CFLAGS=""
  96 if test "x${build_warnings}" != x -a "x$GCC" = xyes
  97 then
  98     AC_MSG_CHECKING(compiler warning flags)
  99     # Separate out the -Werror flag as some files just cannot be
 100     # compiled with it enabled.
 101     for w in ${build_warnings}; do
 102         # GCC does not complain about -Wno-unknown-warning.  Invert
 103         # and test -Wunknown-warning instead.
 104         case $w in
 105         -Wno-*)
 106                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
 107         *)
 108                 wtest=$w ;;
 109         esac
 110
 111         case $w in
 112         -Werr*) WERROR_CFLAGS=-Werror ;;
 113         *)
 114             # Check whether GCC accepts it.
 115             saved_CFLAGS="$CFLAGS"
 116             CFLAGS="$CFLAGS -Werror $wtest"
 117             saved_CXXFLAGS="$CXXFLAGS"
 118             CXXFLAGS="$CXXFLAGS -Werror $wtest"
 119             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 120             CFLAGS="$saved_CFLAGS"
 121             CXXFLAGS="$saved_CXXFLAGS"
 122         esac
 123     done
 124     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 125 fi
 126 AC_SUBST(WARN_CFLAGS)
 127 AC_SUBST(WERROR_CFLAGS)
 128
 129 AC_LANG_POP([C++])
 130 ])