gprof/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.59)
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([gprof.c])
   5
   6 AC_CANONICAL_TARGET([])
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(gprof, ${BFD_VERSION})
  13
  14 dnl For simplicity, we use the BFD configuration file for most
  15 dnl things.  However, we also need our own configuration file for
  16 dnl the automake PACKAGE and VERSION macros.  We don't name it
  17 dnl config.h, to avoid any possible confusion with the bfd config.h.
  18 AC_CONFIG_HEADERS([gconfig.h:gconfig.in])
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_PROG_INSTALL
  24
  25 LT_INIT
  26
  27 AC_CHECK_FUNCS(setmode)
  28
  29 ALL_LINGUAS="fr tr sv es id da pt_BR de vi rw ga ms fi nl"
  30 ZW_GNU_GETTEXT_SISTER_DIR
  31 AM_PO_SUBDIRS
  32
  33 AM_MAINTAINER_MODE
  34 AM_CONDITIONAL(GENINSRC_NEVER, false)
  35 AC_EXEEXT
  36
  37 AC_CHECK_HEADERS(sys/gmon_out.h)
  38
  39 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
  40 AC_CACHE_VAL(gprof_cv_decl_getopt_unistd_h,
  41 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
  42 gprof_cv_decl_getopt_unistd_h=yes, gprof_cv_decl_getopt_unistd_h=no)])
  43 AC_MSG_RESULT($gprof_cv_decl_getopt_unistd_h)
  44 if test $gprof_cv_decl_getopt_unistd_h = yes; then
  45   AC_DEFINE([HAVE_DECL_GETOPT], 1,
  46             [Is the prototype for getopt in <unistd.h> in the expected format?])
  47 fi
  48
  49 # Some systems have fabs only in -lm, not in -lc.
  50 AC_SEARCH_LIBS(fabs, m)
  51
  52 AM_BINUTILS_WARNINGS
  53
  54 dnl Required by html and install-html
  55 AC_SUBST(datarootdir)
  56 AC_SUBST(docdir)
  57 AC_SUBST(htmldir)
  58
  59 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
  60 AC_OUTPUT