gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT
  22 AC_CONFIG_MACRO_DIRS([../config])
  23 AC_CONFIG_SRCDIR([server.cc])
  24 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_USE_SYSTEM_EXTENSIONS
  31 AC_SYS_LARGEFILE
  32 AM_PROG_INSTALL_STRIP
  33
  34 # Set build, build_cpu, build_vendor and build_os.
  35 AC_CANONICAL_BUILD
  36
  37 # Set host, host_cpu, host_vendor, and host_os.
  38 AC_CANONICAL_HOST
  39
  40 # Set target, target_cpu, target_vendor, and target_os.
  41 AC_CANONICAL_TARGET
  42
  43 AC_PROG_INSTALL
  44 AC_CHECK_TOOL(AR, ar)
  45 AC_PROG_RANLIB
  46
  47 AC_ARG_PROGRAM
  48
  49 # We require a C++11 compiler.  Check if one is available, and if
  50 # necessary, set CXX_DIALECT to some -std=xxx switch.
  51 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  52
  53 AC_HEADER_STDC
  54
  55 GDB_AC_COMMON
  56 # This is set by GDB_AC_COMMON.
  57 AC_SUBST(WIN32APILIBS)
  58
  59 GDB_AC_SELFTEST
  60
  61 ACX_NONCANONICAL_TARGET
  62 ACX_NONCANONICAL_HOST
  63
  64 # Dependency checking.
  65 ZW_CREATE_DEPDIR
  66
  67 dnl Set up for gettext.
  68 ZW_GNU_GETTEXT_SISTER_DIR
  69
  70 # Create sub-directories for objects and dependencies.
  71 CONFIG_SRC_SUBDIR="arch gdbsupport nat target"
  72 AC_SUBST(CONFIG_SRC_SUBDIR)
  73
  74 AC_CONFIG_COMMANDS([gdbdepdir],[
  75   for subdir in ${CONFIG_SRC_SUBDIR}
  76   do
  77       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  78   done],
  79   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  80
  81 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  82
  83 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  84                  sys/procfs.h linux/elf.h dnl
  85                  fcntl.h signal.h sys/file.h dnl
  86                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  87                  netinet/tcp.h arpa/inet.h ws2tcpip.h)
  88 AC_FUNC_FORK
  89 AC_CHECK_FUNCS(pread pwrite pread64)
  90
  91 # Check the return and argument types of ptrace.
  92 GDB_AC_PTRACE
  93
  94 # Check for UST
  95 ustlibs=""
  96 ustinc=""
  97
  98 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  99                           Equivalent to --with-ust-include=PATH/include
 100                           plus --with-ust-lib=PATH/lib])
 101 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 102 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 103
 104 case $with_ust in
 105   no)
 106     ustlibs=
 107     ustinc=
 108     ;;
 109   "" | yes)
 110     ustlibs=" -lust "
 111     ustinc=""
 112     ;;
 113   *)
 114     ustlibs="-L$with_ust/lib -lust"
 115     ustinc="-I$with_ust/include "
 116     ;;
 117 esac
 118 if test "x$with_ust_include" != x; then
 119   ustinc="-I$with_ust_include "
 120 fi
 121 if test "x$with_ust_lib" != x; then
 122   ustlibs="-L$with_ust_lib -lust"
 123 fi
 124
 125 if test "x$with_ust" != "xno"; then
 126   saved_CFLAGS="$CFLAGS"
 127   CFLAGS="$CFLAGS $ustinc"
 128   AC_MSG_CHECKING([for ust])
 129   AC_COMPILE_IFELSE(
 130     [AC_LANG_PROGRAM(
 131        [
 132 #define CONFIG_UST_GDB_INTEGRATION
 133 #include <ust/ust.h>
 134        ],
 135        []
 136      )],
 137     [AC_MSG_RESULT([yes]);
 138      AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 139     [AC_MSG_RESULT([no])
 140      ustlibs= ; ustinc= ]
 141   )
 142   CFLAGS="$saved_CFLAGS"
 143 fi
 144
 145 # Flags needed for UST
 146 AC_SUBST(ustlibs)
 147 AC_SUBST(ustinc)
 148
 149 AM_GDB_WARNINGS
 150
 151 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 152 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 153 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 154 dnl augment LIBS.
 155 old_LIBS="$LIBS"
 156 LIBS="$LIBS -ldl"
 157 AC_CHECK_FUNCS(dladdr)
 158 LIBS="$old_LIBS"
 159
 160 libiberty_INIT
 161
 162 AC_CHECK_DECLS([perror, vasprintf, vsnprintf])
 163
 164 AC_CHECK_TYPES(socklen_t, [], [],
 165 [#include <sys/types.h>
 166 #if HAVE_SYS_SOCKET_H
 167 # include <sys/socket.h>
 168 #elif HAVE_WS2TCPIP_H
 169 # include <ws2tcpip.h>
 170 #endif
 171 ])
 172
 173 case "${target}" in
 174   *-android*)
 175     # Starting with NDK version 9, <elf.h> actually includes definitions
 176     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 177     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 178     # leading to conflicts with the defintions from <linux/elf.h>.
 179     # This makes it impossible for us to include both <elf.h> and
 180     # <linux/elf.h>, which means that, in practice, we do not have
 181     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 182     # Therefore, do not try to auto-detect availability, as it would
 183     # get it wrong on this platform.
 184     ;;
 185   *)
 186     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 187     #include <elf.h>
 188     )
 189 esac
 190
 191 ACX_PKGVERSION([GDB])
 192 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 193 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 194 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 195
 196 # Check for various supplementary target information (beyond the
 197 # triplet) which might affect the choices in configure.srv.
 198 case "${target}" in
 199 changequote(,)dnl
 200   i[34567]86-*-linux*)
 201 changequote([,])dnl
 202     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 203                    [save_CPPFLAGS="$CPPFLAGS"
 204                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 205                     AC_EGREP_CPP([got it], [
 206 #if __x86_64__
 207 got it
 208 #endif
 209                  ], [gdb_cv_i386_is_x86_64=yes],
 210                     [gdb_cv_i386_is_x86_64=no])
 211                     CPPFLAGS="$save_CPPFLAGS"])
 212     ;;
 213
 214   x86_64-*-linux*)
 215     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 216                    [save_CPPFLAGS="$CPPFLAGS"
 217                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 218                     AC_EGREP_CPP([got it], [
 219 #if __x86_64__ && __ILP32__
 220 got it
 221 #endif
 222                  ], [gdb_cv_x86_is_x32=yes],
 223                     [gdb_cv_x86_is_x32=no])
 224                     CPPFLAGS="$save_CPPFLAGS"])
 225     ;;
 226
 227   m68k-*-*)
 228     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 229                    [save_CPPFLAGS="$CPPFLAGS"
 230                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 231                     AC_EGREP_CPP([got it], [
 232 #ifdef __mcoldfire__
 233 got it
 234 #endif
 235                  ], [gdb_cv_m68k_is_coldfire=yes],
 236                     [gdb_cv_m68k_is_coldfire=no])
 237                     CPPFLAGS="$save_CPPFLAGS"])
 238     ;;
 239 esac
 240
 241 . ${srcdir}/configure.srv
 242
 243 if test "${srv_mingwce}" = "yes"; then
 244   LIBS="$LIBS -lws2"
 245 elif test "${srv_mingw}" = "yes"; then
 246   # WIN32APILIBS is set by GDB_AC_COMMON.
 247   LIBS="$LIBS $WIN32APILIBS"
 248 fi
 249
 250 if test "${srv_linux_usrregs}" = "yes"; then
 251   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 252             [Define if the target supports PTRACE_PEEKUSR for register ]
 253             [access.])
 254 fi
 255
 256 if test "${srv_linux_regsets}" = "yes"; then
 257   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 258             [Define if the target supports register sets.])
 259
 260   AC_MSG_CHECKING(for PTRACE_GETREGS)
 261   AC_CACHE_VAL(
 262     [gdbsrv_cv_have_ptrace_getregs],
 263     [AC_COMPILE_IFELSE(
 264        [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
 265        [gdbsrv_cv_have_ptrace_getregs=yes],
 266        [gdbsrv_cv_have_ptrace_getregs=no]
 267      )]
 268   )
 269   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 270   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 271     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 272               [Define if the target supports PTRACE_GETREGS for register ]
 273               [access.])
 274   fi
 275
 276   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 277   AC_CACHE_VAL(
 278     [gdbsrv_cv_have_ptrace_getfpxregs],
 279     [AC_COMPILE_IFELSE(
 280        [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
 281        [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 282        [gdbsrv_cv_have_ptrace_getfpxregs=no]
 283      )]
 284   )
 285   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 286   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 287     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 288               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 289               [register access.])
 290   fi
 291 fi
 292
 293 if test "${srv_linux_btrace}" = "yes"; then
 294   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 295             [Define if the target supports branch tracing.])
 296 fi
 297
 298 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 299 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 300   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 301 fi
 302
 303 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 304 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 305   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 306 fi
 307
 308 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 309 dnl needs it (and gdbreplay doesn't).
 310 old_LIBS="$LIBS"
 311 AC_CHECK_LIB(dl, dlopen)
 312 LIBS="$old_LIBS"
 313
 314 srv_thread_depfiles=
 315 srv_libs=
 316
 317 if test "$srv_linux_thread_db" = "yes"; then
 318   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 319     srv_libs="-ldl"
 320     AC_MSG_CHECKING(for the dynamic export flag)
 321     old_LDFLAGS="$LDFLAGS"
 322     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 323     # supported there.
 324     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 325     LDFLAGS="$LDFLAGS $RDYNAMIC"
 326     AC_LINK_IFELSE(
 327       [AC_LANG_PROGRAM([],[])],
 328       [found="-Wl,--dynamic-list"
 329        RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 330       [RDYNAMIC="-rdynamic"
 331        LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 332        AC_LINK_IFELSE(
 333          [AC_LANG_PROGRAM([], [])],
 334          [found="-rdynamic"],
 335          [found="no"
 336           RDYNAMIC=""]
 337        )]
 338     )
 339     AC_SUBST(RDYNAMIC)
 340     LDFLAGS="$old_LDFLAGS"
 341     AC_MSG_RESULT($found)
 342   else
 343     srv_libs="-lthread_db"
 344   fi
 345
 346   srv_thread_depfiles="thread-db.o proc-service.o"
 347   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 348   AC_CACHE_CHECK(
 349     [for TD_VERSION],
 350     [gdbsrv_cv_have_td_version],
 351     [AC_COMPILE_IFELSE(
 352        [AC_LANG_PROGRAM([#include <thread_db.h>], [TD_VERSION;])],
 353        [gdbsrv_cv_have_td_version=yes],
 354        [gdbsrv_cv_have_td_version=no]
 355      )]
 356   )
 357   if test "$gdbsrv_cv_have_td_version" = yes; then
 358     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 359   fi
 360 fi
 361
 362 AC_ARG_WITH(libthread-db,
 363 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 364 [srv_libthread_db_path="${withval}"
 365   srv_libs="$srv_libthread_db_path"
 366 ])
 367
 368 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 369   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 370 fi
 371
 372 if test "$srv_xmlfiles" != ""; then
 373   srv_xmlbuiltin="xml-builtin.o"
 374   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 375
 376   tmp_xmlfiles=$srv_xmlfiles
 377   srv_xmlfiles=""
 378   for f in $tmp_xmlfiles; do
 379     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 380   done
 381 fi
 382
 383 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_thread_depfiles"
 384 GDBSERVER_LIBS="$srv_libs"
 385
 386 dnl Check whether the target supports __sync_*_compare_and_swap.
 387 AC_CACHE_CHECK(
 388   [whether the target supports __sync_*_compare_and_swap],
 389   [gdbsrv_cv_have_sync_builtins],
 390   [AC_LINK_IFELSE(
 391      [AC_LANG_PROGRAM(
 392         [],
 393         [int foo, bar;
 394          bar = __sync_val_compare_and_swap(&foo, 0, 1);]
 395       )],
 396      [gdbsrv_cv_have_sync_builtins=yes],
 397      [gdbsrv_cv_have_sync_builtins=no]
 398    )]
 399 )
 400 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
 401   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 402     [Define to 1 if the target supports __sync_*_compare_and_swap])
 403 fi
 404
 405 dnl Check for -fvisibility=hidden support in the compiler.
 406 saved_cflags="$CFLAGS"
 407 CFLAGS="$CFLAGS -fvisibility=hidden"
 408 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 409                         [gdbsrv_cv_have_visibility_hidden=yes],
 410                         [gdbsrv_cv_have_visibility_hidden=no])
 411 CFLAGS="$saved_cflags"
 412
 413 IPA_DEPFILES=""
 414 extra_libraries=""
 415
 416 # check whether to enable the inprocess agent
 417 if test "$ipa_obj" != "" \
 418    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 419    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 420    have_ipa=true
 421 else
 422    have_ipa=false
 423 fi
 424
 425 AC_ARG_ENABLE(inprocess-agent,
 426 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 427 [case "$enableval" in
 428   yes) want_ipa=true ;;
 429   no) want_ipa=false ;;
 430   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 431 esac],
 432 [want_ipa=$have_ipa])
 433
 434 if $want_ipa ; then
 435    if $have_ipa ; then
 436      IPA_DEPFILES="$ipa_obj"
 437      extra_libraries="$extra_libraries libinproctrace.so"
 438    else
 439      AC_MSG_ERROR([inprocess agent not supported for this target])
 440    fi
 441 fi
 442
 443 AC_SUBST(GDBSERVER_DEPFILES)
 444 AC_SUBST(GDBSERVER_LIBS)
 445 AC_SUBST(srv_xmlbuiltin)
 446 AC_SUBST(srv_xmlfiles)
 447 AC_SUBST(IPA_DEPFILES)
 448 AC_SUBST(extra_libraries)
 449
 450 GNULIB=../gnulib/import
 451
 452 GNULIB_STDINT_H=
 453 if test x"$STDINT_H" != x; then
 454   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 455 fi
 456 AC_SUBST(GNULIB_STDINT_H)
 457
 458 AC_CONFIG_FILES([Makefile])
 459
 460 AC_OUTPUT