projects / deliverable / linux.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
Merge remote-tracking branch 'mmc-uh/next'
[deliverable/linux.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 #include <linux/export.h>
58
59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
60 #define ALIGN_FUNCTION() . = ALIGN(8)
61
62 /*
63 * Align to a 32 byte boundary equal to the
64 * alignment gcc 4.5 uses for a struct
65 */
66 #define STRUCT_ALIGNMENT 32
67 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
68
69 /* The actual configuration determine if the init/exit sections
70 * are handled as text/data or they can be discarded (which
71 * often happens at runtime)
72 */
73 #ifdef CONFIG_HOTPLUG_CPU
74 #define CPU_KEEP(sec) *(.cpu##sec)
75 #define CPU_DISCARD(sec)
76 #else
77 #define CPU_KEEP(sec)
78 #define CPU_DISCARD(sec) *(.cpu##sec)
79 #endif
80
81 #if defined(CONFIG_MEMORY_HOTPLUG)
82 #define MEM_KEEP(sec) *(.mem##sec)
83 #define MEM_DISCARD(sec)
84 #else
85 #define MEM_KEEP(sec)
86 #define MEM_DISCARD(sec) *(.mem##sec)
87 #endif
88
89 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
90 #define MCOUNT_REC() . = ALIGN(8); \
91 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
92 *(__mcount_loc) \
93 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
94 #else
95 #define MCOUNT_REC()
96 #endif
97
98 #ifdef CONFIG_TRACE_BRANCH_PROFILING
99 #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
100 *(_ftrace_annotated_branch) \
101 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
102 #else
103 #define LIKELY_PROFILE()
104 #endif
105
106 #ifdef CONFIG_PROFILE_ALL_BRANCHES
107 #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
108 *(_ftrace_branch) \
109 VMLINUX_SYMBOL(__stop_branch_profile) = .;
110 #else
111 #define BRANCH_PROFILE()
112 #endif
113
114 #ifdef CONFIG_KPROBES
115 #define KPROBE_BLACKLIST() . = ALIGN(8); \
116 VMLINUX_SYMBOL(__start_kprobe_blacklist) = .; \
117 *(_kprobe_blacklist) \
118 VMLINUX_SYMBOL(__stop_kprobe_blacklist) = .;
119 #else
120 #define KPROBE_BLACKLIST()
121 #endif
122
123 #ifdef CONFIG_EVENT_TRACING
124 #define FTRACE_EVENTS() . = ALIGN(8); \
125 VMLINUX_SYMBOL(__start_ftrace_events) = .; \
126 *(_ftrace_events) \
127 VMLINUX_SYMBOL(__stop_ftrace_events) = .; \
128 VMLINUX_SYMBOL(__start_ftrace_enum_maps) = .; \
129 *(_ftrace_enum_map) \
130 VMLINUX_SYMBOL(__stop_ftrace_enum_maps) = .;
131 #else
132 #define FTRACE_EVENTS()
133 #endif
134
135 #ifdef CONFIG_TRACING
136 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
137 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
138 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
139 #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \
140 *(__tracepoint_str) /* Trace_printk fmt' pointer */ \
141 VMLINUX_SYMBOL(__stop___tracepoint_str) = .;
142 #else
143 #define TRACE_PRINTKS()
144 #define TRACEPOINT_STR()
145 #endif
146
147 #ifdef CONFIG_FTRACE_SYSCALLS
148 #define TRACE_SYSCALLS() . = ALIGN(8); \
149 VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
150 *(__syscalls_metadata) \
151 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
152 #else
153 #define TRACE_SYSCALLS()
154 #endif
155
156 #ifdef CONFIG_SERIAL_EARLYCON
157 #define EARLYCON_TABLE() STRUCT_ALIGN(); \
158 VMLINUX_SYMBOL(__earlycon_table) = .; \
159 *(__earlycon_table) \
160 VMLINUX_SYMBOL(__earlycon_table_end) = .;
161 #else
162 #define EARLYCON_TABLE()
163 #endif
164
165 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
166 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
167 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
168 #define _OF_TABLE_0(name)
169 #define _OF_TABLE_1(name) \
170 . = ALIGN(8); \
171 VMLINUX_SYMBOL(__##name##_of_table) = .; \
172 *(__##name##_of_table) \
173 *(__##name##_of_table_end)
174
175 #define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc)
176 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
177 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
178 #define IOMMU_OF_TABLES() OF_TABLE(CONFIG_OF_IOMMU, iommu)
179 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
180 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
181 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
182
183 #ifdef CONFIG_ACPI
184 #define ACPI_PROBE_TABLE(name) \
185 . = ALIGN(8); \
186 VMLINUX_SYMBOL(__##name##_acpi_probe_table) = .; \
187 *(__##name##_acpi_probe_table) \
188 VMLINUX_SYMBOL(__##name##_acpi_probe_table_end) = .;
189 #else
190 #define ACPI_PROBE_TABLE(name)
191 #endif
192
193 #define KERNEL_DTB() \
194 STRUCT_ALIGN(); \
195 VMLINUX_SYMBOL(__dtb_start) = .; \
196 *(.dtb.init.rodata) \
197 VMLINUX_SYMBOL(__dtb_end) = .;
198
199 /*
200 * .data section
201 * -fdata-sections generates .data.identifier which needs to be pulled in
202 * with .data, but don't want to pull in .data..stuff which has its own
203 * requirements. Same for bss.
204 */
205 #define DATA_DATA \
206 *(.data .data.[0-9a-zA-Z_]*) \
207 *(.ref.data) \
208 *(.data..shared_aligned) /* percpu related */ \
209 MEM_KEEP(init.data) \
210 MEM_KEEP(exit.data) \
211 *(.data.unlikely) \
212 STRUCT_ALIGN(); \
213 *(__tracepoints) \
214 /* implement dynamic printk debug */ \
215 . = ALIGN(8); \
216 VMLINUX_SYMBOL(__start___jump_table) = .; \
217 *(__jump_table) \
218 VMLINUX_SYMBOL(__stop___jump_table) = .; \
219 . = ALIGN(8); \
220 VMLINUX_SYMBOL(__start___verbose) = .; \
221 *(__verbose) \
222 VMLINUX_SYMBOL(__stop___verbose) = .; \
223 LIKELY_PROFILE() \
224 BRANCH_PROFILE() \
225 TRACE_PRINTKS() \
226 TRACEPOINT_STR()
227
228 /*
229 * Data section helpers
230 */
231 #define NOSAVE_DATA \
232 . = ALIGN(PAGE_SIZE); \
233 VMLINUX_SYMBOL(__nosave_begin) = .; \
234 *(.data..nosave) \
235 . = ALIGN(PAGE_SIZE); \
236 VMLINUX_SYMBOL(__nosave_end) = .;
237
238 #define PAGE_ALIGNED_DATA(page_align) \
239 . = ALIGN(page_align); \
240 *(.data..page_aligned)
241
242 #define READ_MOSTLY_DATA(align) \
243 . = ALIGN(align); \
244 *(.data..read_mostly) \
245 . = ALIGN(align);
246
247 #define CACHELINE_ALIGNED_DATA(align) \
248 . = ALIGN(align); \
249 *(.data..cacheline_aligned)
250
251 #define INIT_TASK_DATA(align) \
252 . = ALIGN(align); \
253 VMLINUX_SYMBOL(__start_init_task) = .; \
254 *(.data..init_task) \
255 VMLINUX_SYMBOL(__end_init_task) = .;
256
257 /*
258 * Allow architectures to handle ro_after_init data on their
259 * own by defining an empty RO_AFTER_INIT_DATA.
260 */
261 #ifndef RO_AFTER_INIT_DATA
262 #define RO_AFTER_INIT_DATA *(.data..ro_after_init)
263 #endif
264
265 /*
266 * Read only Data
267 */
268 #define RO_DATA_SECTION(align) \
269 . = ALIGN((align)); \
270 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
271 VMLINUX_SYMBOL(__start_rodata) = .; \
272 *(.rodata) *(.rodata.*) \
273 RO_AFTER_INIT_DATA /* Read only after init */ \
274 *(__vermagic) /* Kernel version magic */ \
275 . = ALIGN(8); \
276 VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \
277 *(__tracepoints_ptrs) /* Tracepoints: pointer array */\
278 VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \
279 *(__tracepoints_strings)/* Tracepoints: strings */ \
280 } \
281 \
282 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
283 *(.rodata1) \
284 } \
285 \
286 BUG_TABLE \
287 \
288 /* PCI quirks */ \
289 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
290 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
291 *(.pci_fixup_early) \
292 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
293 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
294 *(.pci_fixup_header) \
295 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
296 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
297 *(.pci_fixup_final) \
298 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
299 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
300 *(.pci_fixup_enable) \
301 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
302 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
303 *(.pci_fixup_resume) \
304 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
305 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
306 *(.pci_fixup_resume_early) \
307 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
308 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
309 *(.pci_fixup_suspend) \
310 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
311 VMLINUX_SYMBOL(__start_pci_fixups_suspend_late) = .; \
312 *(.pci_fixup_suspend_late) \
313 VMLINUX_SYMBOL(__end_pci_fixups_suspend_late) = .; \
314 } \
315 \
316 /* Built-in firmware blobs */ \
317 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
318 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
319 *(.builtin_fw) \
320 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
321 } \
322 \
323 TRACEDATA \
324 \
325 /* Kernel symbol table: Normal symbols */ \
326 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
327 VMLINUX_SYMBOL(__start___ksymtab) = .; \
328 KEEP(*(SORT(___ksymtab+*))) \
329 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
330 } \
331 \
332 /* Kernel symbol table: GPL-only symbols */ \
333 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
334 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
335 KEEP(*(SORT(___ksymtab_gpl+*))) \
336 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
337 } \
338 \
339 /* Kernel symbol table: Normal unused symbols */ \
340 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
341 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
342 KEEP(*(SORT(___ksymtab_unused+*))) \
343 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
344 } \
345 \
346 /* Kernel symbol table: GPL-only unused symbols */ \
347 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
348 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
349 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
350 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
351 } \
352 \
353 /* Kernel symbol table: GPL-future-only symbols */ \
354 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
355 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
356 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
357 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
358 } \
359 \
360 /* Kernel symbol table: Normal symbols */ \
361 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
362 VMLINUX_SYMBOL(__start___kcrctab) = .; \
363 KEEP(*(SORT(___kcrctab+*))) \
364 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
365 } \
366 \
367 /* Kernel symbol table: GPL-only symbols */ \
368 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
369 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
370 KEEP(*(SORT(___kcrctab_gpl+*))) \
371 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
372 } \
373 \
374 /* Kernel symbol table: Normal unused symbols */ \
375 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
376 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
377 KEEP(*(SORT(___kcrctab_unused+*))) \
378 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
379 } \
380 \
381 /* Kernel symbol table: GPL-only unused symbols */ \
382 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
383 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
384 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
385 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
386 } \
387 \
388 /* Kernel symbol table: GPL-future-only symbols */ \
389 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
390 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
391 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
392 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
393 } \
394 \
395 /* Kernel symbol table: strings */ \
396 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
397 KEEP(*(__ksymtab_strings)) \
398 } \
399 \
400 /* __*init sections */ \
401 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
402 *(.ref.rodata) \
403 MEM_KEEP(init.rodata) \
404 MEM_KEEP(exit.rodata) \
405 } \
406 \
407 /* Built-in module parameters. */ \
408 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
409 VMLINUX_SYMBOL(__start___param) = .; \
410 *(__param) \
411 VMLINUX_SYMBOL(__stop___param) = .; \
412 } \
413 \
414 /* Built-in module versions. */ \
415 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
416 VMLINUX_SYMBOL(__start___modver) = .; \
417 *(__modver) \
418 VMLINUX_SYMBOL(__stop___modver) = .; \
419 . = ALIGN((align)); \
420 VMLINUX_SYMBOL(__end_rodata) = .; \
421 } \
422 . = ALIGN((align));
423
424 /* RODATA & RO_DATA provided for backward compatibility.
425 * All archs are supposed to use RO_DATA() */
426 #define RODATA RO_DATA_SECTION(4096)
427 #define RO_DATA(align) RO_DATA_SECTION(align)
428
429 #define SECURITY_INIT \
430 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
431 VMLINUX_SYMBOL(__security_initcall_start) = .; \
432 KEEP(*(.security_initcall.init)) \
433 VMLINUX_SYMBOL(__security_initcall_end) = .; \
434 }
435
436 /* .text section. Map to function alignment to avoid address changes
437 * during second ld run in second ld pass when generating System.map */
438 #define TEXT_TEXT \
439 ALIGN_FUNCTION(); \
440 *(.text.hot .text .text.fixup .text.unlikely .text.*) \
441 *(.ref.text) \
442 MEM_KEEP(init.text) \
443 MEM_KEEP(exit.text) \
444
445
446 /* sched.text is aling to function alignment to secure we have same
447 * address even at second ld pass when generating System.map */
448 #define SCHED_TEXT \
449 ALIGN_FUNCTION(); \
450 VMLINUX_SYMBOL(__sched_text_start) = .; \
451 *(.sched.text) \
452 VMLINUX_SYMBOL(__sched_text_end) = .;
453
454 /* spinlock.text is aling to function alignment to secure we have same
455 * address even at second ld pass when generating System.map */
456 #define LOCK_TEXT \
457 ALIGN_FUNCTION(); \
458 VMLINUX_SYMBOL(__lock_text_start) = .; \
459 *(.spinlock.text) \
460 VMLINUX_SYMBOL(__lock_text_end) = .;
461
462 #define KPROBES_TEXT \
463 ALIGN_FUNCTION(); \
464 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
465 *(.kprobes.text) \
466 VMLINUX_SYMBOL(__kprobes_text_end) = .;
467
468 #define ENTRY_TEXT \
469 ALIGN_FUNCTION(); \
470 VMLINUX_SYMBOL(__entry_text_start) = .; \
471 *(.entry.text) \
472 VMLINUX_SYMBOL(__entry_text_end) = .;
473
474 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
475 #define IRQENTRY_TEXT \
476 ALIGN_FUNCTION(); \
477 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
478 *(.irqentry.text) \
479 VMLINUX_SYMBOL(__irqentry_text_end) = .;
480 #else
481 #define IRQENTRY_TEXT
482 #endif
483
484 #if defined(CONFIG_FUNCTION_GRAPH_TRACER) || defined(CONFIG_KASAN)
485 #define SOFTIRQENTRY_TEXT \
486 ALIGN_FUNCTION(); \
487 VMLINUX_SYMBOL(__softirqentry_text_start) = .; \
488 *(.softirqentry.text) \
489 VMLINUX_SYMBOL(__softirqentry_text_end) = .;
490 #else
491 #define SOFTIRQENTRY_TEXT
492 #endif
493
494 /* Section used for early init (in .S files) */
495 #define HEAD_TEXT *(.head.text)
496
497 #define HEAD_TEXT_SECTION \
498 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
499 HEAD_TEXT \
500 }
501
502 /*
503 * Exception table
504 */
505 #define EXCEPTION_TABLE(align) \
506 . = ALIGN(align); \
507 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
508 VMLINUX_SYMBOL(__start___ex_table) = .; \
509 *(__ex_table) \
510 VMLINUX_SYMBOL(__stop___ex_table) = .; \
511 }
512
513 /*
514 * Init task
515 */
516 #define INIT_TASK_DATA_SECTION(align) \
517 . = ALIGN(align); \
518 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
519 INIT_TASK_DATA(align) \
520 }
521
522 #ifdef CONFIG_CONSTRUCTORS
523 #define KERNEL_CTORS() . = ALIGN(8); \
524 VMLINUX_SYMBOL(__ctors_start) = .; \
525 *(.ctors) \
526 *(SORT(.init_array.*)) \
527 *(.init_array) \
528 VMLINUX_SYMBOL(__ctors_end) = .;
529 #else
530 #define KERNEL_CTORS()
531 #endif
532
533 /* init and exit section handling */
534 #define INIT_DATA \
535 KEEP(*(SORT(___kentry+*))) \
536 *(.init.data) \
537 MEM_DISCARD(init.data) \
538 KERNEL_CTORS() \
539 MCOUNT_REC() \
540 *(.init.rodata) \
541 FTRACE_EVENTS() \
542 TRACE_SYSCALLS() \
543 KPROBE_BLACKLIST() \
544 MEM_DISCARD(init.rodata) \
545 CLK_OF_TABLES() \
546 RESERVEDMEM_OF_TABLES() \
547 CLKSRC_OF_TABLES() \
548 IOMMU_OF_TABLES() \
549 CPU_METHOD_OF_TABLES() \
550 CPUIDLE_METHOD_OF_TABLES() \
551 KERNEL_DTB() \
552 IRQCHIP_OF_MATCH_TABLE() \
553 ACPI_PROBE_TABLE(irqchip) \
554 ACPI_PROBE_TABLE(clksrc) \
555 EARLYCON_TABLE()
556
557 #define INIT_TEXT \
558 *(.init.text) \
559 *(.text.startup) \
560 MEM_DISCARD(init.text)
561
562 #define EXIT_DATA \
563 *(.exit.data) \
564 *(.fini_array) \
565 *(.dtors) \
566 MEM_DISCARD(exit.data) \
567 MEM_DISCARD(exit.rodata)
568
569 #define EXIT_TEXT \
570 *(.exit.text) \
571 *(.text.exit) \
572 MEM_DISCARD(exit.text)
573
574 #define EXIT_CALL \
575 *(.exitcall.exit)
576
577 /*
578 * bss (Block Started by Symbol) - uninitialized data
579 * zeroed during startup
580 */
581 #define SBSS(sbss_align) \
582 . = ALIGN(sbss_align); \
583 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
584 *(.sbss) \
585 *(.scommon) \
586 }
587
588 /*
589 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
590 * sections to the front of bss.
591 */
592 #ifndef BSS_FIRST_SECTIONS
593 #define BSS_FIRST_SECTIONS
594 #endif
595
596 #define BSS(bss_align) \
597 . = ALIGN(bss_align); \
598 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
599 BSS_FIRST_SECTIONS \
600 *(.bss..page_aligned) \
601 *(.dynbss) \
602 *(.bss .bss.[0-9a-zA-Z_]*) \
603 *(COMMON) \
604 }
605
606 /*
607 * DWARF debug sections.
608 * Symbols in the DWARF debugging sections are relative to
609 * the beginning of the section so we begin them at 0.
610 */
611 #define DWARF_DEBUG \
612 /* DWARF 1 */ \
613 .debug 0 : { *(.debug) } \
614 .line 0 : { *(.line) } \
615 /* GNU DWARF 1 extensions */ \
616 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
617 .debug_sfnames 0 : { *(.debug_sfnames) } \
618 /* DWARF 1.1 and DWARF 2 */ \
619 .debug_aranges 0 : { *(.debug_aranges) } \
620 .debug_pubnames 0 : { *(.debug_pubnames) } \
621 /* DWARF 2 */ \
622 .debug_info 0 : { *(.debug_info \
623 .gnu.linkonce.wi.*) } \
624 .debug_abbrev 0 : { *(.debug_abbrev) } \
625 .debug_line 0 : { *(.debug_line) } \
626 .debug_frame 0 : { *(.debug_frame) } \
627 .debug_str 0 : { *(.debug_str) } \
628 .debug_loc 0 : { *(.debug_loc) } \
629 .debug_macinfo 0 : { *(.debug_macinfo) } \
630 /* SGI/MIPS DWARF 2 extensions */ \
631 .debug_weaknames 0 : { *(.debug_weaknames) } \
632 .debug_funcnames 0 : { *(.debug_funcnames) } \
633 .debug_typenames 0 : { *(.debug_typenames) } \
634 .debug_varnames 0 : { *(.debug_varnames) } \
635
636 /* Stabs debugging sections. */
637 #define STABS_DEBUG \
638 .stab 0 : { *(.stab) } \
639 .stabstr 0 : { *(.stabstr) } \
640 .stab.excl 0 : { *(.stab.excl) } \
641 .stab.exclstr 0 : { *(.stab.exclstr) } \
642 .stab.index 0 : { *(.stab.index) } \
643 .stab.indexstr 0 : { *(.stab.indexstr) } \
644 .comment 0 : { *(.comment) }
645
646 #ifdef CONFIG_GENERIC_BUG
647 #define BUG_TABLE \
648 . = ALIGN(8); \
649 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
650 VMLINUX_SYMBOL(__start___bug_table) = .; \
651 *(__bug_table) \
652 VMLINUX_SYMBOL(__stop___bug_table) = .; \
653 }
654 #else
655 #define BUG_TABLE
656 #endif
657
658 #ifdef CONFIG_PM_TRACE
659 #define TRACEDATA \
660 . = ALIGN(4); \
661 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
662 VMLINUX_SYMBOL(__tracedata_start) = .; \
663 *(.tracedata) \
664 VMLINUX_SYMBOL(__tracedata_end) = .; \
665 }
666 #else
667 #define TRACEDATA
668 #endif
669
670 #define NOTES \
671 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
672 VMLINUX_SYMBOL(__start_notes) = .; \
673 *(.note.*) \
674 VMLINUX_SYMBOL(__stop_notes) = .; \
675 }
676
677 #define INIT_SETUP(initsetup_align) \
678 . = ALIGN(initsetup_align); \
679 VMLINUX_SYMBOL(__setup_start) = .; \
680 *(.init.setup) \
681 VMLINUX_SYMBOL(__setup_end) = .;
682
683 #define INIT_CALLS_LEVEL(level) \
684 VMLINUX_SYMBOL(__initcall##level##_start) = .; \
685 KEEP(*(.initcall##level##.init)) \
686 KEEP(*(.initcall##level##s.init)) \
687
688 #define INIT_CALLS \
689 VMLINUX_SYMBOL(__initcall_start) = .; \
690 KEEP(*(.initcallearly.init)) \
691 INIT_CALLS_LEVEL(0) \
692 INIT_CALLS_LEVEL(1) \
693 INIT_CALLS_LEVEL(2) \
694 INIT_CALLS_LEVEL(3) \
695 INIT_CALLS_LEVEL(4) \
696 INIT_CALLS_LEVEL(5) \
697 INIT_CALLS_LEVEL(rootfs) \
698 INIT_CALLS_LEVEL(6) \
699 INIT_CALLS_LEVEL(7) \
700 VMLINUX_SYMBOL(__initcall_end) = .;
701
702 #define CON_INITCALL \
703 VMLINUX_SYMBOL(__con_initcall_start) = .; \
704 KEEP(*(.con_initcall.init)) \
705 VMLINUX_SYMBOL(__con_initcall_end) = .;
706
707 #define SECURITY_INITCALL \
708 VMLINUX_SYMBOL(__security_initcall_start) = .; \
709 KEEP(*(.security_initcall.init)) \
710 VMLINUX_SYMBOL(__security_initcall_end) = .;
711
712 #ifdef CONFIG_BLK_DEV_INITRD
713 #define INIT_RAM_FS \
714 . = ALIGN(4); \
715 VMLINUX_SYMBOL(__initramfs_start) = .; \
716 KEEP(*(.init.ramfs)) \
717 . = ALIGN(8); \
718 KEEP(*(.init.ramfs.info))
719 #else
720 #define INIT_RAM_FS
721 #endif
722
723 /*
724 * Default discarded sections.
725 *
726 * Some archs want to discard exit text/data at runtime rather than
727 * link time due to cross-section references such as alt instructions,
728 * bug table, eh_frame, etc. DISCARDS must be the last of output
729 * section definitions so that such archs put those in earlier section
730 * definitions.
731 */
732 #define DISCARDS \
733 /DISCARD/ : { \
734 EXIT_TEXT \
735 EXIT_DATA \
736 EXIT_CALL \
737 *(.discard) \
738 *(.discard.*) \
739 }
740
741 /**
742 * PERCPU_INPUT - the percpu input sections
743 * @cacheline: cacheline size
744 *
745 * The core percpu section names and core symbols which do not rely
746 * directly upon load addresses.
747 *
748 * @cacheline is used to align subsections to avoid false cacheline
749 * sharing between subsections for different purposes.
750 */
751 #define PERCPU_INPUT(cacheline) \
752 VMLINUX_SYMBOL(__per_cpu_start) = .; \
753 *(.data..percpu..first) \
754 . = ALIGN(PAGE_SIZE); \
755 *(.data..percpu..page_aligned) \
756 . = ALIGN(cacheline); \
757 *(.data..percpu..read_mostly) \
758 . = ALIGN(cacheline); \
759 *(.data..percpu) \
760 *(.data..percpu..shared_aligned) \
761 VMLINUX_SYMBOL(__per_cpu_end) = .;
762
763 /**
764 * PERCPU_VADDR - define output section for percpu area
765 * @cacheline: cacheline size
766 * @vaddr: explicit base address (optional)
767 * @phdr: destination PHDR (optional)
768 *
769 * Macro which expands to output section for percpu area.
770 *
771 * @cacheline is used to align subsections to avoid false cacheline
772 * sharing between subsections for different purposes.
773 *
774 * If @vaddr is not blank, it specifies explicit base address and all
775 * percpu symbols will be offset from the given address. If blank,
776 * @vaddr always equals @laddr + LOAD_OFFSET.
777 *
778 * @phdr defines the output PHDR to use if not blank. Be warned that
779 * output PHDR is sticky. If @phdr is specified, the next output
780 * section in the linker script will go there too. @phdr should have
781 * a leading colon.
782 *
783 * Note that this macros defines __per_cpu_load as an absolute symbol.
784 * If there is no need to put the percpu section at a predetermined
785 * address, use PERCPU_SECTION.
786 */
787 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
788 VMLINUX_SYMBOL(__per_cpu_load) = .; \
789 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
790 - LOAD_OFFSET) { \
791 PERCPU_INPUT(cacheline) \
792 } phdr \
793 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
794
795 /**
796 * PERCPU_SECTION - define output section for percpu area, simple version
797 * @cacheline: cacheline size
798 *
799 * Align to PAGE_SIZE and outputs output section for percpu area. This
800 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
801 * __per_cpu_start will be identical.
802 *
803 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
804 * except that __per_cpu_load is defined as a relative symbol against
805 * .data..percpu which is required for relocatable x86_32 configuration.
806 */
807 #define PERCPU_SECTION(cacheline) \
808 . = ALIGN(PAGE_SIZE); \
809 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
810 VMLINUX_SYMBOL(__per_cpu_load) = .; \
811 PERCPU_INPUT(cacheline) \
812 }
813
814
815 /*
816 * Definition of the high level *_SECTION macros
817 * They will fit only a subset of the architectures
818 */
819
820
821 /*
822 * Writeable data.
823 * All sections are combined in a single .data section.
824 * The sections following CONSTRUCTORS are arranged so their
825 * typical alignment matches.
826 * A cacheline is typical/always less than a PAGE_SIZE so
827 * the sections that has this restriction (or similar)
828 * is located before the ones requiring PAGE_SIZE alignment.
829 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
830 * matches the requirement of PAGE_ALIGNED_DATA.
831 *
832 * use 0 as page_align if page_aligned data is not used */
833 #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
834 . = ALIGN(PAGE_SIZE); \
835 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
836 INIT_TASK_DATA(inittask) \
837 NOSAVE_DATA \
838 PAGE_ALIGNED_DATA(pagealigned) \
839 CACHELINE_ALIGNED_DATA(cacheline) \
840 READ_MOSTLY_DATA(cacheline) \
841 DATA_DATA \
842 CONSTRUCTORS \
843 }
844
845 #define INIT_TEXT_SECTION(inittext_align) \
846 . = ALIGN(inittext_align); \
847 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
848 VMLINUX_SYMBOL(_sinittext) = .; \
849 INIT_TEXT \
850 VMLINUX_SYMBOL(_einittext) = .; \
851 }
852
853 #define INIT_DATA_SECTION(initsetup_align) \
854 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
855 INIT_DATA \
856 INIT_SETUP(initsetup_align) \
857 INIT_CALLS \
858 CON_INITCALL \
859 SECURITY_INITCALL \
860 INIT_RAM_FS \
861 }
862
863 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
864 . = ALIGN(sbss_align); \
865 VMLINUX_SYMBOL(__bss_start) = .; \
866 SBSS(sbss_align) \
867 BSS(bss_align) \
868 . = ALIGN(stop_align); \
869 VMLINUX_SYMBOL(__bss_stop) = .;
Linux kernel - Deliverables
This page took 0.049806 seconds and 5 git commands to generate.