ld/ldlex.l

   1 %option nounput
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2014 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ld.h"
  29 #include "ldmisc.h"
  30 #include "ldexp.h"
  31 #include "ldlang.h"
  32 #include <ldgram.h>
  33 #include "ldfile.h"
  34 #include "ldlex.h"
  35 #include "ldmain.h"
  36 #include "libiberty.h"
  37
  38 /* The type of top-level parser input.
  39    yylex and yyparse (indirectly) both check this.  */
  40 input_type parser_input;
  41
  42 /* Line number in the current input file.
  43    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  44 unsigned int lineno = 1;
  45
  46 /* The string we are currently lexing, or NULL if we are reading a
  47    file.  */
  48 const char *lex_string = NULL;
  49
  50 /* Support for flex reading from more than one input file (stream).
  51    `include_stack' is flex's input state for each open file;
  52    `file_name_stack' is the file names.  `lineno_stack' is the current
  53    line numbers.
  54
  55    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  56    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  57
  58 #undef YY_INPUT
  59 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  60
  61 #ifndef YY_NO_UNPUT
  62 #define YY_NO_UNPUT
  63 #endif
  64
  65 #define MAX_INCLUDE_DEPTH 10
  66 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  67 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  70 static unsigned int include_stack_ptr = 0;
  71 static int vers_node_nesting = 0;
  72
  73 static int yy_input (char *, int);
  74 static void comment (void);
  75 static void lex_warn_invalid (char *where, char *what);
  76
  77 /* STATES
  78         EXPRESSION      definitely in an expression
  79         SCRIPT          definitely in a script
  80         BOTH            either EXPRESSION or SCRIPT
  81         DEFSYMEXP       in an argument to -defsym
  82         MRI             in an MRI script
  83         VERS_START      starting a Sun style mapfile
  84         VERS_SCRIPT     a Sun style mapfile
  85         VERS_NODE       a node within a Sun style mapfile
  86 */
  87 #define RTOKEN(x)  {  yylval.token = x; return x; }
  88
  89 /* Some versions of flex want this.  */
  90 #ifndef yywrap
  91 int yywrap (void) { return 1; }
  92 #endif
  93 %}
  94
  95 %a 4000
  96 %o 5000
  97
  98 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  99 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 100 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 101 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 102 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 103 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
 104 WHITE           [ \t\n\r]+
 105
 106 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 107
 108 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 109 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 110
 111 %s SCRIPT
 112 %s EXPRESSION
 113 %s BOTH
 114 %s DEFSYMEXP
 115 %s MRI
 116 %s VERS_START
 117 %s VERS_SCRIPT
 118 %s VERS_NODE
 119 %%
 120
 121   if (parser_input != input_selected)
 122     {
 123       /* The first token of the input determines the initial parser state.  */
 124       input_type t = parser_input;
 125       parser_input = input_selected;
 126       switch (t)
 127         {
 128         case input_script: return INPUT_SCRIPT; break;
 129         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 130         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 131         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 132         case input_defsym: return INPUT_DEFSYM; break;
 133         default: abort ();
 134         }
 135     }
 136
 137 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 138
 139
 140 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 141 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 142 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 143 <DEFSYMEXP>"="                  { RTOKEN('='); }
 144
 145 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 146                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 147                                 yylval.bigint.str = NULL;
 148                                 return INT;
 149                         }
 150
 151 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 152                                    int ibase ;
 153                                    switch (yytext[yyleng - 1]) {
 154                                     case 'X':
 155                                     case 'x':
 156                                     case 'H':
 157                                     case 'h':
 158                                      ibase = 16;
 159                                      break;
 160                                     case 'O':
 161                                     case 'o':
 162                                      ibase = 8;
 163                                      break;
 164                                     case 'B':
 165                                     case 'b':
 166                                      ibase = 2;
 167                                      break;
 168                                     default:
 169                                      ibase = 10;
 170                                    }
 171                                    yylval.integer = bfd_scan_vma (yytext, 0,
 172                                                                   ibase);
 173                                    yylval.bigint.str = NULL;
 174                                    return INT;
 175                                  }
 176 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 177                                   char *s = yytext;
 178                                   int ibase = 0;
 179
 180                                   if (*s == '$')
 181                                     {
 182                                       ++s;
 183                                       ibase = 16;
 184                                     }
 185                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 186                                   yylval.bigint.str = NULL;
 187                                   if (yytext[yyleng - 1] == 'M'
 188                                       || yytext[yyleng - 1] == 'm')
 189                                     {
 190                                       yylval.integer *= 1024 * 1024;
 191                                     }
 192                                   else if (yytext[yyleng - 1] == 'K'
 193                                       || yytext[yyleng - 1]=='k')
 194                                     {
 195                                       yylval.integer *= 1024;
 196                                     }
 197                                   else if (yytext[0] == '0'
 198                                            && (yytext[1] == 'x'
 199                                                || yytext[1] == 'X'))
 200                                     {
 201                                       yylval.bigint.str = xstrdup (yytext + 2);
 202                                     }
 203                                   return INT;
 204                                 }
 205 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>")"         { RTOKEN(')');}
 240 <BOTH,SCRIPT,EXPRESSION,MRI>"("         { RTOKEN('(');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 242 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 243 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 244 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 245 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 246 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 247 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 248 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 249 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 250 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 251 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 252 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 254 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 255 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 256 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 257 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 258 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 259 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 260 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 261 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 262 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 263 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 264 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 265 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 266 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 267 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 268 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 269 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 270 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 271 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 272 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 273 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 274 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 275 <EXPRESSION,BOTH,SCRIPT>"AS_NEEDED"     { RTOKEN(AS_NEEDED);}
 276 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 277 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 278 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 279 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 280 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 281 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 282 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 283 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 284 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 285 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 286 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 287 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 288 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 289 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 290 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 291 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 292 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 293 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 294 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 295 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 296 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 297 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 298 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 299 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 300 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 301 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 302 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 303 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 304 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 305 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 306 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 307 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 308 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 309 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 310 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 311 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 312 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 313 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 314 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 315 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 316 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 317 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 318 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 319 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 320 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 321 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 322 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 323 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 324 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 325 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 326 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 327 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 328 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 329 <MRI>"#".*\n?                   { ++ lineno; }
 330 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 331 <MRI>"*".*                      { /* Mri comment line */ }
 332 <MRI>";".*                      { /* Mri comment line */ }
 333 <MRI>"END"                      { RTOKEN(ENDWORD); }
 334 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 335 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 336 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 337 <MRI>"BASE"                     { RTOKEN(BASE); }
 338 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 339 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 340 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 341 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 342 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 343 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 344 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 345 <MRI>"CASE"                     { RTOKEN(CASE); }
 346 <MRI>"START"                    { RTOKEN(START); }
 347 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 348 <MRI>"SECT"                     { RTOKEN(SECT); }
 349 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 350 <MRI>"end"                      { RTOKEN(ENDWORD); }
 351 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 352 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 353 <MRI>"chip"                     { RTOKEN(CHIP); }
 354 <MRI>"base"                     { RTOKEN(BASE); }
 355 <MRI>"alias"                    { RTOKEN(ALIAS); }
 356 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 357 <MRI>"load"                     { RTOKEN(LOAD); }
 358 <MRI>"public"                   { RTOKEN(PUBLIC); }
 359 <MRI>"order"                    { RTOKEN(ORDER); }
 360 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 361 <MRI>"format"                   { RTOKEN(FORMAT); }
 362 <MRI>"case"                     { RTOKEN(CASE); }
 363 <MRI>"extern"                   { RTOKEN(EXTERN); }
 364 <MRI>"start"                    { RTOKEN(START); }
 365 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 366 <MRI>"sect"                     { RTOKEN(SECT); }
 367 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 368
 369 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 370 /* Filename without commas, needed to parse mri stuff */
 371                                  yylval.name = xstrdup (yytext);
 372                                   return NAME;
 373                                 }
 374
 375
 376 <BOTH>{FILENAMECHAR1}{FILENAMECHAR}*    {
 377                                  yylval.name = xstrdup (yytext);
 378                                   return NAME;
 379                                 }
 380 <BOTH>"-l"{FILENAMECHAR}+ {
 381                                   yylval.name = xstrdup (yytext + 2);
 382                                   return LNAME;
 383                                 }
 384 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 385                                  yylval.name = xstrdup (yytext);
 386                                   return NAME;
 387                                 }
 388 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 389                                   yylval.name = xstrdup (yytext + 2);
 390                                   return LNAME;
 391                                 }
 392 <SCRIPT>{WILDCHAR}* {
 393                 /* Annoyingly, this pattern can match comments, and we have
 394                    longest match issues to consider.  So if the first two
 395                    characters are a comment opening, put the input back and
 396                    try again.  */
 397                 if (yytext[0] == '/' && yytext[1] == '*')
 398                   {
 399                     yyless (2);
 400                     comment ();
 401                   }
 402                 else
 403                   {
 404                     yylval.name = xstrdup (yytext);
 405                     return NAME;
 406                   }
 407         }
 408
 409 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 410                                         /* No matter the state, quotes
 411                                            give what's inside */
 412                                         yylval.name = xstrdup (yytext + 1);
 413                                         yylval.name[yyleng - 2] = 0;
 414                                         return NAME;
 415                                 }
 416 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 417 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 418
 419 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 420
 421 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 422
 423 <VERS_NODE>local                { RTOKEN(LOCAL); }
 424
 425 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 426
 427 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 428                                   return VERS_IDENTIFIER; }
 429
 430 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 431                                   return VERS_TAG; }
 432
 433 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 434
 435 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 436                                   vers_node_nesting = 0;
 437                                   return *yytext;
 438                                 }
 439 <VERS_SCRIPT>"}"                { return *yytext; }
 440 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 441 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 442                                     BEGIN(VERS_SCRIPT);
 443                                   return *yytext;
 444                                 }
 445
 446 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 447
 448 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 449
 450 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 451
 452 <<EOF>> {
 453   include_stack_ptr--;
 454   if (include_stack_ptr == 0)
 455     yyterminate ();
 456   else
 457     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 458
 459   lineno = lineno_stack[include_stack_ptr];
 460   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 461
 462   return END;
 463 }
 464
 465 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 466 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 467
 468 %%
 469 \f
 470
 471 /* Switch flex to reading script file NAME, open on FILE,
 472    saving the current input info on the include stack.  */
 473
 474 void
 475 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 476 {
 477   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 478     {
 479       einfo ("%F:includes nested too deeply\n");
 480     }
 481   file_name_stack[include_stack_ptr] = name;
 482   lineno_stack[include_stack_ptr] = lineno;
 483   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 484   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 485
 486   include_stack_ptr++;
 487   lineno = 1;
 488   input_flags.sysrooted = sysrooted;
 489   yyin = file;
 490   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 491 }
 492
 493 /* Return a newly created flex input buffer containing STRING,
 494    which is SIZE bytes long.  */
 495
 496 static YY_BUFFER_STATE
 497 yy_create_string_buffer (const char *string, size_t size)
 498 {
 499   YY_BUFFER_STATE b;
 500
 501   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 502   b = malloc (sizeof (struct yy_buffer_state));
 503   b->yy_input_file = 0;
 504   b->yy_buf_size = size;
 505
 506   /* yy_ch_buf has to be 2 characters longer than the size given because
 507      we need to put in 2 end-of-buffer characters.  */
 508   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 509
 510   b->yy_ch_buf[0] = '\n';
 511   strcpy (b->yy_ch_buf+1, string);
 512   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 513   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 514   b->yy_n_chars = size+1;
 515   b->yy_buf_pos = &b->yy_ch_buf[1];
 516
 517   b->yy_is_our_buffer = 1;
 518   b->yy_is_interactive = 0;
 519   b->yy_at_bol = 1;
 520   b->yy_fill_buffer = 0;
 521
 522   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 523      a flex internal interface in the first place!  */
 524 #ifdef YY_BUFFER_NEW
 525   b->yy_buffer_status = YY_BUFFER_NEW;
 526 #else
 527   b->yy_eof_status = EOF_NOT_SEEN;
 528 #endif
 529
 530   return b;
 531 }
 532
 533 /* Switch flex to reading from STRING, saving the current input info
 534    on the include stack.  */
 535
 536 void
 537 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 538 {
 539   YY_BUFFER_STATE tmp;
 540
 541   yy_init = 0;
 542   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 543     {
 544       einfo("%F: macros nested too deeply\n");
 545     }
 546   file_name_stack[include_stack_ptr] = fake_filename;
 547   lineno_stack[include_stack_ptr] = lineno;
 548   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 549   include_stack_ptr++;
 550   lineno = count;
 551   tmp = yy_create_string_buffer (string, strlen (string));
 552   yy_switch_to_buffer (tmp);
 553 }
 554 \f
 555 /* Functions to switch to a different flex start condition,
 556    saving the current start condition on `state_stack'.  */
 557
 558 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 559 static int *state_stack_p = state_stack;
 560
 561 void
 562 ldlex_script (void)
 563 {
 564   *(state_stack_p)++ = yy_start;
 565   BEGIN (SCRIPT);
 566 }
 567
 568 void
 569 ldlex_mri_script (void)
 570 {
 571   *(state_stack_p)++ = yy_start;
 572   BEGIN (MRI);
 573 }
 574
 575 void
 576 ldlex_version_script (void)
 577 {
 578   *(state_stack_p)++ = yy_start;
 579   BEGIN (VERS_START);
 580 }
 581
 582 void
 583 ldlex_version_file (void)
 584 {
 585   *(state_stack_p)++ = yy_start;
 586   BEGIN (VERS_SCRIPT);
 587 }
 588
 589 void
 590 ldlex_defsym (void)
 591 {
 592   *(state_stack_p)++ = yy_start;
 593   BEGIN (DEFSYMEXP);
 594 }
 595
 596 void
 597 ldlex_expression (void)
 598 {
 599   *(state_stack_p)++ = yy_start;
 600   BEGIN (EXPRESSION);
 601 }
 602
 603 void
 604 ldlex_both (void)
 605 {
 606   *(state_stack_p)++ = yy_start;
 607   BEGIN (BOTH);
 608 }
 609
 610 void
 611 ldlex_popstate (void)
 612 {
 613   yy_start = *(--state_stack_p);
 614 }
 615
 616 /* Return the current file name, or the previous file if no file is
 617    current.  */
 618
 619 const char*
 620 ldlex_filename (void)
 621 {
 622   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 623 }
 624 \f
 625
 626 /* Place up to MAX_SIZE characters in BUF and return
 627    either the number of characters read, or 0 to indicate EOF.  */
 628
 629 static int
 630 yy_input (char *buf, int max_size)
 631 {
 632   int result = 0;
 633   if (YY_CURRENT_BUFFER->yy_input_file)
 634     {
 635       if (yyin)
 636         {
 637           result = fread (buf, 1, max_size, yyin);
 638           if (result < max_size && ferror (yyin))
 639             einfo ("%F%P: read in flex scanner failed\n");
 640         }
 641     }
 642   return result;
 643 }
 644
 645 /* Eat the rest of a C-style comment.  */
 646
 647 static void
 648 comment (void)
 649 {
 650   int c;
 651
 652   while (1)
 653   {
 654     c = input();
 655     while (c != '*' && c != EOF)
 656     {
 657       if (c == '\n')
 658         lineno++;
 659       c = input();
 660     }
 661
 662     if (c == '*')
 663     {
 664       c = input();
 665       while (c == '*')
 666        c = input();
 667       if (c == '/')
 668        break;                   /* found the end */
 669     }
 670
 671     if (c == '\n')
 672       lineno++;
 673
 674     if (c == EOF)
 675     {
 676       einfo( "%F%P: EOF in comment\n");
 677       break;
 678     }
 679   }
 680 }
 681
 682 /* Warn the user about a garbage character WHAT in the input
 683    in context WHERE.  */
 684
 685 static void
 686 lex_warn_invalid (char *where, char *what)
 687 {
 688   char buf[5];
 689
 690   /* If we have found an input file whose format we do not recognize,
 691      and we are therefore treating it as a linker script, and we find
 692      an invalid character, then most likely this is a real object file
 693      of some different format.  Treat it as such.  */
 694   if (ldfile_assumed_script)
 695     {
 696       bfd_set_error (bfd_error_file_not_recognized);
 697       einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
 698     }
 699
 700   if (! ISPRINT (*what))
 701     {
 702       sprintf (buf, "\\%03o", *(unsigned char *) what);
 703       what = buf;
 704     }
 705
 706   einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
 707 }