projects / deliverable / linux.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
Restartable sequences: tests: introduce simple rseq start/finish
[deliverable/linux.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
61
62 /*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69 /* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec) *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
80
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec) *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
88
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
97
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
105
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
113
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 *(_kprobe_blacklist) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
122
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 *(_ftrace_events) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
128 VMLINUX_SYMBOL(__start_ftrace_enum_maps) = .; \
129 *(_ftrace_enum_map) \
130 VMLINUX_SYMBOL(__stop_ftrace_enum_maps) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
134
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
137 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
138 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
140 *(__tracepoint_str) /* Trace_printk fmt' pointer */ \
141 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142 #else
143 #define TRACE_PRINTKS()
144 #define TRACEPOINT_STR()
145 #endif
146
147 #ifdef CONFIG_FTRACE_SYSCALLS
148 #define TRACE_SYSCALLS() . = ALIGN(8); \
149 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150 *(__syscalls_metadata) \
151 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152 #else
153 #define TRACE_SYSCALLS()
154 #endif
155
156 #ifdef CONFIG_SERIAL_EARLYCON
157 #define EARLYCON_TABLE() STRUCT_ALIGN(); \
158 VMLINUX_SYMBOL(__earlycon_table) = .; \
159 *(__earlycon_table) \
160 VMLINUX_SYMBOL(__earlycon_table_end) = .;
161 #else
162 #define EARLYCON_TABLE()
163 #endif
164
165 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
166 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
167 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
168 #define _OF_TABLE_0(name)
169 #define _OF_TABLE_1(name) \
170 . = ALIGN(8); \
171 VMLINUX_SYMBOL(__##name##_of_table) = .; \
172 *(__##name##_of_table) \
173 *(__##name##_of_table_end)
174
175 #define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
176 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
177 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
178 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
179 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
180 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
181 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
182
183 #ifdef CONFIG_ACPI
184 #define ACPI_PROBE_TABLE(name) \
185 . = ALIGN(8); \
186 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
187 *(__##name##_acpi_probe_table) \
188 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
189 #else
190 #define ACPI_PROBE_TABLE(name)
191 #endif
192
193 #define KERNEL_DTB() \
194 STRUCT_ALIGN(); \
195 VMLINUX_SYMBOL(__dtb_start) = .; \
196 *(.dtb.init.rodata) \
197 VMLINUX_SYMBOL(__dtb_end) = .;
198
199 /* .data section */
200 #define DATA_DATA \
201 *(.data) \
202 *(.ref.data) \
203 *(.data..shared_aligned) /* percpu related */ \
204 MEM_KEEP(init.data) \
205 MEM_KEEP(exit.data) \
206 *(.data.unlikely) \
207 STRUCT_ALIGN(); \
208 *(__tracepoints) \
209 /* implement dynamic printk debug */ \
210 . = ALIGN(8); \
211 VMLINUX_SYMBOL(__start___jump_table) = .; \
212 *(__jump_table) \
213 VMLINUX_SYMBOL(__stop___jump_table) = .; \
214 . = ALIGN(8); \
215 VMLINUX_SYMBOL(__start___verbose) = .; \
216 *(__verbose) \
217 VMLINUX_SYMBOL(__stop___verbose) = .; \
218 LIKELY_PROFILE() \
219 BRANCH_PROFILE() \
220 TRACE_PRINTKS() \
221 TRACEPOINT_STR()
222
223 /*
224 * Data section helpers
225 */
226 #define NOSAVE_DATA \
227 . = ALIGN(PAGE_SIZE); \
228 VMLINUX_SYMBOL(__nosave_begin) = .; \
229 *(.data..nosave) \
230 . = ALIGN(PAGE_SIZE); \
231 VMLINUX_SYMBOL(__nosave_end) = .;
232
233 #define PAGE_ALIGNED_DATA(page_align) \
234 . = ALIGN(page_align); \
235 *(.data..page_aligned)
236
237 #define READ_MOSTLY_DATA(align) \
238 . = ALIGN(align); \
239 *(.data..read_mostly) \
240 . = ALIGN(align);
241
242 #define CACHELINE_ALIGNED_DATA(align) \
243 . = ALIGN(align); \
244 *(.data..cacheline_aligned)
245
246 #define INIT_TASK_DATA(align) \
247 . = ALIGN(align); \
248 VMLINUX_SYMBOL(__start_init_task) = .; \
249 *(.data..init_task) \
250 VMLINUX_SYMBOL(__end_init_task) = .;
251
252 /*
253 * Allow architectures to handle ro_after_init data on their
254 * own by defining an empty RO_AFTER_INIT_DATA.
255 */
256 #ifndef RO_AFTER_INIT_DATA
257 #define RO_AFTER_INIT_DATA *(.data..ro_after_init)
258 #endif
259
260 /*
261 * Read only Data
262 */
263 #define RO_DATA_SECTION(align) \
264 . = ALIGN((align)); \
265 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
266 VMLINUX_SYMBOL(__start_rodata) = .; \
267 *(.rodata) *(.rodata.*) \
268 RO_AFTER_INIT_DATA /* Read only after init */ \
269 *(__vermagic) /* Kernel version magic */ \
270 . = ALIGN(8); \
271 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
272 *(__tracepoints_ptrs) /* Tracepoints: pointer array */\
273 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
274 *(__tracepoints_strings)/* Tracepoints: strings */ \
275 } \
276 \
277 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
278 *(.rodata1) \
279 } \
280 \
281 BUG_TABLE \
282 \
283 /* PCI quirks */ \
284 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
285 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
286 *(.pci_fixup_early) \
287 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
288 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
289 *(.pci_fixup_header) \
290 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
291 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
292 *(.pci_fixup_final) \
293 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
294 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
295 *(.pci_fixup_enable) \
296 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
297 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
298 *(.pci_fixup_resume) \
299 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
300 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
301 *(.pci_fixup_resume_early) \
302 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
303 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
304 *(.pci_fixup_suspend) \
305 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
306 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
307 *(.pci_fixup_suspend_late) \
308 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
309 } \
310 \
311 /* Built-in firmware blobs */ \
312 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
313 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
314 *(.builtin_fw) \
315 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
316 } \
317 \
318 TRACEDATA \
319 \
320 /* Kernel symbol table: Normal symbols */ \
321 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
322 VMLINUX_SYMBOL(__start___ksymtab) = .; \
323 *(SORT(___ksymtab+*)) \
324 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
325 } \
326 \
327 /* Kernel symbol table: GPL-only symbols */ \
328 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
329 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
330 *(SORT(___ksymtab_gpl+*)) \
331 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
332 } \
333 \
334 /* Kernel symbol table: Normal unused symbols */ \
335 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
336 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
337 *(SORT(___ksymtab_unused+*)) \
338 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
339 } \
340 \
341 /* Kernel symbol table: GPL-only unused symbols */ \
342 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
343 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
344 *(SORT(___ksymtab_unused_gpl+*)) \
345 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
346 } \
347 \
348 /* Kernel symbol table: GPL-future-only symbols */ \
349 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
350 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
351 *(SORT(___ksymtab_gpl_future+*)) \
352 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
353 } \
354 \
355 /* Kernel symbol table: Normal symbols */ \
356 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
357 VMLINUX_SYMBOL(__start___kcrctab) = .; \
358 *(SORT(___kcrctab+*)) \
359 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
360 } \
361 \
362 /* Kernel symbol table: GPL-only symbols */ \
363 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
364 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
365 *(SORT(___kcrctab_gpl+*)) \
366 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
367 } \
368 \
369 /* Kernel symbol table: Normal unused symbols */ \
370 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
371 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
372 *(SORT(___kcrctab_unused+*)) \
373 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
374 } \
375 \
376 /* Kernel symbol table: GPL-only unused symbols */ \
377 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
378 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
379 *(SORT(___kcrctab_unused_gpl+*)) \
380 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
381 } \
382 \
383 /* Kernel symbol table: GPL-future-only symbols */ \
384 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
385 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
386 *(SORT(___kcrctab_gpl_future+*)) \
387 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
388 } \
389 \
390 /* Kernel symbol table: strings */ \
391 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
392 *(__ksymtab_strings) \
393 } \
394 \
395 /* __*init sections */ \
396 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
397 *(.ref.rodata) \
398 MEM_KEEP(init.rodata) \
399 MEM_KEEP(exit.rodata) \
400 } \
401 \
402 /* Built-in module parameters. */ \
403 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
404 VMLINUX_SYMBOL(__start___param) = .; \
405 *(__param) \
406 VMLINUX_SYMBOL(__stop___param) = .; \
407 } \
408 \
409 /* Built-in module versions. */ \
410 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
411 VMLINUX_SYMBOL(__start___modver) = .; \
412 *(__modver) \
413 VMLINUX_SYMBOL(__stop___modver) = .; \
414 . = ALIGN((align)); \
415 VMLINUX_SYMBOL(__end_rodata) = .; \
416 } \
417 . = ALIGN((align));
418
419 /* RODATA & RO_DATA provided for backward compatibility.
420 * All archs are supposed to use RO_DATA() */
421 #define RODATA RO_DATA_SECTION(4096)
422 #define RO_DATA(align) RO_DATA_SECTION(align)
423
424 #define SECURITY_INIT \
425 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
426 VMLINUX_SYMBOL(__security_initcall_start) = .; \
427 *(.security_initcall.init) \
428 VMLINUX_SYMBOL(__security_initcall_end) = .; \
429 }
430
431 /* .text section. Map to function alignment to avoid address changes
432 * during second ld run in second ld pass when generating System.map */
433 #define TEXT_TEXT \
434 ALIGN_FUNCTION(); \
435 *(.text.hot .text .text.fixup .text.unlikely) \
436 *(.ref.text) \
437 MEM_KEEP(init.text) \
438 MEM_KEEP(exit.text) \
439
440
441 /* sched.text is aling to function alignment to secure we have same
442 * address even at second ld pass when generating System.map */
443 #define SCHED_TEXT \
444 ALIGN_FUNCTION(); \
445 VMLINUX_SYMBOL(__sched_text_start) = .; \
446 *(.sched.text) \
447 VMLINUX_SYMBOL(__sched_text_end) = .;
448
449 /* spinlock.text is aling to function alignment to secure we have same
450 * address even at second ld pass when generating System.map */
451 #define LOCK_TEXT \
452 ALIGN_FUNCTION(); \
453 VMLINUX_SYMBOL(__lock_text_start) = .; \
454 *(.spinlock.text) \
455 VMLINUX_SYMBOL(__lock_text_end) = .;
456
457 #define KPROBES_TEXT \
458 ALIGN_FUNCTION(); \
459 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
460 *(.kprobes.text) \
461 VMLINUX_SYMBOL(__kprobes_text_end) = .;
462
463 #define ENTRY_TEXT \
464 ALIGN_FUNCTION(); \
465 VMLINUX_SYMBOL(__entry_text_start) = .; \
466 *(.entry.text) \
467 VMLINUX_SYMBOL(__entry_text_end) = .;
468
469 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
470 #define IRQENTRY_TEXT \
471 ALIGN_FUNCTION(); \
472 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
473 *(.irqentry.text) \
474 VMLINUX_SYMBOL(__irqentry_text_end) = .;
475 #else
476 #define IRQENTRY_TEXT
477 #endif
478
479 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
480 #define SOFTIRQENTRY_TEXT \
481 ALIGN_FUNCTION(); \
482 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
483 *(.softirqentry.text) \
484 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
485 #else
486 #define SOFTIRQENTRY_TEXT
487 #endif
488
489 /* Section used for early init (in .S files) */
490 #define HEAD_TEXT *(.head.text)
491
492 #define HEAD_TEXT_SECTION \
493 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
494 HEAD_TEXT \
495 }
496
497 /*
498 * Exception table
499 */
500 #define EXCEPTION_TABLE(align) \
501 . = ALIGN(align); \
502 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
503 VMLINUX_SYMBOL(__start___ex_table) = .; \
504 *(__ex_table) \
505 VMLINUX_SYMBOL(__stop___ex_table) = .; \
506 }
507
508 /*
509 * Init task
510 */
511 #define INIT_TASK_DATA_SECTION(align) \
512 . = ALIGN(align); \
513 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
514 INIT_TASK_DATA(align) \
515 }
516
517 #ifdef CONFIG_CONSTRUCTORS
518 #define KERNEL_CTORS() . = ALIGN(8); \
519 VMLINUX_SYMBOL(__ctors_start) = .; \
520 *(.ctors) \
521 *(SORT(.init_array.*)) \
522 *(.init_array) \
523 VMLINUX_SYMBOL(__ctors_end) = .;
524 #else
525 #define KERNEL_CTORS()
526 #endif
527
528 /* init and exit section handling */
529 #define INIT_DATA \
530 *(.init.data) \
531 MEM_DISCARD(init.data) \
532 KERNEL_CTORS() \
533 MCOUNT_REC() \
534 *(.init.rodata) \
535 FTRACE_EVENTS() \
536 TRACE_SYSCALLS() \
537 KPROBE_BLACKLIST() \
538 MEM_DISCARD(init.rodata) \
539 CLK_OF_TABLES() \
540 RESERVEDMEM_OF_TABLES() \
541 CLKSRC_OF_TABLES() \
542 IOMMU_OF_TABLES() \
543 CPU_METHOD_OF_TABLES() \
544 CPUIDLE_METHOD_OF_TABLES() \
545 KERNEL_DTB() \
546 IRQCHIP_OF_MATCH_TABLE() \
547 ACPI_PROBE_TABLE(irqchip) \
548 ACPI_PROBE_TABLE(clksrc) \
549 EARLYCON_TABLE()
550
551 #define INIT_TEXT \
552 *(.init.text) \
553 *(.text.startup) \
554 MEM_DISCARD(init.text)
555
556 #define EXIT_DATA \
557 *(.exit.data) \
558 *(.fini_array) \
559 *(.dtors) \
560 MEM_DISCARD(exit.data) \
561 MEM_DISCARD(exit.rodata)
562
563 #define EXIT_TEXT \
564 *(.exit.text) \
565 *(.text.exit) \
566 MEM_DISCARD(exit.text)
567
568 #define EXIT_CALL \
569 *(.exitcall.exit)
570
571 /*
572 * bss (Block Started by Symbol) - uninitialized data
573 * zeroed during startup
574 */
575 #define SBSS(sbss_align) \
576 . = ALIGN(sbss_align); \
577 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
578 *(.sbss) \
579 *(.scommon) \
580 }
581
582 /*
583 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
584 * sections to the front of bss.
585 */
586 #ifndef BSS_FIRST_SECTIONS
587 #define BSS_FIRST_SECTIONS
588 #endif
589
590 #define BSS(bss_align) \
591 . = ALIGN(bss_align); \
592 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
593 BSS_FIRST_SECTIONS \
594 *(.bss..page_aligned) \
595 *(.dynbss) \
596 *(.bss) \
597 *(COMMON) \
598 }
599
600 /*
601 * DWARF debug sections.
602 * Symbols in the DWARF debugging sections are relative to
603 * the beginning of the section so we begin them at 0.
604 */
605 #define DWARF_DEBUG \
606 /* DWARF 1 */ \
607 .debug 0 : { *(.debug) } \
608 .line 0 : { *(.line) } \
609 /* GNU DWARF 1 extensions */ \
610 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
611 .debug_sfnames 0 : { *(.debug_sfnames) } \
612 /* DWARF 1.1 and DWARF 2 */ \
613 .debug_aranges 0 : { *(.debug_aranges) } \
614 .debug_pubnames 0 : { *(.debug_pubnames) } \
615 /* DWARF 2 */ \
616 .debug_info 0 : { *(.debug_info \
617 .gnu.linkonce.wi.*) } \
618 .debug_abbrev 0 : { *(.debug_abbrev) } \
619 .debug_line 0 : { *(.debug_line) } \
620 .debug_frame 0 : { *(.debug_frame) } \
621 .debug_str 0 : { *(.debug_str) } \
622 .debug_loc 0 : { *(.debug_loc) } \
623 .debug_macinfo 0 : { *(.debug_macinfo) } \
624 /* SGI/MIPS DWARF 2 extensions */ \
625 .debug_weaknames 0 : { *(.debug_weaknames) } \
626 .debug_funcnames 0 : { *(.debug_funcnames) } \
627 .debug_typenames 0 : { *(.debug_typenames) } \
628 .debug_varnames 0 : { *(.debug_varnames) } \
629
630 /* Stabs debugging sections. */
631 #define STABS_DEBUG \
632 .stab 0 : { *(.stab) } \
633 .stabstr 0 : { *(.stabstr) } \
634 .stab.excl 0 : { *(.stab.excl) } \
635 .stab.exclstr 0 : { *(.stab.exclstr) } \
636 .stab.index 0 : { *(.stab.index) } \
637 .stab.indexstr 0 : { *(.stab.indexstr) } \
638 .comment 0 : { *(.comment) }
639
640 #ifdef CONFIG_GENERIC_BUG
641 #define BUG_TABLE \
642 . = ALIGN(8); \
643 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
644 VMLINUX_SYMBOL(__start___bug_table) = .; \
645 *(__bug_table) \
646 VMLINUX_SYMBOL(__stop___bug_table) = .; \
647 }
648 #else
649 #define BUG_TABLE
650 #endif
651
652 #ifdef CONFIG_PM_TRACE
653 #define TRACEDATA \
654 . = ALIGN(4); \
655 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
656 VMLINUX_SYMBOL(__tracedata_start) = .; \
657 *(.tracedata) \
658 VMLINUX_SYMBOL(__tracedata_end) = .; \
659 }
660 #else
661 #define TRACEDATA
662 #endif
663
664 #define NOTES \
665 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
666 VMLINUX_SYMBOL(__start_notes) = .; \
667 *(.note.*) \
668 VMLINUX_SYMBOL(__stop_notes) = .; \
669 }
670
671 #define INIT_SETUP(initsetup_align) \
672 . = ALIGN(initsetup_align); \
673 VMLINUX_SYMBOL(__setup_start) = .; \
674 *(.init.setup) \
675 VMLINUX_SYMBOL(__setup_end) = .;
676
677 #define INIT_CALLS_LEVEL(level) \
678 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
679 *(.initcall##level##.init) \
680 *(.initcall##level##s.init) \
681
682 #define INIT_CALLS \
683 VMLINUX_SYMBOL(__initcall_start) = .; \
684 *(.initcallearly.init) \
685 INIT_CALLS_LEVEL(0) \
686 INIT_CALLS_LEVEL(1) \
687 INIT_CALLS_LEVEL(2) \
688 INIT_CALLS_LEVEL(3) \
689 INIT_CALLS_LEVEL(4) \
690 INIT_CALLS_LEVEL(5) \
691 INIT_CALLS_LEVEL(rootfs) \
692 INIT_CALLS_LEVEL(6) \
693 INIT_CALLS_LEVEL(7) \
694 VMLINUX_SYMBOL(__initcall_end) = .;
695
696 #define CON_INITCALL \
697 VMLINUX_SYMBOL(__con_initcall_start) = .; \
698 *(.con_initcall.init) \
699 VMLINUX_SYMBOL(__con_initcall_end) = .;
700
701 #define SECURITY_INITCALL \
702 VMLINUX_SYMBOL(__security_initcall_start) = .; \
703 *(.security_initcall.init) \
704 VMLINUX_SYMBOL(__security_initcall_end) = .;
705
706 #ifdef CONFIG_BLK_DEV_INITRD
707 #define INIT_RAM_FS \
708 . = ALIGN(4); \
709 VMLINUX_SYMBOL(__initramfs_start) = .; \
710 *(.init.ramfs) \
711 . = ALIGN(8); \
712 *(.init.ramfs.info)
713 #else
714 #define INIT_RAM_FS
715 #endif
716
717 /*
718 * Default discarded sections.
719 *
720 * Some archs want to discard exit text/data at runtime rather than
721 * link time due to cross-section references such as alt instructions,
722 * bug table, eh_frame, etc. DISCARDS must be the last of output
723 * section definitions so that such archs put those in earlier section
724 * definitions.
725 */
726 #define DISCARDS \
727 /DISCARD/ : { \
728 EXIT_TEXT \
729 EXIT_DATA \
730 EXIT_CALL \
731 *(.discard) \
732 *(.discard.*) \
733 }
734
735 /**
736 * PERCPU_INPUT - the percpu input sections
737 * @cacheline: cacheline size
738 *
739 * The core percpu section names and core symbols which do not rely
740 * directly upon load addresses.
741 *
742 * @cacheline is used to align subsections to avoid false cacheline
743 * sharing between subsections for different purposes.
744 */
745 #define PERCPU_INPUT(cacheline) \
746 VMLINUX_SYMBOL(__per_cpu_start) = .; \
747 *(.data..percpu..first) \
748 . = ALIGN(PAGE_SIZE); \
749 *(.data..percpu..page_aligned) \
750 . = ALIGN(cacheline); \
751 *(.data..percpu..read_mostly) \
752 . = ALIGN(cacheline); \
753 *(.data..percpu) \
754 *(.data..percpu..shared_aligned) \
755 VMLINUX_SYMBOL(__per_cpu_end) = .;
756
757 /**
758 * PERCPU_VADDR - define output section for percpu area
759 * @cacheline: cacheline size
760 * @vaddr: explicit base address (optional)
761 * @phdr: destination PHDR (optional)
762 *
763 * Macro which expands to output section for percpu area.
764 *
765 * @cacheline is used to align subsections to avoid false cacheline
766 * sharing between subsections for different purposes.
767 *
768 * If @vaddr is not blank, it specifies explicit base address and all
769 * percpu symbols will be offset from the given address. If blank,
770 * @vaddr always equals @laddr + LOAD_OFFSET.
771 *
772 * @phdr defines the output PHDR to use if not blank. Be warned that
773 * output PHDR is sticky. If @phdr is specified, the next output
774 * section in the linker script will go there too. @phdr should have
775 * a leading colon.
776 *
777 * Note that this macros defines __per_cpu_load as an absolute symbol.
778 * If there is no need to put the percpu section at a predetermined
779 * address, use PERCPU_SECTION.
780 */
781 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
782 VMLINUX_SYMBOL(__per_cpu_load) = .; \
783 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
784 - LOAD_OFFSET) { \
785 PERCPU_INPUT(cacheline) \
786 } phdr \
787 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
788
789 /**
790 * PERCPU_SECTION - define output section for percpu area, simple version
791 * @cacheline: cacheline size
792 *
793 * Align to PAGE_SIZE and outputs output section for percpu area. This
794 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
795 * __per_cpu_start will be identical.
796 *
797 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
798 * except that __per_cpu_load is defined as a relative symbol against
799 * .data..percpu which is required for relocatable x86_32 configuration.
800 */
801 #define PERCPU_SECTION(cacheline) \
802 . = ALIGN(PAGE_SIZE); \
803 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
804 VMLINUX_SYMBOL(__per_cpu_load) = .; \
805 PERCPU_INPUT(cacheline) \
806 }
807
808
809 /*
810 * Definition of the high level *_SECTION macros
811 * They will fit only a subset of the architectures
812 */
813
814
815 /*
816 * Writeable data.
817 * All sections are combined in a single .data section.
818 * The sections following CONSTRUCTORS are arranged so their
819 * typical alignment matches.
820 * A cacheline is typical/always less than a PAGE_SIZE so
821 * the sections that has this restriction (or similar)
822 * is located before the ones requiring PAGE_SIZE alignment.
823 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
824 * matches the requirement of PAGE_ALIGNED_DATA.
825 *
826 * use 0 as page_align if page_aligned data is not used */
827 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
828 . = ALIGN(PAGE_SIZE); \
829 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
830 INIT_TASK_DATA(inittask) \
831 NOSAVE_DATA \
832 PAGE_ALIGNED_DATA(pagealigned) \
833 CACHELINE_ALIGNED_DATA(cacheline) \
834 READ_MOSTLY_DATA(cacheline) \
835 DATA_DATA \
836 CONSTRUCTORS \
837 }
838
839 #define INIT_TEXT_SECTION(inittext_align) \
840 . = ALIGN(inittext_align); \
841 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
842 VMLINUX_SYMBOL(_sinittext) = .; \
843 INIT_TEXT \
844 VMLINUX_SYMBOL(_einittext) = .; \
845 }
846
847 #define INIT_DATA_SECTION(initsetup_align) \
848 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
849 INIT_DATA \
850 INIT_SETUP(initsetup_align) \
851 INIT_CALLS \
852 CON_INITCALL \
853 SECURITY_INITCALL \
854 INIT_RAM_FS \
855 }
856
857 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
858 . = ALIGN(sbss_align); \
859 VMLINUX_SYMBOL(__bss_start) = .; \
860 SBSS(sbss_align) \
861 BSS(bss_align) \
862 . = ALIGN(stop_align); \
863 VMLINUX_SYMBOL(__bss_stop) = .;
Linux kernel - Deliverables
This page took 0.047945 seconds and 5 git commands to generate.