gprof/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.59)
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([gprof.c])
   5
   6 AC_CANONICAL_TARGET([])
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(gprof, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 # The location to which bugs should be reported.
  17 AC_ARG_WITH(bugurl,
  18   AS_HELP_STRING([--with-bugurl=URL],
  19                  [Direct users to URL to report a bug]),
  20   [case "$withval" in
  21     yes) AC_MSG_ERROR([bug URL not specified]) ;;
  22     no)  REPORT_BUGS_TO="" ;;
  23     *)   REPORT_BUGS_TO="<URL:$withval>" ;;
  24    esac],
  25    REPORT_BUGS_TO="<URL:http://www.sourceware.org/bugzilla/>"
  26 )
  27 AC_SUBST(REPORT_BUGS_TO)
  28
  29 dnl For simplicity, we use the BFD configuration file for most
  30 dnl things.  However, we also need our own configuration file for
  31 dnl the automake PACKAGE and VERSION macros.  We don't name it
  32 dnl config.h, to avoid any possible confusion with the bfd config.h.
  33 AC_CONFIG_HEADERS([gconfig.h:gconfig.in])
  34
  35 AC_PROG_CC
  36 AC_PROG_INSTALL
  37
  38 AC_CHECK_FUNCS(setmode)
  39
  40 ALL_LINGUAS="fr tr sv es id da pt_BR de vi rw ga ms"
  41 ZW_GNU_GETTEXT_SISTER_DIR
  42 AM_PO_SUBDIRS
  43
  44 AM_MAINTAINER_MODE
  45 AM_CONDITIONAL(GENINSRC_NEVER, false)
  46 AC_EXEEXT
  47
  48 AC_CHECK_HEADERS(sys/gmon_out.h)
  49
  50 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
  51 AC_CACHE_VAL(gprof_cv_decl_getopt_unistd_h,
  52 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
  53 gprof_cv_decl_getopt_unistd_h=yes, gprof_cv_decl_getopt_unistd_h=no)])
  54 AC_MSG_RESULT($gprof_cv_decl_getopt_unistd_h)
  55 if test $gprof_cv_decl_getopt_unistd_h = yes; then
  56   AC_DEFINE([HAVE_DECL_GETOPT], 1,
  57             [Is the prototype for getopt in <unistd.h> in the expected format?])
  58 fi
  59
  60 AM_BINUTILS_WARNINGS
  61
  62 dnl Required by html and install-html
  63 AC_SUBST(datarootdir)
  64 AC_SUBST(docdir)
  65 AC_SUBST(htmldir)
  66
  67 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
  68 AC_OUTPUT