gnulib/import/m4/locale-zh.m4

   1 # locale-zh.m4 serial 15
   2 dnl Copyright (C) 2003, 2005-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a chinese locale with GB18030 encoding.
  10 AC_DEFUN([gt_LOCALE_ZH_CN],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a transitional chinese locale], [gt_cv_locale_zh_CN], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([[
  16 #include <locale.h>
  17 #include <stdlib.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 struct tm t;
  25 char buf[16];
  26 int main ()
  27 {
  28   /* On BeOS and Haiku, locales are not implemented in libc.  Rather, libintl
  29      imitates locale dependent behaviour by looking at the environment
  30      variables, and all locales use the UTF-8 encoding.  */
  31 #if defined __BEOS__ || defined __HAIKU__
  32   return 1;
  33 #else
  34   /* Check whether the given locale name is recognized by the system.  */
  35 # if defined _WIN32 && !defined __CYGWIN__
  36   /* On native Windows, setlocale(category, "") looks at the system settings,
  37      not at the environment variables.  Also, when an encoding suffix such
  38      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  39      category of the locale to "C".  */
  40   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  41       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  42     return 1;
  43 # else
  44   if (setlocale (LC_ALL, "") == NULL) return 1;
  45 # endif
  46   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  47      On Mac OS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  48      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  49      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  50      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  51      some unit tests fail.
  52      On MirBSD 10, when an unsupported locale is specified, setlocale()
  53      succeeds but then nl_langinfo(CODESET) is "UTF-8".  */
  54 # if HAVE_LANGINFO_CODESET
  55   {
  56     const char *cs = nl_langinfo (CODESET);
  57     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  58         || strcmp (cs, "UTF-8") == 0)
  59       return 1;
  60   }
  61 # endif
  62 # ifdef __CYGWIN__
  63   /* On Cygwin, avoid locale names without encoding suffix, because the
  64      locale_charset() function relies on the encoding suffix.  Note that
  65      LC_ALL is set on the command line.  */
  66   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  67 # endif
  68   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  69      This excludes the UTF-8 encoding (except on MirBSD).  */
  70   {
  71     const char *p;
  72     t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  73     if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  74     for (p = buf; *p != '\0'; p++)
  75       if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  76         return 1;
  77   }
  78   /* Check whether a typical GB18030 multibyte sequence is recognized as a
  79      single wide character.  This excludes the GB2312 and GBK encodings.  */
  80   if (mblen ("\203\062\332\066", 5) != 4)
  81     return 1;
  82   return 0;
  83 #endif
  84 }
  85       ]])])
  86     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  87       case "$host_os" in
  88         # Handle native Windows specially, because there setlocale() interprets
  89         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  90         # "fr" or "fra" as "French" or "French_France.1252",
  91         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  92         # "ja" as "Japanese" or "Japanese_Japan.932",
  93         # and similar.
  94         mingw*)
  95           # Test for the hypothetical native Windows locale name.
  96           if (LC_ALL=Chinese_China.54936 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  97             gt_cv_locale_zh_CN=Chinese_China.54936
  98           else
  99             # None found.
 100             gt_cv_locale_zh_CN=none
 101           fi
 102           ;;
 103         solaris2.8)
 104           # On Solaris 8, the locales zh_CN.GB18030, zh_CN.GBK, zh.GBK are
 105           # broken. One witness is the test case in gl_MBRTOWC_SANITYCHECK.
 106           # Another witness is that "LC_ALL=zh_CN.GB18030 bash -c true" dumps core.
 107           gt_cv_locale_zh_CN=none
 108           ;;
 109         *)
 110           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
 111           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
 112           # configure script would override the LC_ALL setting. Likewise for
 113           # LC_CTYPE, which is also set at the beginning of the configure script.
 114           # Test for the locale name without encoding suffix.
 115           if (LC_ALL=zh_CN LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 116             gt_cv_locale_zh_CN=zh_CN
 117           else
 118             # Test for the locale name with explicit encoding suffix.
 119             if (LC_ALL=zh_CN.GB18030 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 120               gt_cv_locale_zh_CN=zh_CN.GB18030
 121             else
 122               # None found.
 123               gt_cv_locale_zh_CN=none
 124             fi
 125           fi
 126           ;;
 127       esac
 128     else
 129       # If there was a link error, due to mblen(), the system is so old that
 130       # it certainly doesn't have a chinese locale.
 131       gt_cv_locale_zh_CN=none
 132     fi
 133     rm -fr conftest*
 134   ])
 135   LOCALE_ZH_CN=$gt_cv_locale_zh_CN
 136   AC_SUBST([LOCALE_ZH_CN])
 137 ])