gold/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT(gold, 0.1)
   6 AC_CONFIG_SRCDIR(gold.cc)
   7
   8 AC_CANONICAL_TARGET
   9
  10 AM_INIT_AUTOMAKE
  11
  12 AM_CONFIG_HEADER(config.h:config.in)
  13
  14 AC_ARG_WITH(sysroot,
  15 [  --with-sysroot[=DIR]    search for usr/lib et al within DIR],
  16 [sysroot=$withval], [sysroot=no])
  17
  18 if test "$sysroot" = "yes"; then
  19   sysroot='${exec_prefix}/${target_alias}/sys-root'
  20 elif test "$sysroot" = "no"; then
  21   sysroot=
  22 fi
  23
  24 sysroot_relocatable=0
  25 if test -n "$sysroot"; then
  26   case "sysroot" in
  27     "${prefix}" | "${prefix}/"* | \
  28     "${exec_prefix}" | "${exec_prefix}/"* | \
  29     '${prefix}' | '${prefix}/'*| \
  30     '${exec_prefix}' | '${exec_prefix}/'*)
  31       sysroot_relocatable=1
  32       ;;
  33   esac
  34 fi
  35
  36 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT, "$sysroot",
  37   [System root for target files])
  38 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT_RELOCATABLE, $sysroot_relocatable,
  39   [Whether the system root can be relocated])
  40
  41 dnl For now threads are a configure time option.
  42 AC_ARG_ENABLE([threads],
  43 [  --enable-threads        multi-threaded linking],
  44 [case "${enableval}" in
  45   yes | "") threads=yes ;;
  46   no) threads=no ;;
  47   *) threads=yes ;;
  48  esac],
  49 [threads=no])
  50 if test "$threads" = "yes"; then
  51   AC_DEFINE(ENABLE_THREADS, 1,
  52             [Define to do multi-threaded linking])
  53 fi
  54 AM_CONDITIONAL(THREADS, test "$threads" = "yes")
  55
  56 AC_ARG_ENABLE([targets],
  57 [  --enable-targets        alternative target configurations],
  58 [case "${enableval}" in
  59   yes | "")
  60     AC_MSG_ERROR([--enable-targets option must specify target names or 'all'])
  61     ;;
  62   no)
  63     enable_targets=
  64     ;;
  65   *)
  66     enable_targets=$enableval
  67     ;;
  68 esac],
  69 [# For now, enable all targets by default
  70  enable_targets=all
  71 ])
  72
  73 # Canonicalize the enabled targets.
  74 if test -n "$enable_targets"; then
  75   for targ in `echo $enable_targets | sed -e 's/,/ /g'`; do
  76     result=`$ac_config_sub $targ 2>/dev/null`
  77     if test -n "$result"; then
  78       canon_targets="$canon_targets $result"
  79     else
  80       # Permit unrecognized target names, like "all".
  81       canon_targets="$canon_targets $targ"
  82     fi
  83   done
  84 fi
  85
  86 # See which specific instantiations we need.
  87 targetobjs=
  88 all_targets=
  89 default_machine=
  90 default_size=
  91 default_big_endian=
  92 targ_32_little=
  93 targ_32_big=
  94 targ_64_little=
  95 targ_64_big=
  96 for targ in $target $canon_targets; do
  97   if test "$targ" = "all"; then
  98     targ_32_little=yes
  99     targ_32_big=yes
 100     targ_64_little=yes
 101     targ_64_big=yes
 102     all_targets=yes
 103   else
 104     . ${srcdir}/configure.tgt
 105
 106     if test "$targ_obj" = "UNKNOWN"; then
 107       AC_MSG_ERROR("unsupported target $targ")
 108     else
 109       targetobjs="$targetobjs ${targ_obj}.\$(OBJEXT)"
 110       if test "$targ_size" = "32" -o "$targ_extra_size" = "32"; then
 111           if test "$targ_big_endian" = "true" \
 112               -o "$targ_extra_big_endian" = "true"; then
 113               targ_32_big=yes
 114           fi
 115           if test "$targ_big_endian" = "false" \
 116               -o "$targ_extra_big_endian" = "false"; then
 117               targ_32_little=yes
 118           fi
 119       fi
 120       if test "$targ_size" = "64" -o "$targ_extra_size" = "64"; then
 121           if test "$targ_big_endian" = "true" \
 122               -o "$targ_extra_big_endian" = "true"; then
 123               targ_64_big=yes
 124           fi
 125           if test "$targ_big_endian" = "false" \
 126               -o "$targ_extra_big_endian" = "false"; then
 127               targ_64_little=yes
 128           fi
 129       fi
 130
 131       if test "$target" = "$targ"; then
 132         default_machine=$targ_machine
 133         default_size=$targ_size
 134         default_big_endian=$targ_big_endian
 135       fi
 136     fi
 137   fi
 138 done
 139
 140 if test -n "$targ_32_little"; then
 141   AC_DEFINE(HAVE_TARGET_32_LITTLE, 1,
 142               [Define to support 32-bit little-endian targets])
 143 fi
 144 if test -n "$targ_32_big"; then
 145   AC_DEFINE(HAVE_TARGET_32_BIG, 1,
 146               [Define to support 32-bit big-endian targets])
 147 fi
 148 if test -n "$targ_64_little"; then
 149   AC_DEFINE(HAVE_TARGET_64_LITTLE, 1,
 150               [Define to support 64-bit little-endian targets])
 151 fi
 152 if test -n "$targ_64_big"; then
 153   AC_DEFINE(HAVE_TARGET_64_BIG, 1,
 154               [Define to support 64-bit big-endian targets])
 155 fi
 156
 157 if test -n "$all_targets"; then
 158   TARGETOBJS='$(ALL_TARGETOBJS)'
 159 else
 160   TARGETOBJS="$targetobjs"
 161 fi
 162 AC_SUBST(TARGETOBJS)
 163
 164 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_MACHINE, $default_machine,
 165                    [Default machine code])
 166 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_SIZE, $default_size,
 167                    [Default size (32 or 64)])
 168 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_BIG_ENDIAN, $default_big_endian,
 169                    [Default big endian (true or false)])
 170
 171 AC_PROG_CC
 172 AC_PROG_CXX
 173 AC_PROG_YACC
 174 AC_PROG_RANLIB
 175 AC_PROG_INSTALL
 176 AC_PROG_LN_S
 177
 178 AC_GNU_SOURCE
 179
 180 ZW_GNU_GETTEXT_SISTER_DIR
 181 AM_PO_SUBDIRS
 182
 183 AC_C_BIGENDIAN
 184
 185 AC_EXEEXT
 186
 187 AM_CONDITIONAL(NATIVE_LINKER,
 188   test "x$target_alias" = "x" -o "x$host_alias" = "x$target_alias")
 189 AM_CONDITIONAL(GCC, test "$GCC" = yes)
 190
 191 dnl Some architectures do not support taking pointers of functions
 192 dnl defined in shared libraries except in -fPIC mode.  We need to
 193 dnl tell the unittest framework if we're compiling for one of those
 194 dnl targets, so it doesn't try to run the tests that do that.
 195 AM_CONDITIONAL(FN_PTRS_IN_SO_WITHOUT_PIC, [
 196   case $target_cpu in
 197     i?86) true;;
 198     x86_64) false;;
 199     sparc64) false;;
 200     *) true;;
 201   esac])
 202
 203 dnl Test for __thread support.
 204 AC_CACHE_CHECK([for thread support], [gold_cv_c_thread],
 205 [AC_COMPILE_IFELSE([__thread int i = 1;],
 206 [gold_cv_c_thread=yes], [gold_cv_c_thread=no])])
 207
 208 AM_CONDITIONAL(TLS, test "$gold_cv_c_thread" = "yes")
 209
 210 dnl On GNU/Linux TLS in static programs only works when using glibc
 211 dnl 2.4 or later.
 212 AC_CACHE_CHECK([for glibc >= 2.4], [gold_cv_lib_glibc24],
 213 [AC_COMPILE_IFELSE([
 214 #include <features.h>
 215 #if !defined __GLIBC__
 216 error
 217 #elif __GLIBC__ < 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ < 4)
 218 error
 219 #endif
 220 ], [gold_cv_lib_glibc24=yes], [gold_cv_lib_glibc24=no])])
 221
 222 AM_CONDITIONAL(STATIC_TLS, test "$gold_cv_lib_glibc24" = "yes")
 223
 224 dnl Test for #pragma omp threadprivate
 225 AC_CACHE_CHECK([for omp support], [gold_cv_c_threadprivate],
 226 [save_CFLAGS="$CFLAGS"
 227 CFLAGS="$CFLAGS -fopenmp"
 228 AC_COMPILE_IFELSE([
 229 #include <omp.h>
 230 int i;
 231 #pragma omp threadprivate (i)
 232 ], [gold_cv_c_threadprivate=yes], [gold_cv_c_threadprivate=no])
 233 CFLAGS="$save_CFLAGS"])
 234 if test "$gold_cv_c_threadprivate" = "yes"; then
 235   AC_DEFINE(HAVE_OMP_SUPPORT, 1,
 236             [Define if compiler supports #pragma omp threadprivate])
 237 fi
 238 AM_CONDITIONAL(OMP_SUPPORT, test "$gold_cv_c_threadprivate" = "yes")
 239
 240 dnl Test for the -ftls-dialect=gnu2 option.
 241 save_CFLAGS="$CFLAGS"
 242 CFLAGS="$CFLAGS -mtls-dialect=gnu2"
 243 AC_COMPILE_IFELSE([int i;], [have_tls_gnu2=yes], [have_tls_gnu2=no])
 244 CFLAGS="$save_CFLAGS"
 245 AM_CONDITIONAL(TLS_GNU2_DIALECT, test "$have_tls_gnu2" = "yes")
 246
 247 dnl On GNU/Linux TLS descriptors are supported by the dynamic loader
 248 dnl only with glibc 2.5 or later.
 249 AC_CACHE_CHECK([for glibc >= 2.5], [gold_cv_lib_glibc25],
 250 [AC_COMPILE_IFELSE([
 251 #include <features.h>
 252 #if !defined __GLIBC__
 253 error
 254 #elif __GLIBC__ < 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ < 5)
 255 error
 256 #endif
 257 ], [gold_cv_lib_glibc25=yes], [gold_cv_lib_glibc25=no])])
 258
 259 AM_CONDITIONAL(TLS_DESCRIPTORS, test "$gold_cv_lib_glibc25" = "yes")
 260
 261 dnl Check whether the compiler supports constructor priorities in
 262 dnl attributes, which were added in gcc 4.3.
 263 AC_CACHE_CHECK([for constructor priorities], [gold_cv_c_conprio],
 264 [AC_COMPILE_IFELSE([void f() __attribute__ ((constructor (1)));],
 265 [gold_cv_c_conprio=yes], [gold_cv_c_conprio=no])])
 266
 267 AM_CONDITIONAL(CONSTRUCTOR_PRIORITY, test "$gold_cv_c_conprio" = "yes")
 268
 269 AM_BINUTILS_WARNINGS
 270
 271 WARN_CXXFLAGS=`echo ${WARN_CFLAGS} | sed -e 's/-Wstrict-prototypes//' -e 's/-Wmissing-prototypes//'`
 272 AC_SUBST(WARN_CXXFLAGS)
 273
 274 dnl Force support for large files by default.  This may need to be
 275 dnl host dependent.  If build == host, we can check getconf LFS_CFLAGS.
 276 LFS_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 277 AC_SUBST(LFS_CFLAGS)
 278
 279 AC_REPLACE_FUNCS(pread)
 280
 281 # Link in zlib if we can.  This allows us to write compressed sections.
 282 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 283 AM_CONDITIONAL(HAVE_ZLIB, test "$ac_cv_search_zlibVersion" != "no")
 284
 285 AC_LANG_PUSH(C++)
 286
 287 AC_CHECK_HEADERS(tr1/unordered_set tr1/unordered_map)
 288 AC_CHECK_HEADERS(ext/hash_map ext/hash_set)
 289 AC_CHECK_FUNCS(mallinfo)
 290
 291 # gcc 4.3.0 doesn't recognize the printf attribute on a template
 292 # function.  Check for that.  This is gcc bug 35546.  This test can
 293 # probably be removed after the bug has been fixed for a while.
 294 AC_CACHE_CHECK([whether we can use attributes with template functions],
 295 [gold_cv_template_attribute],
 296 [AC_COMPILE_IFELSE([
 297 template<typename T> extern void foo(const char*, ...)
 298   __attribute__ ((__format__ (__printf__, 1, 2)));
 299 template<typename T> void foo(const char* format, ...) {}
 300 void bar() { foo<int>("%s\n", "foo"); }
 301 ], [gold_cv_template_attribute=yes], [gold_cv_template_attribute=no])])
 302 if test "$gold_cv_template_attribute" = "yes"; then
 303   AC_DEFINE(HAVE_TEMPLATE_ATTRIBUTES, 1,
 304             [Define if attributes work on C++ templates])
 305 fi
 306
 307 AC_LANG_POP(C++)
 308
 309 AM_MAINTAINER_MODE
 310
 311 AC_OUTPUT(Makefile testsuite/Makefile po/Makefile.in:po/Make-in)