ld/ldlex.l

   1 %option nounput
   2
   3 %{
   4
   5 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   6    2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   7    Free Software Foundation, Inc.
   8    Written by Steve Chamberlain of Cygnus Support.
   9
  10    This file is part of the GNU Binutils.
  11
  12    This program is free software; you can redistribute it and/or modify
  13    it under the terms of the GNU General Public License as published by
  14    the Free Software Foundation; either version 3 of the License, or
  15    (at your option) any later version.
  16
  17    This program is distributed in the hope that it will be useful,
  18    but WITHOUT ANY WARRANTY; without even the implied warranty of
  19    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20    GNU General Public License for more details.
  21
  22    You should have received a copy of the GNU General Public License
  23    along with this program; if not, write to the Free Software
  24    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  25    MA 02110-1301, USA.  */
  26
  27 #include "sysdep.h"
  28 #include "bfd.h"
  29 #include "safe-ctype.h"
  30 #include "bfdlink.h"
  31 #include "ld.h"
  32 #include "ldmisc.h"
  33 #include "ldexp.h"
  34 #include "ldlang.h"
  35 #include <ldgram.h>
  36 #include "ldfile.h"
  37 #include "ldlex.h"
  38 #include "ldmain.h"
  39 #include "libiberty.h"
  40
  41 /* The type of top-level parser input.
  42    yylex and yyparse (indirectly) both check this.  */
  43 input_type parser_input;
  44
  45 /* Line number in the current input file.
  46    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  47 unsigned int lineno = 1;
  48
  49 /* The string we are currently lexing, or NULL if we are reading a
  50    file.  */
  51 const char *lex_string = NULL;
  52
  53 /* Support for flex reading from more than one input file (stream).
  54    `include_stack' is flex's input state for each open file;
  55    `file_name_stack' is the file names.  `lineno_stack' is the current
  56    line numbers.
  57
  58    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  59    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  60
  61 #undef YY_INPUT
  62 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  63
  64 #define YY_NO_UNPUT
  65
  66 #define MAX_INCLUDE_DEPTH 10
  67 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  68 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  70 static unsigned int include_stack_ptr = 0;
  71 static int vers_node_nesting = 0;
  72
  73 static int yy_input (char *, int);
  74 static void comment (void);
  75 static void lex_warn_invalid (char *where, char *what);
  76
  77 /* STATES
  78         EXPRESSION      definitely in an expression
  79         SCRIPT          definitely in a script
  80         BOTH            either EXPRESSION or SCRIPT
  81         DEFSYMEXP       in an argument to -defsym
  82         MRI             in an MRI script
  83         VERS_START      starting a Sun style mapfile
  84         VERS_SCRIPT     a Sun style mapfile
  85         VERS_NODE       a node within a Sun style mapfile
  86 */
  87 #define RTOKEN(x)  {  yylval.token = x; return x; }
  88
  89 /* Some versions of flex want this.  */
  90 #ifndef yywrap
  91 int yywrap (void) { return 1; }
  92 #endif
  93 %}
  94
  95 %a 4000
  96 %o 5000
  97
  98 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  99 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 100 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 101 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 102 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 103 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 104 WHITE           [ \t\n\r]+
 105
 106 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 107
 108 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 109 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 110
 111 %s SCRIPT
 112 %s EXPRESSION
 113 %s BOTH
 114 %s DEFSYMEXP
 115 %s MRI
 116 %s VERS_START
 117 %s VERS_SCRIPT
 118 %s VERS_NODE
 119 %%
 120
 121   if (parser_input != input_selected)
 122     {
 123       /* The first token of the input determines the initial parser state.  */
 124       input_type t = parser_input;
 125       parser_input = input_selected;
 126       switch (t)
 127         {
 128         case input_script: return INPUT_SCRIPT; break;
 129         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 130         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 131         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 132         case input_defsym: return INPUT_DEFSYM; break;
 133         default: abort ();
 134         }
 135     }
 136
 137 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 138
 139
 140 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 141 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 142 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 143 <DEFSYMEXP>"="                  { RTOKEN('='); }
 144
 145 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 146                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 147                                 yylval.bigint.str = NULL;
 148                                 return INT;
 149                         }
 150
 151 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 152                                    int ibase ;
 153                                    switch (yytext[yyleng - 1]) {
 154                                     case 'X':
 155                                     case 'x':
 156                                     case 'H':
 157                                     case 'h':
 158                                      ibase = 16;
 159                                      break;
 160                                     case 'O':
 161                                     case 'o':
 162                                      ibase = 8;
 163                                      break;
 164                                     case 'B':
 165                                     case 'b':
 166                                      ibase = 2;
 167                                      break;
 168                                     default:
 169                                      ibase = 10;
 170                                    }
 171                                    yylval.integer = bfd_scan_vma (yytext, 0,
 172                                                                   ibase);
 173                                    yylval.bigint.str = NULL;
 174                                    return INT;
 175                                  }
 176 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 177                                   char *s = yytext;
 178                                   int ibase = 0;
 179
 180                                   if (*s == '$')
 181                                     {
 182                                       ++s;
 183                                       ibase = 16;
 184                                     }
 185                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 186                                   yylval.bigint.str = NULL;
 187                                   if (yytext[yyleng - 1] == 'M'
 188                                       || yytext[yyleng - 1] == 'm')
 189                                     {
 190                                       yylval.integer *= 1024 * 1024;
 191                                     }
 192                                   else if (yytext[yyleng - 1] == 'K'
 193                                       || yytext[yyleng - 1]=='k')
 194                                     {
 195                                       yylval.integer *= 1024;
 196                                     }
 197                                   else if (yytext[0] == '0'
 198                                            && (yytext[1] == 'x'
 199                                                || yytext[1] == 'X'))
 200                                     {
 201                                       yylval.bigint.str = xstrdup (yytext + 2);
 202                                     }
 203                                   return INT;
 204                                 }
 205 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>")"         { RTOKEN(')');}
 240 <BOTH,SCRIPT,EXPRESSION,MRI>"("         { RTOKEN('(');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 242 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 243 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 244 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 245 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 246 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 247 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 248 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 249 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 250 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 252 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 254 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 255 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 256 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 257 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 258 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 259 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 260 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 261 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 262 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 263 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 264 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 265 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 266 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 267 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 268 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 269 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 270 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 271 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 272 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 273 <EXPRESSION,BOTH,SCRIPT>"AS_NEEDED"     { RTOKEN(AS_NEEDED);}
 274 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 275 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 276 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 277 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 278 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 279 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 280 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 281 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 282 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 283 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 284 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 285 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 286 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 287 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 288 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 289 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 290 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 291 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 292 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 293 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 294 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 295 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 296 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 297 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 298 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 299 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 300 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 301 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 302 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 303 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 304 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 305 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 306 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 307 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 308 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 309 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 310 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 311 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 312 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 313 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 314 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 315 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 316 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 317 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 318 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 319 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 320 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 321 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 322 <MRI>"#".*\n?                   { ++ lineno; }
 323 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 324 <MRI>"*".*                      { /* Mri comment line */ }
 325 <MRI>";".*                      { /* Mri comment line */ }
 326 <MRI>"END"                      { RTOKEN(ENDWORD); }
 327 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 328 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 329 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 330 <MRI>"BASE"                     { RTOKEN(BASE); }
 331 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 332 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 333 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 334 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 335 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 336 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 337 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 338 <MRI>"CASE"                     { RTOKEN(CASE); }
 339 <MRI>"START"                    { RTOKEN(START); }
 340 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 341 <MRI>"SECT"                     { RTOKEN(SECT); }
 342 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 343 <MRI>"end"                      { RTOKEN(ENDWORD); }
 344 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 345 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 346 <MRI>"chip"                     { RTOKEN(CHIP); }
 347 <MRI>"base"                     { RTOKEN(BASE); }
 348 <MRI>"alias"                    { RTOKEN(ALIAS); }
 349 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 350 <MRI>"load"                     { RTOKEN(LOAD); }
 351 <MRI>"public"                   { RTOKEN(PUBLIC); }
 352 <MRI>"order"                    { RTOKEN(ORDER); }
 353 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 354 <MRI>"format"                   { RTOKEN(FORMAT); }
 355 <MRI>"case"                     { RTOKEN(CASE); }
 356 <MRI>"extern"                   { RTOKEN(EXTERN); }
 357 <MRI>"start"                    { RTOKEN(START); }
 358 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 359 <MRI>"sect"                     { RTOKEN(SECT); }
 360 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 361
 362 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 363 /* Filename without commas, needed to parse mri stuff */
 364                                  yylval.name = xstrdup (yytext);
 365                                   return NAME;
 366                                 }
 367
 368
 369 <BOTH>{FILENAMECHAR1}{FILENAMECHAR}*    {
 370                                  yylval.name = xstrdup (yytext);
 371                                   return NAME;
 372                                 }
 373 <BOTH>"-l"{FILENAMECHAR}+ {
 374                                   yylval.name = xstrdup (yytext + 2);
 375                                   return LNAME;
 376                                 }
 377 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 378                                  yylval.name = xstrdup (yytext);
 379                                   return NAME;
 380                                 }
 381 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 382                                   yylval.name = xstrdup (yytext + 2);
 383                                   return LNAME;
 384                                 }
 385 <SCRIPT>{WILDCHAR}* {
 386                 /* Annoyingly, this pattern can match comments, and we have
 387                    longest match issues to consider.  So if the first two
 388                    characters are a comment opening, put the input back and
 389                    try again.  */
 390                 if (yytext[0] == '/' && yytext[1] == '*')
 391                   {
 392                     yyless (2);
 393                     comment ();
 394                   }
 395                 else
 396                   {
 397                     yylval.name = xstrdup (yytext);
 398                     return NAME;
 399                   }
 400         }
 401
 402 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 403                                         /* No matter the state, quotes
 404                                            give what's inside */
 405                                         yylval.name = xstrdup (yytext + 1);
 406                                         yylval.name[yyleng - 2] = 0;
 407                                         return NAME;
 408                                 }
 409 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 410 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 411
 412 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 413
 414 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 415
 416 <VERS_NODE>local                { RTOKEN(LOCAL); }
 417
 418 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 419
 420 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 421                                   return VERS_IDENTIFIER; }
 422
 423 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 424                                   return VERS_TAG; }
 425
 426 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 427
 428 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 429                                   vers_node_nesting = 0;
 430                                   return *yytext;
 431                                 }
 432 <VERS_SCRIPT>"}"                { return *yytext; }
 433 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 434 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 435                                     BEGIN(VERS_SCRIPT);
 436                                   return *yytext;
 437                                 }
 438
 439 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 440
 441 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 442
 443 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 444
 445 <<EOF>> {
 446   include_stack_ptr--;
 447
 448   if (include_stack_ptr == 0)
 449   {
 450     yyterminate ();
 451   }
 452   else
 453   {
 454     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 455   }
 456
 457   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 458   lineno = lineno_stack[include_stack_ptr];
 459
 460   return END;
 461 }
 462
 463 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 464 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 465
 466 %%
 467 \f
 468
 469 /* Switch flex to reading script file NAME, open on FILE,
 470    saving the current input info on the include stack.  */
 471
 472 void
 473 lex_push_file (FILE *file, const char *name)
 474 {
 475   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 476     {
 477       einfo ("%F:includes nested too deeply\n");
 478     }
 479   file_name_stack[include_stack_ptr] = name;
 480   lineno_stack[include_stack_ptr] = lineno;
 481   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 482
 483   include_stack_ptr++;
 484   lineno = 1;
 485   yyin = file;
 486   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 487 }
 488
 489 /* Return a newly created flex input buffer containing STRING,
 490    which is SIZE bytes long.  */
 491
 492 static YY_BUFFER_STATE
 493 yy_create_string_buffer (const char *string, size_t size)
 494 {
 495   YY_BUFFER_STATE b;
 496
 497   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 498   b = malloc (sizeof (struct yy_buffer_state));
 499   b->yy_input_file = 0;
 500   b->yy_buf_size = size;
 501
 502   /* yy_ch_buf has to be 2 characters longer than the size given because
 503      we need to put in 2 end-of-buffer characters.  */
 504   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 505
 506   b->yy_ch_buf[0] = '\n';
 507   strcpy (b->yy_ch_buf+1, string);
 508   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 509   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 510   b->yy_n_chars = size+1;
 511   b->yy_buf_pos = &b->yy_ch_buf[1];
 512
 513   b->yy_is_our_buffer = 1;
 514   b->yy_is_interactive = 0;
 515   b->yy_at_bol = 1;
 516   b->yy_fill_buffer = 0;
 517
 518   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 519      a flex internal interface in the first place!  */
 520 #ifdef YY_BUFFER_NEW
 521   b->yy_buffer_status = YY_BUFFER_NEW;
 522 #else
 523   b->yy_eof_status = EOF_NOT_SEEN;
 524 #endif
 525
 526   return b;
 527 }
 528
 529 /* Switch flex to reading from STRING, saving the current input info
 530    on the include stack.  */
 531
 532 void
 533 lex_redirect (const char *string)
 534 {
 535   YY_BUFFER_STATE tmp;
 536
 537   yy_init = 0;
 538   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 539     {
 540       einfo("%F: macros nested too deeply\n");
 541     }
 542   file_name_stack[include_stack_ptr] = "redirect";
 543   lineno_stack[include_stack_ptr] = lineno;
 544   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 545   include_stack_ptr++;
 546   lineno = 1;
 547   tmp = yy_create_string_buffer (string, strlen (string));
 548   yy_switch_to_buffer (tmp);
 549 }
 550 \f
 551 /* Functions to switch to a different flex start condition,
 552    saving the current start condition on `state_stack'.  */
 553
 554 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 555 static int *state_stack_p = state_stack;
 556
 557 void
 558 ldlex_script (void)
 559 {
 560   *(state_stack_p)++ = yy_start;
 561   BEGIN (SCRIPT);
 562 }
 563
 564 void
 565 ldlex_mri_script (void)
 566 {
 567   *(state_stack_p)++ = yy_start;
 568   BEGIN (MRI);
 569 }
 570
 571 void
 572 ldlex_version_script (void)
 573 {
 574   *(state_stack_p)++ = yy_start;
 575   BEGIN (VERS_START);
 576 }
 577
 578 void
 579 ldlex_version_file (void)
 580 {
 581   *(state_stack_p)++ = yy_start;
 582   BEGIN (VERS_SCRIPT);
 583 }
 584
 585 void
 586 ldlex_defsym (void)
 587 {
 588   *(state_stack_p)++ = yy_start;
 589   BEGIN (DEFSYMEXP);
 590 }
 591
 592 void
 593 ldlex_expression (void)
 594 {
 595   *(state_stack_p)++ = yy_start;
 596   BEGIN (EXPRESSION);
 597 }
 598
 599 void
 600 ldlex_both (void)
 601 {
 602   *(state_stack_p)++ = yy_start;
 603   BEGIN (BOTH);
 604 }
 605
 606 void
 607 ldlex_popstate (void)
 608 {
 609   yy_start = *(--state_stack_p);
 610 }
 611 \f
 612
 613 /* Place up to MAX_SIZE characters in BUF and return
 614    either the number of characters read, or 0 to indicate EOF.  */
 615
 616 static int
 617 yy_input (char *buf, int max_size)
 618 {
 619   int result = 0;
 620   if (YY_CURRENT_BUFFER->yy_input_file)
 621     {
 622       if (yyin)
 623         {
 624           result = fread (buf, 1, max_size, yyin);
 625           if (result < max_size && ferror (yyin))
 626             einfo ("%F%P: read in flex scanner failed\n");
 627         }
 628     }
 629   return result;
 630 }
 631
 632 /* Eat the rest of a C-style comment.  */
 633
 634 static void
 635 comment (void)
 636 {
 637   int c;
 638
 639   while (1)
 640   {
 641     c = input();
 642     while (c != '*' && c != EOF)
 643     {
 644       if (c == '\n')
 645         lineno++;
 646       c = input();
 647     }
 648
 649     if (c == '*')
 650     {
 651       c = input();
 652       while (c == '*')
 653        c = input();
 654       if (c == '/')
 655        break;                   /* found the end */
 656     }
 657
 658     if (c == '\n')
 659       lineno++;
 660
 661     if (c == EOF)
 662     {
 663       einfo( "%F%P: EOF in comment\n");
 664       break;
 665     }
 666   }
 667 }
 668
 669 /* Warn the user about a garbage character WHAT in the input
 670    in context WHERE.  */
 671
 672 static void
 673 lex_warn_invalid (char *where, char *what)
 674 {
 675   char buf[5];
 676
 677   /* If we have found an input file whose format we do not recognize,
 678      and we are therefore treating it as a linker script, and we find
 679      an invalid character, then most likely this is a real object file
 680      of some different format.  Treat it as such.  */
 681   if (ldfile_assumed_script)
 682     {
 683       bfd_set_error (bfd_error_file_not_recognized);
 684       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 685     }
 686
 687   if (! ISPRINT (*what))
 688     {
 689       sprintf (buf, "\\%03o", (unsigned int) *what);
 690       what = buf;
 691     }
 692
 693   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 694 }