ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 # PR gas/19109
 146 # Decide the default method for compressing debug sections.
 147 ac_default_compressed_debug_sections=unset
 148 # Provide a configure time option to override our default.
 149 AC_ARG_ENABLE(compressed_debug_sections,
 150               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 151               [compress debug sections by default])],
 152 [case ,"${enableval}", in
 153   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 154   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 155 esac])dnl
 156
 157 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 158 ac_default_new_dtags=unset
 159 # Provide a configure time option to override our default.
 160 AC_ARG_ENABLE(new_dtags,
 161               AS_HELP_STRING([--enable-new-dtags],
 162               [set DT_RUNPATH instead of DT_RPATH by default])],
 163 [case "${enableval}" in
 164   yes) ac_default_new_dtags=1 ;;
 165   no) ac_default_new_dtags=0 ;;
 166 esac])dnl
 167
 168 # Decide if -z relro should be enabled in ELF linker by default.
 169 ac_default_ld_z_relro=unset
 170 # Provide a configure time option to override our default.
 171 AC_ARG_ENABLE(relro,
 172               AS_HELP_STRING([--enable-relro],
 173               [enable -z relro in ELF linker by default]),
 174 [case "${enableval}" in
 175   yes)  ac_default_ld_z_relro=1 ;;
 176   no)  ac_default_ld_z_relro=0 ;;
 177 esac])dnl
 178
 179 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 180 ac_default_ld_textrel_check=unset
 181 AC_ARG_ENABLE([textrel-check],
 182               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 183                              [enable DT_TEXTREL check in ELF linker]),
 184 [case "${enableval}" in
 185   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 186 esac])
 187
 188 # Decide if -z separate-code should be enabled in ELF linker by default.
 189 ac_default_ld_z_separate_code=unset
 190 AC_ARG_ENABLE(separate-code,
 191               AS_HELP_STRING([--enable-separate-code],
 192               [enable -z separate-code in ELF linker by default]),
 193 [case "${enableval}" in
 194   yes) ac_default_ld_z_separate_code=1 ;;
 195   no) ac_default_ld_z_separate_code=0 ;;
 196 esac])
 197
 198 # Decide which "--hash-style" to use by default
 199 # Provide a configure time option to override our default.
 200 AC_ARG_ENABLE([default-hash-style],
 201 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 202                [use this default hash style]),
 203 [case "${enable_default_hash_style}" in
 204   sysv | gnu | both) ;;
 205   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 206 esac],
 207 [case "${target}" in
 208   # Enable gnu hash only on GNU targets, but not mips
 209   mips*-*-*) enable_default_hash_style=sysv ;;
 210   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 211   *) enable_default_hash_style=sysv ;;
 212 esac])
 213
 214 case "${enable_default_hash_style}" in
 215   sysv | both) ac_default_emit_sysv_hash=1 ;;
 216   *) ac_default_emit_sysv_hash=0 ;;
 217 esac
 218
 219 case "${enable_default_hash_style}" in
 220   gnu | both) ac_default_emit_gnu_hash=1 ;;
 221   *) ac_default_emit_gnu_hash=0 ;;
 222 esac
 223
 224 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 225 if test "${enable_libctf}" = yes; then
 226     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 227 fi
 228 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 229
 230 AM_BINUTILS_WARNINGS
 231
 232 AM_LC_MESSAGES
 233
 234 AC_CONFIG_HEADERS([config.h:config.in])
 235
 236 # PR 14072
 237 AH_VERBATIM([00_CONFIG_H_CHECK],
 238 [/* Check that config.h is #included before system headers
 239    (this works only for glibc, but that should be enough).  */
 240 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 241 #  error config.h must be #included before system headers
 242 #endif
 243 #define __CONFIG_H__ 1])
 244
 245 if test -z "$target" ; then
 246     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 247 fi
 248 if test -z "$host" ; then
 249     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 250 fi
 251
 252 # host-specific stuff:
 253
 254 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 255 ZW_GNU_GETTEXT_SISTER_DIR
 256 AM_PO_SUBDIRS
 257
 258 AC_EXEEXT
 259
 260 AC_PROG_YACC
 261 AM_PROG_LEX
 262
 263 AM_MAINTAINER_MODE
 264 AM_CONDITIONAL(GENINSRC_NEVER, false)
 265 ACX_PROG_CMP_IGNORE_INITIAL
 266
 267 . ${srcdir}/configure.host
 268
 269 AC_SUBST(HDEFINES)
 270 AC_SUBST(NATIVE_LIB_DIRS)
 271
 272 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 273 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 274 ACX_HEADER_STRING
 275 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 276 AC_CHECK_FUNCS(open lseek close)
 277 AC_HEADER_DIRENT
 278
 279 dnl AC_CHECK_HEADERS(sys/mman.h)
 280 AC_FUNC_MMAP
 281
 282 AC_SEARCH_LIBS([dlopen], [dl])
 283
 284 AC_ARG_ENABLE(initfini-array,
 285 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 286 [case "${enableval}" in
 287  yes|no) ;;
 288  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 289  esac], [enable_initfini_array=yes])
 290 AC_SUBST(enable_initfini_array)
 291 if test $enable_initfini_array = yes; then
 292   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 293     [Define .init_array/.fini_array sections are available and working.])
 294 fi
 295
 296 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 297 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 298 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 299 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 300 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 301 if test $ld_cv_decl_getopt_unistd_h = yes; then
 302   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 303             [Is the prototype for getopt in <unistd.h> in the expected format?])
 304 fi
 305
 306 BFD_BINARY_FOPEN
 307
 308 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 309
 310 # Link in zlib if we can.  This allows us to read and write
 311 # compressed CTF sections.
 312 AM_ZLIB
 313
 314 # When converting linker scripts into strings for use in emulation
 315 # files, use astring.sed if the compiler supports ANSI string
 316 # concatenation, or ostring.sed otherwise.  This is to support the
 317 # broken Microsoft MSVC compiler, which limits the length of string
 318 # constants, while still supporting pre-ANSI compilers which do not
 319 # support string concatenation.
 320 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 321 AC_CACHE_VAL(ld_cv_string_concatenation,
 322 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 323   ld_cv_string_concatenation=yes,
 324   ld_cv_string_concatenation=no)])
 325 AC_MSG_RESULT($ld_cv_string_concatenation)
 326 if test "$ld_cv_string_concatenation" = "yes"; then
 327   STRINGIFY=astring.sed
 328 else
 329   STRINGIFY=ostring.sed
 330 fi
 331 AC_SUBST(STRINGIFY)
 332
 333 # target-specific stuff:
 334
 335 all_targets=
 336 EMUL=
 337 all_emuls=
 338 all_emul_extras=
 339 all_libpath=
 340 TDIRS=
 341
 342 # If the host is 64-bit, then we enable 64-bit targets by default.
 343 # This is consistent with what ../bfd/configure.ac does.
 344 if test x${want64} = xfalse; then
 345   AC_CHECK_SIZEOF(void *)
 346   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 347     want64=true
 348   fi
 349 fi
 350
 351 elf_list_options=FALSE
 352 elf_shlib_list_options=FALSE
 353 elf_plt_unwind_list_options=FALSE
 354 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 355 do
 356   if test "$targ_alias" = "all"; then
 357     all_targets=true
 358     elf_list_options=TRUE
 359     elf_shlib_list_options=TRUE
 360     elf_plt_unwind_list_options=TRUE
 361   else
 362     # Canonicalize the secondary target names.
 363     result=`$ac_config_sub $targ_alias 2>/dev/null`
 364     if test -n "$result"; then
 365         targ=$result
 366     else
 367         targ=$targ_alias
 368     fi
 369
 370     . ${srcdir}/configure.tgt
 371
 372     if test "$targ" = "$target"; then
 373       EMUL=$targ_emul
 374     fi
 375
 376     if test x${want64} = xfalse; then
 377       . ${srcdir}/../bfd/config.bfd
 378     fi
 379
 380     if test x${want64} = xtrue; then
 381       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 382       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 383     fi
 384
 385     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 386         case " $all_emuls " in
 387         *" e${i}.o "*) ;;
 388         *)
 389           all_emuls="$all_emuls e${i}.o"
 390           eval result=\$tdir_$i
 391           test -z "$result" && result=$targ_alias
 392           TDIRS="$TDIRS
 393 tdir_$i=$result"
 394           case "${i}" in
 395           *elf*)
 396             elf_list_options=TRUE
 397             ;;
 398           *)
 399             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 400               elf_list_options=TRUE
 401             fi
 402             ;;
 403           esac
 404           if test "$elf_list_options" = "TRUE"; then
 405             source_sh()
 406             {
 407               . $1
 408             }
 409             source_sh ${srcdir}/emulparams/${i}.sh
 410             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 411               elf_shlib_list_options=TRUE
 412             fi
 413             if test x${PLT_UNWIND} = xyes; then
 414               elf_plt_unwind_list_options=TRUE
 415             fi
 416           fi
 417           ;;
 418         esac
 419     done
 420
 421     for i in $targ_emul $targ_extra_libpath; do
 422         case " $all_libpath " in
 423         *" ${i} "*) ;;
 424         *)
 425           if test -z "$all_libpath"; then
 426             all_libpath=${i}
 427           else
 428             all_libpath="$all_libpath ${i}"
 429           fi
 430           ;;
 431         esac
 432     done
 433
 434     for i in $targ_extra_ofiles; do
 435         case " $all_emul_extras " in
 436         *" ${i} "*) ;;
 437         *)
 438           all_emul_extras="$all_emul_extras ${i}"
 439           ;;
 440         esac
 441     done
 442
 443   fi
 444 done
 445
 446 if test x$ac_default_compressed_debug_sections = xyes ; then
 447   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 448 fi
 449
 450 if test "${ac_default_new_dtags}" = unset; then
 451   ac_default_new_dtags=0
 452 fi
 453 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 454   $ac_default_new_dtags,
 455   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 456
 457 if test "${ac_default_ld_z_relro}" = unset; then
 458   ac_default_ld_z_relro=0
 459 fi
 460 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 461   $ac_default_ld_z_relro,
 462   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 463
 464 ac_default_ld_textrel_check_warning=0
 465 case "${ac_default_ld_textrel_check}" in
 466   unset|no)
 467     ac_default_ld_textrel_check=textrel_check_none
 468     ;;
 469   yes|warning)
 470     ac_default_ld_textrel_check=textrel_check_warning
 471     ac_default_ld_textrel_check_warning=1
 472     ;;
 473   error)
 474     ac_default_ld_textrel_check=textrel_check_error
 475     ;;
 476 esac
 477 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 478   $ac_default_ld_textrel_check,
 479   [The default method for DT_TEXTREL check in ELF linker.])
 480 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 481   $ac_default_ld_textrel_check_warning,
 482   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 483
 484 if test "${ac_default_ld_z_separate_code}" = unset; then
 485   ac_default_ld_z_separate_code=0
 486 fi
 487 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 488   $ac_default_ld_z_separate_code,
 489   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 490
 491 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 492   [$ac_default_emit_sysv_hash],
 493   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 494
 495 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 496   [$ac_default_emit_gnu_hash],
 497   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 498
 499 AC_SUBST(elf_list_options)
 500 AC_SUBST(elf_shlib_list_options)
 501 AC_SUBST(elf_plt_unwind_list_options)
 502 AC_SUBST(EMUL)
 503
 504 AC_SUBST(TDIRS)
 505 AM_SUBST_NOTMAKE(TDIRS)
 506
 507 if test x${all_targets} = xtrue; then
 508   if test x${want64} = xtrue; then
 509     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 510     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 511   else
 512     EMULATION_OFILES='$(ALL_EMULATIONS)'
 513     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 514   fi
 515 else
 516   EMULATION_OFILES=$all_emuls
 517   EMUL_EXTRA_OFILES=$all_emul_extras
 518 fi
 519 AC_SUBST(EMULATION_OFILES)
 520 AC_SUBST(EMUL_EXTRA_OFILES)
 521 AC_SUBST(LIB_PATH)
 522
 523 EMULATION_LIBPATH=$all_libpath
 524 AC_SUBST(EMULATION_LIBPATH)
 525
 526 if test x${enable_static} = xno; then
 527   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 528   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 529 else
 530   TESTBFDLIB="../bfd/.libs/libbfd.a"
 531   TESTCTFLIB="../libctf/.libs/libctf.a"
 532 fi
 533 if test "${enable_libctf}" = no; then
 534     TESTCTFLIB=
 535 fi
 536 AC_SUBST(TESTBFDLIB)
 537 AC_SUBST(TESTCTFLIB)
 538
 539 target_vendor=${target_vendor=$host_vendor}
 540 case "$target_vendor" in
 541   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 542   *)  EXTRA_SHLIB_EXTENSION= ;;
 543 esac
 544
 545 case "$target_os" in
 546   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 547 esac
 548
 549 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 550   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 551    [Additional extension a shared object might have.])
 552 fi
 553
 554 AC_CONFIG_COMMANDS([default],
 555 [[
 556 case "$srcdir" in
 557   .) srcdirpre= ;;
 558   *) srcdirpre='$(srcdir)/' ;;
 559 esac
 560 POFILES=
 561 GMOFILES=
 562 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 563   if test $lang != dummy; then
 564     POFILES="$POFILES $srcdirpre$lang.po"
 565     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 566   fi
 567 done
 568 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 569     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 570     -e "s,@POFILES@,$POFILES," \
 571     -e "s,@GMOFILES@,$GMOFILES," \
 572     po/Makefile.in > po/Makefile]],[[]])
 573
 574 dnl Required by html, pdf, install-pdf and install-html
 575 AC_SUBST(datarootdir)
 576 AC_SUBST(docdir)
 577 AC_SUBST(htmldir)
 578 AC_SUBST(pdfdir)
 579
 580 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 581 AC_OUTPUT