ld/ldlex.l

   1 %option nounput noyywrap
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2021 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ctf-api.h"
  29 #include "ld.h"
  30 #include "ldmisc.h"
  31 #include "ldexp.h"
  32 #include "ldlang.h"
  33 #include <ldgram.h>
  34 #include "ldfile.h"
  35 #include "ldlex.h"
  36 #include "ldmain.h"
  37 #include "libiberty.h"
  38
  39 /* The type of top-level parser input.
  40    yylex and yyparse (indirectly) both check this.  */
  41 input_type parser_input;
  42
  43 /* Line number in the current input file.  */
  44 unsigned int lineno;
  45
  46 /* The string we are currently lexing, or NULL if we are reading a
  47    file.  */
  48 const char *lex_string = NULL;
  49
  50 /* Support for flex reading from more than one input file (stream).
  51    `include_stack' is flex's input state for each open file;
  52    `file_name_stack' is the file names.  `lineno_stack' is the current
  53    line numbers.
  54
  55    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  56    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  57
  58 #undef YY_INPUT
  59 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  60
  61 #ifndef YY_NO_UNPUT
  62 #define YY_NO_UNPUT
  63 #endif
  64
  65 #define MAX_INCLUDE_DEPTH 10
  66 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  67 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  70 static unsigned int include_stack_ptr = 0;
  71 static int vers_node_nesting = 0;
  72
  73 static int yy_input (char *, int);
  74 static void comment (void);
  75 static void lex_warn_invalid (char *where, char *what);
  76
  77 /* STATES
  78         EXPRESSION      definitely in an expression
  79         SCRIPT          definitely in a script
  80         INPUTLIST       definitely in a script, a filename-list
  81         BOTH            either EXPRESSION or SCRIPT
  82         MRI             in an MRI script
  83         VERS_START      starting a Sun style mapfile
  84         VERS_SCRIPT     a Sun style mapfile
  85         VERS_NODE       a node within a Sun style mapfile
  86 */
  87 #define RTOKEN(x)  {  yylval.token = x; return x; }
  88
  89 %}
  90
  91 %a 4000
  92 %o 5000
  93
  94 WILDCHAR        [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]\,\=\?\*\^\!]
  95 FILENAMECHAR    [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]\,\=]
  96 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\\\$\~\-\+\:\[\]]
  97 SYMBOLNAMECHAR  [_a-zA-Z0-9\/\.\\\$\~]
  98 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\~]
  99 SYMBOLNAMECHAR1 [_a-zA-Z\.\\\$]
 100 WHITE           [ \t\n\r]+
 101
 102 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 103 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 104
 105 %s SCRIPT
 106 %s INPUTLIST
 107 %s EXPRESSION
 108 %s BOTH
 109 %s MRI
 110 %s VERS_START
 111 %s VERS_SCRIPT
 112 %s VERS_NODE
 113 %%
 114
 115   if (parser_input != input_selected)
 116     {
 117       /* The first token of the input determines the initial parser state.  */
 118       input_type t = parser_input;
 119       parser_input = input_selected;
 120       switch (t)
 121         {
 122         case input_script: return INPUT_SCRIPT; break;
 123         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 124         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 125         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 126         case input_defsym: return INPUT_DEFSYM; break;
 127         default: abort ();
 128         }
 129     }
 130
 131 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 132
 133
 134 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 135                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 136                                 yylval.bigint.str = NULL;
 137                                 return INT;
 138                         }
 139
 140 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 141                                    int ibase ;
 142                                    switch (yytext[yyleng - 1]) {
 143                                     case 'X':
 144                                     case 'x':
 145                                     case 'H':
 146                                     case 'h':
 147                                      ibase = 16;
 148                                      break;
 149                                     case 'O':
 150                                     case 'o':
 151                                      ibase = 8;
 152                                      break;
 153                                     case 'B':
 154                                     case 'b':
 155                                      ibase = 2;
 156                                      break;
 157                                     default:
 158                                      ibase = 10;
 159                                    }
 160                                    yylval.integer = bfd_scan_vma (yytext, 0,
 161                                                                   ibase);
 162                                    yylval.bigint.str = NULL;
 163                                    return INT;
 164                                  }
 165 <SCRIPT,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 166                                   char *s = yytext;
 167                                   int ibase = 0;
 168
 169                                   if (*s == '$')
 170                                     {
 171                                       ++s;
 172                                       ibase = 16;
 173                                     }
 174                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 175                                   yylval.bigint.str = NULL;
 176                                   if (yytext[yyleng - 1] == 'M'
 177                                       || yytext[yyleng - 1] == 'm')
 178                                     {
 179                                       yylval.integer *= 1024 * 1024;
 180                                     }
 181                                   else if (yytext[yyleng - 1] == 'K'
 182                                       || yytext[yyleng - 1]=='k')
 183                                     {
 184                                       yylval.integer *= 1024;
 185                                     }
 186                                   else if (yytext[0] == '0'
 187                                            && (yytext[1] == 'x'
 188                                                || yytext[1] == 'X'))
 189                                     {
 190                                       yylval.bigint.str = xstrdup (yytext + 2);
 191                                     }
 192                                   return INT;
 193                                 }
 194 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 195 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 196 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 197 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 198 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 199 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 200 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 201 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 202 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 203 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 204 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 205 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 213 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 228 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 231 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 232 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 233 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 234 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 235 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 236 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 237 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 238 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 239 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 240 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 241 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 242 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 243 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 244 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 245 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 246 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 247 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 248 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 249 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 250 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 251 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 252 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 253 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 254 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 255 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 256 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 257 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 258 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 259 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 260 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 261 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 262 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 263 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 264 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 265 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 266 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 267 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 268 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 269 <BOTH,SCRIPT>"FORCE_GROUP_ALLOCATION"   { RTOKEN(FORCE_GROUP_ALLOCATION);}
 270 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 271 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 272 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 273 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 274 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 275 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 276 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 277 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 278 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 279 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 280 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 281 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 282 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 283 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 284 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 285 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 286 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 287 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 288 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 289 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS_TO" { RTOKEN(NOCROSSREFS_TO);}
 290 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 291 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 292 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 293 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 294 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 295 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 296 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 297 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 298 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 299 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 300 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 301 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 302 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 303 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 304 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 305 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 306 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 307 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 308 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 309 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 310 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 311 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 312 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 313 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 314 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 315 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 316 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 317 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 318 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 319 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 320 <MRI>"#".*\n?                   { ++ lineno; }
 321 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 322 <MRI>"*".*                      { /* Mri comment line */ }
 323 <MRI>";".*                      { /* Mri comment line */ }
 324 <MRI>"END"                      { RTOKEN(ENDWORD); }
 325 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 326 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 327 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 328 <MRI>"BASE"                     { RTOKEN(BASE); }
 329 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 330 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 331 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 332 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 333 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 334 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 335 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 336 <MRI>"CASE"                     { RTOKEN(CASE); }
 337 <MRI>"START"                    { RTOKEN(START); }
 338 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 339 <MRI>"SECT"                     { RTOKEN(SECT); }
 340 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 341 <MRI>"end"                      { RTOKEN(ENDWORD); }
 342 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 343 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 344 <MRI>"chip"                     { RTOKEN(CHIP); }
 345 <MRI>"base"                     { RTOKEN(BASE); }
 346 <MRI>"alias"                    { RTOKEN(ALIAS); }
 347 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 348 <MRI>"load"                     { RTOKEN(LOAD); }
 349 <MRI>"public"                   { RTOKEN(PUBLIC); }
 350 <MRI>"order"                    { RTOKEN(ORDER); }
 351 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 352 <MRI>"format"                   { RTOKEN(FORMAT); }
 353 <MRI>"case"                     { RTOKEN(CASE); }
 354 <MRI>"extern"                   { RTOKEN(EXTERN); }
 355 <MRI>"start"                    { RTOKEN(START); }
 356 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 357 <MRI>"sect"                     { RTOKEN(SECT); }
 358 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 359
 360 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 361 /* Filename without commas, needed to parse mri stuff */
 362                                   yylval.name = xstrdup (yytext);
 363                                   return NAME;
 364                                 }
 365
 366
 367 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 368                                   yylval.name = xstrdup (yytext);
 369                                   return NAME;
 370                                 }
 371 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 372 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 373                                   yylval.name = xstrdup (yytext);
 374                                   return NAME;
 375                                 }
 376 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 377                                   yylval.name = xstrdup (yytext + 2);
 378                                   return LNAME;
 379                                 }
 380 <EXPRESSION>{SYMBOLNAMECHAR1}{SYMBOLNAMECHAR}* {
 381                                   yylval.name = xstrdup (yytext);
 382                                   return NAME;
 383                                 }
 384 <EXPRESSION>"/DISCARD/"         {
 385                                   yylval.name = xstrdup (yytext);
 386                                   return NAME;
 387                                 }
 388 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 389                                   yylval.name = xstrdup (yytext + 2);
 390                                   return LNAME;
 391                                 }
 392 <SCRIPT>{WILDCHAR}* {
 393                 /* Annoyingly, this pattern can match comments, and we have
 394                    longest match issues to consider.  So if the first two
 395                    characters are a comment opening, put the input back and
 396                    try again.  */
 397                 if (yytext[0] == '/' && yytext[1] == '*')
 398                   {
 399                     yyless (2);
 400                     comment ();
 401                   }
 402                 else
 403                   {
 404                     yylval.name = xstrdup (yytext);
 405                     return NAME;
 406                   }
 407         }
 408
 409 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 410                                         /* No matter the state, quotes
 411                                            give what's inside.  */
 412                                         bfd_size_type len;
 413                                         yylval.name = xstrdup (yytext + 1);
 414                                         /* PR ld/20906.  A corrupt input file
 415                                            can contain bogus strings.  */
 416                                         len = strlen (yylval.name);
 417                                         if (len > (bfd_size_type) yyleng - 2)
 418                                           len = yyleng - 2;
 419                                         yylval.name[len] = 0;
 420                                         return NAME;
 421                                 }
 422 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 423 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 424
 425 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 426
 427 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 428
 429 <VERS_NODE>local                { RTOKEN(LOCAL); }
 430
 431 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 432
 433 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 434                                   return VERS_IDENTIFIER; }
 435
 436 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 437                                   return VERS_TAG; }
 438
 439 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 440
 441 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 442                                   vers_node_nesting = 0;
 443                                   return *yytext;
 444                                 }
 445 <VERS_SCRIPT>"}"                { return *yytext; }
 446 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 447 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 448                                     BEGIN(VERS_SCRIPT);
 449                                   return *yytext;
 450                                 }
 451
 452 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n]        { lineno++; }
 453
 454 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 455
 456 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 457
 458 <<EOF>> {
 459   include_stack_ptr--;
 460   if (include_stack_ptr == 0)
 461     {
 462       lineno = 0;
 463       yyterminate ();
 464     }
 465   else
 466     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 467
 468   lineno = lineno_stack[include_stack_ptr];
 469   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 470
 471   return END;
 472 }
 473
 474 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 475 <EXPRESSION,BOTH>.      lex_warn_invalid (" in expression", yytext);
 476
 477 %%
 478 \f
 479
 480 /* Switch flex to reading script file NAME, open on FILE,
 481    saving the current input info on the include stack.  */
 482
 483 void
 484 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 485 {
 486   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 487     {
 488       einfo (_("%F:includes nested too deeply\n"));
 489     }
 490   file_name_stack[include_stack_ptr] = name;
 491   lineno_stack[include_stack_ptr] = lineno;
 492   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 493   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 494
 495   include_stack_ptr++;
 496   lineno = 1;
 497   input_flags.sysrooted = sysrooted;
 498   yyin = file;
 499   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 500 }
 501
 502 /* Return a newly created flex input buffer containing STRING,
 503    which is SIZE bytes long.  */
 504
 505 static YY_BUFFER_STATE
 506 yy_create_string_buffer (const char *string, size_t size)
 507 {
 508   YY_BUFFER_STATE b;
 509
 510   b = xmalloc (sizeof (struct yy_buffer_state));
 511   b->yy_input_file = 0;
 512   b->yy_buf_size = size;
 513
 514   /* yy_ch_buf has to be 2 characters longer than the size given because
 515      we need to put in 2 end-of-buffer characters.  */
 516   b->yy_ch_buf = xmalloc ((size_t) b->yy_buf_size + 3);
 517
 518   b->yy_ch_buf[0] = '\n';
 519   strcpy (b->yy_ch_buf+1, string);
 520   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 521   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 522   b->yy_n_chars = size+1;
 523   b->yy_buf_pos = &b->yy_ch_buf[1];
 524
 525   b->yy_is_our_buffer = 1;
 526   b->yy_is_interactive = 0;
 527   b->yy_at_bol = 1;
 528   b->yy_fill_buffer = 0;
 529
 530   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 531      a flex internal interface in the first place!  */
 532 #ifdef YY_BUFFER_NEW
 533   b->yy_buffer_status = YY_BUFFER_NEW;
 534 #else
 535   b->yy_eof_status = EOF_NOT_SEEN;
 536 #endif
 537
 538   return b;
 539 }
 540
 541 /* Switch flex to reading from STRING, saving the current input info
 542    on the include stack.  */
 543
 544 void
 545 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 546 {
 547   YY_BUFFER_STATE tmp;
 548
 549   yy_init = 0;
 550   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 551     {
 552       einfo (_("%F: macros nested too deeply\n"));
 553     }
 554   file_name_stack[include_stack_ptr] = fake_filename;
 555   lineno_stack[include_stack_ptr] = lineno;
 556   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 557   include_stack_ptr++;
 558   lineno = count;
 559   tmp = yy_create_string_buffer (string, strlen (string));
 560   yy_switch_to_buffer (tmp);
 561 }
 562 \f
 563 /* Functions to switch to a different flex start condition,
 564    saving the current start condition on `state_stack'.  */
 565
 566 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 567 static int *state_stack_p = state_stack;
 568
 569 void
 570 ldlex_script (void)
 571 {
 572   *(state_stack_p)++ = yy_start;
 573   BEGIN (SCRIPT);
 574 }
 575
 576 void
 577 ldlex_inputlist (void)
 578 {
 579   *(state_stack_p)++ = yy_start;
 580   BEGIN (INPUTLIST);
 581 }
 582
 583 void
 584 ldlex_mri_script (void)
 585 {
 586   *(state_stack_p)++ = yy_start;
 587   BEGIN (MRI);
 588 }
 589
 590 void
 591 ldlex_version_script (void)
 592 {
 593   *(state_stack_p)++ = yy_start;
 594   BEGIN (VERS_START);
 595 }
 596
 597 void
 598 ldlex_version_file (void)
 599 {
 600   *(state_stack_p)++ = yy_start;
 601   BEGIN (VERS_SCRIPT);
 602 }
 603
 604 void
 605 ldlex_expression (void)
 606 {
 607   *(state_stack_p)++ = yy_start;
 608   BEGIN (EXPRESSION);
 609 }
 610
 611 void
 612 ldlex_both (void)
 613 {
 614   *(state_stack_p)++ = yy_start;
 615   BEGIN (BOTH);
 616 }
 617
 618 void
 619 ldlex_popstate (void)
 620 {
 621   yy_start = *(--state_stack_p);
 622 }
 623
 624 /* In cases where the parser needs to look ahead and the context
 625    changes from expression to script or vice-versa, throw away a
 626    NAME.  What constitutes a NAME depends on context.  */
 627
 628 void
 629 ldlex_backup (void)
 630 {
 631   yyless (0);
 632 }
 633
 634 /* Return the current file name, or the previous file if no file is
 635    current.  */
 636
 637 const char*
 638 ldlex_filename (void)
 639 {
 640   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 641 }
 642 \f
 643
 644 /* Place up to MAX_SIZE characters in BUF and return
 645    either the number of characters read, or 0 to indicate EOF.  */
 646
 647 static int
 648 yy_input (char *buf, int max_size)
 649 {
 650   int result = 0;
 651   if (YY_CURRENT_BUFFER->yy_input_file)
 652     {
 653       if (yyin)
 654         {
 655           result = fread (buf, 1, max_size, yyin);
 656           if (result < max_size && ferror (yyin))
 657             einfo (_("%F%P: read in flex scanner failed\n"));
 658         }
 659     }
 660   return result;
 661 }
 662
 663 /* Eat the rest of a C-style comment.  */
 664
 665 static void
 666 comment (void)
 667 {
 668   int c;
 669
 670   while (1)
 671     {
 672       c = input();
 673       while (c != '*' && c != 0)
 674         {
 675           if (c == '\n')
 676             lineno++;
 677           c = input();
 678         }
 679
 680       if (c == '*')
 681         {
 682           c = input();
 683           while (c == '*')
 684             c = input();
 685           if (c == '/')
 686             break;                      /* found the end */
 687         }
 688
 689       if (c == '\n')
 690         lineno++;
 691
 692       if (c == 0)
 693         {
 694           einfo (_("%F%P: EOF in comment\n"));
 695           break;
 696         }
 697     }
 698 }
 699
 700 /* Warn the user about a garbage character WHAT in the input
 701    in context WHERE.  */
 702
 703 static void
 704 lex_warn_invalid (char *where, char *what)
 705 {
 706   char buf[5];
 707
 708   /* If we have found an input file whose format we do not recognize,
 709      and we are therefore treating it as a linker script, and we find
 710      an invalid character, then most likely this is a real object file
 711      of some different format.  Treat it as such.  */
 712   if (ldfile_assumed_script)
 713     {
 714       bfd_set_error (bfd_error_file_not_recognized);
 715       einfo (_("%F%s: file not recognized: %E\n"), ldlex_filename ());
 716     }
 717
 718   if (! ISPRINT (*what))
 719     {
 720       sprintf (buf, "\\%03o", *(unsigned char *) what);
 721       what = buf;
 722     }
 723
 724   einfo (_("%P:%pS: ignoring invalid character `%s'%s\n"), NULL, what, where);
 725 }