ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright 2012 Free Software Foundation
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 AC_INIT
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 changequote(,)dnl
  29 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  30 changequote([,])dnl
  31 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  32 AM_MAINTAINER_MODE
  33
  34 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  35 AC_ARG_ENABLE(targets,
  36 [  --enable-targets        alternative target configurations],
  37 [case "${enableval}" in
  38   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  39             ;;
  40   no)       enable_targets= ;;
  41   *)        enable_targets=$enableval ;;
  42 esac])dnl
  43 AC_ARG_ENABLE(64-bit-bfd,
  44 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  45 [case "${enableval}" in
  46   yes)  want64=true  ;;
  47   no)   want64=false ;;
  48   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  49 esac],[want64=false])dnl
  50
  51 AC_ARG_WITH(sysroot,
  52 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  53 [
  54  case ${with_sysroot} in
  55  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  56  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  57  esac
  58
  59  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  60  use_sysroot=yes
  61
  62  if test "x$prefix" = xNONE; then
  63   test_prefix=/usr/local
  64  else
  65   test_prefix=$prefix
  66  fi
  67  if test "x$exec_prefix" = xNONE; then
  68   test_exec_prefix=$test_prefix
  69  else
  70   test_exec_prefix=$exec_prefix
  71  fi
  72  case ${TARGET_SYSTEM_ROOT} in
  73  "${test_prefix}"|"${test_prefix}/"*|\
  74  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  75  '${prefix}'|'${prefix}/'*|\
  76  '${exec_prefix}'|'${exec_prefix}/'*)
  77    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  78    TARGET_SYSTEM_ROOT_DEFINE="$t"
  79    ;;
  80  esac
  81 ], [
  82  use_sysroot=no
  83  TARGET_SYSTEM_ROOT=
  84  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  85 ])
  86 AC_SUBST(use_sysroot)
  87 AC_SUBST(TARGET_SYSTEM_ROOT)
  88 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  89
  90 dnl Use --enable-gold to decide if this linker should be the default.
  91 dnl "install_as_default" is set to false if gold is the default linker.
  92 dnl "installed_linker" is the installed BFD linker name.
  93 AC_ARG_ENABLE(gold,
  94 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
  95 [case "${enableval}" in
  96  default)
  97    install_as_default=no
  98    installed_linker=ld.bfd
  99    ;;
 100  yes|no)
 101    install_as_default=yes
 102    installed_linker=ld.bfd
 103    ;;
 104  *)
 105    AC_MSG_ERROR([invalid --enable-gold argument])
 106    ;;
 107  esac],
 108 [install_as_default=yes
 109  installed_linker=ld.bfd])
 110 AC_SUBST(install_as_default)
 111 AC_SUBST(installed_linker)
 112
 113 AC_ARG_ENABLE([got],
 114 AS_HELP_STRING([--enable-got=<type>],
 115                [GOT handling scheme (target, single, negative, multigot)]),
 116 [case "${enableval}" in
 117   target | single | negative | multigot)  got_handling=$enableval ;;
 118   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 119 esac],
 120 [got_handling=target])
 121
 122 case "${got_handling}" in
 123   target)
 124     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 125               [Define to choose default GOT handling scheme]) ;;
 126   single)
 127     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 128               [Define to choose default GOT handling scheme]) ;;
 129   negative)
 130     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 131               [Define to choose default GOT handling scheme]) ;;
 132   multigot)
 133     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 134               [Define to choose default GOT handling scheme]) ;;
 135   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 136 esac
 137
 138 AM_BINUTILS_WARNINGS
 139
 140 AM_LC_MESSAGES
 141
 142 AC_CONFIG_HEADERS([config.h:config.in])
 143
 144 # PR 14072
 145 AH_VERBATIM([00_CONFIG_H_CHECK],
 146 [/* Check that config.h is #included before system headers
 147    (this works only for glibc, but that should be enough).  */
 148 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 149 #  error config.h must be #included before system headers
 150 #endif
 151 #define __CONFIG_H__ 1])
 152
 153 if test -z "$target" ; then
 154     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 155 fi
 156 if test -z "$host" ; then
 157     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 158 fi
 159
 160 # host-specific stuff:
 161
 162 AC_PROG_CC
 163 AC_PROG_CXX
 164 AC_GNU_SOURCE
 165 AC_USE_SYSTEM_EXTENSIONS
 166 ACX_LARGEFILE
 167 AC_PROG_INSTALL
 168
 169 LT_INIT
 170
 171 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 172 ZW_GNU_GETTEXT_SISTER_DIR
 173 AM_PO_SUBDIRS
 174
 175 AC_EXEEXT
 176
 177 AC_PROG_YACC
 178 AM_PROG_LEX
 179
 180 AM_MAINTAINER_MODE
 181 AM_CONDITIONAL(GENINSRC_NEVER, false)
 182 ACX_PROG_CMP_IGNORE_INITIAL
 183
 184 . ${srcdir}/configure.host
 185
 186 AC_SUBST(HDEFINES)
 187 AC_SUBST(HOSTING_CRT0)
 188 AC_SUBST(HOSTING_SCRT0)
 189 AC_SUBST(HOSTING_LIBS)
 190 AC_SUBST(HOSTING_SLIBS)
 191 AC_SUBST(NATIVE_LIB_DIRS)
 192
 193 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 194 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 195 ACX_HEADER_STRING
 196 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 197 AC_CHECK_FUNCS(open lseek close)
 198 AC_HEADER_DIRENT
 199
 200 # Check for dlopen support and enable plugins if possible.
 201 enable_plugins=yes
 202 AC_CHECK_HEADER([dlfcn.h],[],[enable_plugins=no],[AC_INCLUDES_DEFAULT])
 203 AC_SEARCH_LIBS([dlopen],[dl],[],[enable_plugins=no],[])
 204 AC_CHECK_FUNCS([dlopen dlsym dlclose],[],[enable_plugins=no])
 205 # We also support plugins on Windows (MinGW).
 206 if test x$enable_plugins = xno ; then
 207   AC_CHECK_HEADERS([windows.h],[enable_plugins=yes],[],[AC_INCLUDES_DEFAULT])
 208 fi
 209 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$enable_plugins = xyes])
 210
 211 AC_ARG_ENABLE(initfini-array,
 212         [  --enable-initfini-array      use .init_array/.fini_array sections],
 213         [], [
 214 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 215                  gcc_cv_initfini_array, [dnl
 216   if test "x${build}" = "x${target}" ; then
 217     AC_RUN_IFELSE([AC_LANG_SOURCE([
 218 static int x = -1;
 219 int main (void) { return x; }
 220 int foo (void) { x = 0; }
 221 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 222              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 223              [gcc_cv_initfini_array=no])
 224    else
 225      gcc_cv_initfini_array=no
 226    fi])
 227   enable_initfini_array=$gcc_cv_initfini_array
 228 ])
 229 AC_SUBST(enable_initfini_array)
 230 if test $enable_initfini_array = yes; then
 231   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 232     [Define .init_array/.fini_array sections are available and working.])
 233 fi
 234
 235 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 236 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 237 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 238 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 239 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 240 if test $ld_cv_decl_getopt_unistd_h = yes; then
 241   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 242             [Is the prototype for getopt in <unistd.h> in the expected format?])
 243 fi
 244
 245 BFD_BINARY_FOPEN
 246
 247 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 248
 249 # Link in zlib if we can.  This is needed only for the bootstrap tests
 250 # right now, since those tests use libbfd, which depends on zlib.
 251 AM_ZLIB
 252
 253 # When converting linker scripts into strings for use in emulation
 254 # files, use astring.sed if the compiler supports ANSI string
 255 # concatenation, or ostring.sed otherwise.  This is to support the
 256 # broken Microsoft MSVC compiler, which limits the length of string
 257 # constants, while still supporting pre-ANSI compilers which do not
 258 # support string concatenation.
 259 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 260 AC_CACHE_VAL(ld_cv_string_concatenation,
 261 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 262   ld_cv_string_concatenation=yes,
 263   ld_cv_string_concatenation=no)])
 264 AC_MSG_RESULT($ld_cv_string_concatenation)
 265 if test "$ld_cv_string_concatenation" = "yes"; then
 266   STRINGIFY=astring.sed
 267 else
 268   STRINGIFY=ostring.sed
 269 fi
 270 AC_SUBST(STRINGIFY)
 271
 272 # target-specific stuff:
 273
 274 all_targets=
 275 EMUL=
 276 all_emuls=
 277 all_emul_extras=
 278 all_emul_extra_binaries=
 279 all_libpath=
 280
 281 dnl We need to get an arbitrary number of tdir definitions into
 282 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 283 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 284 dnl file.
 285 rm -f tdirs
 286
 287 # If the host is 64-bit, then we enable 64-bit targets by default.
 288 # This is consistent with what ../bfd/configure.in does.
 289 if test x${want64} = xfalse; then
 290   AC_CHECK_SIZEOF(void *)
 291   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 292     want64=true
 293   fi
 294 fi
 295
 296 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 297 do
 298   if test "$targ_alias" = "all"; then
 299     all_targets=true
 300   else
 301     # Canonicalize the secondary target names.
 302     result=`$ac_config_sub $targ_alias 2>/dev/null`
 303     if test -n "$result"; then
 304         targ=$result
 305     else
 306         targ=$targ_alias
 307     fi
 308
 309     . ${srcdir}/configure.tgt
 310
 311     if test "$targ" = "$target"; then
 312       EMUL=$targ_emul
 313     fi
 314
 315     if test x${want64} = xfalse; then
 316       . ${srcdir}/../bfd/config.bfd
 317     fi
 318
 319     if test x${want64} = xtrue; then
 320       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 321       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 322     fi
 323
 324     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 325         case " $all_emuls " in
 326         *" e${i}.o "*) ;;
 327         *)
 328           all_emuls="$all_emuls e${i}.o"
 329           eval result=\$tdir_$i
 330           test -z "$result" && result=$targ_alias
 331           echo tdir_$i=$result >> tdirs
 332           ;;
 333         esac
 334     done
 335
 336     for i in $targ_emul $targ_extra_libpath; do
 337         case " $all_libpath " in
 338         *" ${i} "*) ;;
 339         *)
 340           if test -z "$all_libpath"; then
 341             all_libpath=${i}
 342           else
 343             all_libpath="$all_libpath ${i}"
 344           fi
 345           ;;
 346         esac
 347     done
 348
 349     for i in $targ_extra_ofiles; do
 350         case " $all_emul_extras " in
 351         *" ${i} "*) ;;
 352         *)
 353           all_emul_extras="$all_emul_extras ${i}"
 354           ;;
 355         esac
 356     done
 357
 358     for i in $targ_extra_binaries; do
 359         case " $all_emul_extra_binaries " in
 360         *" ${i} "*) ;;
 361         *)
 362           all_emul_extra_binaries="$all_emul_extra_binaries ${i}"
 363           ;;
 364         esac
 365     done
 366   fi
 367 done
 368
 369 AC_SUBST(EMUL)
 370
 371 TDIRS=tdirs
 372 AC_SUBST_FILE(TDIRS)
 373
 374 if test x${all_targets} = xtrue; then
 375   if test x${want64} = xtrue; then
 376     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 377   else
 378     EMULATION_OFILES='$(ALL_EMULATIONS)'
 379   fi
 380   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 381   EMUL_EXTRA_BINARIES='$(ALL_EMUL_EXTRA_BINARIES)'
 382 else
 383   EMULATION_OFILES=$all_emuls
 384   EMUL_EXTRA_OFILES=$all_emul_extras
 385   EMUL_EXTRA_BINARIES=$all_emul_extra_binaries
 386 fi
 387 AC_SUBST(EMULATION_OFILES)
 388 AC_SUBST(EMUL_EXTRA_OFILES)
 389 AC_SUBST(EMUL_EXTRA_BINARIES)
 390 AC_SUBST(LIB_PATH)
 391
 392 EMULATION_LIBPATH=$all_libpath
 393 AC_SUBST(EMULATION_LIBPATH)
 394
 395 if test x${enable_static} = xno; then
 396   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 397 else
 398   TESTBFDLIB="../bfd/.libs/libbfd.a"
 399 fi
 400 AC_SUBST(TESTBFDLIB)
 401
 402 target_vendor=${target_vendor=$host_vendor}
 403 case "$target_vendor" in
 404   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 405   *)  EXTRA_SHLIB_EXTENSION= ;;
 406 esac
 407
 408 case "$target_os" in
 409   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 410 esac
 411
 412 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 413   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 414    [Additional extension a shared object might have.])
 415 fi
 416
 417 dnl Required by html, pdf, install-pdf and install-html
 418 AC_SUBST(datarootdir)
 419 AC_SUBST(docdir)
 420 AC_SUBST(htmldir)
 421 AC_SUBST(pdfdir)
 422
 423 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 424 AC_OUTPUT