gdbsupport/common.m4

   1 dnl Autoconf configure snippets for common.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Invoke configury needed by the files in 'common'.
  20 AC_DEFUN([GDB_AC_COMMON], [
  21   # Set the 'development' global.
  22   . $srcdir/../bfd/development.sh
  23
  24   AC_HEADER_STDC
  25   AC_FUNC_ALLOCA
  26
  27   WIN32APILIBS=
  28   case ${host} in
  29     *mingw32*)
  30       AC_DEFINE(USE_WIN32API, 1,
  31                 [Define if we should use the Windows API, instead of the
  32                  POSIX API.  On Windows, we use the Windows API when
  33                  building for MinGW, but the POSIX API when building
  34                  for Cygwin.])
  35       WIN32APILIBS="-lws2_32"
  36       ;;
  37   esac
  38
  39   dnl Note that this requires codeset.m4, which is included
  40   dnl by the users of common.m4.
  41   AM_LANGINFO_CODESET
  42
  43   AC_CHECK_HEADERS(linux/perf_event.h locale.h memory.h signal.h dnl
  44                    sys/resource.h sys/socket.h dnl
  45                    sys/un.h sys/wait.h dnl
  46                    thread_db.h wait.h dnl
  47                    termios.h dnl
  48                    dlfcn.h dnl
  49                    linux/elf.h sys/procfs.h proc_service.h)
  50
  51   AC_FUNC_MMAP
  52   AC_FUNC_VFORK
  53   AC_CHECK_FUNCS([fdwalk getrlimit pipe pipe2 socketpair sigaction \
  54                   ptrace64 sbrk setns sigaltstack sigprocmask \
  55                   setpgid setpgrp getrusage getauxval])
  56
  57   dnl Check if we can disable the virtual address space randomization.
  58   dnl The functionality of setarch -R.
  59   AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
  60   define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
  61   #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
  62   #       define ADDR_NO_RANDOMIZE 0x0040000
  63   #      endif
  64          /* Test the flag could be set and stays set.  */
  65          personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
  66          if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
  67              return 1])])
  68   AC_RUN_IFELSE([PERSONALITY_TEST],
  69                 [have_personality=true],
  70                 [have_personality=false],
  71                 [AC_LINK_IFELSE([PERSONALITY_TEST],
  72                                 [have_personality=true],
  73                                 [have_personality=false])])
  74   if $have_personality
  75   then
  76       AC_DEFINE([HAVE_PERSONALITY], 1,
  77                 [Define if you support the personality syscall.])
  78   fi
  79
  80   AC_CHECK_DECLS([strstr])
  81
  82   # ----------------------- #
  83   # Checks for structures.  #
  84   # ----------------------- #
  85
  86   AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
  87
  88   AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
  89     [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
  90               [Define to 1 if your system has the kinfo_getfile function. ])])
  91
  92   # Check for std::thread.  This does not work on some platforms, like
  93   # mingw and DJGPP.
  94   AC_LANG_PUSH([C++])
  95   AX_PTHREAD([threads=yes], [threads=no])
  96   if test "$threads" = "yes"; then
  97     save_LIBS="$LIBS"
  98     LIBS="$PTHREAD_LIBS $LIBS"
  99     save_CXXFLAGS="$CXXFLAGS"
 100     CXXFLAGS="$PTHREAD_CFLAGS $save_CXXFLAGS"
 101     AC_CACHE_CHECK([for std::thread],
 102                    gdb_cv_cxx_std_thread,
 103                    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 104     [[#include <thread>
 105       void callback() { }]],
 106     [[std::thread t(callback);]])],
 107                                   gdb_cv_cxx_std_thread=yes,
 108                                   gdb_cv_cxx_std_thread=no)])
 109
 110     # This check must be here, while LIBS includes any necessary
 111     # threading library.
 112     AC_CHECK_FUNCS([pthread_sigmask pthread_setname_np])
 113
 114     LIBS="$save_LIBS"
 115     CXXFLAGS="$save_CXXFLAGS"
 116   fi
 117   if test "$gdb_cv_cxx_std_thread" = "yes"; then
 118     AC_DEFINE(CXX_STD_THREAD, 1,
 119               [Define to 1 if std::thread works.])
 120   fi
 121   AC_LANG_POP
 122
 123   dnl Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't
 124   dnl do since sigsetjmp might only be defined as a macro.
 125   AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 126   [AC_TRY_COMPILE([
 127   #include <setjmp.h>
 128   ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 129   gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 130   if test "$gdb_cv_func_sigsetjmp" = "yes"; then
 131     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 132   fi
 133
 134   AC_ARG_WITH(intel_pt,
 135     AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
 136     [], [with_intel_pt=auto])
 137   AC_MSG_CHECKING([whether to use intel pt])
 138   AC_MSG_RESULT([$with_intel_pt])
 139
 140   if test "${with_intel_pt}" = no; then
 141     AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
 142     HAVE_LIBIPT=no
 143   else
 144     AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 145   #include <linux/perf_event.h>
 146   #ifndef PERF_ATTR_SIZE_VER5
 147   # error
 148   #endif
 149     ]])], [perf_event=yes], [perf_event=no])
 150     if test "$perf_event" != yes; then
 151       if test "$with_intel_pt" = yes; then
 152         AC_MSG_ERROR([linux/perf_event.h missing or too old])
 153       else
 154         AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
 155       fi
 156     fi
 157
 158     AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
 159     if test "$HAVE_LIBIPT" != yes; then
 160       if test "$with_intel_pt" = yes; then
 161         AC_MSG_ERROR([libipt is missing or unusable])
 162       else
 163         AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
 164       fi
 165     else
 166       save_LIBS=$LIBS
 167       LIBS="$LIBS $LIBIPT"
 168       AC_CHECK_FUNCS(pt_insn_event)
 169       AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
 170                        [#include <intel-pt.h>])
 171       LIBS=$save_LIBS
 172     fi
 173   fi
 174
 175   if test "$ac_cv_header_sys_procfs_h" = yes; then
 176     BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 177     BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 178     BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 179     BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 180     BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 181     BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 182     BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 183     BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 184   fi
 185 ])